lisp/org-id.el

   1 ;;; org-id.el --- Global identifiers for Org-mode entries
   2 ;;
   3 ;; Copyright (C) 2008, 2009 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: http://orgmode.org
   8 ;; Version: 6.27trans
   9 ;;
  10 ;; This file is part of GNU Emacs.
  11 ;;
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  25 ;;
  26 ;;; Commentary:
  27
  28 ;; This file implements globally unique identifiers for Org-mode entries.
  29 ;; Identifiers are stored in the entry as an :ID: property.  Functions
  30 ;; are provided that create and retrieve such identifiers, and that find
  31 ;; entries based on the identifier.
  32
  33 ;; Identifiers consist of a prefix (default "Org" given by the variable
  34 ;; `org-id-prefix') and a unique part that can be created by a number
  35 ;; of different methods, see the variable `org-id-method'.
  36 ;; Org has a builtin method that uses a compact encoding of the creation
  37 ;; time of the ID, with microsecond accuracy.  This virtually
  38 ;; guarantees globally unique identifiers, even if several people are
  39 ;; creating IDs at the same time in files that will eventually be used
  40 ;; together.  As an external method `uuidgen' is supported, if installed
  41 ;; on the system.
  42 ;;
  43 ;; This file defines the following API:
  44 ;;
  45 ;; org-id-get-create
  46 ;;        Create an ID for the entry at point if it does not yet have one.
  47 ;;        Returns the ID (old or new).  This function can be used
  48 ;;        interactively, with prefix argument the creation of a new ID is
  49 ;;        forced, even if there was an old one.
  50 ;;
  51 ;; org-id-get
  52 ;;        Get the ID property of an entry.  Using appropriate arguments
  53 ;;        to the function, it can also create the ID for this entry.
  54 ;;
  55 ;; org-id-goto
  56 ;;        Command to go to a specific ID, this command can be used
  57 ;;        interactively.
  58 ;;
  59 ;; org-id-get-with-outline-path-completion
  60 ;;        Retrieve the ID of an entry, using outline path completion.
  61 ;;        This function can work for multiple files.
  62 ;;
  63 ;; org-id-get-with-outline-drilling
  64 ;;        Retrieve the ID of an entry, using outline path completion.
  65 ;;        This function only works for the current file.
  66 ;;
  67 ;; org-id-find
  68 ;;        Find the location of an entry with specific id.
  69 ;;
  70
  71 (require 'org)
  72
  73 (declare-function message-make-fqdn "message" ())
  74
  75 ;;; Customization
  76
  77 (defgroup org-id nil
  78   "Options concerning global entry identifiers in Org-mode."
  79   :tag "Org ID"
  80   :group 'org)
  81
  82
  83 (defcustom org-id-method
  84   (condition-case nil
  85       (if (string-match "\\`[-0-9a-fA-F]\\{36\\}\\'"
  86                         (org-trim (shell-command-to-string "uuidgen")))
  87           'uuidgen
  88         'org)
  89     (error 'org))
  90   "The method that should be used to create new IDs.
  91
  92 If `uuidgen' is available on the system, it will be used as the default method.
  93 if not, the method `org' is used.
  94 An ID will consist of the optional prefix specified in `org-id-prefix',
  95 and a unique part created by the method this variable specifies.
  96
  97 Allowed values are:
  98
  99 org        Org's own internal method, using an encoding of the current time to
 100            microsecond accuracy, and optionally the current domain of the
 101            computer.  See the variable `org-id-include-domain'.
 102
 103 uuidgen    Call the external command uuidgen."
 104   :group 'org-id
 105   :type '(choice
 106           (const :tag "Org's internal method" org)
 107           (const :tag "external: uuidgen" uuidgen)))
 108
 109 (defcustom org-id-prefix nil
 110   "The prefix for IDs.
 111
 112 This may be a string, or it can be nil to indicate that no prefix is required.
 113 When a string, the string should have no space characters as IDs are expected
 114 to have no space characters in them."
 115   :group 'org-id
 116   :type '(choice
 117           (const :tag "No prefix")
 118           (string :tag "Prefix")))
 119
 120 (defcustom org-id-include-domain nil
 121   "Non-nil means, add the domain name to new IDs.
 122 This ensures global uniqueness of IDs, and is also suggested by
 123 RFC 2445 in combination with RFC 822.  This is only relevant if
 124 `org-id-method' is `org'.  When uuidgen is used, the domain will never
 125 be added.
 126 The default is to not use this because we have no really good way to get
 127 the true domain, and Org entries will normally not be shared with enough
 128 people to make this necessary."
 129   :group 'org-id
 130   :type 'boolean)
 131
 132 (defcustom org-id-track-globally t
 133   "Non-nil means, track IDs through files, so that links work globally.
 134 This work by maintaining a hash table for IDs and writing this table
 135 to disk when exiting Emacs.  Because of this, it works best if you use
 136 a single Emacs process, not many.
 137
 138 When nil, IDs are not tracked.  Links to IDs will still work within
 139 a buffer, but not if the entry is located in another file.
 140 IDs can still be used if the entry with the id is in the same file as
 141 the link."
 142   :group 'org-id
 143   :type 'boolean)
 144
 145 (defcustom org-id-locations-file (convert-standard-filename
 146                                   "~/.emacs.d/.org-id-locations")
 147   "The file for remembering in which file an ID was defined.
 148 This variable is only relevant when `org-id-track-globally' is set."
 149   :group 'org-id
 150   :type 'file)
 151
 152 (defvar org-id-locations nil
 153   "List of files with IDs in those files.
 154 Depending on `org-id-use-hash' this can also be a hash table mapping IDs
 155 to files.")
 156
 157 (defvar org-id-files nil
 158   "List of files that contain IDs.")
 159
 160 (defcustom org-id-extra-files 'org-agenda-text-search-extra-files
 161   "Files to be searched for IDs, besides the agenda files.
 162 When Org reparses files to remake the list of files and IDs it is tracking,
 163 it will normally scan the agenda files, the archives related to agenda files,
 164 any files that are listed as ID containing in the current register, and
 165 any Org-mode files currently visited by Emacs.
 166 You can list additional files here.
 167 This variable is only relevant when `org-id-track-globally' is set."
 168   :group 'org-id
 169   :type
 170   '(choice
 171     (symbol :tag "Variable")
 172     (repeat :tag "List of files"
 173             (file))))
 174
 175 (defcustom org-id-search-archives t
 176   "Non-nil means, search also the archive files of agenda files for entries.
 177 This is a possibility to reduce overhead, but it means that entries moved
 178 to the archives can no longer be found by ID.
 179 This variable is only relevant when `org-id-track-globally' is set."
 180   :group 'org-id
 181   :type 'boolean)
 182
 183 ;;; The API functions
 184
 185 ;;;###autoload
 186 (defun org-id-get-create (&optional force)
 187   "Create an ID for the current entry and return it.
 188 If the entry already has an ID, just return it.
 189 With optional argument FORCE, force the creation of a new ID."
 190   (interactive "P")
 191   (when force
 192     (org-entry-put (point) "ID" nil))
 193   (org-id-get (point) 'create))
 194
 195 ;;;###autoload
 196 (defun org-id-copy ()
 197   "Copy the ID of the entry at point to the kill ring.
 198 Create an ID if necessary."
 199   (interactive)
 200   (kill-new (org-id-get nil 'create)))
 201
 202 ;;;###autoload
 203 (defun org-id-get (&optional pom create prefix)
 204   "Get the ID property of the entry at point-or-marker POM.
 205 If POM is nil, refer to the entry at point.
 206 If the entry does not have an ID, the function returns nil.
 207 However, when CREATE is non nil, create an ID if none is present already.
 208 PREFIX will be passed through to `org-id-new'.
 209 In any case, the ID of the entry is returned."
 210   (let ((id (org-entry-get pom "ID")))
 211     (cond
 212      ((and id (stringp id) (string-match "\\S-" id))
 213       id)
 214      (create
 215       (setq id (org-id-new prefix))
 216       (org-entry-put pom "ID" id)
 217       (org-id-add-location id (buffer-file-name (buffer-base-buffer)))
 218       id)
 219      (t nil))))
 220
 221 ;;;###autoload
 222 (defun org-id-get-with-outline-path-completion (&optional targets)
 223   "Use outline-path-completion to retrieve the ID of an entry.
 224 TARGETS may be a setting for `org-refile-targets' to define the eligible
 225 headlines.  When omitted, all headlines in all agenda files are
 226 eligible.
 227 It returns the ID of the entry.  If necessary, the ID is created."
 228   (let* ((org-refile-targets (or targets '((nil . (:maxlevel . 10)))))
 229          (org-refile-use-outline-path
 230           (if (caar org-refile-targets) 'file t))
 231          (org-refile-target-verify-function nil)
 232          (spos (org-refile-get-location "Entry: "))
 233          (pom (and spos (move-marker (make-marker) (nth 3 spos)
 234                                      (get-file-buffer (nth 1 spos))))))
 235     (prog1 (org-id-get pom 'create)
 236       (move-marker pom nil))))
 237
 238 ;;;###autoload
 239 (defun org-id-get-with-outline-drilling (&optional targets)
 240   "Use an outline-cycling interface to retrieve the ID of an entry.
 241 This only finds entries in the current buffer, using `org-get-location'.
 242 It returns the ID of the entry.  If necessary, the ID is created."
 243   (let* ((spos (org-get-location (current-buffer) org-goto-help))
 244          (pom (and spos (move-marker (make-marker) (car spos)))))
 245     (prog1 (org-id-get pom 'create)
 246       (move-marker pom nil))))
 247
 248 ;;;###autoload
 249 (defun org-id-goto (id)
 250   "Switch to the buffer containing the entry with id ID.
 251 Move the cursor to that entry in that buffer."
 252   (interactive "sID: ")
 253   (let ((m (org-id-find id 'marker)))
 254     (unless m
 255       (error "Cannot find entry with ID \"%s\"" id))
 256     (switch-to-buffer (marker-buffer m))
 257     (goto-char m)
 258     (move-marker m nil)
 259     (org-show-context)))
 260
 261 ;;;###autoload
 262 (defun org-id-find (id &optional markerp)
 263   "Return the location of the entry with the id ID.
 264 The return value is a cons cell (file-name . position), or nil
 265 if there is no entry with that ID.
 266 With optional argument MARKERP, return the position as a new marker."
 267   (cond
 268    ((symbolp id) (setq id (symbol-name id)))
 269    ((numberp id) (setq id (number-to-string id))))
 270   (let ((file (org-id-find-id-file id))
 271         org-agenda-new-buffers where)
 272     (when file
 273       (setq where (org-id-find-id-in-file id file markerp)))
 274     (unless where
 275       (org-id-update-id-locations)
 276       (setq file (org-id-find-id-file id))
 277       (when file
 278         (setq where (org-id-find-id-in-file id file markerp))))
 279     where))
 280
 281 ;;; Internal functions
 282
 283 ;; Creating new IDs
 284
 285 (defun org-id-new (&optional prefix)
 286   "Create a new globally unique ID.
 287
 288 An ID consists of two parts separated by a colon:
 289 - a prefix
 290 - a unique part that will be created according to `org-id-method'.
 291
 292 PREFIX can specify the prefix, the default is given by the variable
 293 `org-id-prefix'.  However, if PREFIX is the symbol `none', don't use any
 294 prefix even if `org-id-prefix' specifies one.
 295
 296 So a typical ID could look like \"Org:4nd91V40HI\"."
 297   (let* ((prefix (if (eq prefix 'none)
 298                      ""
 299                    (concat (or prefix org-id-prefix) ":")))
 300          unique)
 301     (if (equal prefix ":") (setq prefix ""))
 302     (cond
 303      ((eq org-id-method 'uuidgen)
 304       (setq unique (org-trim (shell-command-to-string "uuidgen"))))
 305      ((eq org-id-method 'org)
 306       (let* ((etime (org-id-reverse-string (org-id-time-to-b36)))
 307              (postfix (if org-id-include-domain
 308                           (progn
 309                             (require 'message)
 310                             (concat "@" (message-make-fqdn))))))
 311         (setq unique (concat etime postfix))))
 312      (t (error "Invalid `org-id-method'")))
 313     (concat prefix unique)))
 314
 315 (defun org-id-reverse-string (s)
 316   (mapconcat 'char-to-string (nreverse (string-to-list s)) ""))
 317
 318 (defun org-id-int-to-b36-one-digit (i)
 319   "Turn an integer between 0 and 61 into a single character 0..9, A..Z, a..z."
 320   (cond
 321    ((< i 10) (+ ?0 i))
 322    ((< i 36) (+ ?a i -10))
 323    (t (error "Larger that 35"))))
 324
 325 (defun org-id-b36-to-int-one-digit (i)
 326   "Turn a character 0..9, A..Z, a..z into a number 0..61.
 327 The input I may be a character, or a single-letter string."
 328   (and (stringp i) (setq i (string-to-char i)))
 329   (cond
 330    ((and (>= i ?0) (<= i ?9)) (- i ?0))
 331    ((and (>= i ?a) (<= i ?z)) (+ (- i ?a) 10))
 332    (t (error "Invalid b36 letter"))))
 333
 334 (defun org-id-int-to-b36 (i &optional length)
 335   "Convert an integer to a base-36 number represented as a string."
 336   (let ((s ""))
 337     (while (> i 0)
 338       (setq s (concat (char-to-string
 339                        (org-id-int-to-b36-one-digit (mod i 36))) s)
 340             i (/ i 36)))
 341     (setq length (max 1 (or length 1)))
 342     (if (< (length s) length)
 343         (setq s (concat (make-string (- length (length s)) ?0) s)))
 344     s))
 345
 346 (defun org-id-b36-to-int (s)
 347   "Convert a base-36 string into the corresponding integer."
 348   (let ((r 0))
 349     (mapc (lambda (i) (setq r (+ (* r 36) (org-id-b36-to-int-one-digit i))))
 350           s)
 351     r))
 352
 353 (defun org-id-time-to-b36 (&optional time)
 354   "Encode TIME as a 10-digit string.
 355 This string holds the time to micro-second accuracy, and can be decoded
 356 using `org-id-decode'."
 357   (setq time (or time (current-time)))
 358   (concat (org-id-int-to-b36 (nth 0 time) 4)
 359           (org-id-int-to-b36 (nth 1 time) 4)
 360           (org-id-int-to-b36 (or (nth 2 time) 0) 4)))
 361
 362 (defun org-id-decode (id)
 363   "Split ID into the prefix and the time value that was used to create it.
 364 The return value is (prefix . time) where PREFIX is nil or a string,
 365 and time is the usual three-integer representation of time."
 366   (let (prefix time parts)
 367     (setq parts (org-split-string id ":"))
 368     (if (= 2 (length parts))
 369         (setq prefix (car parts) time (nth 1 parts))
 370       (setq prefix nil time (nth 0 parts)))
 371     (setq time (org-id-reverse-string time))
 372     (setq time (list (org-id-b36-to-int (substring time 0 4))
 373                      (org-id-b36-to-int (substring time 4 8))
 374                      (org-id-b36-to-int (substring time 8 12))))
 375     (cons prefix time)))
 376
 377 ;; Storing ID locations (files)
 378
 379 (defun org-id-update-id-locations (&optional files)
 380   "Scan relevant files for IDs.
 381 Store the relation between files and corresponding IDs.
 382 This will scan all agenda files, all associated archives, and all
 383 files currently mentioned in `org-id-locations'.
 384 When FILES is given, scan these files instead.
 385 When CHECK is given, prepare detailed information about duplicate IDs."
 386   (interactive)
 387   (if (not org-id-track-globally)
 388       (error "Please turn on `org-id-track-globally' if you want to track IDs.")
 389     (let ((files
 390            (or files
 391                (append
 392                 ;; Agenda files and all associated archives
 393                 (org-agenda-files t org-id-search-archives)
 394                 ;; Explicit extra files
 395                 (if (symbolp org-id-extra-files)
 396                     (symbol-value org-id-extra-files)
 397                   org-id-extra-files)
 398               ;; Files associated with live org-mode buffers
 399                 (delq nil
 400                       (mapcar (lambda (b)
 401                                 (with-current-buffer b
 402                                   (and (org-mode-p) (buffer-file-name))))
 403                               (buffer-list)))
 404                 ;; All files known to have IDs
 405                 org-id-files)))
 406           org-agenda-new-buffers
 407           file nfiles tfile ids reg found id seen (ndup 0))
 408       (setq nfiles (length files))
 409       (while (setq file (pop files))
 410         (message "Finding ID locations (%d/%d files): %s"
 411                  (- nfiles (length files)) nfiles file)
 412         (setq tfile (file-truename file))
 413         (when (and (file-exists-p file) (not (member tfile seen)))
 414           (push tfile seen)
 415           (setq ids nil)
 416           (with-current-buffer (org-get-agenda-file-buffer file)
 417             (save-excursion
 418               (save-restriction
 419                 (widen)
 420                 (goto-char (point-min))
 421                 (while (re-search-forward "^[ \t]*:ID:[ \t]+\\(\\S-+\\)[ \t]*$"
 422                                           nil t)
 423                   (setq id (org-match-string-no-properties 1))
 424                   (if (member id found)
 425                       (progn
 426                         (message "Duplicate ID \"%s\", also in file %s"
 427                                  id (car (delq
 428                                           nil
 429                                           (mapcar
 430                                            (lambda (x)
 431                                              (if (member id (cdr x)) (car x)))
 432                                            reg))))
 433                         (when (= ndup 0)
 434                           (ding)
 435                           (sit-for 2))
 436                         (setq ndup (1+ ndup)))
 437                     (push id found)
 438                     (push id ids)))
 439                 (push (cons (abbreviate-file-name file) ids) reg))))))
 440       (org-release-buffers org-agenda-new-buffers)
 441       (setq org-agenda-new-buffers nil)
 442       (setq org-id-locations reg)
 443       (setq org-id-files (mapcar 'car org-id-locations))
 444       (org-id-locations-save) ;; this function can also handle the alist form
 445       ;; now convert to a hash
 446       (setq org-id-locations (org-id-alist-to-hash org-id-locations))
 447       (if (> ndup 0)
 448           (message "WARNING: %d duplicate IDs found, check *Messages* buffer" ndup)
 449         (message "%d unique files scanned for IDs" (length org-id-files)))
 450       org-id-locations)))
 451
 452 (defun org-id-locations-save ()
 453   "Save `org-id-locations' in `org-id-locations-file'."
 454   (when org-id-track-globally
 455     (let ((out (if (hash-table-p org-id-locations)
 456                    (org-id-hash-to-alist org-id-locations)
 457                  org-id-locations)))
 458       (with-temp-file org-id-locations-file
 459         (print out (current-buffer))))))
 460
 461 (defun org-id-locations-load ()
 462   "Read the data from `org-id-locations-file'."
 463   (setq org-id-locations nil)
 464   (when org-id-track-globally
 465     (with-temp-buffer
 466       (condition-case nil
 467           (progn
 468             (insert-file-contents-literally org-id-locations-file)
 469             (goto-char (point-min))
 470             (setq org-id-locations (read (current-buffer))))
 471         (error
 472          (message "Could not read org-id-values from %s. Setting it to nil."
 473                   org-id-locations-file))))
 474     (setq org-id-files (mapcar 'car org-id-locations))
 475     (setq org-id-locations (org-id-alist-to-hash org-id-locations))))
 476
 477 (defun org-id-add-location (id file)
 478   "Add the ID with location FILE to the database of ID locations."
 479   ;; Only if global tracking is on, and when the buffer has a file
 480   (when (and org-id-track-globally id file)
 481     (unless org-id-locations (org-id-locations-load))
 482     (puthash id (abbreviate-file-name file) org-id-locations)
 483     (add-to-list 'org-id-files (abbreviate-file-name file))))
 484
 485 (add-hook 'kill-emacs-hook 'org-id-locations-save)
 486
 487 (defun org-id-hash-to-alist (hash)
 488   "Turn an org-id hash into an alist, so that it can be written to a file."
 489   (let (res x)
 490     (maphash
 491      (lambda (k v)
 492        (if (setq x (member v res))
 493            (setcdr x (cons k (cdr x)))
 494          (push (list v k) res)))
 495      hash)
 496     res))
 497
 498 (defun org-id-alist-to-hash (list)
 499   "Turn an org-id location list into a hash table."
 500   (let ((res (make-hash-table
 501               :test 'equal
 502               :size (apply '+ (mapcar 'length list))))
 503         f)
 504     (mapc
 505      (lambda (x)
 506        (setq f (car x))
 507        (mapc (lambda (i) (puthash i f res)) (cdr x)))
 508      list)
 509     res))
 510
 511 (defun org-id-paste-tracker (txt &optional buffer-or-file)
 512   "Update any IDs in TXT and assign BUFFER-OR-FILE to them."
 513   (when org-id-track-globally
 514     (save-match-data
 515       (setq buffer-or-file (or buffer-or-file (current-buffer)))
 516       (when (bufferp buffer-or-file)
 517         (setq buffer-or-file (or (buffer-base-buffer buffer-or-file)
 518                                  buffer-or-file))
 519         (setq buffer-or-file (buffer-file-name buffer-or-file)))
 520       (when buffer-or-file
 521         (let ((fname (abbreviate-file-name buffer-or-file))
 522               (s 0))
 523           (while (string-match "^[ \t]*:ID:[ \t]+\\([^ \t\n\r]+\\)" txt s)
 524             (setq s (match-end 0))
 525             (org-id-add-location (match-string 1 txt) fname)))))))
 526
 527 ;; Finding entries with specified id
 528
 529 ;;;###autoload
 530 (defun org-id-find-id-file (id)
 531   "Query the id database for the file in which this ID is located."
 532   (unless org-id-locations (org-id-locations-load))
 533   (or (gethash id org-id-locations)
 534       ;; ball back on current buffer
 535       (buffer-file-name (or (buffer-base-buffer (current-buffer))
 536                             (current-buffer)))))
 537
 538 (defun org-id-find-id-in-file (id file &optional markerp)
 539   "Return the position of the entry ID in FILE.
 540 If that files does not exist, or if it does not contain this ID,
 541 return nil.
 542 The position is returned as a cons cell (file-name . position).  With
 543 optional argument MARKERP, return the position as a new marker."
 544   (let (org-agenda-new-buffers buf pos)
 545     (cond
 546      ((not file) nil)
 547      ((not (file-exists-p file)) nil)
 548      (t (with-current-buffer (setq buf (org-get-agenda-file-buffer file))
 549           (setq pos (org-find-entry-with-id id))
 550           (when pos
 551             (if markerp
 552                 (move-marker (make-marker) pos buf)
 553               (cons file pos))))))))
 554
 555 ;; id link type
 556
 557 ;; Calling the following function is hard-coded into `org-store-link',
 558 ;; so we do have to add it to `org-store-link-functions'.
 559
 560 (defun org-id-store-link ()
 561   "Store a link to the current entry, using it's ID."
 562   (interactive)
 563   (let* ((link (org-make-link "id:" (org-id-get-create)))
 564          (desc (save-excursion
 565                  (org-back-to-heading t)
 566                  (or (and (looking-at org-complex-heading-regexp)
 567                           (if (match-end 4) (match-string 4) (match-string 0)))
 568                      link))))
 569     (org-store-link-props :link link :description desc :type "id")
 570     link))
 571
 572 (defun org-id-open (id)
 573   "Go to the entry with id ID."
 574   (org-mark-ring-push)
 575   (let ((m (org-id-find id 'marker)))
 576     (unless m
 577       (error "Cannot find entry with ID \"%s\"" id))
 578     (if (not (equal (current-buffer) (marker-buffer m)))
 579         (switch-to-buffer-other-window (marker-buffer m)))
 580     (goto-char m)
 581     (move-marker m nil)
 582     (org-show-context)))
 583
 584 (org-add-link-type "id" 'org-id-open)
 585
 586 (provide 'org-id)
 587
 588 ;;; org-id.el ends here
 589
 590 ;; arch-tag: e5abaca4-e16f-4b25-832a-540cfb63a712
 591
 592