org-publish.el

   1 ;;; org-publish.el --- publish related org-mode files as a website
   2
   3 ;; Copyright (C) 2006, 2007, 2008  Free Software Foundation, Inc.
   4
   5 ;; Author: David O'Toole <dto@gnu.org>
   6 ;; Maintainer: Bastien Guerry <bzg AT altern DOT org>
   7 ;; Keywords: hypermedia, outlines, wp
   8 ;; Version: 1.81
   9
  10 ;; This file is part of GNU Emacs.
  11 ;;
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 3, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Requires at least version 4.27 of org.el
  30
  31 ;; This program allow configurable publishing of related sets of
  32 ;; Org-mode files as a complete website.
  33 ;;
  34 ;; org-publish.el can do the following:
  35 ;;
  36 ;; + Publish all one's org-files to HTML or LaTeX
  37 ;; + Upload HTML, images, attachments and other files to a web server
  38 ;; + Exclude selected private pages from publishing
  39 ;; + Publish a clickable index of pages
  40 ;; + Manage local timestamps for publishing only changed files
  41 ;; + Accept plugin functions to extend range of publishable content
  42 ;;
  43 ;; Special thanks to the org-mode maintainer Carsten Dominik for his
  44 ;; ideas, enthusiasm, and cooperation.
  45
  46 ;;; Installation:
  47
  48 ;; Put org-publish.el in your load path, byte-compile it, and then add
  49 ;; the following lines to your emacs initialization file:
  50
  51 ;; (autoload 'org-publish "org-publish" nil t)
  52 ;; (autoload 'org-publish "org-publish-all" nil t)
  53 ;; (autoload 'org-publish "org-publish-current-file" nil t)
  54 ;; (autoload 'org-publish "org-publish-current-project" nil t)
  55
  56 ;; NOTE: When org-publish.el is included with org.el, those forms are
  57 ;; already in the file org-install.el, and hence don't need to be put
  58 ;; in your emacs initialization file in this case.
  59
  60 ;;; Usage:
  61 ;;
  62 ;; The program's main configuration variable is
  63 ;; `org-publish-project-alist'. See below for example configurations
  64 ;; with commentary.
  65
  66 ;; The main interactive functions are:
  67 ;;
  68 ;; M-x org-publish
  69 ;; M-x org-publish-all
  70 ;; M-x org-publish-current-file
  71 ;; M-x org-publish-current-project
  72
  73 ;;;; Simple example configuration:
  74
  75 ;; (setq org-publish-project-alist
  76 ;;       (list
  77 ;;        '("org" . (:base-directory "~/org/"
  78 ;;                   :base-extension "org"
  79 ;;                   :publishing-directory "~/public_html"
  80 ;;                   :with-section-numbers nil
  81 ;;                   :table-of-contents nil
  82 ;;                   :recursive t
  83 ;;                   :style "<link rel=stylesheet href=\"../other/mystyle.css\" type=\"text/css\">")))
  84
  85 ;;;; More complex example configuration:
  86
  87 ;; Imagine your *.org files are kept in ~/org, your images in
  88 ;; ~/images, and stylesheets in ~/other. Now imagine you want to
  89 ;; publish the files through an ssh connection to a remote host, via
  90 ;; Tramp-mode. To maintain relative links from *.org files to /images
  91 ;; and /other, we should replicate the same directory structure in
  92 ;; your web server account's designated html root (in this case,
  93 ;; assumed to be ~/html)
  94
  95 ;; Once you've done created the proper directories, you can adapt the
  96 ;; following example configuration to your specific paths, run M-x
  97 ;; org-publish-all, and it should publish the files to the correct
  98 ;; directories on the web server, transforming the *.org files into
  99 ;; HTML, and leaving other files alone.
 100
 101 ;; (setq org-publish-project-alist
 102 ;;       (list
 103 ;;        '("orgfiles" :base-directory "~/org/"
 104 ;;                     :base-extension "org"
 105 ;;                     :publishing-directory "/ssh:user@host:~/html/notebook/"
 106 ;;                     :publishing-function org-publish-org-to-html
 107 ;;                     :exclude "PrivatePage.org"   ;; regexp
 108 ;;                     :headline-levels 3
 109 ;;                     :with-section-numbers nil
 110 ;;                     :table-of-contents nil
 111 ;;                     :style "<link rel=stylesheet href=\"../other/mystyle.css\" type=\"text/css\">"
 112 ;;                     :auto-preamble t
 113 ;;                     :auto-postamble nil)
 114 ;;         ("images" :base-directory "~/images/"
 115 ;;                   :base-extension "jpg\\|gif\\|png"
 116 ;;                   :publishing-directory "/ssh:user@host:~/html/images/"
 117 ;;                   :publishing-function org-publish-attachment)
 118 ;;         ("other"  :base-directory "~/other/"
 119 ;;                   :base-extension "css"
 120 ;;                   :publishing-directory "/ssh:user@host:~/html/other/"
 121 ;;                   :publishing-function org-publish-attachment)
 122 ;;         ("website" :components ("orgfiles" "images" "other"))))
 123
 124 ;; For more information, see the documentation for the variable
 125 ;; `org-publish-project-alist'.
 126
 127 ;; Of course, you don't have to publish to remote directories from
 128 ;; within emacs. You can always just publish to local folders, and
 129 ;; then use the synchronization/upload tool of your choice.
 130
 131 ;;; List of user-visible changes since version 1.27
 132
 133 ;; 1.78: Allow list-valued :publishing-function
 134 ;; 1.77: Added :preparation-function, this allows you to use GNU Make etc.
 135 ;; 1.65: Remove old "composite projects". They're redundant.
 136 ;; 1.64: Allow meta-projects with :components
 137 ;; 1.57: Timestamps flag is now called "org-publish-use-timestamps-flag"
 138 ;; 1.52: Properly set default for :index-filename
 139 ;; 1.48: Composite projects allowed.
 140 ;;       :include keyword allowed.
 141 ;; 1.43: Index no longer includes itself in the index.
 142 ;; 1.42: Fix "function definition is void" error
 143 ;;       when :publishing-function not set in org-publish-current-file.
 144 ;; 1.41: Fixed bug where index isn't published on first try.
 145 ;; 1.37: Added interactive function "org-publish". Prompts for particular
 146 ;;       project name to publish.
 147 ;; 1.34: Added force-publish option to all interactive functions.
 148 ;; 1.32: Fixed "index.org has changed on disk" error during index publishing.
 149 ;; 1.30: Fixed startup error caused by (require 'em-unix)
 150
 151 ;;; Code:
 152
 153 (eval-when-compile
 154   (require 'cl))
 155
 156 (require 'dired-aux)
 157
 158 (defgroup org-publish nil
 159         "Options for publishing a set of Org-mode and related files."
 160    :tag "Org Publishing"
 161    :group 'org)
 162
 163 (defcustom org-publish-project-alist nil
 164   "Association list to control publishing behavior.
 165 Each element of the alist is a publishing 'project.'  The CAR of
 166 each element is a string, uniquely identifying the project. The
 167 CDR of each element is in one of the following forms:
 168
 169   (:property value :property value ... )
 170
 171 OR,
 172
 173   (:components (\"project-1\" \"project-2\" ...))
 174
 175 When the CDR of an element of org-publish-project-alist is in
 176 this second form, the elements of the list after :components are
 177 taken to be components of the project, which group together files
 178 requiring different publishing options. When you publish such a
 179 project with M-x org-publish, the components all publish.
 180
 181 When a property is given a value in org-publish-project-alist, its
 182 setting overrides the value of the corresponding user variable
 183  (if any) during publishing. However, options set within a file
 184 override everything.
 185
 186 Most properties are optional, but some should always be set:
 187
 188   :base-directory        Directory containing publishing source files
 189   :base-extension        Extension (without the dot!) of source files.
 190                          This can be a regular expression.
 191   :publishing-directory  Directory (possibly remote) where output
 192                          files will be published
 193
 194 The :exclude property may be used to prevent certain files from
 195 being published. Its value may be a string or regexp matching
 196 file names you don't want to be published.
 197
 198 The :include property may be used to include extra files. Its
 199 value may be a list of filenames to include. The filenames are
 200 considered relative to the publishing directory.
 201
 202 When both :include and :exclude properties are given values, the
 203 exclusion step happens first.
 204
 205 One special property controls which back-end function to use for
 206 publishing files in the project. This can be used to extend the
 207 set of file types publishable by org-publish, as well as the set
 208 of output formats.
 209
 210   :publishing-function     Function to publish file. The default is
 211                            org-publish-org-to-html, but other
 212                            values are possible. May also be a
 213                            list of functions, in which case
 214                            each function in the list is invoked
 215                            in turn.
 216
 217 Another property allows you to insert code that prepares a
 218 project for publishing. For example, you could call GNU Make on a
 219 certain makefile, to ensure published files are built up to date.
 220
 221   :preparation-function   Function to be called before publishing
 222                           this project.
 223
 224 Some properties control details of the Org publishing process,
 225 and are equivalent to the corresponding user variables listed in
 226 the right column. See the documentation for those variables to
 227 learn more about their use and default values.
 228
 229   :language              org-export-default-language
 230   :headline-levels       org-export-headline-levels
 231   :section-numbers       org-export-with-section-numbers
 232   :table-of-contents     org-export-with-toc
 233   :emphasize             org-export-with-emphasize
 234   :sub-superscript       org-export-with-sub-superscripts
 235   :TeX-macros            org-export-with-TeX-macros
 236   :fixed-width           org-export-with-fixed-width
 237   :tables                org-export-with-tables
 238   :table-auto-headline   org-export-highlight-first-table-line
 239   :style                 org-export-html-style
 240   :convert-org-links     org-export-html-link-org-files-as-html
 241   :inline-images         org-export-html-inline-images
 242   :expand-quoted-html    org-export-html-expand
 243   :timestamp             org-export-html-with-timestamp
 244   :publishing-directory  org-export-publishing-directory
 245   :preamble              org-export-html-preamble
 246   :postamble             org-export-html-postamble
 247   :auto-preamble         org-export-html-auto-preamble
 248   :auto-postamble        org-export-html-auto-postamble
 249   :author                user-full-name
 250   :email                 user-mail-address
 251
 252 The following properties may be used to control publishing of an
 253 index of files or summary page for a given project.
 254
 255   :auto-index            Whether to publish an index during
 256                          org-publish-current-project or org-publish-all.
 257   :index-filename        Filename for output of index. Defaults
 258                          to 'index.org' (which becomes 'index.html')
 259   :index-title           Title of index page. Defaults to name of file.
 260   :index-function        Plugin function to use for generation of index.
 261                          Defaults to 'org-publish-org-index', which
 262                          generates a plain list of links to all files
 263                          in the project."
 264   :group 'org-publish
 265   :type 'alist)
 266
 267 (defcustom org-publish-use-timestamps-flag t
 268   "When non-nil, use timestamp checking to publish only changed files.
 269 When nil, do no timestamp checking and always publish all
 270 files."
 271   :group 'org-publish
 272   :type 'boolean)
 273
 274 (defcustom org-publish-timestamp-directory "~/.org-timestamps/"
 275   "Name of directory in which to store publishing timestamps."
 276   :group 'org-publish
 277   :type 'directory)
 278
 279
 280 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 281 ;;; Timestamp-related functions
 282
 283 (defun org-publish-timestamp-filename (filename)
 284   "Return path to timestamp file for filename FILENAME."
 285   (while (string-match
 286           (if (eq system-type 'windows-nt) "~\\|/\\|:" "~\\|/") filename)
 287     (setq filename (replace-match "_" nil t filename)))
 288   (concat org-publish-timestamp-directory filename ".timestamp"))
 289
 290 (defun org-publish-needed-p (filename)
 291   "Return `t' if FILENAME should be published."
 292   (if org-publish-use-timestamps-flag
 293       (if (file-exists-p org-publish-timestamp-directory)
 294           ;; first handle possible wrong timestamp directory
 295           (if (not (file-directory-p org-publish-timestamp-directory))
 296               (error "Org publish timestamp: %s is not a directory"
 297                      org-publish-timestamp-directory)
 298             ;; there is a timestamp, check if FILENAME is newer
 299             (file-newer-than-file-p
 300              filename (org-publish-timestamp-filename filename))))
 301     ;; don't use timestamps, always return t
 302     t))
 303
 304 (defun org-publish-update-timestamp (filename)
 305   "Update publishing timestamp for file FILENAME.
 306 If there is no timestamp, create one."
 307   (let ((timestamp-file (org-publish-timestamp-filename filename))
 308         newly-created-timestamp)
 309     (if (not (file-exists-p timestamp-file))
 310         ;; create timestamp file if needed
 311         (with-temp-buffer
 312           (make-directory (file-name-directory timestamp-file) t)
 313           (write-file timestamp-file)
 314           (setq newly-created-timestamp t)))
 315     ;; Emacs 21 doesn't have `set-file-times'
 316     (if (and (fboundp 'set-file-times)
 317              (not newly-created-timestamp))
 318         (set-file-times timestamp-file)
 319       (call-process "touch" nil 0 nil timestamp-file))))
 320
 321
 322 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 323 ;;; Mapping files to project names
 324
 325 (defvar org-publish-files-alist nil
 326   "Alist of files and their parent project.
 327 Each element of this alist is of the form:
 328
 329   (file-name . project-name)")
 330
 331 (defun org-publish-initialize-files-alist (&optional refresh)
 332   "Set `org-publish-files-alist' if it is not set.
 333 Also set it if the optional argument REFRESH is non-nil."
 334   (when (or (not org-publish-files-alist) refresh)
 335     (setq org-publish-files-alist
 336           (org-publish-get-files org-publish-project-alist))))
 337
 338 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 339 ;;; Compatibility aliases
 340
 341 ;; Looks like dired-files-attributes is not in Emacs 21.4a.
 342 ;; FIXME: Check this twice
 343 (if (fboundp 'dired-files-attributes)
 344     (defalias 'org-publish-dired-files-attributes 'dired-files-attributes)
 345   ;; taken from dired-aux.el
 346   (defun org-publish-dired-files-attributes (dir)
 347     "Return a list of all file names and attributes from DIR.
 348 List has a form of (file-name full-file-name (attribute-list))"
 349     (mapcar
 350      (lambda (file-name)
 351        (let ((full-file-name (expand-file-name file-name dir)))
 352          (list file-name
 353                full-file-name
 354                (file-attributes full-file-name))))
 355      (directory-files dir))))
 356
 357 ;; Delete-dups is not in Emacs <22
 358 (if (fboundp 'delete-dups)
 359     (defalias 'org-publish-delete-dups 'delete-dups)
 360   (defun org-publish-delete-dups (list)
 361     "Destructively remove `equal' duplicates from LIST.
 362 Store the result in LIST and return it.  LIST must be a proper list.
 363 Of several `equal' occurrences of an element in LIST, the first
 364 one is kept.
 365
 366 This is a compatibility function for Emacsen without `delete-dups'."
 367     ;; Code from `subr.el' in Emacs 22:
 368     (let ((tail list))
 369       (while tail
 370         (setcdr tail (delete (car tail) (cdr tail)))
 371         (setq tail (cdr tail))))
 372     list))
 373
 374 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 375 ;;; Getting project information out of org-publish-project-alist
 376
 377 (defun org-publish-get-files (projects-alist &optional no-exclusion)
 378   "Return the list of all publishable files for PROJECTS-ALIST.
 379 If NO-EXCLUSION is non-nil, don't exclude files."
 380   (let (all-files)
 381     ;; add all projects
 382     (mapc
 383      (lambda(p)
 384        (let* ((exclude (plist-get (cdr p) :exclude))
 385               (files (org-publish-get-base-files p exclude)))
 386          ;; add all files from this project
 387          (mapc (lambda(f)
 388                  (add-to-list 'all-files
 389                               (cons (file-truename f) (car p))))
 390                files)))
 391      (org-publish-expand-projects projects-alist))
 392     all-files))
 393
 394 (defun org-publish-expand-projects (projects-alist)
 395   "Expand projects contained in PROJECTS-ALIST."
 396   (let (without-component with-component)
 397     (mapc (lambda(p)
 398             (add-to-list
 399              (if (plist-get (cdr p) :components)
 400                  'with-component 'without-component) p))
 401           projects-alist)
 402     (org-publish-delete-dups
 403      (append without-component
 404              (car (mapcar (lambda(p) (org-publish-expand-components p))
 405                           with-component))))))
 406
 407 (defun org-publish-expand-components (project)
 408   "Expand PROJECT into an alist of its components."
 409   (let* ((components (plist-get (cdr project) :components)))
 410     (org-publish-delete-dups
 411      (mapcar (lambda(c) (assoc c org-publish-project-alist))
 412              components))))
 413
 414 (defun org-publish-get-base-files (project &optional exclude-regexp)
 415   "Return a list of all files in PROJECT.
 416 If EXCLUDE-REGEXP is set, this will be used to filter out
 417 matching filenames."
 418   (let* ((project-plist (cdr project))
 419          (base-dir (file-name-as-directory
 420                     (plist-get project-plist :base-directory)))
 421          (include-list (plist-get project-plist :include))
 422          (recursive-p (plist-get project-plist :recursive))
 423          (extension (or (plist-get project-plist :base-extension) "org"))
 424          (regexp (concat "^[^\\.].*\\.\\(" extension "\\)$"))
 425          alldirs allfiles files dir)
 426     ;; Get all files and directories in base-directory
 427     (setq files (org-publish-dired-files-attributes base-dir))
 428     ;; Get all subdirectories if recursive-p
 429     (setq alldirs
 430           (if recursive-p
 431               (delq nil (mapcar (lambda(f) (if (caaddr f) (cadr f))) files))
 432             (list base-dir)))
 433     (while (setq dir (pop alldirs))
 434       (setq files (directory-files dir t regexp))
 435       ;; Exclude files
 436       (setq files
 437             (if (not exclude-regexp)
 438                 files
 439               (delq nil
 440                     (mapcar (lambda (x)
 441                               (if (string-match exclude-regexp x) nil x))
 442                             files))))
 443       ;; Include extra files
 444       (let (inc)
 445         (while (setq inc (pop include-list))
 446           (setq files (cons (expand-file-name inc dir) files))))
 447       (setq allfiles (append allfiles files)))
 448     allfiles))
 449
 450 (defun org-publish-get-project-from-filename (filename)
 451   "Return the project FILENAME belongs."
 452   (let* ((project-name (cdr (assoc (file-truename filename)
 453                                    org-publish-files-alist))))
 454     (assoc project-name org-publish-project-alist)))
 455
 456
 457 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 458 ;;; Pluggable publishing back-end functions
 459
 460 (defun org-publish-org-to (format plist filename pub-dir)
 461   "Publish an org file to FORMAT.
 462 PLIST is the property list for the given project.
 463 FILENAME is the filename of the org file to be published.
 464 PUB-DIR is the publishing directory."
 465   (require 'org)
 466   (unless (file-exists-p pub-dir)
 467     (make-directory pub-dir t))
 468   (find-file filename)
 469   (funcall (intern (concat "org-export-as-" format))
 470            (plist-get plist :headline-levels)
 471            nil plist nil nil pub-dir)
 472   (kill-buffer (current-buffer)))
 473
 474 (defun org-publish-org-to-latex (plist filename pub-dir)
 475   "Publish an org file to LaTeX.
 476 See `org-publish-org-to' to the list of arguments."
 477   (org-publish-org-to "latex" plist filename pub-dir))
 478
 479 (defun org-publish-org-to-html (plist filename pub-dir)
 480   "Publish an org file to HTML.
 481 See `org-publish-org-to' to the list of arguments."
 482   (org-publish-org-to "html" plist filename pub-dir))
 483
 484 (defun org-publish-attachment (plist filename)
 485   "Publish a file with no transformation of any kind.
 486 PLIST is the property list for the given project.
 487 FILENAME is the filename of the file to be published."
 488   ;; make sure eshell/cp code is loaded
 489   (eval-and-compile
 490     (require 'eshell)
 491     (require 'esh-maint)
 492     (require 'em-unix))
 493   (let ((destination (file-name-as-directory
 494                       (plist-get plist :publishing-directory))))
 495     (eshell/cp filename destination)))
 496
 497
 498 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 499 ;;; Publishing files, sets of files, and indices
 500
 501 (defun org-publish-file (filename &optional project)
 502   "Publish file FILENAME from PROJECT."
 503   (when (org-publish-needed-p filename)
 504     (let* ((project (or project (org-publish-get-project-from-filename filename)))
 505            (project-plist (cdr project))
 506            (publishing-function (or (plist-get project-plist :publishing-function)
 507                                     'org-publish-org-to-html))
 508            (base-dir (file-truename (plist-get project-plist :base-directory)))
 509            (pub-dir (file-truename (plist-get project-plist :publishing-directory)))
 510            tmp-pub-dir)
 511       (if (not project) (error "File %s is not part of any known project" filename))
 512       (setq tmp-pub-dir
 513             (file-name-directory
 514              (concat pub-dir
 515                      (and (string-match (regexp-quote base-dir) filename)
 516                           (substring filename (match-end 0))))))
 517       (if (listp publishing-function)
 518           ;; allow chain of publishing functions
 519           (mapc (lambda (f)
 520                   (funcall f project-plist filename tmp-pub-dir))
 521                 publishing-function)
 522         (funcall publishing-function project-plist filename tmp-pub-dir))
 523       (org-publish-update-timestamp filename))))
 524
 525 (defun org-publish-projects (projects)
 526   "Publish all files belonging to the PROJECTS alist.
 527 If :auto-index is set, publish the index too."
 528   (mapc
 529    (lambda (project)
 530      (let* ((project-plist (cdr project))
 531             (exclude-regexp (plist-get project-plist :exclude))
 532             (index-p (plist-get project-plist :auto-index))
 533             (index-filename (or (plist-get project-plist :index-filename)
 534                                 "index.org"))
 535             (index-function (or (plist-get project-plist :index-function)
 536                                 'org-publish-org-index))
 537             (preparation-function (plist-get project-plist :preparation-function))
 538             (files (org-publish-get-base-files project exclude-regexp)) file)
 539        (when preparation-function (funcall preparation-function))
 540        (if index-p (funcall index-function project index-filename))
 541        (while (setq file (pop files))
 542          (org-publish-file file project))))
 543    (org-publish-expand-projects projects)))
 544
 545 (defun org-publish-org-index (project &optional index-filename)
 546   "Create an index of pages in set defined by PROJECT.
 547 Optionally set the filename of the index with INDEX-FILENAME.
 548 Default for INDEX-FILENAME is 'index.org'."
 549   (let* ((project-plist (cdr project))
 550          (dir (file-name-as-directory
 551                (plist-get project-plist :base-directory)))
 552          (exclude-regexp (plist-get project-plist :exclude))
 553          (files (org-publish-get-base-files project exclude-regexp))
 554          (index-filename (concat dir (or index-filename "index.org")))
 555          (index-buffer (find-buffer-visiting index-filename))
 556          (ifn (file-name-nondirectory index-filename))
 557          file)
 558     ;; if buffer is already open, kill it to prevent error message
 559     (if index-buffer
 560         (kill-buffer index-buffer))
 561     (with-temp-buffer
 562       (while (setq file (pop files))
 563         (let ((fn (file-name-nondirectory file)))
 564           (unless (string= fn ifn) ;; index shouldn't index itself
 565             (insert (concat " + [[file:" fn "]["
 566                             (file-name-sans-extension fn)
 567                             "]]\n")))))
 568       (write-file index-filename)
 569       (kill-buffer (current-buffer)))))
 570
 571
 572 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 573 ;;; Interactive publishing functions
 574
 575 ;;;###autoload
 576 (defun org-publish (project &optional force)
 577   "Publish PROJECT."
 578   (interactive "P")
 579   (save-window-excursion
 580     (let* ((force current-prefix-arg)
 581            (org-publish-use-timestamps-flag
 582             (if force nil org-publish-use-timestamps-flag)))
 583       (org-publish-projects
 584        (list (or project
 585                  (assoc (completing-read
 586                          "Publish project: "
 587                          org-publish-project-alist nil t)
 588                         org-publish-project-alist)))))))
 589
 590 ;;;###autoload
 591 (defun org-publish-all (&optional force)
 592   "Publish all projects.
 593 With prefix argument, force publish all files."
 594   (interactive "P")
 595   (org-publish-initialize-files-alist)
 596   (save-window-excursion
 597     (let ((org-publish-use-timestamps-flag
 598            (if force nil org-publish-use-timestamps-flag)))
 599       (org-publish-projects org-publish-project-alist))))
 600
 601 ;;;###autoload
 602 (defun org-publish-current-file (&optional force)
 603   "Publish the current file.
 604 With prefix argument, force publish the file."
 605   (interactive "P")
 606   (org-publish-initialize-files-alist)
 607   (save-window-excursion
 608     (let ((org-publish-use-timestamps-flag
 609            (if force nil org-publish-use-timestamps-flag)))
 610       (org-publish-file (buffer-file-name)))))
 611
 612 ;;;###autoload
 613 (defun org-publish-current-project (&optional force)
 614   "Publish the project associated with the current file.
 615 With a prefix argument, force publishing of all files in
 616 the project."
 617   (interactive "P")
 618   (org-publish-initialize-files-alist)
 619   (save-window-excursion
 620     (let ((project (org-publish-get-project-from-filename (buffer-file-name)))
 621           (org-publish-use-timestamps-flag
 622            (if force nil org-publish-use-timestamps-flag)))
 623       (if (not project)
 624           (error "File %s is not part of any known project" (buffer-file-name)))
 625       (org-publish project))))
 626
 627 (provide 'org-publish)
 628
 629
 630 ;; arch-tag: 72807f3c-8af0-4a6b-8dca-c3376eb25adb
 631 ;;; org-publish.el ends here