lisp/ox-md.el

   1 ;;; ox-md.el --- Markdown Back-End for Org Export Engine
   2
   3 ;; Copyright (C) 2012-2015 Free Software Foundation, Inc.
   4
   5 ;; Author: Nicolas Goaziou <n.goaziou@gmail.com>
   6 ;; Keywords: org, wp, markdown
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This library implements a Markdown back-end (vanilla flavor) for
  26 ;; Org exporter, based on `html' back-end.  See Org manual for more
  27 ;; information.
  28
  29 ;;; Code:
  30
  31 (eval-when-compile (require 'cl))
  32 (require 'ox-html)
  33 (require 'ox-publish)
  34
  35 \f
  36 ;;; User-Configurable Variables
  37
  38 (defgroup org-export-md nil
  39   "Options specific to Markdown export back-end."
  40   :tag "Org Markdown"
  41   :group 'org-export
  42   :version "24.4"
  43   :package-version '(Org . "8.0"))
  44
  45 (defcustom org-md-headline-style 'atx
  46   "Style used to format headlines.
  47 This variable can be set to either `atx' or `setext'."
  48   :group 'org-export-md
  49   :type '(choice
  50           (const :tag "Use \"atx\" style" atx)
  51           (const :tag "Use \"Setext\" style" setext)))
  52
  53
  54 \f
  55 ;;; Define Back-End
  56
  57 (org-export-define-derived-backend 'md 'html
  58   :export-block '("MD" "MARKDOWN")
  59   :filters-alist '((:filter-parse-tree . org-md-separate-elements))
  60   :menu-entry
  61   '(?m "Export to Markdown"
  62        ((?M "To temporary buffer"
  63             (lambda (a s v b) (org-md-export-as-markdown a s v)))
  64         (?m "To file" (lambda (a s v b) (org-md-export-to-markdown a s v)))
  65         (?o "To file and open"
  66             (lambda (a s v b)
  67               (if a (org-md-export-to-markdown t s v)
  68                 (org-open-file (org-md-export-to-markdown nil s v)))))))
  69   :translate-alist '((bold . org-md-bold)
  70                      (code . org-md-verbatim)
  71                      (example-block . org-md-example-block)
  72                      (export-block . org-md-export-block)
  73                      (fixed-width . org-md-example-block)
  74                      (headline . org-md-headline)
  75                      (horizontal-rule . org-md-horizontal-rule)
  76                      (inline-src-block . org-md-verbatim)
  77                      (inner-template . org-md-inner-template)
  78                      (italic . org-md-italic)
  79                      (item . org-md-item)
  80                      (keyword . org-md-keyword)
  81                      (line-break . org-md-line-break)
  82                      (link . org-md-link)
  83                      (node-property . org-md-node-property)
  84                      (paragraph . org-md-paragraph)
  85                      (plain-list . org-md-plain-list)
  86                      (plain-text . org-md-plain-text)
  87                      (property-drawer . org-md-property-drawer)
  88                      (quote-block . org-md-quote-block)
  89                      (section . org-md-section)
  90                      (src-block . org-md-example-block)
  91                      (template . org-md-template)
  92                      (verbatim . org-md-verbatim))
  93   :options-alist '((:md-headline-style nil nil org-md-headline-style)))
  94
  95 \f
  96 ;;; Filters
  97
  98 (defun org-md-separate-elements (tree backend info)
  99   "Fix blank lines between elements.
 100
 101 TREE is the parse tree being exported.  BACKEND is the export
 102 back-end used.  INFO is a plist used as a communication channel.
 103
 104 Enforce a blank line between elements.  There are two exceptions
 105 to this rule:
 106
 107   1. Preserve blank lines between sibling items in a plain list,
 108
 109   2. In an item, remove any blank line before the very first
 110      paragraph and the next sub-list.
 111
 112 Assume BACKEND is `md'."
 113   (org-element-map tree (remq 'item org-element-all-elements)
 114     (lambda (e)
 115       (org-element-put-property
 116        e :post-blank
 117        (if (and (eq (org-element-type e) 'paragraph)
 118                 (eq (org-element-type (org-element-property :parent e)) 'item)
 119                 (eq (org-element-type (org-export-get-next-element e info))
 120                     'plain-list)
 121                 (not (org-export-get-previous-element e info)))
 122            0
 123          1))))
 124   ;; Return updated tree.
 125   tree)
 126
 127
 128 \f
 129 ;;; Transcode Functions
 130
 131 ;;;; Bold
 132
 133 (defun org-md-bold (bold contents info)
 134   "Transcode BOLD object into Markdown format.
 135 CONTENTS is the text within bold markup.  INFO is a plist used as
 136 a communication channel."
 137   (format "**%s**" contents))
 138
 139
 140 ;;;; Code and Verbatim
 141
 142 (defun org-md-verbatim (verbatim contents info)
 143   "Transcode VERBATIM object into Markdown format.
 144 CONTENTS is nil.  INFO is a plist used as a communication
 145 channel."
 146   (let ((value (org-element-property :value verbatim)))
 147     (format (cond ((not (string-match "`" value)) "`%s`")
 148                   ((or (string-match "\\``" value)
 149                        (string-match "`\\'" value))
 150                    "`` %s ``")
 151                   (t "``%s``"))
 152             value)))
 153
 154
 155 ;;;; Example Block, Src Block and export Block
 156
 157 (defun org-md-example-block (example-block contents info)
 158   "Transcode EXAMPLE-BLOCK element into Markdown format.
 159 CONTENTS is nil.  INFO is a plist used as a communication
 160 channel."
 161   (replace-regexp-in-string
 162    "^" "    "
 163    (org-remove-indentation
 164     (org-export-format-code-default example-block info))))
 165
 166 (defun org-md-export-block (export-block contents info)
 167   "Transcode a EXPORT-BLOCK element from Org to Markdown.
 168 CONTENTS is nil.  INFO is a plist holding contextual information."
 169   (if (member (org-element-property :type export-block) '("MARKDOWN" "MD"))
 170       (org-remove-indentation (org-element-property :value export-block))
 171     ;; Also include HTML export blocks.
 172     (org-export-with-backend 'html export-block contents info)))
 173
 174
 175 ;;;; Headline
 176
 177 (defun org-md-headline (headline contents info)
 178   "Transcode HEADLINE element into Markdown format.
 179 CONTENTS is the headline contents.  INFO is a plist used as
 180 a communication channel."
 181   (unless (org-element-property :footnote-section-p headline)
 182     (let* ((level (org-export-get-relative-level headline info))
 183            (title (org-export-data (org-element-property :title headline) info))
 184            (todo (and (plist-get info :with-todo-keywords)
 185                       (let ((todo (org-element-property :todo-keyword
 186                                                         headline)))
 187                         (and todo (concat (org-export-data todo info) " ")))))
 188            (tags (and (plist-get info :with-tags)
 189                       (let ((tag-list (org-export-get-tags headline info)))
 190                         (and tag-list
 191                              (format "     :%s:"
 192                                      (mapconcat 'identity tag-list ":"))))))
 193            (priority
 194             (and (plist-get info :with-priority)
 195                  (let ((char (org-element-property :priority headline)))
 196                    (and char (format "[#%c] " char)))))
 197            (anchor
 198             (and (plist-get info :with-toc)
 199                  (org-html--anchor
 200                   (org-export-get-reference headline info) nil nil info)))
 201            ;; Headline text without tags.
 202            (heading (concat todo priority title))
 203            (style (plist-get info :md-headline-style)))
 204       (cond
 205        ;; Cannot create a headline.  Fall-back to a list.
 206        ((or (org-export-low-level-p headline info)
 207             (not (memq style '(atx setext)))
 208             (and (eq style 'atx) (> level 6))
 209             (and (eq style 'setext) (> level 2)))
 210         (let ((bullet
 211                (if (not (org-export-numbered-headline-p headline info)) "-"
 212                  (concat (number-to-string
 213                           (car (last (org-export-get-headline-number
 214                                       headline info))))
 215                          "."))))
 216           (concat bullet (make-string (- 4 (length bullet)) ? ) heading tags
 217                   "\n\n"
 218                   (and contents
 219                        (replace-regexp-in-string "^" "    " contents)))))
 220        ;; Use "Setext" style.
 221        ((eq style 'setext)
 222         (concat heading tags anchor "\n"
 223                 (make-string (length heading) (if (= level 1) ?= ?-))
 224                 "\n\n"
 225                 contents))
 226        ;; Use "atx" style.
 227        (t (concat (make-string level ?#) " " heading tags anchor "\n\n" contents))))))
 228
 229
 230 ;;;; Horizontal Rule
 231
 232 (defun org-md-horizontal-rule (horizontal-rule contents info)
 233   "Transcode HORIZONTAL-RULE element into Markdown format.
 234 CONTENTS is the horizontal rule contents.  INFO is a plist used
 235 as a communication channel."
 236   "---")
 237
 238
 239 ;;;; Italic
 240
 241 (defun org-md-italic (italic contents info)
 242   "Transcode ITALIC object into Markdown format.
 243 CONTENTS is the text within italic markup.  INFO is a plist used
 244 as a communication channel."
 245   (format "*%s*" contents))
 246
 247
 248 ;;;; Item
 249
 250 (defun org-md-item (item contents info)
 251   "Transcode ITEM element into Markdown format.
 252 CONTENTS is the item contents.  INFO is a plist used as
 253 a communication channel."
 254   (let* ((type (org-element-property :type (org-export-get-parent item)))
 255          (struct (org-element-property :structure item))
 256          (bullet (if (not (eq type 'ordered)) "-"
 257                    (concat (number-to-string
 258                             (car (last (org-list-get-item-number
 259                                         (org-element-property :begin item)
 260                                         struct
 261                                         (org-list-prevs-alist struct)
 262                                         (org-list-parents-alist struct)))))
 263                            "."))))
 264     (concat bullet
 265             (make-string (- 4 (length bullet)) ? )
 266             (case (org-element-property :checkbox item)
 267               (on "[X] ")
 268               (trans "[-] ")
 269               (off "[ ] "))
 270             (let ((tag (org-element-property :tag item)))
 271               (and tag (format "**%s:** "(org-export-data tag info))))
 272             (and contents
 273                  (org-trim (replace-regexp-in-string "^" "    " contents))))))
 274
 275
 276
 277 ;;;; Keyword
 278
 279 (defun org-md-keyword (keyword contents info)
 280   "Transcode a KEYWORD element into Markdown format.
 281 CONTENTS is nil.  INFO is a plist used as a communication
 282 channel."
 283   (if (member (org-element-property :key keyword) '("MARKDOWN" "MD"))
 284       (org-element-property :value keyword)
 285     (org-export-with-backend 'html keyword contents info)))
 286
 287
 288 ;;;; Line Break
 289
 290 (defun org-md-line-break (line-break contents info)
 291   "Transcode LINE-BREAK object into Markdown format.
 292 CONTENTS is nil.  INFO is a plist used as a communication
 293 channel."
 294   "  \n")
 295
 296
 297 ;;;; Link
 298
 299 (defun org-md-link (link contents info)
 300   "Transcode LINE-BREAK object into Markdown format.
 301 CONTENTS is the link's description.  INFO is a plist used as
 302 a communication channel."
 303   (let ((link-org-files-as-md
 304          (function
 305           (lambda (raw-path)
 306             ;; Treat links to `file.org' as links to `file.md'.
 307             (if (string= ".org" (downcase (file-name-extension raw-path ".")))
 308                 (concat (file-name-sans-extension raw-path) ".md")
 309               raw-path))))
 310         (type (org-element-property :type link)))
 311     (cond
 312      ;; Link type is handled by a special function.
 313      ((org-export-custom-protocol-maybe link contents 'md))
 314      ((member type '("custom-id" "id"))
 315       (let ((destination (org-export-resolve-id-link link info)))
 316         (if (stringp destination)       ; External file.
 317             (let ((path (funcall link-org-files-as-md destination)))
 318               (if (not contents) (format "<%s>" path)
 319                 (format "[%s](%s)" contents path)))
 320           (concat
 321            (and contents (concat contents " "))
 322            (format "(%s)"
 323                    (format (org-export-translate "See section %s" :html info)
 324                            (if (org-export-numbered-headline-p destination info)
 325                                (mapconcat #'number-to-string
 326                                           (org-export-get-headline-number
 327                                            destination info)
 328                                           ".")
 329                              (org-export-data
 330                               (org-element-property :title destination) info))))))))
 331      ((org-export-inline-image-p link org-html-inline-image-rules)
 332       (let ((path (let ((raw-path (org-element-property :path link)))
 333                     (if (not (file-name-absolute-p raw-path)) raw-path
 334                       (expand-file-name raw-path))))
 335             (caption (org-export-data
 336                       (org-export-get-caption
 337                        (org-export-get-parent-element link)) info)))
 338         (format "![img](%s)"
 339                 (if (not (org-string-nw-p caption)) path
 340                   (format "%s \"%s\"" path caption)))))
 341      ((string= type "coderef")
 342       (let ((ref (org-element-property :path link)))
 343         (format (org-export-get-coderef-format ref contents)
 344                 (org-export-resolve-coderef ref info))))
 345      ((equal type "radio") contents)
 346      ((equal type "fuzzy")
 347       (let ((destination (org-export-resolve-fuzzy-link link info)))
 348         (if (org-string-nw-p contents) contents
 349           (when destination
 350             (let ((number (org-export-get-ordinal destination info)))
 351               (if number
 352                   (if (atom number) (number-to-string number)
 353                     (mapconcat #'number-to-string number "."))
 354                 ;; Unnumbered headline.
 355                 (and (eq 'headline (org-element-type destination))
 356                      ;; BUG: shouldn't headlines have a form like [ref](name) in md?
 357                      (org-export-data
 358                       (org-element-property :title destination) info))))))))
 359      (t (let* ((raw-path (org-element-property :path link))
 360                (path
 361                 (cond
 362                  ((member type '("http" "https" "ftp"))
 363                   (concat type ":" raw-path))
 364                  ((string= type "file")
 365                   (org-export-file-uri (funcall link-org-files-as-md raw-path)))
 366                  (t raw-path))))
 367           (if (not contents) (format "<%s>" path)
 368             (format "[%s](%s)" contents path)))))))
 369
 370
 371 ;;;; Node Property
 372
 373 (defun org-md-node-property (node-property contents info)
 374   "Transcode a NODE-PROPERTY element into Markdown syntax.
 375 CONTENTS is nil.  INFO is a plist holding contextual
 376 information."
 377   (format "%s:%s"
 378           (org-element-property :key node-property)
 379           (let ((value (org-element-property :value node-property)))
 380             (if value (concat " " value) ""))))
 381
 382
 383 ;;;; Paragraph
 384
 385 (defun org-md-paragraph (paragraph contents info)
 386   "Transcode PARAGRAPH element into Markdown format.
 387 CONTENTS is the paragraph contents.  INFO is a plist used as
 388 a communication channel."
 389   (let ((first-object (car (org-element-contents paragraph))))
 390     ;; If paragraph starts with a #, protect it.
 391     (if (and (stringp first-object) (string-match "\\`#" first-object))
 392         (replace-regexp-in-string "\\`#" "\\#" contents nil t)
 393       contents)))
 394
 395
 396 ;;;; Plain List
 397
 398 (defun org-md-plain-list (plain-list contents info)
 399   "Transcode PLAIN-LIST element into Markdown format.
 400 CONTENTS is the plain-list contents.  INFO is a plist used as
 401 a communication channel."
 402   contents)
 403
 404
 405 ;;;; Plain Text
 406
 407 (defun org-md-plain-text (text info)
 408   "Transcode a TEXT string into Markdown format.
 409 TEXT is the string to transcode.  INFO is a plist holding
 410 contextual information."
 411   (when (plist-get info :with-smart-quotes)
 412     (setq text (org-export-activate-smart-quotes text :html info)))
 413   ;; Protect ambiguous #.  This will protect # at the beginning of
 414   ;; a line, but not at the beginning of a paragraph.  See
 415   ;; `org-md-paragraph'.
 416   (setq text (replace-regexp-in-string "\n#" "\n\\\\#" text))
 417   ;; Protect ambiguous !
 418   (setq text (replace-regexp-in-string "\\(!\\)\\[" "\\\\!" text nil nil 1))
 419   ;; Protect `, *, _ and \
 420   (setq text (replace-regexp-in-string "[`*_\\]" "\\\\\\&" text))
 421   ;; Handle special strings, if required.
 422   (when (plist-get info :with-special-strings)
 423     (setq text (org-html-convert-special-strings text)))
 424   ;; Handle break preservation, if required.
 425   (when (plist-get info :preserve-breaks)
 426     (setq text (replace-regexp-in-string "[ \t]*\n" "  \n" text)))
 427   ;; Return value.
 428   text)
 429
 430
 431 ;;;; Property Drawer
 432
 433 (defun org-md-property-drawer (property-drawer contents info)
 434   "Transcode a PROPERTY-DRAWER element into Markdown format.
 435 CONTENTS holds the contents of the drawer.  INFO is a plist
 436 holding contextual information."
 437   (and (org-string-nw-p contents)
 438        (replace-regexp-in-string "^" "    " contents)))
 439
 440
 441 ;;;; Quote Block
 442
 443 (defun org-md-quote-block (quote-block contents info)
 444   "Transcode QUOTE-BLOCK element into Markdown format.
 445 CONTENTS is the quote-block contents.  INFO is a plist used as
 446 a communication channel."
 447   (replace-regexp-in-string
 448    "^" "> "
 449    (replace-regexp-in-string "\n\\'" "" contents)))
 450
 451
 452 ;;;; Section
 453
 454 (defun org-md-section (section contents info)
 455   "Transcode SECTION element into Markdown format.
 456 CONTENTS is the section contents.  INFO is a plist used as
 457 a communication channel."
 458   contents)
 459
 460
 461 ;;;; Template
 462
 463 (defun org-md-inner-template (contents info)
 464   "Return body of document after converting it to Markdown syntax.
 465 CONTENTS is the transcoded contents string.  INFO is a plist
 466 holding export options."
 467   ;; Make sure CONTENTS is separated from table of contents and
 468   ;; footnotes with at least a blank line.
 469   (org-trim (org-html-inner-template (concat "\n" contents "\n") info)))
 470
 471 (defun org-md-template (contents info)
 472   "Return complete document string after Markdown conversion.
 473 CONTENTS is the transcoded contents string.  INFO is a plist used
 474 as a communication channel."
 475   contents)
 476
 477
 478 \f
 479 ;;; Interactive function
 480
 481 ;;;###autoload
 482 (defun org-md-export-as-markdown (&optional async subtreep visible-only)
 483   "Export current buffer to a Markdown buffer.
 484
 485 If narrowing is active in the current buffer, only export its
 486 narrowed part.
 487
 488 If a region is active, export that region.
 489
 490 A non-nil optional argument ASYNC means the process should happen
 491 asynchronously.  The resulting buffer should be accessible
 492 through the `org-export-stack' interface.
 493
 494 When optional argument SUBTREEP is non-nil, export the sub-tree
 495 at point, extracting information from the headline properties
 496 first.
 497
 498 When optional argument VISIBLE-ONLY is non-nil, don't export
 499 contents of hidden elements.
 500
 501 Export is done in a buffer named \"*Org MD Export*\", which will
 502 be displayed when `org-export-show-temporary-export-buffer' is
 503 non-nil."
 504   (interactive)
 505   (org-export-to-buffer 'md "*Org MD Export*"
 506     async subtreep visible-only nil nil (lambda () (text-mode))))
 507
 508 ;;;###autoload
 509 (defun org-md-convert-region-to-md ()
 510   "Assume the current region has org-mode syntax, and convert it to Markdown.
 511 This can be used in any buffer.  For example, you can write an
 512 itemized list in org-mode syntax in a Markdown buffer and use
 513 this command to convert it."
 514   (interactive)
 515   (org-export-replace-region-by 'md))
 516
 517
 518 ;;;###autoload
 519 (defun org-md-export-to-markdown (&optional async subtreep visible-only)
 520   "Export current buffer to a Markdown file.
 521
 522 If narrowing is active in the current buffer, only export its
 523 narrowed part.
 524
 525 If a region is active, export that region.
 526
 527 A non-nil optional argument ASYNC means the process should happen
 528 asynchronously.  The resulting file should be accessible through
 529 the `org-export-stack' interface.
 530
 531 When optional argument SUBTREEP is non-nil, export the sub-tree
 532 at point, extracting information from the headline properties
 533 first.
 534
 535 When optional argument VISIBLE-ONLY is non-nil, don't export
 536 contents of hidden elements.
 537
 538 Return output file's name."
 539   (interactive)
 540   (let ((outfile (org-export-output-file-name ".md" subtreep)))
 541     (org-export-to-file 'md outfile async subtreep visible-only)))
 542
 543 ;;;###autoload
 544 (defun org-md-publish-to-md (plist filename pub-dir)
 545   "Publish an org file to Markdown.
 546
 547 FILENAME is the filename of the Org file to be published.  PLIST
 548 is the property list for the given project.  PUB-DIR is the
 549 publishing directory.
 550
 551 Return output file name."
 552   (org-publish-org-to 'md filename ".md" plist pub-dir))
 553
 554 (provide 'ox-md)
 555
 556 ;; Local variables:
 557 ;; generated-autoload-file: "org-loaddefs.el"
 558 ;; End:
 559
 560 ;;; ox-md.el ends here