lisp/org-timer.el

   1 ;;; org-timer.el --- The relative timer code for Org-mode
   2
   3 ;; Copyright (C) 2008-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: http://orgmode.org
   8 ;;
   9 ;; This file is part of GNU Emacs.
  10 ;;
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  24 ;;
  25 ;;; Commentary:
  26
  27 ;; This file contains the relative timer code for Org-mode
  28
  29 ;;; Code:
  30
  31 (require 'org)
  32
  33 (declare-function org-notify "org-clock" (notification &optional play-sound))
  34 (declare-function org-agenda-error "org-agenda" ())
  35
  36 (defvar org-timer-start-time nil
  37   "t=0 for the running timer.")
  38
  39 (defvar org-timer-pause-time nil
  40   "Time when the timer was paused.")
  41
  42 (defconst org-timer-re "\\([-+]?[0-9]+\\):\\([0-9]\\{2\\}\\):\\([0-9]\\{2\\}\\)"
  43   "Regular expression used to match timer stamps.")
  44
  45 (defcustom org-timer-format "%s "
  46   "The format to insert the time of the timer.
  47 This format must contain one instance of \"%s\" which will be replaced by
  48 the value of the relative timer."
  49   :group 'org-time
  50   :type 'string)
  51
  52 (defcustom org-timer-default-timer 0
  53   "The default timer when a timer is set.
  54 When 0, the user is prompted for a value."
  55   :group 'org-time
  56   :version "24.1"
  57   :type 'number)
  58
  59 (defcustom org-timer-display 'mode-line
  60   "When a timer is running, org-mode can display it in the mode
  61 line and/or frame title.
  62 Allowed values are:
  63
  64 both         displays in both mode line and frame title
  65 mode-line    displays only in mode line (default)
  66 frame-title  displays only in frame title
  67 nil          current timer is not displayed"
  68   :group 'org-time
  69   :type '(choice
  70           (const :tag "Mode line" mode-line)
  71           (const :tag "Frame title" frame-title)
  72           (const :tag "Both" both)
  73           (const :tag "None" nil)))
  74
  75 (defvar org-timer-start-hook nil
  76   "Hook run after relative timer is started.")
  77
  78 (defvar org-timer-stop-hook nil
  79   "Hook run before relative timer is stopped.")
  80
  81 (defvar org-timer-pause-hook nil
  82   "Hook run before relative timer is paused.")
  83
  84 (defvar org-timer-continue-hook nil
  85   "Hook run after relative timer is continued.")
  86
  87 (defvar org-timer-set-hook nil
  88   "Hook run after countdown timer is set.")
  89
  90 (defvar org-timer-done-hook nil
  91   "Hook run after countdown timer reaches zero.")
  92
  93 (defvar org-timer-cancel-hook nil
  94   "Hook run before countdown timer is canceled.")
  95
  96 ;;;###autoload
  97 (defun org-timer-start (&optional offset)
  98   "Set the starting time for the relative timer to now.
  99 When called with prefix argument OFFSET, prompt the user for an offset time,
 100 with the default taken from a timer stamp at point, if any.
 101 If OFFSET is a string or an integer, it is directly taken to be the offset
 102 without user interaction.
 103 When called with a double prefix arg, all timer strings in the active
 104 region will be shifted by a specific amount.  You will be prompted for
 105 the amount, with the default to make the first timer string in
 106 the region 0:00:00."
 107   (interactive "P")
 108   (if (equal offset '(16))
 109       (call-interactively 'org-timer-change-times-in-region)
 110     (let (delta def s)
 111       (if (not offset)
 112           (setq org-timer-start-time (current-time))
 113         (cond
 114          ((integerp offset) (setq delta offset))
 115          ((stringp offset) (setq delta (org-timer-hms-to-secs offset)))
 116          (t
 117           (setq def (if (org-in-regexp org-timer-re)
 118                         (match-string 0)
 119                       "0:00:00")
 120                 s (read-string
 121                    (format "Restart timer with offset [%s]: " def)))
 122           (unless (string-match "\\S-" s) (setq s def))
 123           (setq delta (org-timer-hms-to-secs (org-timer-fix-incomplete s)))))
 124         (setq org-timer-start-time
 125               (seconds-to-time
 126                (- (org-float-time) delta))))
 127       (org-timer-set-mode-line 'on)
 128       (message "Timer start time set to %s, current value is %s"
 129                (format-time-string "%T" org-timer-start-time)
 130                (org-timer-secs-to-hms (or delta 0)))
 131       (run-hooks 'org-timer-start-hook))))
 132
 133 (defun org-timer-pause-or-continue (&optional stop)
 134   "Pause or continue the relative timer.
 135 With prefix arg STOP, stop it entirely."
 136   (interactive "P")
 137   (cond
 138    (stop (org-timer-stop))
 139    ((not org-timer-start-time) (error "No timer is running"))
 140    (org-timer-pause-time
 141     ;; timer is paused, continue
 142     (setq org-timer-start-time
 143           (seconds-to-time
 144            (-
 145             (org-float-time)
 146             (- (org-float-time org-timer-pause-time)
 147                (org-float-time org-timer-start-time))))
 148           org-timer-pause-time nil)
 149     (org-timer-set-mode-line 'on)
 150     (run-hooks 'org-timer-continue-hook)
 151     (message "Timer continues at %s" (org-timer-value-string)))
 152    (t
 153     ;; pause timer
 154     (run-hooks 'org-timer-pause-hook)
 155     (setq org-timer-pause-time (current-time))
 156     (org-timer-set-mode-line 'pause)
 157     (message "Timer paused at %s" (org-timer-value-string)))))
 158
 159 (defvar org-timer-current-timer nil)
 160 (defun org-timer-stop ()
 161   "Stop the relative timer."
 162   (interactive)
 163   (if (not org-timer-current-timer)
 164       (message "No running timer")
 165     (run-hooks 'org-timer-stop-hook)
 166     (setq org-timer-start-time nil
 167           org-timer-pause-time nil
 168           org-timer-current-timer nil)
 169     (org-timer-set-mode-line 'off)
 170     (message "Timer stopped")))
 171
 172 ;;;###autoload
 173 (defun org-timer (&optional restart no-insert-p)
 174   "Insert a H:MM:SS string from the timer into the buffer.
 175 The first time this command is used, the timer is started.  When used with
 176 a \\[universal-argument] prefix, force restarting the timer.
 177 When used with a double prefix argument \\[universal-argument], change all the timer string
 178 in the region by a fixed amount.  This can be used to recalibrate a timer
 179 that was not started at the correct moment.
 180
 181 If NO-INSERT-P is non-nil, return the string instead of inserting
 182 it in the buffer."
 183   (interactive "P")
 184   (when (or (equal restart '(4)) (not org-timer-start-time))
 185     (org-timer-start))
 186   (if no-insert-p
 187       (org-timer-value-string)
 188     (insert (org-timer-value-string))))
 189
 190 (defun org-timer-value-string ()
 191   (format org-timer-format (org-timer-secs-to-hms (floor (org-timer-seconds)))))
 192
 193 (defvar org-timer-timer-is-countdown nil)
 194 (defun org-timer-seconds ()
 195   (if org-timer-timer-is-countdown
 196       (- (org-float-time org-timer-start-time)
 197          (org-float-time (current-time)))
 198     (- (org-float-time (or org-timer-pause-time (current-time)))
 199        (org-float-time org-timer-start-time))))
 200
 201 ;;;###autoload
 202 (defun org-timer-change-times-in-region (beg end delta)
 203   "Change all h:mm:ss time in region by a DELTA."
 204   (interactive
 205    "r\nsEnter time difference like \"-1:08:26\".  Default is first time to zero: ")
 206   (let ((re "[-+]?[0-9]+:[0-9]\\{2\\}:[0-9]\\{2\\}") p)
 207     (unless (string-match "\\S-" delta)
 208       (save-excursion
 209         (goto-char beg)
 210         (when (re-search-forward re end t)
 211           (setq delta (match-string 0))
 212           (if (equal (string-to-char delta) ?-)
 213               (setq delta (substring delta 1))
 214             (setq delta (concat "-" delta))))))
 215     (setq delta (org-timer-hms-to-secs (org-timer-fix-incomplete delta)))
 216     (when (= delta 0) (error "No change"))
 217     (save-excursion
 218       (goto-char end)
 219       (while (re-search-backward re beg t)
 220         (setq p (point))
 221         (replace-match
 222          (save-match-data
 223            (org-timer-secs-to-hms (+ (org-timer-hms-to-secs (match-string 0)) delta)))
 224          t t)
 225         (goto-char p)))))
 226
 227 ;;;###autoload
 228 (defun org-timer-item (&optional arg)
 229   "Insert a description-type item with the current timer value."
 230   (interactive "P")
 231   (let ((itemp (org-in-item-p)) (pos (point)))
 232     (cond
 233      ;; In a timer list, insert with `org-list-insert-item',
 234      ;; then fix the list.
 235      ((and itemp (goto-char itemp) (org-at-item-timer-p))
 236       (let* ((struct (org-list-struct))
 237              (prevs (org-list-prevs-alist struct))
 238              (s (concat (org-timer (when arg '(4)) t) ":: ")))
 239         (setq struct (org-list-insert-item pos struct prevs nil s))
 240         (org-list-write-struct struct (org-list-parents-alist struct))
 241         (looking-at org-list-full-item-re)
 242         (goto-char (match-end 0))))
 243      ;; In a list of another type, don't break anything: throw an error.
 244      (itemp (goto-char pos) (error "This is not a timer list"))
 245      ;; Else, start a new list.
 246      (t
 247       (beginning-of-line)
 248       (org-indent-line)
 249       (insert  "- ")
 250       (org-timer (when arg '(4)))
 251       (insert ":: ")))))
 252
 253 (defun org-timer-fix-incomplete (hms)
 254   "If hms is a H:MM:SS string with missing hour or hour and minute, fix it."
 255   (if (string-match "\\(?:\\([0-9]+:\\)?\\([0-9]+:\\)\\)?\\([0-9]+\\)" hms)
 256       (replace-match
 257        (format "%d:%02d:%02d"
 258                (if (match-end 1) (string-to-number (match-string 1 hms)) 0)
 259                (if (match-end 2) (string-to-number (match-string 2 hms)) 0)
 260                (string-to-number (match-string 3 hms)))
 261        t t hms)
 262     (error "Cannot parse HMS string \"%s\"" hms)))
 263
 264 (defun org-timer-hms-to-secs (hms)
 265   "Convert h:mm:ss string to an integer time.
 266 If the string starts with a minus sign, the integer will be negative."
 267   (if (not (string-match
 268             "\\([-+]?[0-9]+\\):\\([0-9]\\{2\\}\\):\\([0-9]\\{2\\}\\)"
 269             hms))
 270       0
 271     (let* ((h (string-to-number (match-string 1 hms)))
 272            (m (string-to-number (match-string 2 hms)))
 273            (s (string-to-number (match-string 3 hms)))
 274            (sign (equal (substring (match-string 1 hms) 0 1) "-")))
 275       (setq h (abs h))
 276       (* (if sign -1 1) (+ s (* 60 (+ m (* 60 h))))))))
 277
 278 (defun org-timer-secs-to-hms (s)
 279   "Convert integer S into h:mm:ss.
 280 If the integer is negative, the string will start with \"-\"."
 281   (let (sign m h)
 282     (setq sign (if (< s 0) "-" "")
 283           s (abs s)
 284           m (/ s 60) s (- s (* 60 m))
 285           h (/ m 60) m (- m (* 60 h)))
 286     (format "%s%d:%02d:%02d" sign h m s)))
 287
 288 (defvar org-timer-mode-line-timer nil)
 289 (defvar org-timer-mode-line-string nil)
 290
 291 (defun org-timer-set-mode-line (value)
 292   "Set the mode-line display of the relative timer.
 293 VALUE can be `on', `off', or `pause'."
 294   (when (or (eq org-timer-display 'mode-line)
 295             (eq org-timer-display 'both))
 296     (or global-mode-string (setq global-mode-string '("")))
 297     (or (memq 'org-timer-mode-line-string global-mode-string)
 298         (setq global-mode-string
 299               (append global-mode-string '(org-timer-mode-line-string)))))
 300   (when (or (eq org-timer-display 'frame-title)
 301             (eq org-timer-display 'both))
 302     (or (memq 'org-timer-mode-line-string frame-title-format)
 303         (setq frame-title-format
 304               (append frame-title-format '(org-timer-mode-line-string)))))
 305   (cond
 306    ((equal value 'off)
 307     (when org-timer-mode-line-timer
 308       (cancel-timer org-timer-mode-line-timer)
 309       (setq org-timer-mode-line-timer nil))
 310     (when (or (eq org-timer-display 'mode-line)
 311               (eq org-timer-display 'both))
 312       (setq global-mode-string
 313             (delq 'org-timer-mode-line-string global-mode-string)))
 314     (when (or (eq org-timer-display 'frame-title)
 315               (eq org-timer-display 'both))
 316       (setq frame-title-format
 317             (delq 'org-timer-mode-line-string frame-title-format)))
 318     (force-mode-line-update))
 319    ((equal value 'pause)
 320     (when org-timer-mode-line-timer
 321       (cancel-timer org-timer-mode-line-timer)
 322       (setq org-timer-mode-line-timer nil)))
 323    ((equal value 'on)
 324     (when (or (eq org-timer-display 'mode-line)
 325               (eq org-timer-display 'both))
 326       (or global-mode-string (setq global-mode-string '("")))
 327       (or (memq 'org-timer-mode-line-string global-mode-string)
 328           (setq global-mode-string
 329                 (append global-mode-string '(org-timer-mode-line-string)))))
 330     (when (or (eq org-timer-display 'frame-title)
 331               (eq org-timer-display 'both))
 332       (or (memq 'org-timer-mode-line-string frame-title-format)
 333           (setq frame-title-format
 334                 (append frame-title-format '(org-timer-mode-line-string)))))
 335     (org-timer-update-mode-line)
 336     (when org-timer-mode-line-timer
 337       (cancel-timer org-timer-mode-line-timer)
 338       (setq org-timer-mode-line-timer nil))
 339     (when org-timer-display
 340       (setq org-timer-mode-line-timer
 341             (run-with-timer 1 1 'org-timer-update-mode-line))))))
 342
 343 (defun org-timer-update-mode-line ()
 344   "Update the timer time in the mode line."
 345   (if org-timer-pause-time
 346       nil
 347     (setq org-timer-mode-line-string
 348           (concat " <" (substring (org-timer-value-string) 0 -1) ">"))
 349     (force-mode-line-update)))
 350
 351 (defun org-timer-cancel-timer ()
 352   "Cancel the current timer."
 353   (interactive)
 354   (if (not org-timer-current-timer)
 355       (message "No timer to cancel")
 356     (run-hooks 'org-timer-cancel-hook)
 357     (cancel-timer org-timer-current-timer)
 358     (setq org-timer-current-timer nil
 359           org-timer-timer-is-countdown nil)
 360     (org-timer-set-mode-line 'off)
 361     (message "Last timer canceled")))
 362
 363 (defun org-timer-show-remaining-time ()
 364   "Display the remaining time before the timer ends."
 365   (interactive)
 366   (require 'time)
 367   (if (not org-timer-current-timer)
 368       (message "No timer set")
 369     (let* ((rtime (decode-time
 370                    (time-subtract (timer--time org-timer-current-timer)
 371                                   (current-time))))
 372            (rsecs (nth 0 rtime))
 373            (rmins (nth 1 rtime)))
 374       (message "%d minute(s) %d seconds left before next time out"
 375                rmins rsecs))))
 376
 377 (defvar org-clock-sound)
 378
 379 ;;;###autoload
 380 (defun org-timer-set-timer (&optional opt)
 381   "Prompt for a duration and set a timer.
 382
 383 If `org-timer-default-timer' is not zero, suggest this value as
 384 the default duration for the timer.  If a timer is already set,
 385 prompt the user if she wants to replace it.
 386
 387 Called with a numeric prefix argument, use this numeric value as
 388 the duration of the timer.
 389
 390 Called with a `C-u' prefix arguments, use `org-timer-default-timer'
 391 without prompting the user for a duration.
 392
 393 With two `C-u' prefix arguments, use `org-timer-default-timer'
 394 without prompting the user for a duration and automatically
 395 replace any running timer.
 396
 397 By default, the timer duration will be set to the number of
 398 minutes in the Effort property, if any.  You can ignore this by
 399 using three `C-u' prefix arguments."
 400   (interactive "P")
 401   (let ((minutes (or (and (not (equal opt '(64)))
 402                           (number-to-string
 403                            (org-hh:mm-string-to-minutes
 404                             (org-entry-get (point) "effort"))))
 405                      (and (numberp opt) (number-to-string opt))
 406                      (and (listp opt) (not (null opt))
 407                           (number-to-string org-timer-default-timer))
 408                      (read-from-minibuffer
 409                       "How many minutes left? "
 410                       (if (not (eq org-timer-default-timer 0))
 411                           (number-to-string org-timer-default-timer))))))
 412     (if (not (string-match "[0-9]+" minutes))
 413         (org-timer-show-remaining-time)
 414       (let* ((mins (string-to-number (match-string 0 minutes)))
 415              (secs (* mins 60))
 416              (hl (cond
 417                   ((string-match "Org Agenda" (buffer-name))
 418                    (let* ((marker (or (get-text-property (point) 'org-marker)
 419                                       (org-agenda-error)))
 420                           (hdmarker (or (get-text-property (point) 'org-hd-marker)
 421                                         marker))
 422                           (pos (marker-position marker)))
 423                      (with-current-buffer (marker-buffer marker)
 424                        (widen)
 425                        (goto-char pos)
 426                        (org-show-entry)
 427                        (or (ignore-errors (org-get-heading))
 428                            (concat "File:" (file-name-nondirectory (buffer-file-name)))))))
 429                   ((derived-mode-p 'org-mode)
 430                    (or (ignore-errors (org-get-heading))
 431                        (concat "File:" (file-name-nondirectory (buffer-file-name)))))
 432                   (t (error "Not in an Org buffer"))))
 433              timer-set)
 434         (if (or (and org-timer-current-timer
 435                      (or (equal opt '(16))
 436                          (y-or-n-p "Replace current timer? ")))
 437                 (not org-timer-current-timer))
 438             (progn
 439               (require 'org-clock)
 440               (when org-timer-current-timer
 441                 (cancel-timer org-timer-current-timer))
 442               (setq org-timer-current-timer
 443                     (run-with-timer
 444                      secs nil `(lambda ()
 445                                  (setq org-timer-current-timer nil)
 446                                  (org-notify ,(format "%s: time out" hl) ,org-clock-sound)
 447                                  (setq org-timer-timer-is-countdown nil)
 448                                  (org-timer-set-mode-line 'off)
 449                                  (run-hooks 'org-timer-done-hook))))
 450               (run-hooks 'org-timer-set-hook)
 451               (setq org-timer-timer-is-countdown t
 452                     org-timer-start-time
 453                     (time-add (current-time) (seconds-to-time (* mins 60))))
 454               (org-timer-set-mode-line 'on))
 455           (message "No timer set"))))))
 456
 457 (provide 'org-timer)
 458
 459 ;; Local variables:
 460 ;; generated-autoload-file: "org-loaddefs.el"
 461 ;; End:
 462
 463 ;;; org-timer.el ends here