lisp/org-timer.el

   1 ;;; org-timer.el --- Timer code for Org mode         -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2008-2016 Free Software Foundation, Inc.
   4
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: http://orgmode.org
   8 ;;
   9 ;; This file is part of GNU Emacs.
  10 ;;
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  24 ;;
  25 ;;; Commentary:
  26
  27 ;; This file implements two types of timers for Org buffers:
  28 ;;
  29 ;; - A relative timer that counts up (from 0 or a specified offset)
  30 ;; - A countdown timer that counts down from a specified time
  31 ;;
  32 ;; The relative and countdown timers differ in their entry points.
  33 ;; Use `org-timer' or `org-timer-start' to start the relative timer,
  34 ;; and `org-timer-set-timer' to start the countdown timer.
  35
  36 ;;; Code:
  37
  38 (require 'cl-lib)
  39 (require 'org-clock)
  40
  41 (declare-function org-agenda-error "org-agenda" ())
  42
  43 (defvar org-timer-start-time nil
  44   "t=0 for the running timer.")
  45
  46 (defvar org-timer-pause-time nil
  47   "Time when the timer was paused.")
  48
  49 (defvar org-timer-countdown-timer nil
  50   "Current countdown timer.
  51 This is a timer object if there is an active countdown timer,
  52 `paused' if there is a paused countdown timer, and nil
  53 otherwise.")
  54
  55 (defvar org-timer-countdown-timer-title nil
  56   "Title for notification displayed when a countdown finishes.")
  57
  58 (defconst org-timer-re "\\([-+]?[0-9]+\\):\\([0-9]\\{2\\}\\):\\([0-9]\\{2\\}\\)"
  59   "Regular expression used to match timer stamps.")
  60
  61 (defcustom org-timer-format "%s "
  62   "The format to insert the time of the timer.
  63 This format must contain one instance of \"%s\" which will be replaced by
  64 the value of the timer."
  65   :group 'org-time
  66   :type 'string)
  67
  68 (defcustom org-timer-default-timer "0"
  69   "The default timer when a timer is set, in minutes or hh:mm:ss format.
  70 When 0, the user is prompted for a value."
  71   :group 'org-time
  72   :version "25.1"
  73   :package-version '(Org . "8.3")
  74   :type 'string)
  75
  76 (defcustom org-timer-display 'mode-line
  77   "Define where running timer is displayed, if at all.
  78 When a timer is running, Org can display it in the mode line
  79 and/or frame title.  Allowed values are:
  80
  81 both         displays in both mode line and frame title
  82 mode-line    displays only in mode line (default)
  83 frame-title  displays only in frame title
  84 nil          current timer is not displayed"
  85   :group 'org-time
  86   :type '(choice
  87           (const :tag "Mode line" mode-line)
  88           (const :tag "Frame title" frame-title)
  89           (const :tag "Both" both)
  90           (const :tag "None" nil)))
  91
  92 (defvar org-timer-start-hook nil
  93   "Hook run after relative timer is started.")
  94
  95 (defvar org-timer-stop-hook nil
  96   "Hook run before relative or countdown timer is stopped.")
  97
  98 (defvar org-timer-pause-hook nil
  99   "Hook run before relative or countdown timer is paused.")
 100
 101 (defvar org-timer-continue-hook nil
 102   "Hook run after relative or countdown timer is continued.")
 103
 104 (defvar org-timer-set-hook nil
 105   "Hook run after countdown timer is set.")
 106
 107 (defvar org-timer-done-hook nil
 108   "Hook run after countdown timer reaches zero.")
 109
 110 ;;;###autoload
 111 (defun org-timer-start (&optional offset)
 112   "Set the starting time for the relative timer to now.
 113 When called with prefix argument OFFSET, prompt the user for an offset time,
 114 with the default taken from a timer stamp at point, if any.
 115 If OFFSET is a string or an integer, it is directly taken to be the offset
 116 without user interaction.
 117 When called with a double prefix arg, all timer strings in the active
 118 region will be shifted by a specific amount.  You will be prompted for
 119 the amount, with the default to make the first timer string in
 120 the region 0:00:00."
 121   (interactive "P")
 122   (cond
 123    ((equal offset '(16))
 124     (call-interactively 'org-timer-change-times-in-region))
 125    (org-timer-countdown-timer
 126     (user-error "Countdown timer is running.  Cancel first"))
 127    (t
 128     (let (delta def s)
 129       (if (not offset)
 130           (setq org-timer-start-time (current-time))
 131         (cond
 132          ((integerp offset) (setq delta offset))
 133          ((stringp offset) (setq delta (org-timer-hms-to-secs offset)))
 134          (t
 135           (setq def (if (org-in-regexp org-timer-re)
 136                         (match-string 0)
 137                       "0:00:00")
 138                 s (read-string
 139                    (format "Restart timer with offset [%s]: " def)))
 140           (unless (string-match "\\S-" s) (setq s def))
 141           (setq delta (org-timer-hms-to-secs (org-timer-fix-incomplete s)))))
 142         (setq org-timer-start-time
 143               (seconds-to-time
 144                ;; Pass `current-time' result to `float-time' (instead
 145                ;; of calling without arguments) so that only
 146                ;; `current-time' has to be overriden in tests.
 147                (- (float-time (current-time)) delta))))
 148       (setq org-timer-pause-time nil)
 149       (org-timer-set-mode-line 'on)
 150       (message "Timer start time set to %s, current value is %s"
 151                (format-time-string "%T" org-timer-start-time)
 152                (org-timer-secs-to-hms (or delta 0)))
 153       (run-hooks 'org-timer-start-hook)))))
 154
 155 (defun org-timer-pause-or-continue (&optional stop)
 156   "Pause or continue the relative or countdown timer.
 157 With prefix arg STOP, stop it entirely."
 158   (interactive "P")
 159   (cond
 160    (stop (org-timer-stop))
 161    ((not org-timer-start-time) (error "No timer is running"))
 162    (org-timer-pause-time
 163     (let ((start-secs (float-time org-timer-start-time))
 164           (pause-secs (float-time org-timer-pause-time)))
 165       (if org-timer-countdown-timer
 166           (let ((new-secs (- start-secs pause-secs)))
 167             (setq org-timer-countdown-timer
 168                   (org-timer--run-countdown-timer
 169                    new-secs org-timer-countdown-timer-title))
 170             (setq org-timer-start-time
 171                   (time-add (current-time) (seconds-to-time new-secs))))
 172         (setq org-timer-start-time
 173               ;; Pass `current-time' result to `float-time' (instead
 174               ;; of calling without arguments) so that only
 175               ;; `current-time' has to be overriden in tests.
 176               (seconds-to-time (- (float-time (current-time))
 177                                   (- pause-secs start-secs)))))
 178       (setq org-timer-pause-time nil)
 179       (org-timer-set-mode-line 'on)
 180       (run-hooks 'org-timer-continue-hook)
 181       (message "Timer continues at %s" (org-timer-value-string))))
 182    (t
 183     ;; pause timer
 184     (when org-timer-countdown-timer
 185       (cancel-timer org-timer-countdown-timer)
 186       (setq org-timer-countdown-timer 'paused))
 187     (run-hooks 'org-timer-pause-hook)
 188     (setq org-timer-pause-time (current-time))
 189     (org-timer-set-mode-line 'paused)
 190     (message "Timer paused at %s" (org-timer-value-string)))))
 191
 192 (defun org-timer-stop ()
 193   "Stop the relative or countdown timer."
 194   (interactive)
 195   (unless org-timer-start-time
 196     (user-error "No timer running"))
 197   (when (timerp org-timer-countdown-timer)
 198     (cancel-timer org-timer-countdown-timer))
 199   (run-hooks 'org-timer-stop-hook)
 200   (setq org-timer-start-time nil
 201         org-timer-pause-time nil
 202         org-timer-countdown-timer nil)
 203   (org-timer-set-mode-line 'off)
 204   (message "Timer stopped"))
 205
 206 ;;;###autoload
 207 (defun org-timer (&optional restart no-insert-p)
 208   "Insert a H:MM:SS string from the timer into the buffer.
 209 The first time this command is used, the timer is started.  When used with
 210 a \\[universal-argument] prefix, force restarting the timer.
 211 When used with a double prefix argument \\[universal-argument], change all the timer string
 212 in the region by a fixed amount.  This can be used to recalibrate a timer
 213 that was not started at the correct moment.
 214
 215 If NO-INSERT-P is non-nil, return the string instead of inserting
 216 it in the buffer."
 217   (interactive "P")
 218   (if (equal restart '(16))
 219       (org-timer-start restart)
 220     (when (or (equal restart '(4)) (not org-timer-start-time))
 221       (org-timer-start))
 222     (if no-insert-p
 223         (org-timer-value-string)
 224       (insert (org-timer-value-string)))))
 225
 226 (defun org-timer-value-string ()
 227   "Set the timer string."
 228   (format org-timer-format
 229           (org-timer-secs-to-hms
 230            (abs (floor (org-timer-seconds))))))
 231
 232 (defun org-timer-seconds ()
 233   ;; Pass `current-time' result to `float-time' (instead of calling
 234   ;; without arguments) so that only `current-time' has to be
 235   ;; overriden in tests.
 236   (if org-timer-countdown-timer
 237       (- (float-time org-timer-start-time)
 238          (float-time (or org-timer-pause-time (current-time))))
 239     (- (float-time (or org-timer-pause-time (current-time)))
 240        (float-time org-timer-start-time))))
 241
 242 ;;;###autoload
 243 (defun org-timer-change-times-in-region (beg end delta)
 244   "Change all h:mm:ss time in region by a DELTA."
 245   (interactive
 246    "r\nsEnter time difference like \"-1:08:26\".  Default is first time to zero: ")
 247   (let ((re "[-+]?[0-9]+:[0-9]\\{2\\}:[0-9]\\{2\\}") p)
 248     (unless (string-match "\\S-" delta)
 249       (save-excursion
 250         (goto-char beg)
 251         (when (re-search-forward re end t)
 252           (setq delta (match-string 0))
 253           (if (equal (string-to-char delta) ?-)
 254               (setq delta (substring delta 1))
 255             (setq delta (concat "-" delta))))))
 256     (setq delta (org-timer-hms-to-secs (org-timer-fix-incomplete delta)))
 257     (when (= delta 0) (error "No change"))
 258     (save-excursion
 259       (goto-char end)
 260       (while (re-search-backward re beg t)
 261         (setq p (point))
 262         (replace-match
 263          (save-match-data
 264            (org-timer-secs-to-hms (+ (org-timer-hms-to-secs (match-string 0)) delta)))
 265          t t)
 266         (goto-char p)))))
 267
 268 ;;;###autoload
 269 (defun org-timer-item (&optional arg)
 270   "Insert a description-type item with the current timer value."
 271   (interactive "P")
 272   (let ((itemp (org-in-item-p)) (pos (point)))
 273     (cond
 274      ;; In a timer list, insert with `org-list-insert-item',
 275      ;; then fix the list.
 276      ((and itemp (goto-char itemp) (org-at-item-timer-p))
 277       (let* ((struct (org-list-struct))
 278              (prevs (org-list-prevs-alist struct))
 279              (s (concat (org-timer (when arg '(4)) t) ":: ")))
 280         (setq struct (org-list-insert-item pos struct prevs nil s))
 281         (org-list-write-struct struct (org-list-parents-alist struct))
 282         (looking-at org-list-full-item-re)
 283         (goto-char (match-end 0))))
 284      ;; In a list of another type, don't break anything: throw an error.
 285      (itemp (goto-char pos) (error "This is not a timer list"))
 286      ;; Else, start a new list.
 287      (t
 288       (beginning-of-line)
 289       (org-indent-line)
 290       (insert  "- ")
 291       (org-timer (when arg '(4)))
 292       (insert ":: ")))))
 293
 294 (defun org-timer-fix-incomplete (hms)
 295   "If hms is a H:MM:SS string with missing hour or hour and minute, fix it."
 296   (if (string-match "\\(?:\\([0-9]+:\\)?\\([0-9]+:\\)\\)?\\([0-9]+\\)" hms)
 297       (replace-match
 298        (format "%d:%02d:%02d"
 299                (if (match-end 1) (string-to-number (match-string 1 hms)) 0)
 300                (if (match-end 2) (string-to-number (match-string 2 hms)) 0)
 301                (string-to-number (match-string 3 hms)))
 302        t t hms)
 303     (error "Cannot parse HMS string \"%s\"" hms)))
 304
 305 (defun org-timer-hms-to-secs (hms)
 306   "Convert h:mm:ss string to an integer time.
 307 If the string starts with a minus sign, the integer will be negative."
 308   (if (not (string-match
 309             "\\([-+]?[0-9]+\\):\\([0-9]\\{2\\}\\):\\([0-9]\\{2\\}\\)"
 310             hms))
 311       0
 312     (let* ((h (string-to-number (match-string 1 hms)))
 313            (m (string-to-number (match-string 2 hms)))
 314            (s (string-to-number (match-string 3 hms)))
 315            (sign (equal (substring (match-string 1 hms) 0 1) "-")))
 316       (setq h (abs h))
 317       (* (if sign -1 1) (+ s (* 60 (+ m (* 60 h))))))))
 318
 319 (defun org-timer-secs-to-hms (s)
 320   "Convert integer S into h:mm:ss.
 321 If the integer is negative, the string will start with \"-\"."
 322   (let (sign m h)
 323     (setq sign (if (< s 0) "-" "")
 324           s (abs s)
 325           m (/ s 60) s (- s (* 60 m))
 326           h (/ m 60) m (- m (* 60 h)))
 327     (format "%s%d:%02d:%02d" sign h m s)))
 328
 329 (defvar org-timer-mode-line-timer nil)
 330 (defvar org-timer-mode-line-string nil)
 331
 332 (defun org-timer-set-mode-line (value)
 333   "Set the mode-line display for relative or countdown timer.
 334 VALUE can be `on', `off', or `paused'."
 335   (when (or (eq org-timer-display 'mode-line)
 336             (eq org-timer-display 'both))
 337     (or global-mode-string (setq global-mode-string '("")))
 338     (or (memq 'org-timer-mode-line-string global-mode-string)
 339         (setq global-mode-string
 340               (append global-mode-string '(org-timer-mode-line-string)))))
 341   (when (or (eq org-timer-display 'frame-title)
 342             (eq org-timer-display 'both))
 343     (or (memq 'org-timer-mode-line-string frame-title-format)
 344         (setq frame-title-format
 345               (append frame-title-format '(org-timer-mode-line-string)))))
 346   (cl-case value
 347     (off
 348      (when org-timer-mode-line-timer
 349        (cancel-timer org-timer-mode-line-timer)
 350        (setq org-timer-mode-line-timer nil))
 351      (when (or (eq org-timer-display 'mode-line)
 352                (eq org-timer-display 'both))
 353        (setq global-mode-string
 354              (delq 'org-timer-mode-line-string global-mode-string)))
 355      (when (or (eq org-timer-display 'frame-title)
 356                (eq org-timer-display 'both))
 357        (setq frame-title-format
 358              (delq 'org-timer-mode-line-string frame-title-format)))
 359      (force-mode-line-update))
 360     (paused
 361      (when org-timer-mode-line-timer
 362        (cancel-timer org-timer-mode-line-timer)
 363        (setq org-timer-mode-line-timer nil)))
 364     (on
 365      (when (or (eq org-timer-display 'mode-line)
 366                (eq org-timer-display 'both))
 367        (or global-mode-string (setq global-mode-string '("")))
 368        (or (memq 'org-timer-mode-line-string global-mode-string)
 369            (setq global-mode-string
 370                  (append global-mode-string '(org-timer-mode-line-string)))))
 371      (when (or (eq org-timer-display 'frame-title)
 372                (eq org-timer-display 'both))
 373        (or (memq 'org-timer-mode-line-string frame-title-format)
 374            (setq frame-title-format
 375                  (append frame-title-format '(org-timer-mode-line-string)))))
 376      (org-timer-update-mode-line)
 377      (when org-timer-mode-line-timer
 378        (cancel-timer org-timer-mode-line-timer)
 379        (setq org-timer-mode-line-timer nil))
 380      (when org-timer-display
 381        (setq org-timer-mode-line-timer
 382              (run-with-timer 1 1 'org-timer-update-mode-line))))))
 383
 384 (defun org-timer-update-mode-line ()
 385   "Update the timer time in the mode line."
 386   (if org-timer-pause-time
 387       nil
 388     (setq org-timer-mode-line-string
 389           (concat " <" (substring (org-timer-value-string) 0 -1) ">"))
 390     (force-mode-line-update)))
 391
 392 (defun org-timer-show-remaining-time ()
 393   "Display the remaining time before the timer ends."
 394   (interactive)
 395   (require 'time)
 396   (if (not org-timer-countdown-timer)
 397       (message "No timer set")
 398     (let* ((rtime (decode-time
 399                    (time-subtract (timer--time org-timer-countdown-timer)
 400                                   (current-time))))
 401            (rsecs (nth 0 rtime))
 402            (rmins (nth 1 rtime)))
 403       (message "%d minute(s) %d seconds left before next time out"
 404                rmins rsecs))))
 405
 406 ;;;###autoload
 407 (defun org-timer-set-timer (&optional opt)
 408   "Prompt for a duration in minutes or hh:mm:ss and set a timer.
 409
 410 If `org-timer-default-timer' is not \"0\", suggest this value as
 411 the default duration for the timer.  If a timer is already set,
 412 prompt the user if she wants to replace it.
 413
 414 Called with a numeric prefix argument, use this numeric value as
 415 the duration of the timer in minutes.
 416
 417 Called with a `C-u' prefix arguments, use `org-timer-default-timer'
 418 without prompting the user for a duration.
 419
 420 With two `C-u' prefix arguments, use `org-timer-default-timer'
 421 without prompting the user for a duration and automatically
 422 replace any running timer.
 423
 424 By default, the timer duration will be set to the number of
 425 minutes in the Effort property, if any.  You can ignore this by
 426 using three `C-u' prefix arguments."
 427   (interactive "P")
 428   (when (and org-timer-start-time
 429              (not org-timer-countdown-timer))
 430     (user-error "Relative timer is running.  Stop first"))
 431   (let* ((default-timer
 432            ;; `org-timer-default-timer' used to be a number, don't choke:
 433            (if (numberp org-timer-default-timer)
 434                (number-to-string org-timer-default-timer)
 435              org-timer-default-timer))
 436          (effort-minutes (ignore-errors (org-get-at-eol 'effort-minutes 1)))
 437          (minutes (or (and (numberp opt) (number-to-string opt))
 438                       (and (not (equal opt '(64)))
 439                            effort-minutes
 440                            (number-to-string effort-minutes))
 441                       (and (consp opt) default-timer)
 442                       (and (stringp opt) opt)
 443                       (read-from-minibuffer
 444                        "How much time left? (minutes or h:mm:ss) "
 445                        (and (not (string-equal default-timer "0")) default-timer)))))
 446     (when (string-match "\\`[0-9]+\\'" minutes)
 447       (setq minutes (concat minutes ":00")))
 448     (if (not (string-match "[0-9]+" minutes))
 449         (org-timer-show-remaining-time)
 450       (let ((secs (org-timer-hms-to-secs (org-timer-fix-incomplete minutes))))
 451         (if (and org-timer-countdown-timer
 452                  (not (or (equal opt '(16))
 453                           (y-or-n-p "Replace current timer? "))))
 454             (message "No timer set")
 455           (when (timerp org-timer-countdown-timer)
 456             (cancel-timer org-timer-countdown-timer))
 457           (setq org-timer-countdown-timer-title
 458                 (org-timer--get-timer-title))
 459           (setq org-timer-countdown-timer
 460                 (org-timer--run-countdown-timer
 461                  secs org-timer-countdown-timer-title))
 462           (run-hooks 'org-timer-set-hook)
 463           (setq org-timer-start-time
 464                 (time-add (current-time) (seconds-to-time secs)))
 465           (setq org-timer-pause-time nil)
 466           (org-timer-set-mode-line 'on))))))
 467
 468 (defun org-timer--run-countdown-timer (secs title)
 469   "Start countdown timer that will last SECS.
 470 TITLE will be appended to the notification message displayed when
 471 time is up."
 472   (let ((msg (format "%s: time out" title)))
 473     (run-with-timer
 474      secs nil `(lambda ()
 475                  (setq org-timer-countdown-timer nil
 476                        org-timer-start-time nil)
 477                  (org-notify ,msg ,org-clock-sound)
 478                  (org-timer-set-mode-line 'off)
 479                  (run-hooks 'org-timer-done-hook)))))
 480
 481 (defun org-timer--get-timer-title ()
 482   "Construct timer title from heading or file name of Org buffer."
 483   (cond
 484    ((derived-mode-p 'org-agenda-mode)
 485     (let* ((marker (or (get-text-property (point) 'org-marker)
 486                        (org-agenda-error)))
 487            (hdmarker (or (get-text-property (point) 'org-hd-marker)
 488                          marker)))
 489       (with-current-buffer (marker-buffer marker)
 490         (org-with-wide-buffer
 491          (goto-char hdmarker)
 492          (org-show-entry)
 493          (or (ignore-errors (org-get-heading))
 494              (buffer-name (buffer-base-buffer)))))))
 495    ((derived-mode-p 'org-mode)
 496     (or (ignore-errors (org-get-heading))
 497         (buffer-name (buffer-base-buffer))))
 498    (t (error "Not in an Org buffer"))))
 499
 500 (provide 'org-timer)
 501
 502 ;; Local variables:
 503 ;; generated-autoload-file: "org-loaddefs.el"
 504 ;; End:
 505
 506 ;;; org-timer.el ends here