lisp/org-mew.el

   1 ;;; org-mew.el --- Support for links to Mew messages from within Org-mode
   2
   3 ;; Copyright (C) 2008-2013 Free Software Foundation, Inc.
   4
   5 ;; Author: Tokuya Kameshima <kames at fa2 dot so-net dot ne dot jp>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: http://orgmode.org
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  24 ;;
  25 ;;; Commentary:
  26
  27 ;; This file implements links to Mew messages from within Org-mode.
  28 ;; Org-mode loads this module by default - if this is not what you want,
  29 ;; configure the variable `org-modules'.
  30 ;;
  31 ;; Here is an example of workflow:
  32
  33 ;; In your ~/.mew.el configuration file:
  34 ;;
  35 ;; (define-key mew-summary-mode-map "'" 'org-mew-search)
  36 ;; (eval-after-load "mew-summary"
  37 ;;   '(define-key mew-summary-mode-map "\C-o" 'org-mew-capture))
  38
  39 ;; 1. In the Mew's inbox folder, take a glance at new messages to find
  40 ;;    a message that requires any action.
  41
  42 ;; 2. If the message is a reply from somebody and associated with the
  43 ;;    existing orgmode entry, type M-x `org-mew-search' RET (or press
  44 ;;    the ' key simply) to find the entry.  If you can find the entry
  45 ;;    successfully and think you should start the task right now,
  46 ;;    start the task by M-x `org-agenda-clock-in' RET.
  47
  48 ;; 3. If the message is a new message, type M-x `org-mew-capture' RET,
  49 ;;    enter the refile folder, and the buffer to capture the message
  50 ;;    is shown up (without selecting the template by hand).  Then you
  51 ;;    can fill the template and type C-c C-c to complete the capture.
  52 ;;    Note that you can configure `org-capture-templates' so that the
  53 ;;    captured entry has a link to the message.
  54
  55 ;;; Code:
  56
  57 (require 'org)
  58
  59 (defgroup org-mew nil
  60   "Options concerning the Mew link."
  61   :tag "Org Startup"
  62   :group 'org-link)
  63
  64 (defcustom org-mew-link-to-refile-destination t
  65   "Create a link to the refile destination if the message is marked as refile."
  66   :group 'org-mew
  67   :type 'boolean)
  68
  69 (defcustom org-mew-inbox-folder nil
  70   "The folder where new messages are incorporated.
  71 If `org-mew-inbox-folder' is non-nil, `org-mew-open' locates the message
  72 in this inbox folder as well as the folder specified by the link."
  73   :group 'org-mew
  74   :version "24.4"
  75   :package-version '(Org . "8.0")
  76   :type 'string)
  77
  78 (defcustom org-mew-use-id-db t
  79   "Use ID database to locate the message if id.db is created."
  80   :group 'org-mew
  81   :version "24.4"
  82   :package-version '(Org . "8.0")
  83   :type 'boolean)
  84
  85 (defcustom org-mew-subject-alist
  86   (list (cons (concat "^\\(?:\\(?:re\\|fwd?\\): *\\)*"
  87                       "\\(?:[[(][a-z0-9._-]+[:,]? [0-9]+[])]\\)? *"
  88                       "\\(?:\\(?:re\\|fwd?\\): *\\)*"
  89                       "\\(.*\\)[ \t]*")
  90               1))
  91   "Alist of subject regular expression and matched group number for search."
  92   :group 'org-mew
  93   :version "24.4"
  94   :package-version '(Org . "8.0")
  95   :type '(repeat (cons (regexp) (integer))))
  96
  97 (defcustom org-mew-capture-inbox-folders nil
  98   "List of inbox folders whose messages need refile marked before capture.
  99 `org-mew-capture' will ask you to put the refile mark on the
 100 message if the message's folder is any of these folders and the
 101 message is not marked.  Nil means `org-mew-capture' never ask you
 102 destination folders before capture."
 103   :group 'org-mew
 104   :version "24.4"
 105   :package-version '(Org . "8.0")
 106   :type '(repeat string))
 107
 108 (defcustom org-mew-capture-guess-alist nil
 109   "Alist of the regular expression of the folder name and the capture
 110 template selection keys.
 111
 112 For example,
 113     '((\"^%emacs-orgmode$\" . \"o\")
 114       (\"\" . \"t\"))
 115 the messages in \"%emacs-orgmode\" folder will be captured with
 116 the capture template associated with \"o\" key, and any other
 117 messages will be captured with the capture template associated
 118 with \"t\" key."
 119   :group 'org-mew
 120   :version "24.4"
 121   :package-version '(Org . "8.0")
 122   :type '(repeat (cons regexp string)))
 123
 124 ;; Declare external functions and variables
 125 (declare-function mew-cache-hit "ext:mew-cache" (fld msg &optional must-hit))
 126 (declare-function mew-case-folder "ext:mew-func" (case folder))
 127 (declare-function mew-folder-path-to-folder
 128                   "ext:mew-func" (path &optional has-proto))
 129 (declare-function mew-folder-remotep "ext:mew-func" (folder))
 130 (declare-function mew-folder-virtualp "ext:mew-func" (folder))
 131 (declare-function mew-header-get-value "ext:mew-header"
 132                   (field &optional as-list))
 133 (declare-function mew-init "ext:mew" ())
 134 (declare-function mew-refile-get "ext:mew-refile" (msg))
 135 (declare-function mew-sinfo-get-case "ext:mew-summary" ())
 136 (declare-function mew-summary-diag-global "ext:mew-thread" (id opt who))
 137 (declare-function mew-summary-display "ext:mew-summary2" (&optional redisplay))
 138 (declare-function mew-summary-folder-name "ext:mew-syntax" (&optional ext))
 139 (declare-function mew-summary-get-mark "ext:mew-mark" ())
 140 (declare-function mew-summary-message-number2 "ext:mew-syntax" ())
 141 (declare-function mew-summary-pick-with-mewl "ext:mew-pick"
 142                   (pattern folder src-msgs))
 143 (declare-function mew-summary-refile "ext:mew-refile" (&optional report))
 144 (declare-function mew-summary-search-msg "ext:mew-const" (msg))
 145 (declare-function mew-summary-set-message-buffer "ext:mew-summary3" (fld msg))
 146 (declare-function mew-summary-visit-folder "ext:mew-summary4"
 147                   (folder &optional goend no-ls))
 148 (declare-function mew-window-push "ext:mew" ())
 149 (defvar mew-init-p)
 150 (defvar mew-mark-afterstep-spec)
 151 (defvar mew-summary-goto-line-then-display)
 152
 153 ;; Install the link type
 154 (org-add-link-type "mew" 'org-mew-open)
 155 (add-hook 'org-store-link-functions 'org-mew-store-link)
 156
 157 ;; Implementation
 158 (defun org-mew-store-link ()
 159   "Store a link to a Mew folder or message."
 160   (save-window-excursion
 161     (if (eq major-mode 'mew-message-mode)
 162         (mew-message-goto-summary))
 163     (when (memq major-mode '(mew-summary-mode mew-virtual-mode))
 164       (let ((msgnum (mew-summary-message-number2))
 165             (folder-name (org-mew-folder-name)))
 166         (if (fboundp 'mew-summary-set-message-buffer)
 167             (mew-summary-set-message-buffer folder-name msgnum)
 168           (set-buffer (mew-cache-hit folder-name msgnum t)))
 169         (let* ((message-id (mew-header-get-value "Message-Id:"))
 170                (from (mew-header-get-value "From:"))
 171                (to (mew-header-get-value "To:"))
 172                (date (mew-header-get-value "Date:"))
 173                (date-ts (and date (format-time-string
 174                                    (org-time-stamp-format t)
 175                                    (date-to-time date))))
 176                (date-ts-ia (and date (format-time-string
 177                                       (org-time-stamp-format t t)
 178                                       (date-to-time date))))
 179                (subject (mew-header-get-value "Subject:"))
 180                desc link)
 181           (org-store-link-props :type "mew" :from from :to to
 182                                 :subject subject :message-id message-id)
 183           (when date
 184             (org-add-link-props :date date :date-timestamp date-ts
 185                                 :date-timestamp-inactive date-ts-ia))
 186           (setq message-id (org-remove-angle-brackets message-id))
 187           (setq desc (org-email-link-description))
 188           (setq link (concat "mew:" folder-name "#" message-id))
 189           (org-add-link-props :link link :description desc)
 190           link)))))
 191
 192 (defun org-mew-folder-name ()
 193   "Return the folder name of the current message."
 194   (save-window-excursion
 195     (if (eq major-mode 'mew-message-mode)
 196         (mew-message-goto-summary))
 197     (let* ((msgnum (mew-summary-message-number2))
 198            (mark-info (mew-summary-get-mark)))
 199       (if (and org-mew-link-to-refile-destination
 200                (eq mark-info ?o))       ; marked as refile
 201           (nth 1 (mew-refile-get msgnum))
 202         (let ((folder-or-path (mew-summary-folder-name)))
 203           (mew-folder-path-to-folder folder-or-path t))))))
 204
 205 (defun org-mew-open (path)
 206   "Follow the Mew message link specified by PATH."
 207   (let (folder message-id)
 208     (cond ((string-match "\\`\\(+.*\\)+\\+\\([0-9]+\\)\\'" path) ; for Bastien's
 209            (setq folder (match-string 1 path))
 210            (setq message-id (match-string 2 path)))
 211           ((string-match "\\`\\(\\(%#\\)?[^#]+\\)\\(#\\(.*\\)\\)?" path)
 212            (setq folder (match-string 1 path))
 213            (setq message-id (match-string 4 path)))
 214           ((and org-mew-use-id-db (string-match "\\`#\\(.+\\)" path))
 215            (setq folder nil)
 216            (setq message-id (match-string 1 path)))
 217           (t (error "Error in Mew link")))
 218     (require 'mew)
 219     (mew-window-push)
 220     (unless mew-init-p (mew-init))
 221     (if (null folder)
 222         (progn
 223           (mew t)
 224           (org-mew-open-by-message-id message-id))
 225       (or (org-mew-follow-link folder message-id)
 226           (and org-mew-inbox-folder (not (string= org-mew-inbox-folder folder))
 227                (org-mew-follow-link org-mew-inbox-folder message-id))
 228           (and org-mew-use-id-db
 229                (org-mew-open-by-message-id message-id))
 230           (error "Message not found")))))
 231
 232 (defun org-mew-follow-link (folder message-id)
 233   (unless (org-mew-folder-exists-p folder)
 234     (error "No such folder or wrong folder %s" folder))
 235   (mew-summary-visit-folder folder)
 236   (when message-id
 237     (let ((msgnum (org-mew-get-msgnum folder message-id)))
 238       (when (mew-summary-search-msg msgnum)
 239         (if mew-summary-goto-line-then-display
 240             (mew-summary-display))
 241         t))))
 242
 243 (defun org-mew-folder-exists-p (folder)
 244   (let ((dir (mew-expand-folder folder)))
 245     (cond
 246      ((mew-folder-virtualp folder) (get-buffer folder))
 247      ((null dir) nil)
 248      ((mew-folder-remotep (mew-case:folder-folder folder)) t)
 249      (t (file-directory-p dir)))))
 250
 251 (defun org-mew-get-msgnum (folder message-id)
 252   (if (string-match "\\`[0-9]+\\'" message-id)
 253       message-id
 254     (let* ((pattern (concat "message-id=" message-id))
 255            (msgs (mew-summary-pick-with-mewl pattern folder nil)))
 256       (car msgs))))
 257
 258 (defun org-mew-open-by-message-id (message-id)
 259   "Open message using ID database."
 260   (let ((result (mew-summary-diag-global (format "<%s>" message-id)
 261                                          "-p" "Message")))
 262     (unless (eq result t)
 263       (error "Message not found"))))
 264
 265 ;; In ~/.mew.el, add the following line:
 266 ;;   (define-key mew-summary-mode-map "'" 'org-mew-search)
 267 (defun org-mew-search (&optional arg)
 268   "Show all entries related to the message using `org-search-view'.
 269
 270 It shows entries which contains the message ID, the reference
 271 IDs, or the subject of the message.
 272
 273 With C-u prefix, search for the entries that contains the message
 274 ID or any of the reference IDs.  With C-u C-u prefix, search for
 275 the message ID or the last reference ID.
 276
 277 The search phase for the subject is extracted with
 278 `org-mew-subject-alist', which defines the regular expression of
 279 the subject and the group number to extract.  You can get rid of
 280 \"Re:\" and some other prefix from the subject text."
 281   (interactive "P")
 282   (when (memq major-mode '(mew-summary-mode mew-virtual-mode))
 283     (let ((last-reference-only (equal arg '(16)))
 284           (by-subject (null arg))
 285           (msgnum (mew-summary-message-number2))
 286           (folder-name (mew-summary-folder-name))
 287           subject message-id references id-list)
 288       (save-window-excursion
 289         (if (fboundp 'mew-summary-set-message-buffer)
 290             (mew-summary-set-message-buffer folder-name msgnum)
 291           (set-buffer (mew-cache-hit folder-name msgnum t)))
 292         (setq subject (mew-header-get-value "Subject:"))
 293         (setq message-id (mew-header-get-value "Message-Id:"))
 294         (setq references (mew-header-get-value "References:")))
 295       (setq id-list (mapcar (lambda (id) (org-remove-angle-brackets id))
 296                             (mew-idstr-to-id-list references)))
 297       (if last-reference-only
 298           (setq id-list (last id-list))
 299         (if message-id
 300             (setq id-list (cons (org-remove-angle-brackets message-id)
 301                                 id-list))))
 302       (when (and by-subject (stringp subject))
 303         (catch 'matched
 304           (mapc (lambda (elem)
 305                   (let ((regexp (car elem))
 306                         (num (cdr elem)))
 307                     (when (string-match regexp subject)
 308                       (setq subject (match-string num subject))
 309                       (throw 'matched t))))
 310                 org-mew-subject-alist))
 311         (setq id-list (cons subject id-list)))
 312       (cond ((null id-list)
 313              (error "No message ID to search."))
 314             ((equal (length id-list) 1)
 315              (org-search-view nil (car id-list)))
 316             (t
 317              (org-search-view nil (format "{\\(%s\\)}"
 318                                           (mapconcat 'regexp-quote
 319                                                      id-list "\\|"))))))
 320     (delete-other-windows)))
 321
 322 (defun org-mew-capture (arg)
 323   "Guess the capture template from the folder name and invoke `org-capture'.
 324
 325 This selects a capture template in `org-capture-templates' by
 326 searching for capture template selection keys defined in
 327 `org-mew-capture-guess-alist' which are associated with the
 328 regular expression that matches the message's folder name, and
 329 then invokes `org-capture'.
 330
 331 If the message's folder is a inbox folder, you are prompted to
 332 put the refile mark on the message and the capture template is
 333 guessed from the refile destination folder.  You can customize
 334 the inbox folders by `org-mew-capture-inbox-folders'.
 335
 336 If ARG is non-nil, this does not guess the capture template but
 337 asks you to select the capture template."
 338   (interactive "P")
 339   (or (not (member (org-mew-folder-name)
 340                    org-mew-capture-inbox-folders))
 341       (eq (mew-summary-get-mark) ?o)
 342       (save-window-excursion
 343         (if (eq major-mode 'mew-message-mode)
 344             (mew-message-goto-summary))
 345         (let ((mew-mark-afterstep-spec '((?o 0 0 0 0 0 0 0))))
 346           (mew-summary-refile)))
 347       (error "No refile folder selected."))
 348   (let* ((org-mew-link-to-refile-destination t)
 349          (folder-name (org-mew-folder-name))
 350          (keys (if arg
 351                    nil
 352                  (org-mew-capture-guess-selection-keys folder-name))))
 353     (org-capture nil keys)))
 354
 355 (defun org-mew-capture-guess-selection-keys (folder-name)
 356   (catch 'found
 357     (let ((alist org-mew-capture-guess-alist))
 358       (while alist
 359         (let ((elem (car alist)))
 360           (if (string-match (car elem) folder-name)
 361               (throw 'found (cdr elem))))
 362         (setq alist (cdr alist))))))
 363
 364 (provide 'org-mew)
 365
 366 ;;; org-mew.el ends here