lisp/org-id.el

   1 ;;; org-id.el --- Global identifiers for Org-mode entries
   2 ;;
   3 ;; Copyright (C) 2008-2013 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: http://orgmode.org
   8 ;;
   9 ;; This file is part of GNU Emacs.
  10 ;;
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  24 ;;
  25 ;;; Commentary:
  26
  27 ;; This file implements globally unique identifiers for Org-mode entries.
  28 ;; Identifiers are stored in the entry as an :ID: property.  Functions
  29 ;; are provided that create and retrieve such identifiers, and that find
  30 ;; entries based on the identifier.
  31
  32 ;; Identifiers consist of a prefix (default "Org" given by the variable
  33 ;; `org-id-prefix') and a unique part that can be created by a number
  34 ;; of different methods, see the variable `org-id-method'.
  35 ;; Org has a builtin method that uses a compact encoding of the creation
  36 ;; time of the ID, with microsecond accuracy.  This virtually
  37 ;; guarantees globally unique identifiers, even if several people are
  38 ;; creating IDs at the same time in files that will eventually be used
  39 ;; together.
  40 ;;
  41 ;; By default Org uses UUIDs as global unique identifiers.
  42 ;;
  43 ;; This file defines the following API:
  44 ;;
  45 ;; org-id-get-create
  46 ;;        Create an ID for the entry at point if it does not yet have one.
  47 ;;        Returns the ID (old or new).  This function can be used
  48 ;;        interactively, with prefix argument the creation of a new ID is
  49 ;;        forced, even if there was an old one.
  50 ;;
  51 ;; org-id-get
  52 ;;        Get the ID property of an entry.  Using appropriate arguments
  53 ;;        to the function, it can also create the ID for this entry.
  54 ;;
  55 ;; org-id-goto
  56 ;;        Command to go to a specific ID, this command can be used
  57 ;;        interactively.
  58 ;;
  59 ;; org-id-get-with-outline-path-completion
  60 ;;        Retrieve the ID of an entry, using outline path completion.
  61 ;;        This function can work for multiple files.
  62 ;;
  63 ;; org-id-get-with-outline-drilling
  64 ;;        Retrieve the ID of an entry, using outline path completion.
  65 ;;        This function only works for the current file.
  66 ;;
  67 ;; org-id-find
  68 ;;        Find the location of an entry with specific id.
  69 ;;
  70
  71 ;;; Code:
  72
  73 (require 'org)
  74
  75 (declare-function message-make-fqdn "message" ())
  76 (declare-function org-pop-to-buffer-same-window
  77                   "org-compat" (&optional buffer-or-name norecord label))
  78
  79 ;;; Customization
  80
  81 (defgroup org-id nil
  82   "Options concerning global entry identifiers in Org-mode."
  83   :tag "Org ID"
  84   :group 'org)
  85
  86 (define-obsolete-variable-alias
  87   'org-link-to-org-use-id 'org-id-link-to-org-use-id "24.3")
  88 (defcustom org-id-link-to-org-use-id nil
  89   "Non-nil means storing a link to an Org file will use entry IDs.
  90
  91 The variable can have the following values:
  92
  93 t     Create an ID if needed to make a link to the current entry.
  94
  95 create-if-interactive
  96       If `org-store-link' is called directly (interactively, as a user
  97       command), do create an ID to support the link.  But when doing the
  98       job for capture, only use the ID if it already exists.  The
  99       purpose of this setting is to avoid proliferation of unwanted
 100       IDs, just because you happen to be in an Org file when you
 101       call `org-capture' that automatically and preemptively creates a
 102       link.  If you do want to get an ID link in a capture template to
 103       an entry not having an ID, create it first by explicitly creating
 104       a link to it, using `C-c C-l' first.
 105
 106 create-if-interactive-and-no-custom-id
 107       Like create-if-interactive, but do not create an ID if there is
 108       a CUSTOM_ID property defined in the entry.
 109
 110 use-existing
 111       Use existing ID, do not create one.
 112
 113 nil   Never use an ID to make a link, instead link using a text search for
 114       the headline text."
 115   :group 'org-link-store
 116   :group 'org-id
 117   :version "24.3"
 118   :type '(choice
 119           (const :tag "Create ID to make link" t)
 120           (const :tag "Create if storing link interactively"
 121                  create-if-interactive)
 122           (const :tag "Create if storing link interactively and no CUSTOM_ID is present"
 123                  create-if-interactive-and-no-custom-id)
 124           (const :tag "Only use existing" use-existing)
 125           (const :tag "Do not use ID to create link" nil)))
 126
 127 (defcustom org-id-uuid-program "uuidgen"
 128   "The uuidgen program."
 129   :group 'org-id
 130   :type 'string)
 131
 132 (defcustom org-id-method 'uuid
 133   "The method that should be used to create new IDs.
 134
 135 An ID will consist of the optional prefix specified in `org-id-prefix',
 136 and a unique part created by the method this variable specifies.
 137
 138 Allowed values are:
 139
 140 org        Org's own internal method, using an encoding of the current time to
 141            microsecond accuracy, and optionally the current domain of the
 142            computer.  See the variable `org-id-include-domain'.
 143
 144 uuid       Create random (version 4) UUIDs.  If the program defined in
 145            `org-id-uuid-program' is available it is used to create the ID.
 146            Otherwise an internal functions is used."
 147   :group 'org-id
 148   :type '(choice
 149           (const :tag "Org's internal method" org)
 150           (const :tag "external: uuidgen" uuid)))
 151
 152 (defcustom org-id-prefix nil
 153   "The prefix for IDs.
 154
 155 This may be a string, or it can be nil to indicate that no prefix is required.
 156 When a string, the string should have no space characters as IDs are expected
 157 to have no space characters in them."
 158   :group 'org-id
 159   :type '(choice
 160           (const :tag "No prefix")
 161           (string :tag "Prefix")))
 162
 163 (defcustom org-id-include-domain nil
 164   "Non-nil means add the domain name to new IDs.
 165 This ensures global uniqueness of IDs, and is also suggested by
 166 RFC 2445 in combination with RFC 822.  This is only relevant if
 167 `org-id-method' is `org'.  When uuidgen is used, the domain will never
 168 be added.
 169 The default is to not use this because we have no really good way to get
 170 the true domain, and Org entries will normally not be shared with enough
 171 people to make this necessary."
 172   :group 'org-id
 173   :type 'boolean)
 174
 175 (defcustom org-id-track-globally t
 176   "Non-nil means track IDs through files, so that links work globally.
 177 This work by maintaining a hash table for IDs and writing this table
 178 to disk when exiting Emacs.  Because of this, it works best if you use
 179 a single Emacs process, not many.
 180
 181 When nil, IDs are not tracked.  Links to IDs will still work within
 182 a buffer, but not if the entry is located in another file.
 183 IDs can still be used if the entry with the id is in the same file as
 184 the link."
 185   :group 'org-id
 186   :type 'boolean)
 187
 188 (defcustom org-id-locations-file (convert-standard-filename
 189                                   (concat user-emacs-directory ".org-id-locations"))
 190   "The file for remembering in which file an ID was defined.
 191 This variable is only relevant when `org-id-track-globally' is set."
 192   :group 'org-id
 193   :type 'file)
 194
 195 (defvar org-id-locations nil
 196   "List of files with IDs in those files.")
 197
 198 (defvar org-id-files nil
 199   "List of files that contain IDs.")
 200
 201 (defcustom org-id-extra-files 'org-agenda-text-search-extra-files
 202   "Files to be searched for IDs, besides the agenda files.
 203 When Org reparses files to remake the list of files and IDs it is tracking,
 204 it will normally scan the agenda files, the archives related to agenda files,
 205 any files that are listed as ID containing in the current register, and
 206 any Org-mode files currently visited by Emacs.
 207 You can list additional files here.
 208 This variable is only relevant when `org-id-track-globally' is set."
 209   :group 'org-id
 210   :type
 211   '(choice
 212     (symbol :tag "Variable")
 213     (repeat :tag "List of files"
 214             (file))))
 215
 216 (defcustom org-id-search-archives t
 217   "Non-nil means search also the archive files of agenda files for entries.
 218 This is a possibility to reduce overhead, but it means that entries moved
 219 to the archives can no longer be found by ID.
 220 This variable is only relevant when `org-id-track-globally' is set."
 221   :group 'org-id
 222   :type 'boolean)
 223
 224 ;;; The API functions
 225
 226 ;;;###autoload
 227 (defun org-id-get-create (&optional force)
 228   "Create an ID for the current entry and return it.
 229 If the entry already has an ID, just return it.
 230 With optional argument FORCE, force the creation of a new ID."
 231   (interactive "P")
 232   (when force
 233     (org-entry-put (point) "ID" nil))
 234   (org-id-get (point) 'create))
 235
 236 (defun org-id-copy ()
 237   "Copy the ID of the entry at point to the kill ring.
 238 Create an ID if necessary."
 239   (interactive)
 240   (org-kill-new (org-id-get nil 'create)))
 241
 242 ;;;###autoload
 243 (defun org-id-get (&optional pom create prefix)
 244   "Get the ID property of the entry at point-or-marker POM.
 245 If POM is nil, refer to the entry at point.
 246 If the entry does not have an ID, the function returns nil.
 247 However, when CREATE is non nil, create an ID if none is present already.
 248 PREFIX will be passed through to `org-id-new'.
 249 In any case, the ID of the entry is returned."
 250   (org-with-point-at pom
 251     (let ((id (org-entry-get nil "ID")))
 252       (cond
 253        ((and id (stringp id) (string-match "\\S-" id))
 254         id)
 255        (create
 256         (setq id (org-id-new prefix))
 257         (org-entry-put pom "ID" id)
 258         (org-id-add-location id (buffer-file-name (buffer-base-buffer)))
 259         id)))))
 260
 261 (defun org-id-get-with-outline-path-completion (&optional targets)
 262   "Use `outline-path-completion' to retrieve the ID of an entry.
 263 TARGETS may be a setting for `org-refile-targets' to define
 264 eligible headlines.  When omitted, all headlines in the current
 265 file are eligible.  This function returns the ID of the entry.
 266 If necessary, the ID is created."
 267   (let* ((org-refile-targets (or targets '((nil . (:maxlevel . 10)))))
 268          (org-refile-use-outline-path
 269           (if (caar org-refile-targets) 'file t))
 270          (org-refile-target-verify-function nil)
 271          (spos (org-refile-get-location "Entry"))
 272          (pom (and spos (move-marker (make-marker) (nth 3 spos)
 273                                      (get-file-buffer (nth 1 spos))))))
 274     (prog1 (org-id-get pom 'create)
 275       (move-marker pom nil))))
 276
 277 (defun org-id-get-with-outline-drilling (&optional targets)
 278   "Use an outline-cycling interface to retrieve the ID of an entry.
 279 This only finds entries in the current buffer, using `org-get-location'.
 280 It returns the ID of the entry.  If necessary, the ID is created."
 281   (let* ((spos (org-get-location (current-buffer) org-goto-help))
 282          (pom (and spos (move-marker (make-marker) (car spos)))))
 283     (prog1 (org-id-get pom 'create)
 284       (move-marker pom nil))))
 285
 286 ;;;###autoload
 287 (defun org-id-goto (id)
 288   "Switch to the buffer containing the entry with id ID.
 289 Move the cursor to that entry in that buffer."
 290   (interactive "sID: ")
 291   (let ((m (org-id-find id 'marker)))
 292     (unless m
 293       (error "Cannot find entry with ID \"%s\"" id))
 294     (org-pop-to-buffer-same-window (marker-buffer m))
 295     (goto-char m)
 296     (move-marker m nil)
 297     (org-show-context)))
 298
 299 ;;;###autoload
 300 (defun org-id-find (id &optional markerp)
 301   "Return the location of the entry with the id ID.
 302 The return value is a cons cell (file-name . position), or nil
 303 if there is no entry with that ID.
 304 With optional argument MARKERP, return the position as a new marker."
 305   (cond
 306    ((symbolp id) (setq id (symbol-name id)))
 307    ((numberp id) (setq id (number-to-string id))))
 308   (let ((file (org-id-find-id-file id))
 309         org-agenda-new-buffers where)
 310     (when file
 311       (setq where (org-id-find-id-in-file id file markerp)))
 312     (unless where
 313       (org-id-update-id-locations nil t)
 314       (setq file (org-id-find-id-file id))
 315       (when file
 316         (setq where (org-id-find-id-in-file id file markerp))))
 317     where))
 318
 319 ;;; Internal functions
 320
 321 ;; Creating new IDs
 322
 323 (defun org-id-new (&optional prefix)
 324   "Create a new globally unique ID.
 325
 326 An ID consists of two parts separated by a colon:
 327 - a prefix
 328 - a unique part that will be created according to `org-id-method'.
 329
 330 PREFIX can specify the prefix, the default is given by the variable
 331 `org-id-prefix'.  However, if PREFIX is the symbol `none', don't use any
 332 prefix even if `org-id-prefix' specifies one.
 333
 334 So a typical ID could look like \"Org:4nd91V40HI\"."
 335   (let* ((prefix (if (eq prefix 'none)
 336                      ""
 337                    (concat (or prefix org-id-prefix) ":")))
 338          unique)
 339     (if (equal prefix ":") (setq prefix ""))
 340     (cond
 341      ((memq org-id-method '(uuidgen uuid))
 342       (setq unique (org-trim (shell-command-to-string org-id-uuid-program)))
 343       (unless (org-uuidgen-p unique)
 344         (setq unique (org-id-uuid))))
 345      ((eq org-id-method 'org)
 346       (let* ((etime (org-reverse-string (org-id-time-to-b36)))
 347              (postfix (if org-id-include-domain
 348                           (progn
 349                             (require 'message)
 350                             (concat "@" (message-make-fqdn))))))
 351         (setq unique (concat etime postfix))))
 352      (t (error "Invalid `org-id-method'")))
 353     (concat prefix unique)))
 354
 355 (defun org-id-uuid ()
 356   "Return string with random (version 4) UUID."
 357   (let ((rnd (md5 (format "%s%s%s%s%s%s%s"
 358                           (random)
 359                           (current-time)
 360                           (user-uid)
 361                           (emacs-pid)
 362                           (user-full-name)
 363                           user-mail-address
 364                           (recent-keys)))))
 365     (format "%s-%s-4%s-%s%s-%s"
 366             (substring rnd 0 8)
 367             (substring rnd 8 12)
 368             (substring rnd 13 16)
 369             (format "%x"
 370                     (logior
 371                      #b10000000
 372                      (logand
 373                       #b10111111
 374                       (string-to-number
 375                        (substring rnd 16 18) 16))))
 376             (substring rnd 18 20)
 377             (substring rnd 20 32))))
 378
 379 (defun org-id-int-to-b36-one-digit (i)
 380   "Turn an integer between 0 and 61 into a single character 0..9, A..Z, a..z."
 381   (cond
 382    ((< i 10) (+ ?0 i))
 383    ((< i 36) (+ ?a i -10))
 384    (t (error "Larger that 35"))))
 385
 386 (defun org-id-b36-to-int-one-digit (i)
 387   "Turn a character 0..9, A..Z, a..z into a number 0..61.
 388 The input I may be a character, or a single-letter string."
 389   (and (stringp i) (setq i (string-to-char i)))
 390   (cond
 391    ((and (>= i ?0) (<= i ?9)) (- i ?0))
 392    ((and (>= i ?a) (<= i ?z)) (+ (- i ?a) 10))
 393    (t (error "Invalid b36 letter"))))
 394
 395 (defun org-id-int-to-b36 (i &optional length)
 396   "Convert an integer to a base-36 number represented as a string."
 397   (let ((s ""))
 398     (while (> i 0)
 399       (setq s (concat (char-to-string
 400                        (org-id-int-to-b36-one-digit (mod i 36))) s)
 401             i (/ i 36)))
 402     (setq length (max 1 (or length 1)))
 403     (if (< (length s) length)
 404         (setq s (concat (make-string (- length (length s)) ?0) s)))
 405     s))
 406
 407 (defun org-id-b36-to-int (s)
 408   "Convert a base-36 string into the corresponding integer."
 409   (let ((r 0))
 410     (mapc (lambda (i) (setq r (+ (* r 36) (org-id-b36-to-int-one-digit i))))
 411           s)
 412     r))
 413
 414 (defun org-id-time-to-b36 (&optional time)
 415   "Encode TIME as a 10-digit string.
 416 This string holds the time to micro-second accuracy, and can be decoded
 417 using `org-id-decode'."
 418   (setq time (or time (current-time)))
 419   (concat (org-id-int-to-b36 (nth 0 time) 4)
 420           (org-id-int-to-b36 (nth 1 time) 4)
 421           (org-id-int-to-b36 (or (nth 2 time) 0) 4)))
 422
 423 (defun org-id-decode (id)
 424   "Split ID into the prefix and the time value that was used to create it.
 425 The return value is (prefix . time) where PREFIX is nil or a string,
 426 and time is the usual three-integer representation of time."
 427   (let (prefix time parts)
 428     (setq parts (org-split-string id ":"))
 429     (if (= 2 (length parts))
 430         (setq prefix (car parts) time (nth 1 parts))
 431       (setq prefix nil time (nth 0 parts)))
 432     (setq time (org-reverse-string time))
 433     (setq time (list (org-id-b36-to-int (substring time 0 4))
 434                      (org-id-b36-to-int (substring time 4 8))
 435                      (org-id-b36-to-int (substring time 8 12))))
 436     (cons prefix time)))
 437
 438 ;; Storing ID locations (files)
 439
 440 (defun org-id-update-id-locations (&optional files silent)
 441   "Scan relevant files for IDs.
 442 Store the relation between files and corresponding IDs.
 443 This will scan all agenda files, all associated archives, and all
 444 files currently mentioned in `org-id-locations'.
 445 When FILES is given, scan these files instead.
 446 When CHECK is given, prepare detailed information about duplicate IDs."
 447   (interactive)
 448   (if (not org-id-track-globally)
 449       (error "Please turn on `org-id-track-globally' if you want to track IDs")
 450     (let* ((org-id-search-archives
 451             (or org-id-search-archives
 452                 (and (symbolp org-id-extra-files)
 453                      (symbol-value org-id-extra-files)
 454                      (member 'agenda-archives org-id-extra-files))))
 455            (files
 456             (or files
 457                 (append
 458                  ;; Agenda files and all associated archives
 459                  (org-agenda-files t org-id-search-archives)
 460                  ;; Explicit extra files
 461                  (if (symbolp org-id-extra-files)
 462                      (symbol-value org-id-extra-files)
 463                    org-id-extra-files)
 464                  ;; Files associated with live org-mode buffers
 465                  (delq nil
 466                        (mapcar (lambda (b)
 467                                  (with-current-buffer b
 468                                    (and (derived-mode-p 'org-mode) (buffer-file-name))))
 469                                (buffer-list)))
 470                  ;; All files known to have IDs
 471                  org-id-files)))
 472            org-agenda-new-buffers
 473            file nfiles tfile ids reg found id seen (ndup 0))
 474       (when (member 'agenda-archives files)
 475         (setq files (delq 'agenda-archives (copy-sequence files))))
 476       (setq nfiles (length files))
 477       (while (setq file (pop files))
 478         (unless silent
 479           (message "Finding ID locations (%d/%d files): %s"
 480                    (- nfiles (length files)) nfiles file))
 481         (setq tfile (file-truename file))
 482         (when (and (file-exists-p file) (not (member tfile seen)))
 483           (push tfile seen)
 484           (setq ids nil)
 485           (with-current-buffer (org-get-agenda-file-buffer file)
 486             (save-excursion
 487               (save-restriction
 488                 (widen)
 489                 (goto-char (point-min))
 490                 (while (re-search-forward "^[ \t]*:ID:[ \t]+\\(\\S-+\\)[ \t]*$"
 491                                           nil t)
 492                   (setq id (org-match-string-no-properties 1))
 493                   (if (member id found)
 494                       (progn
 495                         (message "Duplicate ID \"%s\", also in file %s"
 496                                  id (or (car (delq
 497                                               nil
 498                                               (mapcar
 499                                                (lambda (x)
 500                                                  (if (member id (cdr x))
 501                                                      (car x)))
 502                                                reg)))
 503                                         (buffer-file-name)))
 504                         (when (= ndup 0)
 505                           (ding)
 506                           (sit-for 2))
 507                         (setq ndup (1+ ndup)))
 508                     (push id found)
 509                     (push id ids)))
 510                 (push (cons (abbreviate-file-name file) ids) reg))))))
 511       (org-release-buffers org-agenda-new-buffers)
 512       (setq org-agenda-new-buffers nil)
 513       (setq org-id-locations reg)
 514       (setq org-id-files (mapcar 'car org-id-locations))
 515       (org-id-locations-save) ;; this function can also handle the alist form
 516       ;; now convert to a hash
 517       (setq org-id-locations (org-id-alist-to-hash org-id-locations))
 518       (if (> ndup 0)
 519           (message "WARNING: %d duplicate IDs found, check *Messages* buffer" ndup)
 520         (message "%d unique files scanned for IDs" (length org-id-files)))
 521       org-id-locations)))
 522
 523 (defun org-id-locations-save ()
 524   "Save `org-id-locations' in `org-id-locations-file'."
 525   (when (and org-id-track-globally org-id-locations)
 526     (let ((out (if (hash-table-p org-id-locations)
 527                    (org-id-hash-to-alist org-id-locations)
 528                  org-id-locations)))
 529       (with-temp-file org-id-locations-file
 530         (print out (current-buffer))))))
 531
 532 (defun org-id-locations-load ()
 533   "Read the data from `org-id-locations-file'."
 534   (setq org-id-locations nil)
 535   (when org-id-track-globally
 536     (with-temp-buffer
 537       (condition-case nil
 538           (progn
 539             (insert-file-contents-literally org-id-locations-file)
 540             (goto-char (point-min))
 541             (setq org-id-locations (read (current-buffer))))
 542         (error
 543          (message "Could not read org-id-values from %s.  Setting it to nil."
 544                   org-id-locations-file))))
 545     (setq org-id-files (mapcar 'car org-id-locations))
 546     (setq org-id-locations (org-id-alist-to-hash org-id-locations))))
 547
 548 (defun org-id-add-location (id file)
 549   "Add the ID with location FILE to the database of ID locations."
 550   ;; Only if global tracking is on, and when the buffer has a file
 551   (when (and org-id-track-globally id file)
 552     (unless org-id-locations (org-id-locations-load))
 553     (puthash id (abbreviate-file-name file) org-id-locations)
 554     (add-to-list 'org-id-files (abbreviate-file-name file))))
 555
 556 (unless noninteractive
 557   (add-hook 'kill-emacs-hook 'org-id-locations-save))
 558
 559 (defun org-id-hash-to-alist (hash)
 560   "Turn an org-id hash into an alist, so that it can be written to a file."
 561   (let (res x)
 562     (maphash
 563      (lambda (k v)
 564        (if (setq x (member v res))
 565            (setcdr x (cons k (cdr x)))
 566          (push (list v k) res)))
 567      hash)
 568     res))
 569
 570 (defun org-id-alist-to-hash (list)
 571   "Turn an org-id location list into a hash table."
 572   (let ((res (make-hash-table
 573               :test 'equal
 574               :size (apply '+ (mapcar 'length list))))
 575         f)
 576     (mapc
 577      (lambda (x)
 578        (setq f (car x))
 579        (mapc (lambda (i) (puthash i f res)) (cdr x)))
 580      list)
 581     res))
 582
 583 (defun org-id-paste-tracker (txt &optional buffer-or-file)
 584   "Update any IDs in TXT and assign BUFFER-OR-FILE to them."
 585   (when org-id-track-globally
 586     (save-match-data
 587       (setq buffer-or-file (or buffer-or-file (current-buffer)))
 588       (when (bufferp buffer-or-file)
 589         (setq buffer-or-file (or (buffer-base-buffer buffer-or-file)
 590                                  buffer-or-file))
 591         (setq buffer-or-file (buffer-file-name buffer-or-file)))
 592       (when buffer-or-file
 593         (let ((fname (abbreviate-file-name buffer-or-file))
 594               (s 0))
 595           (while (string-match "^[ \t]*:ID:[ \t]+\\([^ \t\n\r]+\\)" txt s)
 596             (setq s (match-end 0))
 597             (org-id-add-location (match-string 1 txt) fname)))))))
 598
 599 ;; Finding entries with specified id
 600
 601 ;;;###autoload
 602 (defun org-id-find-id-file (id)
 603   "Query the id database for the file in which this ID is located."
 604   (unless org-id-locations (org-id-locations-load))
 605   (or (and org-id-locations
 606            (hash-table-p org-id-locations)
 607            (gethash id org-id-locations))
 608       ;; ball back on current buffer
 609       (buffer-file-name (or (buffer-base-buffer (current-buffer))
 610                             (current-buffer)))))
 611
 612 (defun org-id-find-id-in-file (id file &optional markerp)
 613   "Return the position of the entry ID in FILE.
 614 If that files does not exist, or if it does not contain this ID,
 615 return nil.
 616 The position is returned as a cons cell (file-name . position).  With
 617 optional argument MARKERP, return the position as a new marker."
 618   (let (org-agenda-new-buffers buf pos)
 619     (cond
 620      ((not file) nil)
 621      ((not (file-exists-p file)) nil)
 622      (t (with-current-buffer (setq buf (org-get-agenda-file-buffer file))
 623           (setq pos (org-find-entry-with-id id))
 624           (when pos
 625             (if markerp
 626                 (move-marker (make-marker) pos buf)
 627               (cons file pos))))))))
 628
 629 ;; id link type
 630
 631 ;; Calling the following function is hard-coded into `org-store-link',
 632 ;; so we do have to add it to `org-store-link-functions'.
 633
 634 ;;;###autoload
 635 (defun org-id-store-link ()
 636   "Store a link to the current entry, using its ID."
 637   (interactive)
 638   (when (and (buffer-file-name (buffer-base-buffer)) (derived-mode-p 'org-mode))
 639     (let* ((link (concat "id:" (org-id-get-create)))
 640            (case-fold-search nil)
 641            (desc (save-excursion
 642                    (org-back-to-heading t)
 643                    (or (and (looking-at org-complex-heading-regexp)
 644                             (if (match-end 4)
 645                                 (match-string 4)
 646                               (match-string 0)))
 647                        link))))
 648       (org-store-link-props :link link :description desc :type "id")
 649       link)))
 650
 651 (defun org-id-open (id)
 652   "Go to the entry with id ID."
 653   (org-mark-ring-push)
 654   (let ((m (org-id-find id 'marker))
 655         cmd)
 656     (unless m
 657       (error "Cannot find entry with ID \"%s\"" id))
 658     ;; Use a buffer-switching command in analogy to finding files
 659     (setq cmd
 660           (or
 661            (cdr
 662             (assq
 663              (cdr (assq 'file org-link-frame-setup))
 664              '((find-file . switch-to-buffer)
 665                (find-file-other-window . switch-to-buffer-other-window)
 666                (find-file-other-frame . switch-to-buffer-other-frame))))
 667            'switch-to-buffer-other-window))
 668     (if (not (equal (current-buffer) (marker-buffer m)))
 669         (funcall cmd (marker-buffer m)))
 670     (goto-char m)
 671     (move-marker m nil)
 672     (org-show-context)))
 673
 674 (org-add-link-type "id" 'org-id-open)
 675
 676 (provide 'org-id)
 677
 678 ;; Local variables:
 679 ;; generated-autoload-file: "org-loaddefs.el"
 680 ;; End:
 681
 682 ;;; org-id.el ends here