lisp/ob-ocaml.el

   1 ;;; ob-ocaml.el --- org-babel functions for ocaml evaluation
   2
   3 ;; Copyright (C) 2009-2013 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Org-Babel support for evaluating ocaml source code.  This one will
  27 ;; be sort of tricky because ocaml programs must be compiled before
  28 ;; they can be run, but ocaml code can also be run through an
  29 ;; interactive interpreter.
  30 ;;
  31 ;; For now lets only allow evaluation using the ocaml interpreter.
  32
  33 ;;; Requirements:
  34
  35 ;; - tuareg-mode :: http://www-rocq.inria.fr/~acohen/tuareg/
  36
  37 ;;; Code:
  38 (require 'ob)
  39 (require 'comint)
  40 (eval-when-compile (require 'cl))
  41
  42 (declare-function tuareg-run-caml "ext:tuareg" ())
  43 (declare-function tuareg-run-ocaml "ext:tuareg" ())
  44 (declare-function tuareg-interactive-send-input "ext:tuareg" ())
  45
  46 (defvar org-babel-tangle-lang-exts)
  47 (add-to-list 'org-babel-tangle-lang-exts '("ocaml" . "ml"))
  48
  49 (defvar org-babel-default-header-args:ocaml '())
  50
  51 (defvar org-babel-ocaml-eoe-indicator "\"org-babel-ocaml-eoe\";;")
  52 (defvar org-babel-ocaml-eoe-output "org-babel-ocaml-eoe")
  53
  54 (defun org-babel-execute:ocaml (body params)
  55   "Execute a block of Ocaml code with Babel."
  56   (let* ((vars (mapcar #'cdr (org-babel-get-header params :var)))
  57          (full-body (org-babel-expand-body:generic
  58                      body params
  59                      (org-babel-variable-assignments:ocaml params)))
  60          (session (org-babel-prep-session:ocaml
  61                    (cdr (assoc :session params)) params))
  62          (raw (org-babel-comint-with-output
  63                   (session org-babel-ocaml-eoe-output t full-body)
  64                 (insert
  65                  (concat
  66                   (org-babel-chomp full-body)";;\n"org-babel-ocaml-eoe-indicator))
  67                 (tuareg-interactive-send-input)))
  68          (clean
  69           (car (let ((re (regexp-quote org-babel-ocaml-eoe-output)) out)
  70                  (delq nil (mapcar (lambda (line)
  71                                      (if out
  72                                          (progn (setq out nil) line)
  73                                        (when (string-match re line)
  74                                          (progn (setq out t) nil))))
  75                                    (mapcar #'org-babel-trim (reverse raw))))))))
  76     (org-babel-reassemble-table
  77      (let ((raw (org-babel-trim clean))
  78            (result-params (cdr (assoc :result-params params))))
  79        (org-babel-result-cond result-params
  80          ;; strip type information from output unless verbatim is specified
  81          (if (and (not (member "verbatim" result-params))
  82                   (string-match "= \\(.+\\)$" raw))
  83              (match-string 1 raw) raw)
  84          (org-babel-ocaml-parse-output raw)))
  85      (org-babel-pick-name
  86       (cdr (assoc :colname-names params)) (cdr (assoc :colnames params)))
  87      (org-babel-pick-name
  88       (cdr (assoc :rowname-names params)) (cdr (assoc :rownames params))))))
  89
  90 (defvar tuareg-interactive-buffer-name)
  91 (defun org-babel-prep-session:ocaml (session params)
  92   "Prepare SESSION according to the header arguments in PARAMS."
  93   (require 'tuareg)
  94   (let ((tuareg-interactive-buffer-name (if (and (not (string= session "none"))
  95                                                  (not (string= session "default"))
  96                                                  (stringp session))
  97                                             session
  98                                           tuareg-interactive-buffer-name)))
  99     (save-window-excursion
 100       (if (fboundp 'tuareg-run-caml) (tuareg-run-caml) (tuareg-run-ocaml))
 101       (get-buffer tuareg-interactive-buffer-name))))
 102
 103 (defun org-babel-variable-assignments:ocaml (params)
 104   "Return list of ocaml statements assigning the block's variables."
 105   (mapcar
 106    (lambda (pair) (format "let %s = %s;;" (car pair)
 107                           (org-babel-ocaml-elisp-to-ocaml (cdr pair))))
 108    (mapcar #'cdr (org-babel-get-header params :var))))
 109
 110 (defun org-babel-ocaml-elisp-to-ocaml (val)
 111   "Return a string of ocaml code which evaluates to VAL."
 112   (if (listp val)
 113       (concat "[|" (mapconcat #'org-babel-ocaml-elisp-to-ocaml val "; ") "|]")
 114     (format "%S" val)))
 115
 116 (defun org-babel-ocaml-parse-output (output)
 117   "Parse OUTPUT.
 118 OUTPUT is string output from an ocaml process."
 119   (let ((regexp "[^:]+ : %s = \\(.+\\)$"))
 120     (cond
 121      ((string-match (format regexp "string") output)
 122       (org-babel-read (match-string 1 output)))
 123      ((or (string-match (format regexp "int") output)
 124           (string-match (format regexp "float") output))
 125       (string-to-number (match-string 1 output)))
 126      ((string-match (format regexp "list") output)
 127       (org-babel-ocaml-read-list (match-string 1 output)))
 128      ((string-match (format regexp "array") output)
 129       (org-babel-ocaml-read-array (match-string 1 output)))
 130      (t (message "don't recognize type of %s" output) output))))
 131
 132 (defun org-babel-ocaml-read-list (results)
 133   "Convert RESULTS into an elisp table or string.
 134 If the results look like a table, then convert them into an
 135 Emacs-lisp table, otherwise return the results as a string."
 136   (org-babel-script-escape (replace-regexp-in-string ";" "," results)))
 137
 138 (defun org-babel-ocaml-read-array (results)
 139   "Convert RESULTS into an elisp table or string.
 140 If the results look like a table, then convert them into an
 141 Emacs-lisp table, otherwise return the results as a string."
 142   (org-babel-script-escape
 143    (replace-regexp-in-string
 144     "\\[|" "[" (replace-regexp-in-string
 145                 "|\\]" "]" (replace-regexp-in-string
 146                             "; " "," results)))))
 147
 148 (provide 'ob-ocaml)
 149
 150
 151
 152 ;;; ob-ocaml.el ends here