lisp/ob-ref.el

   1 ;;; ob-ref.el --- Babel Functions for Referencing External Data -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2009-2015 Free Software Foundation, Inc.
   4
   5 ;; Authors: Eric Schulte
   6 ;;       Dan Davison
   7 ;; Keywords: literate programming, reproducible research
   8 ;; Homepage: http://orgmode.org
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Functions for referencing data from the header arguments of a
  28 ;; org-babel block.  The syntax of such a reference should be
  29
  30 ;;   #+VAR: variable-name=file:resource-id
  31
  32 ;; - variable-name :: the name of the variable to which the value
  33 ;;                    will be assigned
  34
  35 ;; - file :: path to the file containing the resource, or omitted if
  36 ;;           resource is in the current file
  37
  38 ;; - resource-id :: the id or name of the resource
  39
  40 ;; So an example of a simple src block referencing table data in the
  41 ;; same file would be
  42
  43 ;;  #+NAME: sandbox
  44 ;;  | 1 |         2 | 3 |
  45 ;;  | 4 | org-babel | 6 |
  46 ;;
  47 ;;  #+begin_src emacs-lisp :var table=sandbox
  48 ;;    (message table)
  49 ;;  #+end_src
  50
  51 ;;; Code:
  52 (require 'ob-core)
  53 (require 'cl-lib)
  54
  55 (declare-function org-at-item-p "org-list" ())
  56 (declare-function org-at-table-p "org" (&optional table-type))
  57 (declare-function org-babel-lob-execute "ob-lob" (info))
  58 (declare-function org-babel-lob-get-info "ob-lob" nil)
  59 (declare-function org-element-at-point "org-element" ())
  60 (declare-function org-element-property "org-element" (property element))
  61 (declare-function org-element-type "org-element" (element))
  62 (declare-function org-end-of-meta-data "org" (&optional full))
  63 (declare-function org-find-property "org" (property &optional value))
  64 (declare-function org-id-find-id-file "org-id" (id))
  65 (declare-function org-id-find-id-in-file "org-id" (id file &optional markerp))
  66 (declare-function org-in-commented-heading-p "org" (&optional no-inheritance))
  67 (declare-function org-narrow-to-subtree "org" ())
  68 (declare-function org-pop-to-buffer-same-window "org-compat"
  69                   (&optional buffer-or-name norecord label))
  70 (declare-function org-show-context "org" (&optional key))
  71
  72
  73 (defvar org-babel-ref-split-regexp
  74   "[ \f\t\n\r\v]*\\(.+?\\)[ \f\t\n\r\v]*=[ \f\t\n\r\v]*\\(.+\\)[ \f\t\n\r\v]*")
  75
  76 (defvar org-babel-update-intermediate nil
  77   "Update the in-buffer results of code blocks executed to resolve references.")
  78
  79 (defun org-babel-ref-parse (assignment)
  80   "Parse a variable ASSIGNMENT in a header argument.
  81 If the right hand side of the assignment has a literal value
  82 return that value, otherwise interpret as a reference to an
  83 external resource and find its value using
  84 `org-babel-ref-resolve'.  Return a list with two elements.  The
  85 first element of the list will be the name of the variable, and
  86 the second will be an emacs-lisp representation of the value of
  87 the variable."
  88   (when (string-match org-babel-ref-split-regexp assignment)
  89     (let ((var (match-string 1 assignment))
  90           (ref (match-string 2 assignment)))
  91       (cons (intern var)
  92             (let ((out (save-excursion
  93                          (when org-babel-current-src-block-location
  94                            (goto-char (if (markerp org-babel-current-src-block-location)
  95                                           (marker-position org-babel-current-src-block-location)
  96                                         org-babel-current-src-block-location)))
  97                          (org-babel-read ref))))
  98               (if (equal out ref)
  99                   (if (string-match "^\".*\"$" ref)
 100                       (read ref)
 101                     (org-babel-ref-resolve ref))
 102                 out))))))
 103
 104 (defun org-babel-ref-goto-headline-id (id)
 105   (or (let ((h (org-find-property "CUSTOM_ID" id)))
 106         (when h (goto-char h)))
 107       (let* ((file (org-id-find-id-file id))
 108              (m (when file (org-id-find-id-in-file id file 'marker))))
 109         (when (and file m)
 110           (message "file:%S" file)
 111           (org-pop-to-buffer-same-window (marker-buffer m))
 112           (goto-char m)
 113           (move-marker m nil)
 114           (org-show-context)
 115           t))))
 116
 117 (defun org-babel-ref-headline-body ()
 118   (save-restriction
 119     (org-narrow-to-subtree)
 120     (buffer-substring
 121      (save-excursion (goto-char (point-min))
 122                      (org-end-of-meta-data)
 123                      (point))
 124      (point-max))))
 125
 126 (defvar org-babel-lob-one-liner-regexp)
 127 (defvar org-babel-library-of-babel)
 128 (defun org-babel-ref-resolve (ref)
 129   "Resolve the reference REF and return its value."
 130   (save-window-excursion
 131     (with-current-buffer (or org-babel-exp-reference-buffer (current-buffer))
 132       (save-excursion
 133         (let ((case-fold-search t)
 134               args new-refere new-header-args new-referent split-file split-ref
 135               index)
 136           ;; if ref is indexed grab the indices -- beware nested indices
 137           (when (and (string-match "\\[\\([^\\[]+\\)\\]$" ref)
 138                      (let ((str (substring ref 0 (match-beginning 0))))
 139                        (= (cl-count ?( str) (cl-count ?) str))))
 140             (setq index (match-string 1 ref))
 141             (setq ref (substring ref 0 (match-beginning 0))))
 142           ;; assign any arguments to pass to source block
 143           (when (string-match
 144                  "^\\(.+?\\)\\(\\[\\(.*\\)\\]\\|\\(\\)\\)(\\(.*\\))$" ref)
 145             (setq new-refere      (match-string 1 ref))
 146             (setq new-header-args (match-string 3 ref))
 147             (setq new-referent    (match-string 5 ref))
 148             (when (> (length new-refere) 0)
 149               (when (> (length new-referent) 0)
 150                 (setq args (mapcar (lambda (ref) (cons :var ref))
 151                                    (org-babel-ref-split-args new-referent))))
 152               (when (> (length new-header-args) 0)
 153                 (setq args (append (org-babel-parse-header-arguments
 154                                     new-header-args) args)))
 155               (setq ref new-refere)))
 156           (when (string-match "^\\(.+\\):\\(.+\\)$" ref)
 157             (setq split-file (match-string 1 ref))
 158             (setq split-ref (match-string 2 ref))
 159             (find-file split-file)
 160             (setq ref split-ref))
 161           (org-with-wide-buffer
 162            (goto-char (point-min))
 163            (let* ((params (append args '((:results . "silent"))))
 164                   (regexp (org-babel-named-data-regexp-for-name ref))
 165                   (result
 166                    (catch :found
 167                      ;; Check for code blocks or named data.
 168                      (while (re-search-forward regexp nil t)
 169                        ;; Ignore COMMENTed headings and orphaned
 170                        ;; affiliated keywords.
 171                        (unless (org-in-commented-heading-p)
 172                          (let ((e (org-element-at-point)))
 173                            (when (equal (org-element-property :name e) ref)
 174                              (goto-char
 175                               (org-element-property :post-affiliated e))
 176                              (pcase (org-element-type e)
 177                                (`babel-call
 178                                 (throw :found
 179                                        (org-babel-lob-execute
 180                                         (org-babel-lob-get-info))))
 181                                (`src-block
 182                                 (throw :found
 183                                        (org-babel-execute-src-block
 184                                         nil nil
 185                                         (and
 186                                          (not org-babel-update-intermediate)
 187                                          params))))
 188                                ((and (let v (org-babel-read-element e))
 189                                      (guard v))
 190                                 (throw :found v))
 191                                (_ (error "Reference not found")))))))
 192                      ;; Check for local or global headlines by ID.
 193                      (when (org-babel-ref-goto-headline-id ref)
 194                        (throw :found (org-babel-ref-headline-body)))
 195                      ;; Check the Library of Babel.
 196                      (let ((info (cdr (assq (intern ref)
 197                                             org-babel-library-of-babel))))
 198                        (when info
 199                          (throw :found
 200                                 (org-babel-execute-src-block nil info params))))
 201                      (error "Reference `%s' not found in this buffer" ref))))
 202              (cond
 203               ((symbolp result) (format "%S" result))
 204               ((and index (listp result))
 205                (org-babel-ref-index-list index result))
 206               (t result)))))))))
 207
 208 (defun org-babel-ref-index-list (index lis)
 209   "Return the subset of LIS indexed by INDEX.
 210
 211 Indices are 0 based and negative indices count from the end of
 212 LIS, so 0 references the first element of LIS and -1 references
 213 the last.  If INDEX is separated by \",\"s then each \"portion\"
 214 is assumed to index into the next deepest nesting or dimension.
 215
 216 A valid \"portion\" can consist of either an integer index, two
 217 integers separated by a \":\" in which case the entire range is
 218 returned, or an empty string or \"*\" both of which are
 219 interpreted to mean the entire range and as such are equivalent
 220 to \"0:-1\"."
 221   (if (and (> (length index) 0) (string-match "^\\([^,]*\\),?" index))
 222       (let* ((ind-re "\\(\\([-[:digit:]]+\\):\\([-[:digit:]]+\\)\\|\\*\\)")
 223              (lgth (length lis))
 224              (portion (match-string 1 index))
 225              (remainder (substring index (match-end 0)))
 226              (wrap (lambda (num) (if (< num 0) (+ lgth num) num)))
 227              (open (lambda (ls) (if (and (listp ls) (= (length ls) 1)) (car ls) ls))))
 228         (funcall
 229          open
 230          (mapcar
 231           (lambda (sub-lis)
 232             (if (listp sub-lis)
 233                 (org-babel-ref-index-list remainder sub-lis)
 234               sub-lis))
 235           (if (or (= 0 (length portion)) (string-match ind-re portion))
 236               (mapcar
 237                (lambda (n) (nth n lis))
 238                (apply 'org-number-sequence
 239                       (if (and (> (length portion) 0) (match-string 2 portion))
 240                           (list
 241                            (funcall wrap (string-to-number (match-string 2 portion)))
 242                            (funcall wrap (string-to-number (match-string 3 portion))))
 243                         (list (funcall wrap 0) (funcall wrap -1)))))
 244             (list (nth (funcall wrap (string-to-number portion)) lis))))))
 245     lis))
 246
 247 (defun org-babel-ref-split-args (arg-string)
 248   "Split ARG-STRING into top-level arguments of balanced parenthesis."
 249   (mapcar #'org-babel-trim (org-babel-balanced-split arg-string 44)))
 250
 251
 252 (provide 'ob-ref)
 253
 254 ;;; ob-ref.el ends here