lisp/ob-table.el

   1 ;;; ob-table.el --- support for calling org-babel functions from tables
   2
   3 ;; Copyright (C) 2009, 2010  Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8 ;; Version: 7.01trans
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Should allow calling functions from org-mode tables using the
  28 ;; function `sbe' as so...
  29
  30 ;; #+begin_src emacs-lisp :results silent
  31 ;;   (defun fibbd (n) (if (< n 2) 1 (+ (fibbd (- n 1)) (fibbd (- n 2)))))
  32 ;; #+end_src
  33
  34 ;; #+srcname: fibbd
  35 ;; #+begin_src emacs-lisp :var n=2 :results silent
  36 ;; (fibbd n)
  37 ;; #+end_src
  38
  39 ;; | original | fibbd  |
  40 ;; |----------+--------|
  41 ;; |        0 |        |
  42 ;; |        1 |        |
  43 ;; |        2 |        |
  44 ;; |        3 |        |
  45 ;; |        4 |        |
  46 ;; |        5 |        |
  47 ;; |        6 |        |
  48 ;; |        7 |        |
  49 ;; |        8 |        |
  50 ;; |        9 |        |
  51 ;; #+TBLFM: $2='(sbe 'fibbd (n $1))
  52
  53 ;;; Code:
  54 (require 'ob)
  55
  56 (defun org-babel-table-truncate-at-newline (string)
  57   "Replace newline character with ellipses.
  58 If STRING ends in a newline character, then remove the newline
  59 character and replace it with ellipses."
  60   (if (and (stringp string) (string-match "[\n\r]" string))
  61       (concat (substring string 0 (match-beginning 0)) "...")
  62     string))
  63
  64 (defmacro sbe (source-block &rest variables)
  65   "Return the results of calling SOURCE-BLOCK with VARIABLES.
  66 Each element of VARIABLES should be a two
  67 element list, whose first element is the name of the variable and
  68 second element is a string of its value.  The following call to
  69 `sbe' would be equivalent to the following source code block.
  70
  71  (sbe 'source-block (n $2) (m 3))
  72
  73 #+begin_src emacs-lisp :var results=source-block(n=val_at_col_2, m=3) :results silent
  74 results
  75 #+end_src
  76
  77 NOTE: by default string variable names are interpreted as
  78 references to source-code blocks, to force interpretation of a
  79 cell's value as a string, prefix the identifier with two \"$\"s
  80 rather than a single \"$\" (i.e. \"$$2\" instead of \"$2\" in the
  81 example above."
  82   (let* (quote
  83          (variables (mapcar
  84                      (lambda (var)
  85                        ;; ensure that all cells prefixed with $'s are strings
  86                        (cons (car var)
  87                              (delq nil
  88                                    (mapcar
  89                                     (lambda (el)
  90                                       (if (eq '$ el)
  91                                           (setq quote t)
  92                                         (prog1
  93                                             (if quote
  94                                                 (format "\"%s\"" el)
  95                                               (org-babel-clean-text-properties el))
  96                                           (setq quote nil))))
  97                                     (cdr var)))))
  98                      variables)))
  99     (unless (stringp source-block)
 100       (setq source-block (symbol-name source-block)))
 101     (org-babel-table-truncate-at-newline ;; org-table cells can't be multi-line
 102      (if (and source-block (> (length source-block) 0))
 103          (let ((params
 104                 (eval `(org-babel-parse-header-arguments
 105                         (concat ":var results="
 106                                 ,source-block
 107                                 "("
 108                                 (mapconcat
 109                                  (lambda (var-spec)
 110                                    (if (> (length (cdr var-spec)) 1)
 111                                        (format "%S='%S"
 112                                                (car var-spec) (mapcar #'read (cdr var-spec)))
 113                                      (format "%S=%s"
 114                                              (car var-spec) (cadr var-spec))))
 115                                  ',variables ", ")
 116                                 ")")))))
 117            (org-babel-execute-src-block
 118             nil (list "emacs-lisp" "results"
 119                       (org-babel-merge-params '((:results . "silent")) params))))
 120        ""))))
 121
 122 (provide 'ob-table)
 123
 124 ;; arch-tag: 4234cc7c-4fc8-4e92-abb0-2892de1a493b
 125
 126 ;;; ob-table.el ends here