lisp/ox-icalendar.el

   1 ;;; ox-icalendar.el --- iCalendar Back-End for Org Export Engine -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2004-2016 Free Software Foundation, Inc.
   4
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;;      Nicolas Goaziou <n dot goaziou at gmail dot com>
   7 ;; Keywords: outlines, hypermedia, calendar, wp
   8 ;; Homepage: http://orgmode.org
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26 ;;
  27 ;; This library implements an iCalendar back-end for Org generic
  28 ;; exporter.  See Org manual for more information.
  29 ;;
  30 ;; It is expected to conform to RFC 5545.
  31
  32 ;;; Code:
  33
  34 (eval-when-compile (require 'cl))
  35 (require 'cl-lib)
  36 (require 'ox-ascii)
  37 (declare-function org-bbdb-anniv-export-ical "org-bbdb" nil)
  38
  39
  40 \f
  41 ;;; User-Configurable Variables
  42
  43 (defgroup org-export-icalendar nil
  44   "Options specific for iCalendar export back-end."
  45   :tag "Org Export iCalendar"
  46   :group 'org-export)
  47
  48 (defcustom org-icalendar-combined-agenda-file "~/org.ics"
  49   "The file name for the iCalendar file covering all agenda files.
  50 This file is created with the command \\[org-icalendar-combine-agenda-files].
  51 The file name should be absolute.  It will be overwritten without warning."
  52   :group 'org-export-icalendar
  53   :type 'file)
  54
  55 (defcustom org-icalendar-alarm-time 0
  56   "Number of minutes for triggering an alarm for exported timed events.
  57
  58 A zero value (the default) turns off the definition of an alarm trigger
  59 for timed events.  If non-zero, alarms are created.
  60
  61 - a single alarm per entry is defined
  62 - The alarm will go off N minutes before the event
  63 - only a DISPLAY action is defined."
  64   :group 'org-export-icalendar
  65   :version "24.1"
  66   :type 'integer)
  67
  68 (defcustom org-icalendar-combined-name "OrgMode"
  69   "Calendar name for the combined iCalendar representing all agenda files."
  70   :group 'org-export-icalendar
  71   :type 'string)
  72
  73 (defcustom org-icalendar-combined-description ""
  74   "Calendar description for the combined iCalendar (all agenda files)."
  75   :group 'org-export-icalendar
  76   :type 'string)
  77
  78 (defcustom org-icalendar-exclude-tags nil
  79   "Tags that exclude a tree from export.
  80 This variable allows specifying different exclude tags from other
  81 back-ends.  It can also be set with the ICALENDAR_EXCLUDE_TAGS
  82 keyword."
  83   :group 'org-export-icalendar
  84   :type '(repeat (string :tag "Tag")))
  85
  86 (defcustom org-icalendar-use-deadline '(event-if-not-todo todo-due)
  87   "Contexts where iCalendar export should use a deadline time stamp.
  88
  89 This is a list with possibly several symbols in it.  Valid symbols are:
  90
  91 `event-if-todo'       Deadlines in TODO entries become calendar events.
  92 `event-if-not-todo'   Deadlines in non-TODO entries become calendar events.
  93 `todo-due'            Use deadlines in TODO entries as due-dates."
  94   :group 'org-export-icalendar
  95   :type '(set :greedy t
  96               (const :tag "Deadlines in non-TODO entries become events"
  97                      event-if-not-todo)
  98               (const :tag "Deadline in TODO entries become events"
  99                      event-if-todo)
 100               (const :tag "Deadlines in TODO entries become due-dates"
 101                      todo-due)))
 102
 103 (defcustom org-icalendar-use-scheduled '(todo-start)
 104   "Contexts where iCalendar export should use a scheduling time stamp.
 105
 106 This is a list with possibly several symbols in it.  Valid symbols are:
 107
 108 `event-if-todo'       Scheduling time stamps in TODO entries become an event.
 109 `event-if-not-todo'   Scheduling time stamps in non-TODO entries become an event.
 110 `todo-start'          Scheduling time stamps in TODO entries become start date.
 111                       Some calendar applications show TODO entries only after
 112                       that date."
 113   :group 'org-export-icalendar
 114   :type '(set :greedy t
 115               (const :tag
 116                      "SCHEDULED timestamps in non-TODO entries become events"
 117                      event-if-not-todo)
 118               (const :tag "SCHEDULED timestamps in TODO entries become events"
 119                      event-if-todo)
 120               (const :tag "SCHEDULED in TODO entries become start date"
 121                      todo-start)))
 122
 123 (defcustom org-icalendar-categories '(local-tags category)
 124   "Items that should be entered into the \"categories\" field.
 125
 126 This is a list of symbols, the following are valid:
 127 `category'    The Org mode category of the current file or tree
 128 `todo-state'  The todo state, if any
 129 `local-tags'  The tags, defined in the current line
 130 `all-tags'    All tags, including inherited ones."
 131   :group 'org-export-icalendar
 132   :type '(repeat
 133           (choice
 134            (const :tag "The file or tree category" category)
 135            (const :tag "The TODO state" todo-state)
 136            (const :tag "Tags defined in current line" local-tags)
 137            (const :tag "All tags, including inherited ones" all-tags))))
 138
 139 (defcustom org-icalendar-with-timestamps 'active
 140   "Non-nil means make an event from plain time stamps.
 141
 142 It can be set to `active', `inactive', t or nil, in order to make
 143 an event from, respectively, only active timestamps, only
 144 inactive ones, all of them or none.
 145
 146 This variable has precedence over `org-export-with-timestamps'.
 147 It can also be set with the #+OPTIONS line, e.g. \"<:t\"."
 148   :group 'org-export-icalendar
 149   :type '(choice
 150           (const :tag "All timestamps" t)
 151           (const :tag "Only active timestamps" active)
 152           (const :tag "Only inactive timestamps" inactive)
 153           (const :tag "No timestamp" nil)))
 154
 155 (defcustom org-icalendar-include-todo nil
 156   "Non-nil means create VTODO components from TODO items.
 157
 158 Valid values are:
 159 nil                  don't include any task.
 160 t                    include tasks that are not in DONE state.
 161 `unblocked'          include all TODO items that are not blocked.
 162 `all'                include both done and not done items."
 163   :group 'org-export-icalendar
 164   :type '(choice
 165           (const :tag "None" nil)
 166           (const :tag "Unfinished" t)
 167           (const :tag "Unblocked" unblocked)
 168           (const :tag "All" all)
 169           (repeat :tag "Specific TODO keywords"
 170                   (string :tag "Keyword"))))
 171
 172 (defcustom org-icalendar-include-bbdb-anniversaries nil
 173   "Non-nil means a combined iCalendar file should include anniversaries.
 174 The anniversaries are defined in the BBDB database."
 175   :group 'org-export-icalendar
 176   :type 'boolean)
 177
 178 (defcustom org-icalendar-include-sexps t
 179   "Non-nil means export to iCalendar files should also cover sexp entries.
 180 These are entries like in the diary, but directly in an Org file."
 181   :group 'org-export-icalendar
 182   :type 'boolean)
 183
 184 (defcustom org-icalendar-include-body t
 185   "Amount of text below headline to be included in iCalendar export.
 186 This is a number of characters that should maximally be included.
 187 Properties, scheduling and clocking lines will always be removed.
 188 The text will be inserted into the DESCRIPTION field."
 189   :group 'org-export-icalendar
 190   :type '(choice
 191           (const :tag "Nothing" nil)
 192           (const :tag "Everything" t)
 193           (integer :tag "Max characters")))
 194
 195 (defcustom org-icalendar-store-UID nil
 196   "Non-nil means store any created UIDs in properties.
 197
 198 The iCalendar standard requires that all entries have a unique identifier.
 199 Org will create these identifiers as needed.  When this variable is non-nil,
 200 the created UIDs will be stored in the ID property of the entry.  Then the
 201 next time this entry is exported, it will be exported with the same UID,
 202 superseding the previous form of it.  This is essential for
 203 synchronization services.
 204
 205 This variable is not turned on by default because we want to avoid creating
 206 a property drawer in every entry if people are only playing with this feature,
 207 or if they are only using it locally."
 208   :group 'org-export-icalendar
 209   :type 'boolean)
 210
 211 (defcustom org-icalendar-timezone (getenv "TZ")
 212   "The time zone string for iCalendar export.
 213 When nil or the empty string, use output
 214 from (current-time-zone)."
 215   :group 'org-export-icalendar
 216   :type '(choice
 217           (const :tag "Unspecified" nil)
 218           (string :tag "Time zone")))
 219
 220 (defcustom org-icalendar-date-time-format ":%Y%m%dT%H%M%S"
 221   "Format-string for exporting icalendar DATE-TIME.
 222
 223 See `format-time-string' for a full documentation.  The only
 224 difference is that `org-icalendar-timezone' is used for %Z.
 225
 226 Interesting value are:
 227  - \":%Y%m%dT%H%M%S\" for local time
 228  - \";TZID=%Z:%Y%m%dT%H%M%S\" for local time with explicit timezone
 229  - \":%Y%m%dT%H%M%SZ\" for time expressed in Universal Time"
 230   :group 'org-export-icalendar
 231   :version "24.1"
 232   :type '(choice
 233           (const :tag "Local time" ":%Y%m%dT%H%M%S")
 234           (const :tag "Explicit local time" ";TZID=%Z:%Y%m%dT%H%M%S")
 235           (const :tag "Universal time" ":%Y%m%dT%H%M%SZ")
 236           (string :tag "Explicit format")))
 237
 238 (defvar org-icalendar-after-save-hook nil
 239   "Hook run after an iCalendar file has been saved.
 240 This hook is run with the name of the file as argument.  A good
 241 way to use this is to tell a desktop calendar application to
 242 re-read the iCalendar file.")
 243
 244
 245 \f
 246 ;;; Define Back-End
 247
 248 (org-export-define-derived-backend 'icalendar 'ascii
 249   :translate-alist '((clock . ignore)
 250                      (footnote-definition . ignore)
 251                      (footnote-reference . ignore)
 252                      (headline . org-icalendar-entry)
 253                      (inlinetask . ignore)
 254                      (planning . ignore)
 255                      (section . ignore)
 256                      (inner-template . (lambda (c i) c))
 257                      (template . org-icalendar-template))
 258   :options-alist
 259   '((:exclude-tags
 260      "ICALENDAR_EXCLUDE_TAGS" nil org-icalendar-exclude-tags split)
 261     (:with-timestamps nil "<" org-icalendar-with-timestamps)
 262     ;; Other variables.
 263     (:icalendar-alarm-time nil nil org-icalendar-alarm-time)
 264     (:icalendar-categories nil nil org-icalendar-categories)
 265     (:icalendar-date-time-format nil nil org-icalendar-date-time-format)
 266     (:icalendar-include-bbdb-anniversaries nil nil org-icalendar-include-bbdb-anniversaries)
 267     (:icalendar-include-body nil nil org-icalendar-include-body)
 268     (:icalendar-include-sexps nil nil org-icalendar-include-sexps)
 269     (:icalendar-include-todo nil nil org-icalendar-include-todo)
 270     (:icalendar-store-UID nil nil org-icalendar-store-UID)
 271     (:icalendar-timezone nil nil org-icalendar-timezone)
 272     (:icalendar-use-deadline nil nil org-icalendar-use-deadline)
 273     (:icalendar-use-scheduled nil nil org-icalendar-use-scheduled))
 274   :filters-alist
 275   '((:filter-headline . org-icalendar-clear-blank-lines))
 276   :menu-entry
 277   '(?c "Export to iCalendar"
 278        ((?f "Current file" org-icalendar-export-to-ics)
 279         (?a "All agenda files"
 280             (lambda (a s v b) (org-icalendar-export-agenda-files a)))
 281         (?c "Combine all agenda files"
 282             (lambda (a s v b) (org-icalendar-combine-agenda-files a))))))
 283
 284
 285 \f
 286 ;;; Internal Functions
 287
 288 (defun org-icalendar-create-uid (file &optional bell)
 289   "Set ID property on headlines missing it in FILE.
 290 When optional argument BELL is non-nil, inform the user with
 291 a message if the file was modified."
 292   (let (modified-flag)
 293     (org-map-entries
 294      (lambda ()
 295        (let ((entry (org-element-at-point)))
 296          (unless (org-element-property :ID entry)
 297            (org-id-get-create)
 298            (setq modified-flag t)
 299            (forward-line))))
 300      nil nil 'comment)
 301     (when (and bell modified-flag)
 302       (message "ID properties created in file \"%s\"" file)
 303       (sit-for 2))))
 304
 305 (defun org-icalendar-blocked-headline-p (headline info)
 306   "Non-nil when HEADLINE is considered to be blocked.
 307
 308 INFO is a plist used as a communication channel.
 309
 310 A headline is blocked when either
 311
 312   - it has children which are not all in a completed state;
 313
 314   - it has a parent with the property :ORDERED:, and there are
 315     siblings prior to it with incomplete status;
 316
 317   - its parent is blocked because it has siblings that should be
 318     done first or is a child of a blocked grandparent entry."
 319   (or
 320    ;; Check if any child is not done.
 321    (org-element-map headline 'headline
 322      (lambda (hl) (eq (org-element-property :todo-type hl) 'todo))
 323      info 'first-match)
 324    ;; Check :ORDERED: node property.
 325    (catch 'blockedp
 326      (let ((current headline))
 327        (dolist (parent (org-element-lineage headline))
 328          (cond
 329           ((not (org-element-property :todo-keyword parent))
 330            (throw 'blockedp nil))
 331           ((org-not-nil (org-element-property :ORDERED parent))
 332            (let ((sibling current))
 333              (while (setq sibling (org-export-get-previous-element
 334                                    sibling info))
 335                (when (eq (org-element-property :todo-type sibling) 'todo)
 336                  (throw 'blockedp t)))))
 337           (t (setq current parent))))))))
 338
 339 (defun org-icalendar-use-UTC-date-time-p ()
 340   "Non-nil when `org-icalendar-date-time-format' requires UTC time."
 341   (char-equal (elt org-icalendar-date-time-format
 342                    (1- (length org-icalendar-date-time-format))) ?Z))
 343
 344 (defvar org-agenda-default-appointment-duration) ; From org-agenda.el.
 345 (defun org-icalendar-convert-timestamp (timestamp keyword &optional end utc)
 346   "Convert TIMESTAMP to iCalendar format.
 347
 348 TIMESTAMP is a timestamp object.  KEYWORD is added in front of
 349 it, in order to make a complete line (e.g. \"DTSTART\").
 350
 351 When optional argument END is non-nil, use end of time range.
 352 Also increase the hour by two (if time string contains a time),
 353 or the day by one (if it does not contain a time) when no
 354 explicit ending time is specified.
 355
 356 When optional argument UTC is non-nil, time will be expressed in
 357 Universal Time, ignoring `org-icalendar-date-time-format'."
 358   (let* ((year-start (org-element-property :year-start timestamp))
 359          (year-end (org-element-property :year-end timestamp))
 360          (month-start (org-element-property :month-start timestamp))
 361          (month-end (org-element-property :month-end timestamp))
 362          (day-start (org-element-property :day-start timestamp))
 363          (day-end (org-element-property :day-end timestamp))
 364          (hour-start (org-element-property :hour-start timestamp))
 365          (hour-end (org-element-property :hour-end timestamp))
 366          (minute-start (org-element-property :minute-start timestamp))
 367          (minute-end (org-element-property :minute-end timestamp))
 368          (with-time-p minute-start)
 369          (equal-bounds-p
 370           (equal (list year-start month-start day-start hour-start minute-start)
 371                  (list year-end month-end day-end hour-end minute-end)))
 372          (mi (cond ((not with-time-p) 0)
 373                    ((not end) minute-start)
 374                    ((and org-agenda-default-appointment-duration equal-bounds-p)
 375                     (+ minute-end org-agenda-default-appointment-duration))
 376                    (t minute-end)))
 377          (h (cond ((not with-time-p) 0)
 378                   ((not end) hour-start)
 379                   ((or (not equal-bounds-p)
 380                        org-agenda-default-appointment-duration)
 381                    hour-end)
 382                   (t (+ hour-end 2))))
 383          (d (cond ((not end) day-start)
 384                   ((not with-time-p) (1+ day-end))
 385                   (t day-end)))
 386          (m (if end month-end month-start))
 387          (y (if end year-end year-start)))
 388     (concat
 389      keyword
 390      (format-time-string
 391       (cond (utc ":%Y%m%dT%H%M%SZ")
 392             ((not with-time-p) ";VALUE=DATE:%Y%m%d")
 393             (t (replace-regexp-in-string "%Z"
 394                                          org-icalendar-timezone
 395                                          org-icalendar-date-time-format
 396                                          t)))
 397       ;; Convert timestamp into internal time in order to use
 398       ;; `format-time-string' and fix any mistake (i.e. MI >= 60).
 399       (encode-time 0 mi h d m y)
 400       (and (or utc (and with-time-p (org-icalendar-use-UTC-date-time-p)))
 401            t)))))
 402
 403 (defun org-icalendar-dtstamp ()
 404   "Return DTSTAMP property, as a string."
 405   (format-time-string "DTSTAMP:%Y%m%dT%H%M%SZ" nil t))
 406
 407 (defun org-icalendar-get-categories (entry info)
 408   "Return categories according to `org-icalendar-categories'.
 409 ENTRY is a headline or an inlinetask element.  INFO is a plist
 410 used as a communication channel."
 411   (mapconcat
 412    #'identity
 413    (org-uniquify
 414     (let (categories)
 415       (dolist (type org-icalendar-categories (nreverse categories))
 416         (case type
 417           (category
 418            (push (org-export-get-category entry info) categories))
 419           (todo-state
 420            (let ((todo (org-element-property :todo-keyword entry)))
 421              (and todo (push todo categories))))
 422           (local-tags
 423            (setq categories
 424                  (append (nreverse (org-export-get-tags entry info))
 425                          categories)))
 426           (all-tags
 427            (setq categories
 428                  (append (nreverse (org-export-get-tags entry info nil t))
 429                          categories)))))))
 430    ","))
 431
 432 (defun org-icalendar-transcode-diary-sexp (sexp uid summary)
 433   "Transcode a diary sexp into iCalendar format.
 434 SEXP is the diary sexp being transcoded, as a string.  UID is the
 435 unique identifier for the entry.  SUMMARY defines a short summary
 436 or subject for the event."
 437   (when (require 'icalendar nil t)
 438     (org-element-normalize-string
 439      (with-temp-buffer
 440        (let ((sexp (if (not (string-match "\\`<%%" sexp)) sexp
 441                      (concat (substring sexp 1 -1) " " summary))))
 442          (put-text-property 0 1 'uid uid sexp)
 443          (insert sexp "\n"))
 444        (org-diary-to-ical-string (current-buffer))))))
 445
 446 (defun org-icalendar-cleanup-string (s)
 447   "Cleanup string S according to RFC 5545."
 448   (when s
 449     ;; Protect "\", "," and ";" characters. and replace newline
 450     ;; characters with literal \n.
 451     (replace-regexp-in-string
 452      "[ \t]*\n" "\\n"
 453      (replace-regexp-in-string "[\\,;]" "\\\\\\&" s)
 454      nil t)))
 455
 456 (defun org-icalendar-fold-string (s)
 457   "Fold string S according to RFC 5545."
 458   (org-element-normalize-string
 459    (mapconcat
 460     (lambda (line)
 461       ;; Limit each line to a maximum of 75 characters.  If it is
 462       ;; longer, fold it by using "\n " as a continuation marker.
 463       (let ((len (length line)))
 464         (if (<= len 75) line
 465           (let ((folded-line (substring line 0 75))
 466                 (chunk-start 75)
 467                 chunk-end)
 468             ;; Since continuation marker takes up one character on the
 469             ;; line, real contents must be split at 74 chars.
 470             (while (< (setq chunk-end (+ chunk-start 74)) len)
 471               (setq folded-line
 472                     (concat folded-line "\n "
 473                             (substring line chunk-start chunk-end))
 474                     chunk-start chunk-end))
 475             (concat folded-line "\n " (substring line chunk-start))))))
 476     (org-split-string s "\n") "\n")))
 477
 478
 479 \f
 480 ;;; Filters
 481
 482 (defun org-icalendar-clear-blank-lines (headline _back-end _info)
 483   "Remove blank lines in HEADLINE export.
 484 HEADLINE is a string representing a transcoded headline.
 485 BACK-END and INFO are ignored."
 486   (replace-regexp-in-string "^\\(?:[ \t]*\n\\)+" "" headline))
 487
 488
 489 \f
 490 ;;; Transcode Functions
 491
 492 ;;;; Headline and Inlinetasks
 493
 494 ;; The main function is `org-icalendar-entry', which extracts
 495 ;; information from a headline or an inlinetask (summary,
 496 ;; description...) and then delegates code generation to
 497 ;; `org-icalendar--vtodo' and `org-icalendar--vevent', depending
 498 ;; on the component needed.
 499
 500 ;; Obviously, `org-icalendar--valarm' handles alarms, which can
 501 ;; happen within a VTODO component.
 502
 503 (defun org-icalendar-entry (entry contents info)
 504   "Transcode ENTRY element into iCalendar format.
 505
 506 ENTRY is either a headline or an inlinetask.  CONTENTS is
 507 ignored.  INFO is a plist used as a communication channel.
 508
 509 This function is called on every headline, the section below
 510 it (minus inlinetasks) being its contents.  It tries to create
 511 VEVENT and VTODO components out of scheduled date, deadline date,
 512 plain timestamps, diary sexps.  It also calls itself on every
 513 inlinetask within the section."
 514   (unless (org-element-property :footnote-section-p entry)
 515     (let* ((type (org-element-type entry))
 516            ;; Determine contents really associated to the entry.  For
 517            ;; a headline, limit them to section, if any.  For an
 518            ;; inlinetask, this is every element within the task.
 519            (inside
 520             (if (eq type 'inlinetask)
 521                 (cons 'org-data (cons nil (org-element-contents entry)))
 522               (let ((first (car (org-element-contents entry))))
 523                 (and (eq (org-element-type first) 'section)
 524                      (cons 'org-data
 525                            (cons nil (org-element-contents first))))))))
 526       (concat
 527        (let ((todo-type (org-element-property :todo-type entry))
 528              (uid (or (org-element-property :ID entry) (org-id-new)))
 529              (summary (org-icalendar-cleanup-string
 530                        (or (org-element-property :SUMMARY entry)
 531                            (org-export-data
 532                             (org-element-property :title entry) info))))
 533              (loc (org-icalendar-cleanup-string
 534                    (org-element-property :LOCATION entry)))
 535              ;; Build description of the entry from associated section
 536              ;; (headline) or contents (inlinetask).
 537              (desc
 538               (org-icalendar-cleanup-string
 539                (or (org-element-property :DESCRIPTION entry)
 540                    (let ((contents (org-export-data inside info)))
 541                      (cond
 542                       ((not (org-string-nw-p contents)) nil)
 543                       ((wholenump org-icalendar-include-body)
 544                        (let ((contents (org-trim contents)))
 545                          (substring
 546                           contents 0 (min (length contents)
 547                                           org-icalendar-include-body))))
 548                       (org-icalendar-include-body (org-trim contents)))))))
 549              (cat (org-icalendar-get-categories entry info)))
 550          (concat
 551           ;; Events: Delegate to `org-icalendar--vevent' to generate
 552           ;; "VEVENT" component from scheduled, deadline, or any
 553           ;; timestamp in the entry.
 554           (let ((deadline (org-element-property :deadline entry)))
 555             (and deadline
 556                  (memq (if todo-type 'event-if-todo 'event-if-not-todo)
 557                        org-icalendar-use-deadline)
 558                  (org-icalendar--vevent
 559                   entry deadline (concat "DL-" uid)
 560                   (concat "DL: " summary) loc desc cat)))
 561           (let ((scheduled (org-element-property :scheduled entry)))
 562             (and scheduled
 563                  (memq (if todo-type 'event-if-todo 'event-if-not-todo)
 564                        org-icalendar-use-scheduled)
 565                  (org-icalendar--vevent
 566                   entry scheduled (concat "SC-" uid)
 567                   (concat "S: " summary) loc desc cat)))
 568           ;; When collecting plain timestamps from a headline and its
 569           ;; title, skip inlinetasks since collection will happen once
 570           ;; ENTRY is one of them.
 571           (let ((counter 0))
 572             (mapconcat
 573              #'identity
 574              (org-element-map (cons (org-element-property :title entry)
 575                                     (org-element-contents inside))
 576                  'timestamp
 577                (lambda (ts)
 578                  (when (let ((type (org-element-property :type ts)))
 579                          (case (plist-get info :with-timestamps)
 580                            (active (memq type '(active active-range)))
 581                            (inactive (memq type '(inactive inactive-range)))
 582                            ((t) t)))
 583                    (let ((uid (format "TS%d-%s" (incf counter) uid)))
 584                      (org-icalendar--vevent
 585                       entry ts uid summary loc desc cat))))
 586                info nil (and (eq type 'headline) 'inlinetask))
 587              ""))
 588           ;; Task: First check if it is appropriate to export it.  If
 589           ;; so, call `org-icalendar--vtodo' to transcode it into
 590           ;; a "VTODO" component.
 591           (when (and todo-type
 592                      (case (plist-get info :icalendar-include-todo)
 593                        (all t)
 594                        (unblocked
 595                         (and (eq type 'headline)
 596                              (not (org-icalendar-blocked-headline-p
 597                                    entry info))))
 598                        ((t) (eq todo-type 'todo))))
 599             (org-icalendar--vtodo entry uid summary loc desc cat))
 600           ;; Diary-sexp: Collect every diary-sexp element within ENTRY
 601           ;; and its title, and transcode them.  If ENTRY is
 602           ;; a headline, skip inlinetasks: they will be handled
 603           ;; separately.
 604           (when org-icalendar-include-sexps
 605             (let ((counter 0))
 606               (mapconcat #'identity
 607                          (org-element-map
 608                              (cons (org-element-property :title entry)
 609                                    (org-element-contents inside))
 610                              'diary-sexp
 611                            (lambda (sexp)
 612                              (org-icalendar-transcode-diary-sexp
 613                               (org-element-property :value sexp)
 614                               (format "DS%d-%s" (incf counter) uid)
 615                               summary))
 616                            info nil (and (eq type 'headline) 'inlinetask))
 617                          "")))))
 618        ;; If ENTRY is a headline, call current function on every
 619        ;; inlinetask within it.  In agenda export, this is independent
 620        ;; from the mark (or lack thereof) on the entry.
 621        (when (eq type 'headline)
 622          (mapconcat #'identity
 623                     (org-element-map inside 'inlinetask
 624                       (lambda (task) (org-icalendar-entry task nil info))
 625                       info) ""))
 626        ;; Don't forget components from inner entries.
 627        contents))))
 628
 629 (defun org-icalendar--vevent
 630   (entry timestamp uid summary location description categories)
 631   "Create a VEVENT component.
 632
 633 ENTRY is either a headline or an inlinetask element.  TIMESTAMP
 634 is a timestamp object defining the date-time of the event.  UID
 635 is the unique identifier for the event.  SUMMARY defines a short
 636 summary or subject for the event.  LOCATION defines the intended
 637 venue for the event.  DESCRIPTION provides the complete
 638 description of the event.  CATEGORIES defines the categories the
 639 event belongs to.
 640
 641 Return VEVENT component as a string."
 642   (org-icalendar-fold-string
 643    (if (eq (org-element-property :type timestamp) 'diary)
 644        (org-icalendar-transcode-diary-sexp
 645         (org-element-property :raw-value timestamp) uid summary)
 646      (concat "BEGIN:VEVENT\n"
 647              (org-icalendar-dtstamp) "\n"
 648              "UID:" uid "\n"
 649              (org-icalendar-convert-timestamp timestamp "DTSTART") "\n"
 650              (org-icalendar-convert-timestamp timestamp "DTEND" t) "\n"
 651              ;; RRULE.
 652              (when (org-element-property :repeater-type timestamp)
 653                (format "RRULE:FREQ=%s;INTERVAL=%d\n"
 654                        (case (org-element-property :repeater-unit timestamp)
 655                          (hour "HOURLY") (day "DAILY") (week "WEEKLY")
 656                          (month "MONTHLY") (year "YEARLY"))
 657                        (org-element-property :repeater-value timestamp)))
 658              "SUMMARY:" summary "\n"
 659              (and (org-string-nw-p location) (format "LOCATION:%s\n" location))
 660              (and (org-string-nw-p description)
 661                   (format "DESCRIPTION:%s\n" description))
 662              "CATEGORIES:" categories "\n"
 663              ;; VALARM.
 664              (org-icalendar--valarm entry timestamp summary)
 665              "END:VEVENT"))))
 666
 667 (defun org-icalendar--vtodo
 668   (entry uid summary location description categories)
 669   "Create a VTODO component.
 670
 671 ENTRY is either a headline or an inlinetask element.  UID is the
 672 unique identifier for the task.  SUMMARY defines a short summary
 673 or subject for the task.  LOCATION defines the intended venue for
 674 the task.  DESCRIPTION provides the complete description of the
 675 task.  CATEGORIES defines the categories the task belongs to.
 676
 677 Return VTODO component as a string."
 678   (let ((start (or (and (memq 'todo-start org-icalendar-use-scheduled)
 679                         (org-element-property :scheduled entry))
 680                    ;; If we can't use a scheduled time for some
 681                    ;; reason, start task now.
 682                    (let ((now (decode-time)))
 683                      (list 'timestamp
 684                            (list :type 'active
 685                                  :minute-start (nth 1 now)
 686                                  :hour-start (nth 2 now)
 687                                  :day-start (nth 3 now)
 688                                  :month-start (nth 4 now)
 689                                  :year-start (nth 5 now)))))))
 690     (org-icalendar-fold-string
 691      (concat "BEGIN:VTODO\n"
 692              "UID:TODO-" uid "\n"
 693              (org-icalendar-dtstamp) "\n"
 694              (org-icalendar-convert-timestamp start "DTSTART") "\n"
 695              (and (memq 'todo-due org-icalendar-use-deadline)
 696                   (org-element-property :deadline entry)
 697                   (concat (org-icalendar-convert-timestamp
 698                            (org-element-property :deadline entry) "DUE")
 699                           "\n"))
 700              "SUMMARY:" summary "\n"
 701              (and (org-string-nw-p location) (format "LOCATION:%s\n" location))
 702              (and (org-string-nw-p description)
 703                   (format "DESCRIPTION:%s\n" description))
 704              "CATEGORIES:" categories "\n"
 705              "SEQUENCE:1\n"
 706              (format "PRIORITY:%d\n"
 707                      (let ((pri (or (org-element-property :priority entry)
 708                                     org-default-priority)))
 709                        (floor (- 9 (* 8. (/ (float (- org-lowest-priority pri))
 710                                             (- org-lowest-priority
 711                                                org-highest-priority)))))))
 712              (format "STATUS:%s\n"
 713                      (if (eq (org-element-property :todo-type entry) 'todo)
 714                          "NEEDS-ACTION"
 715                        "COMPLETED"))
 716              "END:VTODO"))))
 717
 718 (defun org-icalendar--valarm (entry timestamp summary)
 719   "Create a VALARM component.
 720
 721 ENTRY is the calendar entry triggering the alarm.  TIMESTAMP is
 722 the start date-time of the entry.  SUMMARY defines a short
 723 summary or subject for the task.
 724
 725 Return VALARM component as a string, or nil if it isn't allowed."
 726   ;; Create a VALARM entry if the entry is timed.  This is not very
 727   ;; general in that:
 728   ;; (a) only one alarm per entry is defined,
 729   ;; (b) only minutes are allowed for the trigger period ahead of the
 730   ;;     start time,
 731   ;; (c) only a DISPLAY action is defined.                       [ESF]
 732   (let ((alarm-time
 733          (let ((warntime
 734                 (org-element-property :APPT_WARNTIME entry)))
 735            (if warntime (string-to-number warntime) 0))))
 736     (and (or (> alarm-time 0) (> org-icalendar-alarm-time 0))
 737          (org-element-property :hour-start timestamp)
 738          (format "BEGIN:VALARM
 739 ACTION:DISPLAY
 740 DESCRIPTION:%s
 741 TRIGGER:-P0DT0H%dM0S
 742 END:VALARM\n"
 743                  summary
 744                  (if (zerop alarm-time) org-icalendar-alarm-time alarm-time)))))
 745
 746
 747 ;;;; Template
 748
 749 (defun org-icalendar-template (contents info)
 750   "Return complete document string after iCalendar conversion.
 751 CONTENTS is the transcoded contents string.  INFO is a plist used
 752 as a communication channel."
 753   (org-icalendar--vcalendar
 754    ;; Name.
 755    (if (not (plist-get info :input-file)) (buffer-name (buffer-base-buffer))
 756      (file-name-nondirectory
 757       (file-name-sans-extension (plist-get info :input-file))))
 758    ;; Owner.
 759    (if (not (plist-get info :with-author)) ""
 760      (org-export-data (plist-get info :author) info))
 761    ;; Timezone.
 762    (if (org-string-nw-p org-icalendar-timezone) org-icalendar-timezone
 763      (cadr (current-time-zone)))
 764    ;; Description.
 765    (org-export-data (plist-get info :title) info)
 766    contents))
 767
 768 (defun org-icalendar--vcalendar (name owner tz description contents)
 769   "Create a VCALENDAR component.
 770 NAME, OWNER, TZ, DESCRIPTION and CONTENTS are all strings giving,
 771 respectively, the name of the calendar, its owner, the timezone
 772 used, a short description and the other components included."
 773   (concat (format "BEGIN:VCALENDAR
 774 VERSION:2.0
 775 X-WR-CALNAME:%s
 776 PRODID:-//%s//Emacs with Org mode//EN
 777 X-WR-TIMEZONE:%s
 778 X-WR-CALDESC:%s
 779 CALSCALE:GREGORIAN\n"
 780                   (org-icalendar-cleanup-string name)
 781                   (org-icalendar-cleanup-string owner)
 782                   (org-icalendar-cleanup-string tz)
 783                   (org-icalendar-cleanup-string description))
 784           contents
 785           "END:VCALENDAR\n"))
 786
 787
 788 \f
 789 ;;; Interactive Functions
 790
 791 ;;;###autoload
 792 (defun org-icalendar-export-to-ics
 793   (&optional async subtreep visible-only body-only)
 794   "Export current buffer to an iCalendar file.
 795
 796 If narrowing is active in the current buffer, only export its
 797 narrowed part.
 798
 799 If a region is active, export that region.
 800
 801 A non-nil optional argument ASYNC means the process should happen
 802 asynchronously.  The resulting file should be accessible through
 803 the `org-export-stack' interface.
 804
 805 When optional argument SUBTREEP is non-nil, export the sub-tree
 806 at point, extracting information from the headline properties
 807 first.
 808
 809 When optional argument VISIBLE-ONLY is non-nil, don't export
 810 contents of hidden elements.
 811
 812 When optional argument BODY-ONLY is non-nil, only write code
 813 between \"BEGIN:VCALENDAR\" and \"END:VCALENDAR\".
 814
 815 Return ICS file name."
 816   (interactive)
 817   (let ((file (buffer-file-name (buffer-base-buffer))))
 818     (when (and file org-icalendar-store-UID)
 819       (org-icalendar-create-uid file 'warn-user)))
 820   ;; Export part.  Since this back-end is backed up by `ascii', ensure
 821   ;; links will not be collected at the end of sections.
 822   (let ((outfile (org-export-output-file-name ".ics" subtreep)))
 823     (org-export-to-file 'icalendar outfile
 824       async subtreep visible-only body-only
 825       '(:ascii-charset utf-8 :ascii-links-to-notes nil)
 826       (lambda (file)
 827         (run-hook-with-args 'org-icalendar-after-save-hook file) nil))))
 828
 829 ;;;###autoload
 830 (defun org-icalendar-export-agenda-files (&optional async)
 831   "Export all agenda files to iCalendar files.
 832 When optional argument ASYNC is non-nil, export happens in an
 833 external process."
 834   (interactive)
 835   (if async
 836       ;; Asynchronous export is not interactive, so we will not call
 837       ;; `org-check-agenda-file'.  Instead we remove any non-existent
 838       ;; agenda file from the list.
 839       (let ((files (cl-remove-if-not #'file-exists-p (org-agenda-files t))))
 840         (org-export-async-start
 841             (lambda (results)
 842               (dolist (f results) (org-export-add-to-stack f 'icalendar)))
 843           `(let (output-files)
 844              (dolist (file ',files outputfiles)
 845                (with-current-buffer (org-get-agenda-file-buffer file)
 846                  (push (expand-file-name (org-icalendar-export-to-ics))
 847                        output-files))))))
 848     (let ((files (org-agenda-files t)))
 849       (org-agenda-prepare-buffers files)
 850       (unwind-protect
 851           (dolist (file files)
 852             (catch 'nextfile
 853               (org-check-agenda-file file)
 854               (with-current-buffer (org-get-agenda-file-buffer file)
 855                 (org-icalendar-export-to-ics))))
 856         (org-release-buffers org-agenda-new-buffers)))))
 857
 858 ;;;###autoload
 859 (defun org-icalendar-combine-agenda-files (&optional async)
 860   "Combine all agenda files into a single iCalendar file.
 861
 862 A non-nil optional argument ASYNC means the process should happen
 863 asynchronously.  The resulting file should be accessible through
 864 the `org-export-stack' interface.
 865
 866 The file is stored under the name chosen in
 867 `org-icalendar-combined-agenda-file'."
 868   (interactive)
 869   (if async
 870       (let ((files (cl-remove-if-not #'file-exists-p (org-agenda-files t))))
 871         (org-export-async-start
 872             (lambda (_)
 873               (org-export-add-to-stack
 874                (expand-file-name org-icalendar-combined-agenda-file)
 875                'icalendar))
 876           `(apply #'org-icalendar--combine-files ',files)))
 877     (apply #'org-icalendar--combine-files (org-agenda-files t))))
 878
 879 (defun org-icalendar-export-current-agenda (file)
 880   "Export current agenda view to an iCalendar FILE.
 881 This function assumes major mode for current buffer is
 882 `org-agenda-mode'."
 883   (let* ((org-export-babel-evaluate)    ; Don't evaluate Babel block.
 884          (contents
 885           (org-export-string-as
 886            (with-output-to-string
 887              (save-excursion
 888                (let ((p (point-min)))
 889                  (while (setq p (next-single-property-change p 'org-hd-marker))
 890                    (let ((m (get-text-property p 'org-hd-marker)))
 891                      (when m
 892                        (with-current-buffer (marker-buffer m)
 893                          (org-with-wide-buffer
 894                           (goto-char (marker-position m))
 895                           (princ
 896                            (org-element-normalize-string
 897                             (buffer-substring
 898                              (point) (progn (outline-next-heading) (point)))))))))
 899                    (forward-line)))))
 900            'icalendar t
 901            '(:ascii-charset utf-8 :ascii-links-to-notes nil
 902                             :icalendar-include-todo all))))
 903     (with-temp-file file
 904       (insert
 905        (org-icalendar--vcalendar
 906         org-icalendar-combined-name
 907         user-full-name
 908         (or (org-string-nw-p org-icalendar-timezone) (cadr (current-time-zone)))
 909         org-icalendar-combined-description
 910         contents)))
 911     (run-hook-with-args 'org-icalendar-after-save-hook file)))
 912
 913 (defun org-icalendar--combine-files (&rest files)
 914   "Combine entries from multiple files into an iCalendar file.
 915 FILES is a list of files to build the calendar from."
 916   (org-agenda-prepare-buffers files)
 917   (unwind-protect
 918       (progn
 919         (with-temp-file org-icalendar-combined-agenda-file
 920           (insert
 921            (org-icalendar--vcalendar
 922             ;; Name.
 923             org-icalendar-combined-name
 924             ;; Owner.
 925             user-full-name
 926             ;; Timezone.
 927             (or (org-string-nw-p org-icalendar-timezone)
 928                 (cadr (current-time-zone)))
 929             ;; Description.
 930             org-icalendar-combined-description
 931             ;; Contents.
 932             (concat
 933              ;; Agenda contents.
 934              (mapconcat
 935               (lambda (file)
 936                 (catch 'nextfile
 937                   (org-check-agenda-file file)
 938                   (with-current-buffer (org-get-agenda-file-buffer file)
 939                     ;; Create ID if necessary.
 940                     (when org-icalendar-store-UID
 941                       (org-icalendar-create-uid file t))
 942                     (org-export-as
 943                      'icalendar nil nil t
 944                      '(:ascii-charset utf-8 :ascii-links-to-notes nil)))))
 945               files "")
 946              ;; BBDB anniversaries.
 947              (when (and org-icalendar-include-bbdb-anniversaries
 948                         (require 'org-bbdb nil t))
 949                (with-output-to-string (org-bbdb-anniv-export-ical)))))))
 950         (run-hook-with-args 'org-icalendar-after-save-hook
 951                             org-icalendar-combined-agenda-file))
 952     (org-release-buffers org-agenda-new-buffers)))
 953
 954
 955 (provide 'ox-icalendar)
 956
 957 ;; Local variables:
 958 ;; generated-autoload-file: "org-loaddefs.el"
 959 ;; End:
 960
 961 ;;; ox-icalendar.el ends here