lisp/org-bbdb.el

   1 ;;; org-bbdb.el --- Support for links to BBDB entries from within Org-mode
   2
   3 ;; Copyright (C) 2004-2012 Free Software Foundation, Inc.
   4
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>,
   6 ;;         Thomas Baumann <thomas dot baumann at ch dot tum dot de>
   7 ;; Keywords: outlines, hypermedia, calendar, wp
   8 ;; Homepage: http://orgmode.org
   9 ;;
  10 ;; This file is part of GNU Emacs.
  11 ;;
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  25 ;;
  26 ;;; Commentary:
  27
  28 ;; This file implements links to BBDB database entries from within Org-mode.
  29 ;; Org-mode loads this module by default - if this is not what you want,
  30 ;; configure the variable `org-modules'.
  31
  32 ;; It also implements an interface (based on Ivar Rummelhoff's
  33 ;; bbdb-anniv.el) for those org-mode users, who do not use the diary
  34 ;; but who do want to include the anniversaries stored in the BBDB
  35 ;; into the org-agenda.  If you already include the `diary' into the
  36 ;; agenda, you might want to prefer to include the anniversaries in
  37 ;; the diary using bbdb-anniv.el.
  38 ;;
  39 ;; Put the following in /somewhere/at/home/diary.org and make sure
  40 ;; that this file is in `org-agenda-files`
  41 ;;
  42 ;; %%(org-bbdb-anniversaries)
  43 ;;
  44 ;; For example my diary.org looks like:
  45 ;; * Anniversaries
  46 ;; #+CATEGORY: Anniv
  47 ;; %%(org-bbdb-anniversaries)
  48 ;;
  49 ;;
  50 ;; To add an anniversary to a BBDB record, press `C-o' in the record.
  51 ;; You will be prompted for the field name, in this case it must be
  52 ;; "anniversary".  If this is the first time you are using this field,
  53 ;; you need to confirm that it should be created.
  54 ;;
  55 ;; The format of an anniversary field stored in BBDB is the following
  56 ;; (items in {} are optional):
  57 ;;
  58 ;;     YYYY-MM-DD{ CLASS-OR-FORMAT-STRING}
  59 ;;     {\nYYYY-MM-DD CLASS-OR-FORMAT-STRING}...
  60 ;;
  61 ;; CLASS-OR-FORMAT-STRING is one of two things:
  62 ;;
  63 ;;  - an identifier for a class of anniversaries (eg. birthday or
  64 ;;    wedding) from `org-bbdb-anniversary-format-alist' which then
  65 ;;    defines the format string for this class
  66 ;;  - the (format) string displayed in the diary.
  67 ;;
  68 ;; You can enter multiple anniversaries for a single BBDB record by
  69 ;; separating them with a newline character.  At the BBDB prompt for
  70 ;; the field value, type `C-q C-j' to enter a newline between two
  71 ;; anniversaries.
  72 ;;
  73 ;; If you omit the CLASS-OR-FORMAT-STRING entirely, it defaults to the
  74 ;; value of `org-bbdb-default-anniversary-format' ("birthday" by
  75 ;; default).
  76 ;;
  77 ;; The substitutions in the format string are (in order):
  78 ;;  - the name of the record containing this anniversary
  79 ;;  - the number of years
  80 ;;  - an ordinal suffix (st, nd, rd, th) for the year
  81 ;;
  82 ;; See the documentation of `org-bbdb-anniversary-format-alist' for
  83 ;; further options.
  84 ;;
  85 ;; Example
  86 ;;
  87 ;;       1973-06-22
  88 ;;       20??-??-?? wedding
  89 ;;       1998-03-12 %s created bbdb-anniv.el %d years ago
  90 ;;
  91 ;; From Org's agenda, you can use `C-c C-o' to jump to the BBDB
  92 ;; link from which the entry at point originates.
  93 ;;
  94 ;;; Code:
  95
  96 (require 'org)
  97 (eval-when-compile
  98   (require 'cl))
  99
 100 ;; Declare external functions and variables
 101
 102 (declare-function bbdb "ext:bbdb-com" (string elidep))
 103 (declare-function bbdb-company "ext:bbdb-com" (string elidep))
 104 (declare-function bbdb-current-record "ext:bbdb-com"
 105                   (&optional planning-on-modifying))
 106 (declare-function bbdb-name "ext:bbdb-com" (string elidep))
 107 (declare-function bbdb-completing-read-record "ext:bbdb-com"
 108                   (prompt &optional omit-records))
 109 (declare-function bbdb-record-getprop "ext:bbdb" (record property))
 110 (declare-function bbdb-record-name "ext:bbdb" (record))
 111 (declare-function bbdb-records "ext:bbdb"
 112           (&optional dont-check-disk already-in-db-buffer))
 113 (declare-function bbdb-split "ext:bbdb" (string separators))
 114 (declare-function bbdb-string-trim "ext:bbdb" (string))
 115 (declare-function bbdb-record-get-field "ext:bbdb" (record field))
 116 (declare-function bbdb-search-name "ext:bbdb-com" (regexp &optional layout))
 117 (declare-function bbdb-search-organization "ext:bbdb-com" (regexp &optional layout))
 118
 119 (declare-function calendar-leap-year-p "calendar" (year))
 120 (declare-function diary-ordinal-suffix "diary-lib" (n))
 121
 122 (defvar date)   ;; dynamically scoped from Org
 123 (defvar name)   ;; dynamically scoped from Org
 124
 125 ;; Customization
 126
 127 (defgroup org-bbdb-anniversaries nil
 128   "Customizations for including anniversaries from BBDB into Agenda."
 129   :group 'org-bbdb)
 130
 131 (defcustom org-bbdb-default-anniversary-format "birthday"
 132   "Default anniversary class."
 133   :type  'string
 134   :group 'org-bbdb-anniversaries
 135   :require 'bbdb)
 136
 137 (defcustom org-bbdb-anniversary-format-alist
 138   '(("birthday" lambda
 139      (name years suffix)
 140      (concat "Birthday: [[bbdb:" name "][" name " ("
 141              (format "%s" years)        ; handles numbers as well as strings
 142              suffix ")]]"))
 143     ("wedding" lambda
 144      (name years suffix)
 145      (concat "[[bbdb:" name "][" name "'s "
 146              (format "%s" years)
 147              suffix " wedding anniversary]]")))
 148   "How different types of anniversaries should be formatted.
 149 An alist of elements (STRING . FORMAT) where STRING is the name of an
 150 anniversary class and format is either:
 151 1) A format string with the following substitutions (in order):
 152     * the name of the record containing this anniversary
 153     * the number of years
 154     * an ordinal suffix (st, nd, rd, th) for the year
 155
 156 2) A function to be called with three arguments: NAME YEARS SUFFIX
 157    (string int string) returning a string for the diary or nil.
 158
 159 3) An Emacs Lisp form that should evaluate to a string (or nil) in the
 160    scope of variables NAME, YEARS and SUFFIX (among others)."
 161   :type 'sexp
 162   :group 'org-bbdb-anniversaries
 163   :require 'bbdb)
 164
 165 (defcustom org-bbdb-anniversary-field 'anniversary
 166   "The BBDB field which contains anniversaries.
 167 The anniversaries are stored in the following format
 168
 169 YYYY-MM-DD Class-or-Format-String
 170
 171 where class is one of the customized classes for anniversaries;
 172 birthday and wedding are predefined.  Format-String can take three
 173 substitutions 1) the name of the record containing this
 174 anniversary, 2) the number of years, and 3) an ordinal suffix for
 175 the year.
 176
 177 Multiple anniversaries can be separated by \\n."
 178   :type    'symbol
 179   :group   'org-bbdb-anniversaries
 180   :require 'bbdb)
 181
 182 (defcustom org-bbdb-extract-date-fun 'org-bbdb-anniv-extract-date
 183   "How to retrieve `month date year' from the anniversary field.
 184
 185 Customize if you have already filled your BBDB with dates
 186 different from YYYY-MM-DD.  The function must return a list (month
 187 date year)."
 188   :type 'function
 189   :group 'org-bbdb-anniversaries
 190   :require 'bbdb)
 191
 192
 193 ;; Install the link type
 194 (org-add-link-type "bbdb" 'org-bbdb-open 'org-bbdb-export)
 195 (add-hook 'org-store-link-functions 'org-bbdb-store-link)
 196
 197 ;; Implementation
 198 (defun org-bbdb-store-link ()
 199   "Store a link to a BBDB database entry."
 200   (when (eq major-mode 'bbdb-mode)
 201     ;; This is BBDB, we make this link!
 202     (let* ((rec (bbdb-current-record))
 203            (name (bbdb-record-name rec))
 204            (company (if (fboundp 'bbdb-record-getprop)
 205                         (bbdb-record-getprop rec 'company)
 206                       (car (bbdb-record-get-field rec 'organization))))
 207            (link (org-make-link "bbdb:" name)))
 208       (org-store-link-props :type "bbdb" :name name :company company
 209                             :link link :description name)
 210       link)))
 211
 212 (defun org-bbdb-export (path desc format)
 213   "Create the export version of a BBDB link specified by PATH or DESC.
 214 If exporting to either HTML or LaTeX FORMAT the link will be
 215 italicized, in all other cases it is left unchanged."
 216   (when (string= desc (format "bbdb:%s" path))
 217     (setq desc path))
 218   (cond
 219    ((eq format 'html) (format "<i>%s</i>" desc))
 220    ((eq format 'latex) (format "\\textit{%s}" desc))
 221    (t desc)))
 222
 223 (defun org-bbdb-open (name)
 224   "Follow a BBDB link to NAME."
 225   (require 'bbdb-com)
 226   (let ((inhibit-redisplay (not debug-on-error))
 227         (bbdb-electric-p nil))
 228     (if (fboundp 'bbdb-name)
 229         (org-bbdb-open-old name)
 230       (org-bbdb-open-new name))))
 231
 232 (defun org-bbdb-open-old (name)
 233   (catch 'exit
 234     ;; Exact match on name
 235     (bbdb-name (concat "\\`" name "\\'") nil)
 236     (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 237     ;; Exact match on name
 238     (bbdb-company (concat "\\`" name "\\'") nil)
 239     (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 240     ;; Partial match on name
 241     (bbdb-name name nil)
 242     (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 243     ;; Partial match on company
 244     (bbdb-company name nil)
 245     (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 246     ;; General match including network address and notes
 247     (bbdb name nil)
 248     (when (= 0 (buffer-size (get-buffer "*BBDB*")))
 249       (delete-window (get-buffer-window "*BBDB*"))
 250       (error "No matching BBDB record"))))
 251
 252 (defun org-bbdb-open-new (name)
 253   (catch 'exit
 254     ;; Exact match on name
 255     (bbdb-search-name (concat "\\`" name "\\'") nil)
 256     (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 257     ;; Exact match on name
 258     (bbdb-search-organization (concat "\\`" name "\\'") nil)
 259     (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 260     ;; Partial match on name
 261     (bbdb-search-name name nil)
 262     (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 263     ;; Partial match on company
 264     (bbdb-search-organization name nil)
 265     (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 266     ;; General match including network address and notes
 267     (bbdb name nil)
 268     (when (= 0 (buffer-size (get-buffer "*BBDB*")))
 269       (delete-window (get-buffer-window "*BBDB*"))
 270       (error "No matching BBDB record"))))
 271
 272 (defun org-bbdb-anniv-extract-date (time-str)
 273   "Convert YYYY-MM-DD to (month date year).
 274 Argument TIME-STR is the value retrieved from BBDB.  If YYYY- is omitted
 275 it will be considered unknown."
 276   (multiple-value-bind (a b c) (values-list (bbdb-split time-str "-"))
 277     (if (eq c nil)
 278         (list (string-to-number a)
 279               (string-to-number b)
 280               nil)
 281       (list (string-to-number b)
 282             (string-to-number c)
 283             (string-to-number a)))))
 284
 285 (defun org-bbdb-anniv-split (str)
 286   "Split multiple entries in the BBDB anniversary field.
 287 Argument STR is the anniversary field in BBDB."
 288   (let ((pos (string-match "[ \t]" str)))
 289     (if pos (list (substring str 0 pos)
 290                   (bbdb-string-trim (substring str pos)))
 291       (list str nil))))
 292
 293 (defvar org-bbdb-anniv-hash nil
 294   "A hash holding anniversaries extracted from BBDB.
 295 The hash table is created on first use.")
 296
 297 (defvar org-bbdb-updated-p t
 298   "This is non-nil if BBDB has been updated since we last built the hash.")
 299
 300 (defun org-bbdb-make-anniv-hash ()
 301   "Create a hash with anniversaries extracted from BBDB, for fast access.
 302 The anniversaries are assumed to be stored `org-bbdb-anniversary-field'."
 303
 304   (let (split tmp annivs)
 305     (clrhash org-bbdb-anniv-hash)
 306     (dolist (rec (bbdb-records))
 307       (when (setq annivs (bbdb-record-getprop
 308                           rec org-bbdb-anniversary-field))
 309         (setq annivs (bbdb-split annivs "\n"))
 310         (while annivs
 311           (setq split (org-bbdb-anniv-split (pop annivs)))
 312           (multiple-value-bind (m d y)
 313               (values-list (funcall org-bbdb-extract-date-fun (car split)))
 314             (setq tmp (gethash (list m d) org-bbdb-anniv-hash))
 315             (puthash (list m d) (cons (list y
 316                                             (bbdb-record-name rec)
 317                                             (cadr split))
 318                                       tmp)
 319                      org-bbdb-anniv-hash))))))
 320   (setq org-bbdb-updated-p nil))
 321
 322 (defun org-bbdb-updated (rec)
 323   "Record the fact that BBDB has been updated.
 324 This is used by Org to re-create the anniversary hash table."
 325   (setq org-bbdb-updated-p t))
 326
 327 (add-hook 'bbdb-after-change-hook 'org-bbdb-updated)
 328
 329 ;;;###autoload
 330 (defun org-bbdb-anniversaries()
 331   "Extract anniversaries from BBDB for display in the agenda."
 332   (require 'bbdb)
 333   (require 'diary-lib)
 334   (unless (hash-table-p org-bbdb-anniv-hash)
 335     (setq org-bbdb-anniv-hash
 336           (make-hash-table :test 'equal :size 366)))
 337
 338   (when (or org-bbdb-updated-p
 339             (= 0 (hash-table-count org-bbdb-anniv-hash)))
 340     (org-bbdb-make-anniv-hash))
 341
 342   (let* ((m (car date))    ; month
 343          (d (nth 1 date))  ; day
 344          (y (nth 2 date))  ; year
 345          (annivs (gethash (list m d) org-bbdb-anniv-hash))
 346          (text ())
 347          rec recs)
 348
 349     ;; we don't want to miss people born on Feb. 29th
 350     (when (and (= m 3) (= d 1)
 351                (not (null (gethash (list 2 29) org-bbdb-anniv-hash)))
 352                (not (calendar-leap-year-p y)))
 353       (setq recs (gethash (list 2 29) org-bbdb-anniv-hash))
 354       (while (setq rec (pop recs))
 355         (push rec annivs)))
 356
 357     (when annivs
 358       (while (setq rec (pop annivs))
 359         (when rec
 360           (let* ((class (or (nth 2 rec)
 361                             org-bbdb-default-anniversary-format))
 362                  (form (or (cdr (assoc-string
 363                                  class org-bbdb-anniversary-format-alist t))
 364                            class))      ; (as format string)
 365                  (name (nth 1 rec))
 366                  (years (if (eq (car rec) nil)
 367                             "unknown"
 368                           (- y (car rec))))
 369                  (suffix (if (eq (car rec) nil)
 370                              ""
 371                            (diary-ordinal-suffix years)))
 372                  (tmp (cond
 373                        ((functionp form)
 374                         (funcall form name years suffix))
 375                        ((listp form) (eval form))
 376                        (t (format form name years suffix)))))
 377             (org-add-props tmp nil 'org-bbdb-name name)
 378             (if text
 379                 (setq text (append text (list tmp)))
 380               (setq text (list tmp)))))
 381         ))
 382     text))
 383
 384 (defun org-bbdb-complete-link ()
 385   "Read a bbdb link with name completion."
 386   (require 'bbdb-com)
 387   (concat "bbdb:"
 388           (bbdb-record-name (car (bbdb-completing-read-record "Name: ")))))
 389
 390 (defun org-bbdb-anniv-export-ical ()
 391   "Extract anniversaries from BBDB and convert them to icalendar format."
 392   (require 'bbdb)
 393   (require 'diary-lib)
 394   (unless (hash-table-p org-bbdb-anniv-hash)
 395     (setq org-bbdb-anniv-hash
 396           (make-hash-table :test 'equal :size 366)))
 397   (when (or org-bbdb-updated-p
 398             (= 0 (hash-table-count org-bbdb-anniv-hash)))
 399     (org-bbdb-make-anniv-hash))
 400   (maphash 'org-bbdb-format-vevent org-bbdb-anniv-hash))
 401
 402 (defun org-bbdb-format-vevent (key recs)
 403   (let (rec categ)
 404     (while (setq rec (pop recs))
 405       (setq categ (or (nth 2 rec) org-bbdb-default-anniversary-format))
 406       (princ (format "BEGIN:VEVENT
 407 UID: ANNIV-%4i%02i%02i-%s
 408 DTSTART:%4i%02i%02i
 409 SUMMARY:%s
 410 DESCRIPTION:%s
 411 CATEGORIES:%s
 412 RRULE:FREQ=YEARLY
 413 END:VEVENT\n"
 414                      (nth 0 rec) (nth 0 key) (nth 1 key)
 415                      (mapconcat 'identity
 416                                 (org-split-string (nth 1 rec) "[^a-zA-Z0-90]+")
 417                                 "-")
 418                      (nth 0 rec) (nth 0 key) (nth 1 key)
 419                      (nth 1 rec)
 420                      (concat (capitalize categ) " " (nth 1 rec))
 421                      categ)))))
 422
 423 (provide 'org-bbdb)
 424
 425 ;;; org-bbdb.el ends here