testing/lisp/test-org.el

   1 ;;; test-org.el
   2
   3 ;; Copyright (c) ߚ David Maus
   4 ;; Authors: David Maus
   5
   6 ;; Released under the GNU General Public License version 3
   7 ;; see: http://www.gnu.org/licenses/gpl-3.0.html
   8
   9 ;;;; Comments:
  10
  11 ;; Template test file for Org-mode tests
  12
  13 ;;; Code:
  14
  15 \f
  16 ;;; Comments
  17
  18 (ert-deftest test-org/comment-dwim ()
  19   "Test `comment-dwim' behaviour in an Org buffer."
  20   ;; No region selected, no comment on current line and line not
  21   ;; empty: insert comment on line above.
  22   (should
  23    (equal "# \nComment"
  24           (org-test-with-temp-text "Comment"
  25             (progn (call-interactively 'comment-dwim)
  26                    (buffer-string)))))
  27   ;; No region selected, no comment on current line and line empty:
  28   ;; insert comment on this line.
  29   (should
  30    (equal "# \nParagraph"
  31           (org-test-with-temp-text "\nParagraph"
  32             (progn (call-interactively 'comment-dwim)
  33                    (buffer-string)))))
  34   ;; No region selected, and a comment on this line: indent it.
  35   (should
  36    (equal "* Headline\n  # Comment"
  37           (org-test-with-temp-text "* Headline\n# Comment"
  38             (progn (forward-line)
  39                    (let ((org-adapt-indentation t))
  40                      (call-interactively 'comment-dwim))
  41                    (buffer-string)))))
  42   ;; Also recognize single # at column 0 as comments.
  43   (should
  44    (equal "# Comment"
  45           (org-test-with-temp-text "# Comment"
  46             (progn (forward-line)
  47                    (call-interactively 'comment-dwim)
  48                    (buffer-string)))))
  49   ;; Region selected and only comments and blank lines within it:
  50   ;; un-comment all commented lines.
  51   (should
  52    (equal "Comment 1\n\nComment 2"
  53           (org-test-with-temp-text "# Comment 1\n\n# Comment 2"
  54             (progn
  55               (transient-mark-mode 1)
  56               (push-mark (point) t t)
  57               (goto-char (point-max))
  58               (call-interactively 'comment-dwim)
  59               (buffer-string)))))
  60   ;; Region selected without comments: comment all non-blank lines.
  61   (should
  62    (equal "# Comment 1\n\n# Comment 2"
  63           (org-test-with-temp-text "Comment 1\n\nComment 2"
  64             (progn
  65               (transient-mark-mode 1)
  66               (push-mark (point) t t)
  67               (goto-char (point-max))
  68               (call-interactively 'comment-dwim)
  69               (buffer-string)))))
  70   ;; In front of a keyword without region, insert a new comment.
  71   (should
  72    (equal "# \n#+KEYWORD: value"
  73           (org-test-with-temp-text "#+KEYWORD: value"
  74             (progn (call-interactively 'comment-dwim)
  75                    (buffer-string))))))
  76
  77
  78 \f
  79 ;;; Date Analysis
  80
  81 (ert-deftest test-org/org-read-date ()
  82   "Test `org-read-date' specifications."
  83   ;; Parse ISO date with abbreviated year and month.
  84   (should (equal "2012-03-29 16:40"
  85                  (let ((org-time-was-given t))
  86                    (org-read-date t nil "12-3-29 16:40"))))
  87   ;; Parse Europeans dates.
  88   (should (equal "2012-03-29 16:40"
  89                  (let ((org-time-was-given t))
  90                    (org-read-date t nil "29.03.2012 16:40"))))
  91   ;; Parse Europeans dates without year.
  92   (should (string-match "2[0-9]\\{3\\}-03-29 16:40"
  93                         (let ((org-time-was-given t))
  94                           (org-read-date t nil "29.03. 16:40")))))
  95
  96
  97 \f
  98 ;;; Filling
  99
 100 (ert-deftest test-org/fill-paragraph ()
 101   "Test `org-fill-paragraph' specifications."
 102   ;; At an Org table, align it.
 103   (org-test-with-temp-text "|a|"
 104     (org-fill-paragraph)
 105     (should (equal (buffer-string) "| a |\n")))
 106   ;; At a paragraph, preserve line breaks.
 107   (org-test-with-temp-text "some \\\\\nlong\ntext"
 108     (let ((fill-column 20))
 109       (org-fill-paragraph)
 110       (should (equal (buffer-string) "some \\\\\nlong text"))))
 111   ;; Correctly fill a paragraph when point is at its very end.
 112   (should
 113    (equal "A B"
 114           (org-test-with-temp-text "A\nB"
 115             (let ((fill-column 20))
 116               (goto-char (point-max))
 117               (org-fill-paragraph)
 118               (buffer-string)))))
 119   ;; Correctly fill the last paragraph of a greater element.
 120   (should
 121    (equal "#+BEGIN_CENTER\n- 012345\n  789\n#+END_CENTER"
 122           (org-test-with-temp-text "#+BEGIN_CENTER\n- 012345 789\n#+END_CENTER"
 123             (let ((fill-column 8))
 124               (forward-line)
 125               (end-of-line)
 126               (org-fill-paragraph)
 127               (buffer-string)))))
 128   ;; Correctly fill an element in a narrowed buffer.
 129   (should
 130    (equal "01234\n6"
 131           (org-test-with-temp-text "01234 6789"
 132             (let ((fill-column 5))
 133               (narrow-to-region 1 8)
 134               (org-fill-paragraph)
 135               (buffer-string)))))
 136   ;; Special case: Fill first paragraph when point is at an item or
 137   ;; a plain-list or a footnote reference.
 138   (should
 139    (equal "- A B"
 140           (org-test-with-temp-text "- A\n  B"
 141             (let ((fill-column 20))
 142               (org-fill-paragraph)
 143               (buffer-string)))))
 144   (should
 145    (equal "[fn:1] A B"
 146           (org-test-with-temp-text "[fn:1] A\nB"
 147             (let ((fill-column 20))
 148               (org-fill-paragraph)
 149               (buffer-string)))))
 150   (org-test-with-temp-text "#+BEGIN_VERSE\nSome \\\\\nlong\ntext\n#+END_VERSE"
 151     (let ((fill-column 20))
 152       (org-fill-paragraph)
 153       (should (equal (buffer-string)
 154                      "#+BEGIN_VERSE\nSome \\\\\nlong\ntext\n#+END_VERSE"))))
 155   ;; Fill contents of `comment-block' elements.
 156   (should
 157    (equal
 158     (org-test-with-temp-text "#+BEGIN_COMMENT\nSome\ntext\n#+END_COMMENT"
 159       (let ((fill-column 20))
 160         (forward-line)
 161         (org-fill-paragraph)
 162         (buffer-string)))
 163     "#+BEGIN_COMMENT\nSome text\n#+END_COMMENT"))
 164   ;; Fill `comment' elements.
 165   (should
 166    (equal "  # A B"
 167           (org-test-with-temp-text "  # A\n  # B"
 168             (let ((fill-column 20))
 169               (org-fill-paragraph)
 170               (buffer-string)))))
 171   ;; Do nothing at affiliated keywords.
 172   (org-test-with-temp-text "#+NAME: para\nSome\ntext."
 173     (let ((fill-column 20))
 174       (org-fill-paragraph)
 175       (should (equal (buffer-string) "#+NAME: para\nSome\ntext.")))))
 176
 177 (ert-deftest test-org/auto-fill-function ()
 178   "Test auto-filling features."
 179   ;; Auto fill paragraph.
 180   (should
 181    (equal "12345\n7890"
 182           (org-test-with-temp-text "12345 7890"
 183             (let ((fill-column 5))
 184               (end-of-line)
 185               (org-auto-fill-function)
 186               (buffer-string)))))
 187   ;; Auto fill first paragraph in an item.
 188   (should
 189    (equal "- 12345\n  7890"
 190           (org-test-with-temp-text "- 12345 7890"
 191             (let ((fill-column 7))
 192               (end-of-line)
 193               (org-auto-fill-function)
 194               (buffer-string)))))
 195   ;; Auto fill comments.
 196   (should
 197    (equal "  # 12345\n  # 7890"
 198           (org-test-with-temp-text "  # 12345 7890"
 199             (let ((fill-column 10))
 200               (end-of-line)
 201               (org-auto-fill-function)
 202               (buffer-string)))))
 203   ;; A hash within a line isn't a comment.
 204   (should-not
 205    (equal "12345 # 7890\n# 1"
 206           (org-test-with-temp-text "12345 # 7890 1"
 207             (let ((fill-column 12))
 208               (end-of-line)
 209               (org-auto-fill-function)
 210               (buffer-string)))))
 211   ;; Correctly interpret empty prefix.
 212   (should-not
 213    (equal "# a\n# b\nRegular\n# paragraph"
 214           (org-test-with-temp-text "# a\n# b\nRegular paragraph"
 215             (let ((fill-column 12))
 216               (end-of-line 3)
 217               (org-auto-fill-function)
 218               (buffer-string)))))
 219   ;; Comment block: auto fill contents.
 220   (should
 221    (equal "#+BEGIN_COMMENT\n12345\n7890\n#+END_COMMENT"
 222           (org-test-with-temp-text "#+BEGIN_COMMENT\n12345 7890\n#+END_COMMENT"
 223             (let ((fill-column 5))
 224               (forward-line)
 225               (end-of-line)
 226               (org-auto-fill-function)
 227               (buffer-string)))))
 228   (should
 229    (equal "#+BEGIN_COMMENT\n12345\n7890\n#+END_COMMENT"
 230           (org-test-with-temp-text "#+BEGIN_COMMENT\n12345 7890\n#+END_COMMENT"
 231             (let ((fill-column 5))
 232               (forward-line)
 233               (end-of-line)
 234               (org-auto-fill-function)
 235               (buffer-string)))))
 236   ;; Do not fill if a new item could be created.
 237   (should-not
 238    (equal "12345\n- 90"
 239           (org-test-with-temp-text "12345 - 90"
 240             (let ((fill-column 5))
 241               (end-of-line)
 242               (org-auto-fill-function)
 243               (buffer-string)))))
 244   ;; Do not fill if a line break could be introduced.
 245   (should-not
 246    (equal "123\\\\\n7890"
 247           (org-test-with-temp-text "123\\\\ 7890"
 248             (let ((fill-column 6))
 249               (end-of-line)
 250               (org-auto-fill-function)
 251               (buffer-string)))))
 252   ;; Do not fill affiliated keywords.
 253   (should-not
 254    (equal "#+ATTR_LATEX: ABC\nDEFGHIJKL"
 255           (org-test-with-temp-text "#+ATTR_LATEX: ABC DEFGHIJKL"
 256             (let ((fill-column 20))
 257               (end-of-line)
 258               (org-auto-fill-function)
 259               (buffer-string))))))
 260
 261
 262 \f
 263 ;;; Links
 264
 265 ;;;; Fuzzy Links
 266
 267 ;; Fuzzy links [[text]] encompass links to a target (<<text>>), to
 268 ;; a target keyword (aka an invisible target: #+TARGET: text), to
 269 ;; a named element (#+name: text) and to headlines (* Text).
 270
 271 (ert-deftest test-org/fuzzy-links ()
 272   "Test fuzzy links specifications."
 273   ;; 1. Fuzzy link goes in priority to a matching target.
 274   (org-test-with-temp-text
 275       "#+TARGET: Test\n#+NAME: Test\n|a|b|\n<<Test>>\n* Test\n[[Test]]"
 276     (goto-line 6)
 277     (org-open-at-point)
 278     (should (looking-at "<<Test>>")))
 279   ;; 2. Fuzzy link should then go to a matching target keyword.
 280   (org-test-with-temp-text
 281       "#+NAME: Test\n|a|b|\n#+TARGET: Test\n* Test\n[[Test]]"
 282     (goto-line 5)
 283     (org-open-at-point)
 284     (should (looking-at "#\\+TARGET: Test")))
 285   ;; 3. Then fuzzy link points to an element with a given name.
 286   (org-test-with-temp-text "Test\n#+NAME: Test\n|a|b|\n* Test\n[[Test]]"
 287     (goto-line 5)
 288     (org-open-at-point)
 289     (should (looking-at "#\\+NAME: Test")))
 290   ;; 4. A target still lead to a matching headline otherwise.
 291   (org-test-with-temp-text "* Head1\n* Head2\n*Head3\n[[Head2]]"
 292     (goto-line 4)
 293     (org-open-at-point)
 294     (should (looking-at "\\* Head2")))
 295   ;; 5. With a leading star in link, enforce heading match.
 296   (org-test-with-temp-text "#+TARGET: Test\n* Test\n<<Test>>\n[[*Test]]"
 297     (goto-line 4)
 298     (org-open-at-point)
 299     (should (looking-at "\\* Test"))))
 300
 301
 302 ;;;; Link Escaping
 303
 304 (ert-deftest test-org/org-link-escape-ascii-character ()
 305   "Escape an ascii character."
 306   (should
 307    (string=
 308     "%5B"
 309     (org-link-escape "["))))
 310
 311 (ert-deftest test-org/org-link-escape-ascii-ctrl-character ()
 312   "Escape an ascii control character."
 313   (should
 314    (string=
 315     "%09"
 316     (org-link-escape "\t"))))
 317
 318 (ert-deftest test-org/org-link-escape-multibyte-character ()
 319   "Escape an unicode multibyte character."
 320   (should
 321    (string=
 322     "%E2%82%AC"
 323     (org-link-escape "€"))))
 324
 325 (ert-deftest test-org/org-link-escape-custom-table ()
 326   "Escape string with custom character table."
 327   (should
 328    (string=
 329     "Foo%3A%42ar%0A"
 330     (org-link-escape "Foo:Bar\n" '(?\: ?\B)))))
 331
 332 (ert-deftest test-org/org-link-escape-custom-table-merge ()
 333   "Escape string with custom table merged with default table."
 334   (should
 335    (string=
 336     "%5BF%6F%6F%3A%42ar%0A%5D"
 337     (org-link-escape "[Foo:Bar\n]" '(?\: ?\B ?\o) t))))
 338
 339 (ert-deftest test-org/org-link-unescape-ascii-character ()
 340   "Unescape an ascii character."
 341   (should
 342    (string=
 343     "["
 344     (org-link-unescape "%5B"))))
 345
 346 (ert-deftest test-org/org-link-unescape-ascii-ctrl-character ()
 347   "Unescpae an ascii control character."
 348   (should
 349    (string=
 350     "\n"
 351     (org-link-unescape "%0A"))))
 352
 353 (ert-deftest test-org/org-link-unescape-multibyte-character ()
 354   "Unescape unicode multibyte character."
 355   (should
 356    (string=
 357     "€"
 358     (org-link-unescape "%E2%82%AC"))))
 359
 360 (ert-deftest test-org/org-link-unescape-ascii-extended-char ()
 361   "Unescape old style percent escaped character."
 362   (should
 363    (string=
 364     "àâçèéêîôùû"
 365         (decode-coding-string (org-link-unescape "%E0%E2%E7%E8%E9%EA%EE%F4%F9%FB") 'latin-1))))
 366
 367 (ert-deftest test-org/org-link-escape-url-with-escaped-char ()
 368   "Escape and unscape a URL that includes an escaped char.
 369 http://article.gmane.org/gmane.emacs.orgmode/21459/"
 370   (should
 371    (string=
 372     "http://some.host.com/form?&id=blah%2Bblah25"
 373     (org-link-unescape (org-link-escape "http://some.host.com/form?&id=blah%2Bblah25")))))
 374
 375
 376 \f
 377 ;;; Macros
 378
 379 (ert-deftest test-org/macro-replace-all ()
 380   "Test `org-macro-replace-all' specifications."
 381   ;; Standard test.
 382   (should
 383    (equal
 384     "#+MACRO: A B\n1 B 3"
 385     (org-test-with-temp-text "#+MACRO: A B\n1 {{{A}}} 3"
 386       (progn (org-macro-initialize-templates)
 387              (org-macro-replace-all org-macro-templates)
 388              (buffer-string)))))
 389   ;; Macro with arguments.
 390   (should
 391    (equal
 392     "#+MACRO: macro $1 $2\nsome text"
 393     (org-test-with-temp-text "#+MACRO: macro $1 $2\n{{{macro(some,text)}}}"
 394       (progn (org-macro-initialize-templates)
 395              (org-macro-replace-all org-macro-templates)
 396              (buffer-string)))))
 397   ;; Macro with "eval".
 398   (should
 399    (equal
 400     "#+MACRO: add (eval (+ $1 $2))\n3"
 401     (org-test-with-temp-text "#+MACRO: add (eval (+ $1 $2))\n{{{add(1,2)}}}"
 402       (progn (org-macro-initialize-templates)
 403              (org-macro-replace-all org-macro-templates)
 404              (buffer-string)))))
 405   ;; Nested macros.
 406   (should
 407    (equal
 408     "#+MACRO: in inner\n#+MACRO: out {{{in}}} outer\ninner outer"
 409     (org-test-with-temp-text
 410         "#+MACRO: in inner\n#+MACRO: out {{{in}}} outer\n{{{out}}}"
 411       (progn (org-macro-initialize-templates)
 412              (org-macro-replace-all org-macro-templates)
 413              (buffer-string)))))
 414   ;; Error out when macro expansion is circular.
 415   (should-error
 416    (org-test-with-temp-text
 417        "#+MACRO: mac1 {{{mac2}}}\n#+MACRO: mac2 {{{mac1}}}\n{{{mac1}}}"
 418      (org-macro-initialize-templates)
 419      (org-macro-replace-all org-macro-templates))))
 420
 421
 422 \f
 423 ;;; Node Properties
 424
 425 (ert-deftest test-org/accumulated-properties-in-drawers ()
 426   "Ensure properties accumulate in subtree drawers."
 427   (org-test-at-id "75282ba2-f77a-4309-a970-e87c149fe125"
 428     (org-babel-next-src-block)
 429     (should (equal '(2 1) (org-babel-execute-src-block)))))
 430
 431
 432 \f
 433 ;;; Mark Region
 434
 435 (ert-deftest test-org/mark-subtree ()
 436   "Test `org-mark-subtree' specifications."
 437   ;; Error when point is before first headline.
 438   (should-error
 439    (org-test-with-temp-text "Paragraph\n* Headline\nBody"
 440      (progn (transient-mark-mode 1)
 441             (org-mark-subtree))))
 442   ;; Without argument, mark current subtree.
 443   (should
 444    (equal
 445     '(12 32)
 446     (org-test-with-temp-text "* Headline\n** Sub-headline\nBody"
 447       (progn (transient-mark-mode 1)
 448              (forward-line 2)
 449              (org-mark-subtree)
 450              (list (region-beginning) (region-end))))))
 451   ;; With an argument, move ARG up.
 452   (should
 453    (equal
 454     '(1 32)
 455     (org-test-with-temp-text "* Headline\n** Sub-headline\nBody"
 456       (progn (transient-mark-mode 1)
 457              (forward-line 2)
 458              (org-mark-subtree 1)
 459              (list (region-beginning) (region-end))))))
 460   ;; Do not get fooled by inlinetasks.
 461   (when (featurep 'org-inlinetask)
 462     (should
 463      (= 1
 464         (org-test-with-temp-text "* Headline\n*************** Task\nContents"
 465           (progn (transient-mark-mode 1)
 466                  (forward-line 1)
 467                  (let ((org-inlinetask-min-level 15)) (org-mark-subtree))
 468                  (region-beginning)))))))
 469
 470
 471  \f
 472 ;;; Navigation
 473
 474 (ert-deftest test-org/end-of-line ()
 475   "Test `org-end-of-line' specifications."
 476   ;; Standard test.
 477   (should
 478    (org-test-with-temp-text "Some text\nSome other text"
 479      (progn (org-end-of-line) (eolp))))
 480   ;; At an headline with special movement.
 481   (should
 482    (org-test-with-temp-text "* Headline :tag:"
 483      (let ((org-special-ctrl-a/e t))
 484        (and (progn (org-end-of-line) (looking-at " :tag:"))
 485             (progn (org-end-of-line) (eolp))
 486             (progn (org-end-of-line) (looking-at " :tag:"))))))
 487   ;; At an headline without special movement.
 488   (should
 489    (org-test-with-temp-text "* Headline :tag:"
 490      (let ((org-special-ctrl-a/e nil))
 491        (and (progn (org-end-of-line) (eolp))
 492             (progn (org-end-of-line) (eolp))))))
 493   ;; At an headline, with reversed movement.
 494   (should
 495    (org-test-with-temp-text "* Headline :tag:"
 496      (let ((org-special-ctrl-a/e 'reversed)
 497            (this-command last-command))
 498        (and (progn (org-end-of-line) (eolp))
 499             (progn (org-end-of-line) (looking-at " :tag:"))))))
 500   ;; At a block without hidden contents.
 501   (should
 502    (org-test-with-temp-text "#+BEGIN_CENTER\nContents\n#+END_CENTER"
 503      (progn (org-end-of-line) (eolp))))
 504   ;; At a block with hidden contents.
 505   (should-not
 506    (org-test-with-temp-text "#+BEGIN_CENTER\nContents\n#+END_CENTER"
 507      (progn (org-hide-block-toggle)
 508             (org-end-of-line)
 509             (eobp)))))
 510
 511 (ert-deftest test-org/forward-element ()
 512   "Test `org-forward-element' specifications."
 513   ;; 1. At EOB: should error.
 514   (org-test-with-temp-text "Some text\n"
 515     (goto-char (point-max))
 516     (should-error (org-forward-element)))
 517   ;; 2. Standard move: expected to ignore blank lines.
 518   (org-test-with-temp-text "First paragraph.\n\n\nSecond paragraph."
 519     (org-forward-element)
 520     (should (looking-at "Second paragraph.")))
 521   ;; 3. Headline tests.
 522   (org-test-with-temp-text "
 523 * Head 1
 524 ** Head 1.1
 525 *** Head 1.1.1
 526 ** Head 1.2"
 527     ;; 3.1. At an headline beginning: move to next headline at the
 528     ;;      same level.
 529     (goto-line 3)
 530     (org-forward-element)
 531     (should (looking-at "** Head 1.2"))
 532     ;; 3.2. At an headline beginning: move to parent headline if no
 533     ;;      headline at the same level.
 534     (goto-line 3)
 535     (org-forward-element)
 536     (should (looking-at "** Head 1.2")))
 537   ;; 4. Greater element tests.
 538   (org-test-with-temp-text
 539       "#+BEGIN_CENTER\nInside.\n#+END_CENTER\n\nOutside."
 540     ;; 4.1. At a greater element: expected to skip contents.
 541     (org-forward-element)
 542     (should (looking-at "Outside."))
 543     ;; 4.2. At the end of greater element contents: expected to skip
 544     ;;      to the end of the greater element.
 545     (goto-line 2)
 546     (org-forward-element)
 547     (should (looking-at "Outside.")))
 548   ;; 5. List tests.
 549   (org-test-with-temp-text "
 550 - item1
 551
 552   - sub1
 553
 554   - sub2
 555
 556   - sub3
 557
 558   Inner paragraph.
 559
 560 - item2
 561
 562 Outside."
 563     ;; 5.1. At list top point: expected to move to the element after
 564     ;;      the list.
 565     (goto-line 2)
 566     (org-forward-element)
 567     (should (looking-at "Outside."))
 568     ;; 5.2. Special case: at the first line of a sub-list, but not at
 569     ;;      beginning of line, move to next item.
 570     (goto-line 2)
 571     (forward-char)
 572     (org-forward-element)
 573     (should (looking-at "- item2"))
 574     (goto-line 4)
 575     (forward-char)
 576     (org-forward-element)
 577     (should (looking-at "  - sub2"))
 578     ;; 5.3 At sub-list beginning: expected to move after the sub-list.
 579     (goto-line 4)
 580     (org-forward-element)
 581     (should (looking-at "  Inner paragraph."))
 582     ;; 5.4. At sub-list end: expected to move outside the sub-list.
 583     (goto-line 8)
 584     (org-forward-element)
 585     (should (looking-at "  Inner paragraph."))
 586     ;; 5.5. At an item: expected to move to next item, if any.
 587     (goto-line 6)
 588     (org-forward-element)
 589     (should (looking-at "  - sub3"))))
 590
 591 (ert-deftest test-org/backward-element ()
 592   "Test `org-backward-element' specifications."
 593   ;; 1. Should error at BOB.
 594   (org-test-with-temp-text "    \nParagraph."
 595     (should-error (org-backward-element)))
 596   ;; 2. Should move at BOB when called on the first element in buffer.
 597   (should
 598    (org-test-with-temp-text "\n#+TITLE: test"
 599      (progn (forward-line)
 600             (org-backward-element)
 601             (bobp))))
 602   ;; 3. Not at the beginning of an element: move at its beginning.
 603   (org-test-with-temp-text "Paragraph1.\n\nParagraph2."
 604     (goto-line 3)
 605     (end-of-line)
 606     (org-backward-element)
 607     (should (looking-at "Paragraph2.")))
 608   ;; 4. Headline tests.
 609   (org-test-with-temp-text "
 610 * Head 1
 611 ** Head 1.1
 612 *** Head 1.1.1
 613 ** Head 1.2"
 614     ;; 4.1. At an headline beginning: move to previous headline at the
 615     ;;      same level.
 616     (goto-line 5)
 617     (org-backward-element)
 618     (should (looking-at "** Head 1.1"))
 619     ;; 4.2. At an headline beginning: move to parent headline if no
 620     ;;      headline at the same level.
 621     (goto-line 3)
 622     (org-backward-element)
 623     (should (looking-at "* Head 1"))
 624     ;; 4.3. At the first top-level headline: should error.
 625     (goto-line 2)
 626     (should-error (org-backward-element)))
 627   ;; 5. At beginning of first element inside a greater element:
 628   ;;    expected to move to greater element's beginning.
 629   (org-test-with-temp-text "Before.\n#+BEGIN_CENTER\nInside.\n#+END_CENTER"
 630     (goto-line 3)
 631     (org-backward-element)
 632     (should (looking-at "#\\+BEGIN_CENTER")))
 633   ;; 6. At the beginning of the first element in a section: should
 634   ;;    move back to headline, if any.
 635   (should
 636    (org-test-with-temp-text "#+TITLE: test\n* Headline\n\nParagraph"
 637      (progn (goto-char (point-max))
 638             (beginning-of-line)
 639             (org-backward-element)
 640             (org-at-heading-p))))
 641   ;; 7. List tests.
 642   (org-test-with-temp-text "
 643 - item1
 644
 645   - sub1
 646
 647   - sub2
 648
 649   - sub3
 650
 651   Inner paragraph.
 652
 653 - item2
 654
 655
 656 Outside."
 657     ;; 7.1. At beginning of sub-list: expected to move to the
 658     ;;      paragraph before it.
 659     (goto-line 4)
 660     (org-backward-element)
 661     (should (looking-at "item1"))
 662     ;; 7.2. At an item in a list: expected to move at previous item.
 663     (goto-line 8)
 664     (org-backward-element)
 665     (should (looking-at "  - sub2"))
 666     (goto-line 12)
 667     (org-backward-element)
 668     (should (looking-at "- item1"))
 669     ;; 7.3. At end of list/sub-list: expected to move to list/sub-list
 670     ;;      beginning.
 671     (goto-line 10)
 672     (org-backward-element)
 673     (should (looking-at "  - sub1"))
 674     (goto-line 15)
 675     (org-backward-element)
 676     (should (looking-at "- item1"))
 677     ;; 7.4. At blank-lines before list end: expected to move to top
 678     ;; item.
 679     (goto-line 14)
 680     (org-backward-element)
 681     (should (looking-at "- item1"))))
 682
 683 (ert-deftest test-org/up-element ()
 684   "Test `org-up-element' specifications."
 685   ;; 1. At BOB or with no surrounding element: should error.
 686   (org-test-with-temp-text "Paragraph."
 687     (should-error (org-up-element)))
 688   (org-test-with-temp-text "* Head1\n* Head2"
 689     (goto-line 2)
 690     (should-error (org-up-element)))
 691   (org-test-with-temp-text "Paragraph1.\n\nParagraph2."
 692     (goto-line 3)
 693     (should-error (org-up-element)))
 694   ;; 2. At an headline: move to parent headline.
 695   (org-test-with-temp-text "* Head1\n** Sub-Head1\n** Sub-Head2"
 696     (goto-line 3)
 697     (org-up-element)
 698     (should (looking-at "\\* Head1")))
 699   ;; 3. Inside a greater element: move to greater element beginning.
 700   (org-test-with-temp-text
 701       "Before.\n#+BEGIN_CENTER\nParagraph1\nParagraph2\n#+END_CENTER\n"
 702     (goto-line 3)
 703     (org-up-element)
 704     (should (looking-at "#\\+BEGIN_CENTER")))
 705   ;; 4. List tests.
 706   (org-test-with-temp-text "* Top
 707 - item1
 708
 709   - sub1
 710
 711   - sub2
 712
 713     Paragraph within sub2.
 714
 715 - item2"
 716     ;; 4.1. Within an item: move to the item beginning.
 717     (goto-line 8)
 718     (org-up-element)
 719     (should (looking-at "  - sub2"))
 720     ;; 4.2. At an item in a sub-list: move to parent item.
 721     (goto-line 4)
 722     (org-up-element)
 723     (should (looking-at "- item1"))
 724     ;; 4.3. At an item in top list: move to beginning of whole list.
 725     (goto-line 10)
 726     (org-up-element)
 727     (should (looking-at "- item1"))
 728     ;; 4.4. Special case.  At very top point: should move to parent of
 729     ;;      list.
 730     (goto-line 2)
 731     (org-up-element)
 732     (should (looking-at "\\* Top"))))
 733
 734 (ert-deftest test-org/down-element ()
 735   "Test `org-down-element' specifications."
 736   ;; Error when the element hasn't got a recursive type.
 737   (org-test-with-temp-text "Paragraph."
 738     (should-error (org-down-element)))
 739   ;; Error when the element has no contents
 740   (org-test-with-temp-text "* Headline"
 741     (should-error (org-down-element)))
 742   ;; When at a plain-list, move to first item.
 743   (org-test-with-temp-text "- Item 1\n  - Item 1.1\n  - Item 2.2"
 744     (goto-line 2)
 745     (org-down-element)
 746     (should (looking-at " - Item 1.1")))
 747   (org-test-with-temp-text "#+NAME: list\n- Item 1"
 748     (org-down-element)
 749     (should (looking-at " Item 1")))
 750   ;; When at a table, move to first row
 751   (org-test-with-temp-text "#+NAME: table\n| a | b |"
 752     (org-down-element)
 753     (should (looking-at " a | b |")))
 754   ;; Otherwise, move inside the greater element.
 755   (org-test-with-temp-text "#+BEGIN_CENTER\nParagraph.\n#+END_CENTER"
 756     (org-down-element)
 757     (should (looking-at "Paragraph"))))
 758
 759 (ert-deftest test-org/drag-element-backward ()
 760   "Test `org-drag-element-backward' specifications."
 761   ;; 1. Error when trying to move first element of buffer.
 762   (org-test-with-temp-text "Paragraph 1.\n\nParagraph 2."
 763     (should-error (org-drag-element-backward)))
 764   ;; 2. Error when trying to swap nested elements.
 765   (org-test-with-temp-text "#+BEGIN_CENTER\nTest.\n#+END_CENTER"
 766     (forward-line)
 767     (should-error (org-drag-element-backward)))
 768   ;; 3. Error when trying to swap an headline element and
 769   ;;    a non-headline element.
 770   (org-test-with-temp-text "Test.\n* Head 1"
 771     (forward-line)
 772     (should-error (org-drag-element-backward)))
 773   ;; 4. Otherwise, swap elements, preserving column and blank lines
 774   ;;    between elements.
 775   (org-test-with-temp-text "Para1\n\n\nParagraph 2\n\nPara3"
 776     (search-forward "graph")
 777     (org-drag-element-backward)
 778     (should (equal (buffer-string) "Paragraph 2\n\n\nPara1\n\nPara3"))
 779     (should (looking-at " 2")))
 780   ;; 5. Preserve visibility of elements and their contents.
 781   (org-test-with-temp-text "
 782 #+BEGIN_CENTER
 783 Text.
 784 #+END_CENTER
 785 - item 1
 786   #+BEGIN_QUOTE
 787   Text.
 788   #+END_QUOTE"
 789     (while (search-forward "BEGIN_" nil t) (org-cycle))
 790     (search-backward "- item 1")
 791     (org-drag-element-backward)
 792     (should
 793      (equal
 794       '((63 . 82) (26 . 48))
 795       (mapcar (lambda (ov) (cons (overlay-start ov) (overlay-end ov)))
 796               (overlays-in (point-min) (point-max)))))))
 797
 798 (ert-deftest test-org/drag-element-forward ()
 799   "Test `org-drag-element-forward' specifications."
 800   ;; 1. Error when trying to move first element of buffer.
 801   (org-test-with-temp-text "Paragraph 1.\n\nParagraph 2."
 802     (goto-line 3)
 803     (should-error (org-drag-element-forward)))
 804   ;; 2. Error when trying to swap nested elements.
 805   (org-test-with-temp-text "#+BEGIN_CENTER\nTest.\n#+END_CENTER"
 806     (forward-line)
 807     (should-error (org-drag-element-forward)))
 808   ;; 3. Error when trying to swap a non-headline element and an
 809   ;;    headline.
 810   (org-test-with-temp-text "Test.\n* Head 1"
 811     (should-error (org-drag-element-forward)))
 812   ;; 4. Otherwise, swap elements, preserving column and blank lines
 813   ;;    between elements.
 814   (org-test-with-temp-text "Paragraph 1\n\n\nPara2\n\nPara3"
 815     (search-forward "graph")
 816     (org-drag-element-forward)
 817     (should (equal (buffer-string) "Para2\n\n\nParagraph 1\n\nPara3"))
 818     (should (looking-at " 1")))
 819   ;; 5. Preserve visibility of elements and their contents.
 820   (org-test-with-temp-text "
 821 #+BEGIN_CENTER
 822 Text.
 823 #+END_CENTER
 824 - item 1
 825   #+BEGIN_QUOTE
 826   Text.
 827   #+END_QUOTE"
 828     (while (search-forward "BEGIN_" nil t) (org-cycle))
 829     (search-backward "#+BEGIN_CENTER")
 830     (org-drag-element-forward)
 831     (should
 832      (equal
 833       '((63 . 82) (26 . 48))
 834       (mapcar (lambda (ov) (cons (overlay-start ov) (overlay-end ov)))
 835               (overlays-in (point-min) (point-max)))))))
 836
 837
 838 \f
 839 ;;; Targets and Radio Targets
 840
 841 (ert-deftest test-org/all-targets ()
 842   "Test `org-all-targets' specifications."
 843   ;; Without an argument.
 844   (should
 845    (equal '("radio-target" "target")
 846           (org-test-with-temp-text "<<target>> <<<radio-target>>>\n: <<verb>>"
 847             (org-all-targets))))
 848   ;; With argument.
 849   (should
 850    (equal '("radio-target")
 851           (org-test-with-temp-text "<<target>> <<<radio-target>>>"
 852             (org-all-targets t)))))
 853
 854
 855 (provide 'test-org)
 856
 857 ;;; test-org.el ends here