lisp/ob-python.el

   1 ;;; ob-python.el --- org-babel functions for python evaluation
   2
   3 ;; Copyright (C) 2009-2013 Free Software Foundation, Inc.
   4
   5 ;; Authors: Eric Schulte
   6 ;;       Dan Davison
   7 ;; Keywords: literate programming, reproducible research
   8 ;; Homepage: http://orgmode.org
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Org-Babel support for evaluating python source code.
  28
  29 ;;; Code:
  30 (require 'ob)
  31 (eval-when-compile (require 'cl))
  32
  33 (declare-function org-remove-indentation "org" )
  34 (declare-function py-shell "ext:python-mode" (&optional argprompt))
  35 (declare-function py-toggle-shells "ext:python-mode" (arg))
  36 (declare-function run-python "ext:python" (&optional cmd noshow new))
  37
  38 (defvar org-babel-tangle-lang-exts)
  39 (add-to-list 'org-babel-tangle-lang-exts '("python" . "py"))
  40
  41 (defvar org-babel-default-header-args:python '())
  42
  43 (defcustom org-babel-python-command "python"
  44   "Name of the command for executing Python code."
  45   :version "24.4"
  46   :package-version '(Org . "8.0")
  47   :group 'org-babel
  48   :type 'string)
  49
  50 (defcustom org-babel-python-mode
  51   (if (or (featurep 'xemacs) (featurep 'python-mode)) 'python-mode 'python)
  52   "Preferred python mode for use in running python interactively.
  53 This will typically be either 'python or 'python-mode."
  54   :group 'org-babel
  55   :version "24.4"
  56   :package-version '(Org . "8.0")
  57   :type 'function)
  58
  59 (defvar org-src-preserve-indentation)
  60
  61 (defcustom org-babel-python-hline-to "None"
  62   "Replace hlines in incoming tables with this when translating to python."
  63   :group 'org-babel
  64   :type 'string)
  65
  66 (defcustom org-babel-python-None-to 'hline
  67   "Replace 'None' in python tables with this before returning."
  68   :group 'org-babel
  69   :type 'string)
  70
  71 (defun org-babel-execute:python (body params)
  72   "Execute a block of Python code with Babel.
  73 This function is called by `org-babel-execute-src-block'."
  74   (let* ((session (org-babel-python-initiate-session
  75                    (cdr (assoc :session params))))
  76          (result-params (cdr (assoc :result-params params)))
  77          (result-type (cdr (assoc :result-type params)))
  78          (return-val (when (and (eq result-type 'value) (not session))
  79                        (cdr (assoc :return params))))
  80          (preamble (cdr (assoc :preamble params)))
  81          (full-body
  82           (org-babel-expand-body:generic
  83            (concat body (if return-val (format "\nreturn %s" return-val) ""))
  84            params (org-babel-variable-assignments:python params)))
  85          (result (org-babel-python-evaluate
  86                   session full-body result-type result-params preamble)))
  87     (org-babel-reassemble-table
  88      result
  89      (org-babel-pick-name (cdr (assoc :colname-names params))
  90                           (cdr (assoc :colnames params)))
  91      (org-babel-pick-name (cdr (assoc :rowname-names params))
  92                           (cdr (assoc :rownames params))))))
  93
  94 (defun org-babel-prep-session:python (session params)
  95   "Prepare SESSION according to the header arguments in PARAMS.
  96 VARS contains resolved variable references"
  97   (let* ((session (org-babel-python-initiate-session session))
  98          (var-lines
  99           (org-babel-variable-assignments:python params)))
 100     (org-babel-comint-in-buffer session
 101       (mapc (lambda (var)
 102               (end-of-line 1) (insert var) (comint-send-input)
 103               (org-babel-comint-wait-for-output session)) var-lines))
 104     session))
 105
 106 (defun org-babel-load-session:python (session body params)
 107   "Load BODY into SESSION."
 108   (save-window-excursion
 109     (let ((buffer (org-babel-prep-session:python session params)))
 110       (with-current-buffer buffer
 111         (goto-char (process-mark (get-buffer-process (current-buffer))))
 112         (insert (org-babel-chomp body)))
 113       buffer)))
 114
 115 ;; helper functions
 116
 117 (defun org-babel-variable-assignments:python (params)
 118   "Return a list of Python statements assigning the block's variables."
 119   (mapcar
 120    (lambda (pair)
 121      (format "%s=%s"
 122              (car pair)
 123              (org-babel-python-var-to-python (cdr pair))))
 124    (mapcar #'cdr (org-babel-get-header params :var))))
 125
 126 (defun org-babel-python-var-to-python (var)
 127   "Convert an elisp value to a python variable.
 128 Convert an elisp value, VAR, into a string of python source code
 129 specifying a variable of the same value."
 130   (if (listp var)
 131       (concat "[" (mapconcat #'org-babel-python-var-to-python var ", ") "]")
 132     (if (equal var 'hline)
 133         org-babel-python-hline-to
 134       (format
 135        (if (and (stringp var) (string-match "[\n\r]" var)) "\"\"%S\"\"" "%S")
 136        var))))
 137
 138 (defun org-babel-python-table-or-string (results)
 139   "Convert RESULTS into an appropriate elisp value.
 140 If the results look like a list or tuple, then convert them into an
 141 Emacs-lisp table, otherwise return the results as a string."
 142   ((lambda (res)
 143      (if (listp res)
 144          (mapcar (lambda (el) (if (equal el 'None)
 145                              org-babel-python-None-to el))
 146                  res)
 147        res))
 148    (org-babel-script-escape results)))
 149
 150 (defvar org-babel-python-buffers '((:default . nil)))
 151
 152 (defun org-babel-python-session-buffer (session)
 153   "Return the buffer associated with SESSION."
 154   (cdr (assoc session org-babel-python-buffers)))
 155
 156 (defvar py-default-interpreter)
 157 (defun org-babel-python-initiate-session-by-key (&optional session)
 158   "Initiate a python session.
 159 If there is not a current inferior-process-buffer in SESSION
 160 then create.  Return the initialized session."
 161   (require org-babel-python-mode)
 162   (save-window-excursion
 163     (let* ((session (if session (intern session) :default))
 164            (python-buffer (org-babel-python-session-buffer session)))
 165       (cond
 166        ((and (eq 'python org-babel-python-mode)
 167              (fboundp 'run-python)) ; python.el
 168         (if (version< "24.1" emacs-version)
 169             (run-python org-babel-python-command)
 170           (run-python)))
 171        ((and (eq 'python-mode org-babel-python-mode)
 172              (fboundp 'py-shell)) ; python-mode.el
 173         ;; Make sure that py-which-bufname is initialized, as otherwise
 174         ;; it will be overwritten the first time a Python buffer is
 175         ;; created.
 176         (py-toggle-shells py-default-interpreter)
 177         ;; `py-shell' creates a buffer whose name is the value of
 178         ;; `py-which-bufname' with '*'s at the beginning and end
 179         (let* ((bufname (if (and python-buffer (buffer-live-p python-buffer))
 180                             (replace-regexp-in-string ;; zap surrounding *
 181                              "^\\*\\([^*]+\\)\\*$" "\\1" python-buffer)
 182                           (concat "Python-" (symbol-name session))))
 183                (py-which-bufname bufname))
 184           (py-shell)
 185           (setq python-buffer (concat "*" bufname "*"))))
 186        (t
 187         (error "No function available for running an inferior Python")))
 188       (setq org-babel-python-buffers
 189             (cons (cons session python-buffer)
 190                   (assq-delete-all session org-babel-python-buffers)))
 191       session)))
 192
 193 (defun org-babel-python-initiate-session (&optional session params)
 194   "Create a session named SESSION according to PARAMS."
 195   (unless (string= session "none")
 196     (org-babel-python-session-buffer
 197      (org-babel-python-initiate-session-by-key session))))
 198
 199 (defvar org-babel-python-eoe-indicator "'org_babel_python_eoe'"
 200   "A string to indicate that evaluation has completed.")
 201 (defvar org-babel-python-wrapper-method
 202   "
 203 def main():
 204 %s
 205
 206 open('%s', 'w').write( str(main()) )")
 207 (defvar org-babel-python-pp-wrapper-method
 208   "
 209 import pprint
 210 def main():
 211 %s
 212
 213 open('%s', 'w').write( pprint.pformat(main()) )")
 214
 215 (defun org-babel-python-evaluate
 216   (session body &optional result-type result-params preamble)
 217   "Evaluate BODY as Python code."
 218   (if session
 219       (org-babel-python-evaluate-session
 220        session body result-type result-params)
 221     (org-babel-python-evaluate-external-process
 222      body result-type result-params preamble)))
 223
 224 (defun org-babel-python-evaluate-external-process
 225   (body &optional result-type result-params preamble)
 226   "Evaluate BODY in external python process.
 227 If RESULT-TYPE equals 'output then return standard output as a
 228 string.  If RESULT-TYPE equals 'value then return the value of the
 229 last statement in BODY, as elisp."
 230   ((lambda (raw)
 231      (org-babel-result-cond result-params
 232        raw
 233        (org-babel-python-table-or-string (org-babel-trim raw))))
 234    (case result-type
 235      (output (org-babel-eval org-babel-python-command
 236                              (concat (if preamble (concat preamble "\n") "")
 237                                      body)))
 238      (value (let ((tmp-file (org-babel-temp-file "python-")))
 239               (org-babel-eval
 240                org-babel-python-command
 241                (concat
 242                 (if preamble (concat preamble "\n") "")
 243                 (format
 244                  (if (member "pp" result-params)
 245                      org-babel-python-pp-wrapper-method
 246                    org-babel-python-wrapper-method)
 247                  (mapconcat
 248                   (lambda (line) (format "\t%s" line))
 249                   (split-string
 250                    (org-remove-indentation
 251                     (org-babel-trim body))
 252                    "[\r\n]") "\n")
 253                  (org-babel-process-file-name tmp-file 'noquote))))
 254               (org-babel-eval-read-file tmp-file))))))
 255
 256 (defun org-babel-python-evaluate-session
 257   (session body &optional result-type result-params)
 258   "Pass BODY to the Python process in SESSION.
 259 If RESULT-TYPE equals 'output then return standard output as a
 260 string.  If RESULT-TYPE equals 'value then return the value of the
 261 last statement in BODY, as elisp."
 262   (let* ((send-wait (lambda () (comint-send-input nil t) (sleep-for 0 5)))
 263          (dump-last-value
 264           (lambda
 265             (tmp-file pp)
 266             (mapc
 267              (lambda (statement) (insert statement) (funcall send-wait))
 268              (if pp
 269                  (list
 270                   "import pprint"
 271                   (format "open('%s', 'w').write(pprint.pformat(_))"
 272                           (org-babel-process-file-name tmp-file 'noquote)))
 273                (list (format "open('%s', 'w').write(str(_))"
 274                              (org-babel-process-file-name tmp-file 'noquote)))))))
 275          (input-body (lambda (body)
 276                        (mapc (lambda (line) (insert line) (funcall send-wait))
 277                              (split-string body "[\r\n]"))
 278                        (funcall send-wait))))
 279     ((lambda (results)
 280        (unless (string= (substring org-babel-python-eoe-indicator 1 -1) results)
 281          (org-babel-result-cond result-params
 282            results
 283            (org-babel-python-table-or-string results))))
 284      (case result-type
 285        (output
 286         (mapconcat
 287          #'org-babel-trim
 288          (butlast
 289           (org-babel-comint-with-output
 290               (session org-babel-python-eoe-indicator t body)
 291             (funcall input-body body)
 292             (funcall send-wait) (funcall send-wait)
 293             (insert org-babel-python-eoe-indicator)
 294             (funcall send-wait))
 295           2) "\n"))
 296        (value
 297         (let ((tmp-file (org-babel-temp-file "python-")))
 298           (org-babel-comint-with-output
 299               (session org-babel-python-eoe-indicator nil body)
 300             (let ((comint-process-echoes nil))
 301               (funcall input-body body)
 302               (funcall dump-last-value tmp-file (member "pp" result-params))
 303               (funcall send-wait) (funcall send-wait)
 304               (insert org-babel-python-eoe-indicator)
 305               (funcall send-wait)))
 306           (org-babel-eval-read-file tmp-file)))))))
 307
 308 (defun org-babel-python-read-string (string)
 309   "Strip 's from around Python string."
 310   (if (string-match "^'\\([^\000]+\\)'$" string)
 311       (match-string 1 string)
 312     string))
 313
 314 (provide 'ob-python)
 315
 316
 317
 318 ;;; ob-python.el ends here