lisp/ob-exp.el

   1 ;;; ob-exp.el --- Exportation of org-babel source blocks
   2
   3 ;; Copyright (C) 2009-2016 Free Software Foundation, Inc.
   4
   5 ;; Authors: Eric Schulte
   6 ;;      Dan Davison
   7 ;; Keywords: literate programming, reproducible research
   8 ;; Homepage: http://orgmode.org
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Code:
  26 (require 'ob-core)
  27 (require 'org-src)
  28 (eval-when-compile
  29   (require 'cl))
  30
  31 (defvar org-babel-ref-split-regexp)
  32
  33 (declare-function org-babel-lob-get-info "ob-lob" (&optional datum))
  34 (declare-function org-babel-eval-wipe-error-buffer "ob-eval" ())
  35 (declare-function org-between-regexps-p "org"
  36                   (start-re end-re &optional lim-up lim-down))
  37 (declare-function org-get-indentation "org" (&optional line))
  38 (declare-function org-heading-components "org" ())
  39 (declare-function org-in-commented-heading-p "org" (&optional no-inheritance))
  40 (declare-function org-in-block-p "org" (names))
  41 (declare-function org-in-verbatim-emphasis "org" ())
  42 (declare-function org-link-search "org" (s &optional avoid-pos stealth))
  43 (declare-function org-fill-template "org" (template alist))
  44 (declare-function org-split-string "org" (string &optional separators))
  45 (declare-function org-element-at-point "org-element" ())
  46 (declare-function org-element-context "org-element" ())
  47 (declare-function org-element-property "org-element" (property element))
  48 (declare-function org-element-type "org-element" (element))
  49 (declare-function org-id-get "org-id" (&optional pom create prefix))
  50 (declare-function org-escape-code-in-string "org-src" (s))
  51
  52 (defcustom org-export-babel-evaluate t
  53   "Switch controlling code evaluation during export.
  54 When set to nil no code will be evaluated as part of the export
  55 process.  When set to `inline-only', only inline code blocks will
  56 be executed."
  57   :group 'org-babel
  58   :version "24.1"
  59   :type '(choice (const :tag "Never" nil)
  60                  (const :tag "Only inline code" inline-only)
  61                  (const :tag "Always" t)))
  62 (put 'org-export-babel-evaluate 'safe-local-variable (lambda (x) (eq x nil)))
  63
  64 (defvar org-link-search-inhibit-query)
  65 (defmacro org-babel-exp-in-export-file (lang &rest body)
  66   (declare (indent 1))
  67   `(let* ((lang-headers (intern (concat "org-babel-default-header-args:" ,lang)))
  68           (heading-query (or (org-id-get)
  69                              ;; CUSTOM_IDs don't work, maybe they are
  70                              ;; stripped, or maybe they resolve too
  71                              ;; late in `org-link-search'.
  72                              ;; (org-entry-get nil "CUSTOM_ID")
  73                              (nth 4 (ignore-errors (org-heading-components)))))
  74           (export-buffer (current-buffer))
  75           results)
  76      (when org-babel-exp-reference-buffer
  77        ;; Resolve parameters in the original file so that headline and
  78        ;; file-wide parameters are included, attempt to go to the same
  79        ;; heading in the original file
  80        (set-buffer org-babel-exp-reference-buffer)
  81        (save-restriction
  82          (when heading-query
  83            (condition-case nil
  84                (let ((org-link-search-inhibit-query t))
  85                  ;; TODO: When multiple headings have the same title,
  86                  ;;       this returns the first, which is not always
  87                  ;;       the right heading.  Consider a better way to
  88                  ;;       find the proper heading.
  89                  (org-link-search heading-query))
  90              (error (when heading-query
  91                       (goto-char (point-min))
  92                       (re-search-forward (regexp-quote heading-query) nil t)))))
  93          (setq results ,@body))
  94        (set-buffer export-buffer)
  95        results)))
  96 (def-edebug-spec org-babel-exp-in-export-file (form body))
  97
  98 (defun org-babel-exp-src-block (&rest headers)
  99   "Process source block for export.
 100 Depending on the `export' headers argument, replace the source
 101 code block like this:
 102
 103 both ---- display the code and the results
 104
 105 code ---- the default, display the code inside the block but do
 106           not process
 107
 108 results - just like none only the block is run on export ensuring
 109           that its results are present in the org-mode buffer
 110
 111 none ---- do not display either code or results upon export
 112
 113 Assume point is at the beginning of block's starting line."
 114   (interactive)
 115   (save-excursion
 116     (let* ((info (org-babel-get-src-block-info 'light))
 117            (line (org-current-line))
 118            (lang (nth 0 info))
 119            (raw-params (nth 2 info)) hash)
 120       ;; bail if we couldn't get any info from the block
 121       (unless noninteractive
 122         (message "org-babel-exp process %s at line %d..." lang line))
 123       (when info
 124         ;; if we're actually going to need the parameters
 125         (when (member (cdr (assoc :exports (nth 2 info))) '("both" "results"))
 126           (org-babel-exp-in-export-file lang
 127             (setf (nth 2 info)
 128                   (org-babel-process-params
 129                    (apply #'org-babel-merge-params
 130                           org-babel-default-header-args
 131                           (if (boundp lang-headers) (eval lang-headers) nil)
 132                           (append (org-babel-params-from-properties lang)
 133                                   (list raw-params))))))
 134           (setf hash (org-babel-sha1-hash info)))
 135         (org-babel-exp-do-export info 'block hash)))))
 136
 137 (defcustom org-babel-exp-call-line-template
 138   ""
 139   "Template used to export call lines.
 140 This template may be customized to include the call line name
 141 with any export markup.  The template is filled out using
 142 `org-fill-template', and the following %keys may be used.
 143
 144  line --- call line
 145
 146 An example value would be \"\\n: call: %line\" to export the call line
 147 wrapped in a verbatim environment.
 148
 149 Note: the results are inserted separately after the contents of
 150 this template."
 151   :group 'org-babel
 152   :type 'string)
 153
 154 (defvar org-babel-default-lob-header-args)
 155 (defun org-babel-exp-process-buffer (reference-buffer)
 156   "Execute all Babel blocks in current buffer.
 157 REFERENCE-BUFFER is the buffer containing a pristine copy of the
 158 buffer being processed.  It is used to properly resolve
 159 references in source blocks, as modifications in current buffer
 160 may make them unreachable."
 161   (interactive)
 162   (save-window-excursion
 163     (save-excursion
 164       (let ((case-fold-search t)
 165             (org-babel-exp-reference-buffer reference-buffer)
 166             (regexp "\\(call\\|src\\)_\\|^[ \t]*#\\+\\(BEGIN_SRC\\|CALL:\\)"))
 167         (goto-char (point-min))
 168         (while (re-search-forward regexp nil t)
 169           (unless (save-match-data (org-in-commented-heading-p))
 170             (let* ((element (save-match-data (org-element-context)))
 171                    (type (org-element-type element))
 172                    (begin (copy-marker (org-element-property :begin element)))
 173                    (end (copy-marker
 174                          (save-excursion
 175                            (goto-char (org-element-property :end element))
 176                            (skip-chars-backward " \r\t\n")
 177                            (point)))))
 178               (case type
 179                 (inline-src-block
 180                  (let* ((info (org-babel-get-src-block-info nil element))
 181                         (params (nth 2 info)))
 182                    (setf (nth 1 info)
 183                          (if (and (cdr (assoc :noweb params))
 184                                   (string= "yes" (cdr (assoc :noweb params))))
 185                              (org-babel-expand-noweb-references
 186                               info org-babel-exp-reference-buffer)
 187                            (nth 1 info)))
 188                    (goto-char begin)
 189                    (let ((replacement (org-babel-exp-do-export info 'inline)))
 190                      (if (equal replacement "")
 191                          ;; Replacement code is empty: remove inline
 192                          ;; source block, including extra white space
 193                          ;; that might have been created when
 194                          ;; inserting results.
 195                          (delete-region begin
 196                                         (progn (goto-char end)
 197                                                (skip-chars-forward " \t")
 198                                                (point)))
 199                        ;; Otherwise: remove inline src block but
 200                        ;; preserve following white spaces.  Then
 201                        ;; insert value.
 202                        (delete-region begin end)
 203                        (insert replacement)))))
 204                 ((babel-call inline-babel-call)
 205                  (let* ((lob-info (org-babel-lob-get-info element))
 206                         (results
 207                          (org-babel-exp-do-export
 208                           (list "emacs-lisp" "results"
 209                                 (apply #'org-babel-merge-params
 210                                        org-babel-default-header-args
 211                                        org-babel-default-lob-header-args
 212                                        (append
 213                                         (org-babel-params-from-properties)
 214                                         (list
 215                                          (org-babel-parse-header-arguments
 216                                           (org-no-properties
 217                                            (concat
 218                                             ":var results="
 219                                             (mapconcat #'identity
 220                                                        (butlast lob-info 2)
 221                                                        " ")))))))
 222                                 "" (nth 2 lob-info) (nth 3 lob-info))
 223                           'lob))
 224                         (rep (org-fill-template
 225                               org-babel-exp-call-line-template
 226                               `(("line"  . ,(nth 0 lob-info))))))
 227                    ;; If replacement is empty, completely remove the
 228                    ;; object/element, including any extra white space
 229                    ;; that might have been created when including
 230                    ;; results.
 231                    (if (equal rep "")
 232                        (delete-region
 233                         begin
 234                         (progn (goto-char end)
 235                                (if (not (eq type 'babel-call))
 236                                    (progn (skip-chars-forward " \t") (point))
 237                                  (skip-chars-forward " \r\t\n")
 238                                  (line-beginning-position))))
 239                      ;; Otherwise, preserve following white
 240                      ;; spaces/newlines and then, insert replacement
 241                      ;; string.
 242                      (goto-char begin)
 243                      (delete-region begin end)
 244                      (insert rep))))
 245                 (src-block
 246                  (let* ((match-start (copy-marker (match-beginning 0)))
 247                         (ind (org-get-indentation))
 248                         (lang (or (org-element-property :language element)
 249                                   (user-error
 250                                    "No language for src block: %s"
 251                                    (or (org-element-property :name element)
 252                                        "(unnamed)"))))
 253                         (headers
 254                          (cons lang
 255                                (let ((params
 256                                       (org-element-property
 257                                        :parameters element)))
 258                                  (and params (org-split-string params))))))
 259                    ;; Take care of matched block: compute replacement
 260                    ;; string.  In particular, a nil REPLACEMENT means
 261                    ;; the block should be left as-is while an empty
 262                    ;; string should remove the block.
 263                    (let ((replacement
 264                           (progn (goto-char match-start)
 265                                  (org-babel-exp-src-block headers))))
 266                      (cond ((not replacement) (goto-char end))
 267                            ((equal replacement "")
 268                             (goto-char end)
 269                             (skip-chars-forward " \r\t\n")
 270                             (beginning-of-line)
 271                             (delete-region begin (point)))
 272                            (t
 273                             (goto-char match-start)
 274                             (delete-region (point)
 275                                            (save-excursion (goto-char end)
 276                                                            (line-end-position)))
 277                             (insert replacement)
 278                             (if (or org-src-preserve-indentation
 279                                     (org-element-property :preserve-indent
 280                                                           element))
 281                                 ;; Indent only the code block markers.
 282                                 (save-excursion (skip-chars-backward " \r\t\n")
 283                                                 (indent-line-to ind)
 284                                                 (goto-char match-start)
 285                                                 (indent-line-to ind))
 286                               ;; Indent everything.
 287                               (indent-rigidly match-start (point) ind)))))
 288                    (set-marker match-start nil))))
 289               (set-marker begin nil)
 290               (set-marker end nil))))))))
 291
 292 (defun org-babel-exp-do-export (info type &optional hash)
 293   "Return a string with the exported content of a code block.
 294 The function respects the value of the :exports header argument."
 295   (let ((silently (lambda () (let ((session (cdr (assoc :session (nth 2 info)))))
 296                           (unless (equal "none" session)
 297                             (org-babel-exp-results info type 'silent)))))
 298         (clean (lambda () (if (eq type 'inline)
 299                          (org-babel-remove-inline-result)
 300                        (org-babel-remove-result info)))))
 301     (pcase (or (cdr (assq :exports (nth 2 info))) "code")
 302       ("none" (funcall silently) (funcall clean) "")
 303       ("code" (funcall silently) (funcall clean) (org-babel-exp-code info type))
 304       ("results" (org-babel-exp-results info type nil hash) "")
 305       ("both"
 306        (org-babel-exp-results info type nil hash)
 307        (org-babel-exp-code info type)))))
 308
 309 (defcustom org-babel-exp-code-template
 310   "#+BEGIN_SRC %lang%switches%flags\n%body\n#+END_SRC"
 311   "Template used to export the body of code blocks.
 312 This template may be customized to include additional information
 313 such as the code block name, or the values of particular header
 314 arguments.  The template is filled out using `org-fill-template',
 315 and the following %keys may be used.
 316
 317  lang ------ the language of the code block
 318  name ------ the name of the code block
 319  body ------ the body of the code block
 320  switches -- the switches associated to the code block
 321  flags ----- the flags passed to the code block
 322
 323 In addition to the keys mentioned above, every header argument
 324 defined for the code block may be used as a key and will be
 325 replaced with its value."
 326   :group 'org-babel
 327   :type 'string)
 328
 329 (defcustom org-babel-exp-inline-code-template
 330   "src_%lang[%switches%flags]{%body}"
 331   "Template used to export the body of inline code blocks.
 332 This template may be customized to include additional information
 333 such as the code block name, or the values of particular header
 334 arguments.  The template is filled out using `org-fill-template',
 335 and the following %keys may be used.
 336
 337  lang ------ the language of the code block
 338  name ------ the name of the code block
 339  body ------ the body of the code block
 340  switches -- the switches associated to the code block
 341  flags ----- the flags passed to the code block
 342
 343 In addition to the keys mentioned above, every header argument
 344 defined for the code block may be used as a key and will be
 345 replaced with its value."
 346   :group 'org-babel
 347   :type 'string
 348   :version "25.1"
 349   :package-version '(Org . "8.3"))
 350
 351 (defun org-babel-exp-code (info type)
 352   "Return the original code block formatted for export."
 353   (setf (nth 1 info)
 354         (if (string= "strip-export" (cdr (assoc :noweb (nth 2 info))))
 355             (replace-regexp-in-string
 356              (org-babel-noweb-wrap) "" (nth 1 info))
 357           (if (org-babel-noweb-p (nth 2 info) :export)
 358               (org-babel-expand-noweb-references
 359                info org-babel-exp-reference-buffer)
 360             (nth 1 info))))
 361   (org-fill-template
 362    (if (eq type 'inline)
 363        org-babel-exp-inline-code-template
 364        org-babel-exp-code-template)
 365    `(("lang"  . ,(nth 0 info))
 366      ("body"  . ,(org-escape-code-in-string (nth 1 info)))
 367      ("switches" . ,(let ((f (nth 3 info)))
 368                       (and (org-string-nw-p f) (concat " " f))))
 369      ("flags" . ,(let ((f (assq :flags (nth 2 info))))
 370                    (and f (concat " " (cdr f)))))
 371      ,@(mapcar (lambda (pair)
 372                  (cons (substring (symbol-name (car pair)) 1)
 373                        (format "%S" (cdr pair))))
 374                (nth 2 info))
 375      ("name"  . ,(or (nth 4 info) "")))))
 376
 377 (defun org-babel-exp-results (info type &optional silent hash)
 378   "Evaluate and return the results of the current code block for export.
 379 Results are prepared in a manner suitable for export by Org mode.
 380 This function is called by `org-babel-exp-do-export'.  The code
 381 block will be evaluated.  Optional argument SILENT can be used to
 382 inhibit insertion of results into the buffer."
 383   (when (and (or (eq org-export-babel-evaluate t)
 384                  (and (eq type 'inline)
 385                       (eq org-export-babel-evaluate 'inline-only)))
 386              (not (and hash (equal hash (org-babel-current-result-hash)))))
 387     (let ((lang (nth 0 info))
 388           (body (if (org-babel-noweb-p (nth 2 info) :eval)
 389                     (org-babel-expand-noweb-references
 390                      info org-babel-exp-reference-buffer)
 391                   (nth 1 info)))
 392           (info (copy-sequence info))
 393           (org-babel-current-src-block-location (point-marker)))
 394       ;; Skip code blocks which we can't evaluate.
 395       (when (fboundp (intern (concat "org-babel-execute:" lang)))
 396         (org-babel-eval-wipe-error-buffer)
 397         (prog1 nil
 398           (setf (nth 1 info) body)
 399           (setf (nth 2 info)
 400                 (org-babel-exp-in-export-file lang
 401                   (org-babel-process-params
 402                    (org-babel-merge-params
 403                     (nth 2 info)
 404                     `((:results . ,(if silent "silent" "replace")))))))
 405           (pcase type
 406             (`block (org-babel-execute-src-block nil info))
 407             (`inline
 408               ;; Position the point on the inline source block
 409               ;; allowing `org-babel-insert-result' to check that the
 410               ;; block is inline.
 411               (goto-char (nth 5 info))
 412               (org-babel-execute-src-block nil info))
 413             (`lob
 414              (save-excursion
 415               (goto-char (nth 5 info))
 416               (let (org-confirm-babel-evaluate)
 417                 (org-babel-execute-src-block nil info))))))))))
 418
 419
 420 (provide 'ob-exp)
 421
 422 ;;; ob-exp.el ends here