lisp/org-clock.el

   1 ;;; org-clock.el --- The time clocking code for Org-mode
   2
   3 ;; Copyright (C) 2004, 2005, 2006, 2007, 2008, 2009
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   7 ;; Keywords: outlines, hypermedia, calendar, wp
   8 ;; Homepage: http://orgmode.org
   9 ;; Version: 6.28trans
  10 ;;
  11 ;; This file is part of GNU Emacs.
  12 ;;
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  26 ;;
  27 ;;; Commentary:
  28
  29 ;; This file contains the time clocking code for Org-mode
  30
  31 (require 'org)
  32 (eval-when-compile
  33   (require 'cl)
  34   (require 'calendar))
  35
  36 (declare-function calendar-absolute-from-iso    "cal-iso"    (&optional date))
  37 (defvar org-time-stamp-formats)
  38
  39 (defgroup org-clock nil
  40   "Options concerning clocking working time in Org-mode."
  41   :tag "Org Clock"
  42   :group 'org-progress)
  43
  44 (defcustom org-clock-into-drawer org-log-into-drawer
  45   "Should clocking info be wrapped into a drawer?
  46 When t, clocking info will always be inserted into a :LOGBOOK: drawer.
  47 If necessary, the drawer will be created.
  48 When nil, the drawer will not be created, but used when present.
  49 When an integer and the number of clocking entries in an item
  50 reaches or exceeds this number, a drawer will be created.
  51 When a string, it names the drawer to be used.
  52
  53 The default for this variable is the value of `org-log-into-drawer',
  54 which see."
  55   :group 'org-todo
  56   :group 'org-clock
  57   :type '(choice
  58           (const :tag "Always" t)
  59           (const :tag "Only when drawer exists" nil)
  60           (integer :tag "When at least N clock entries")
  61           (const :tag "Into LOGBOOK drawer" "LOGBOOK")
  62           (string :tag "Into Drawer named...")))
  63
  64 (defcustom org-clock-out-when-done t
  65   "When non-nil, clock will be stopped when the clocked entry is marked DONE.
  66 A nil value means, clock will keep running until stopped explicitly with
  67 `C-c C-x C-o', or until the clock is started in a different item."
  68   :group 'org-clock
  69   :type 'boolean)
  70
  71 (defcustom org-clock-out-remove-zero-time-clocks nil
  72   "Non-nil means, remove the clock line when the resulting time is zero."
  73   :group 'org-clock
  74   :type 'boolean)
  75
  76 (defcustom org-clock-in-switch-to-state nil
  77   "Set task to a special todo state while clocking it.
  78 The value should be the state to which the entry should be
  79 switched. If the value is a function, it must take one
  80 parameter (the current TODO state of the item) and return the
  81 state to switch it to."
  82   :group 'org-clock
  83   :group 'org-todo
  84   :type '(choice
  85           (const :tag "Don't force a state" nil)
  86           (string :tag "State")
  87           (symbol :tag "Function")))
  88
  89 (defcustom org-clock-out-switch-to-state nil
  90   "Set task to a special todo state after clocking out.
  91 The value should be the state to which the entry should be
  92 switched. If the value is a function, it must take one
  93 parameter (the current TODO state of the item) and return the
  94 state to switch it to."
  95   :group 'org-clock
  96   :group 'org-todo
  97   :type '(choice
  98           (const :tag "Don't force a state" nil)
  99           (string :tag "State")
 100           (symbol :tag "Function")))
 101
 102 (defcustom org-clock-history-length 5
 103   "Number of clock tasks to remember in history."
 104   :group 'org-clock
 105   :type 'integer)
 106
 107 (defcustom org-clock-goto-may-find-recent-task t
 108   "Non-nil means, `org-clock-goto' can go to recent task if no active clock."
 109   :group 'org-clock
 110   :type 'boolean)
 111
 112 (defcustom org-clock-heading-function nil
 113   "When non-nil, should be a function to create `org-clock-heading'.
 114 This is the string shown in the mode line when a clock is running.
 115 The function is called with point at the beginning of the headline."
 116   :group 'org-clock
 117   :type 'function)
 118
 119 (defcustom org-clock-string-limit 0
 120   "Maximum length of clock strings in the modeline. 0 means no limit."
 121   :group 'org-clock
 122   :type 'integer)
 123
 124 (defcustom org-clock-in-resume nil
 125   "If non-nil, resume clock when clocking into task with open clock.
 126 When clocking into a task with a clock entry which has not been closed,
 127 the clock can be resumed from that point."
 128   :group 'org-clock
 129   :type 'boolean)
 130
 131 (defcustom org-clock-persist nil
 132   "When non-nil, save the running clock when emacs is closed.
 133 The clock is resumed when emacs restarts.
 134 When this is t, both the running clock, and the entire clock
 135 history are saved.  When this is the symbol `clock', only the
 136 running clock is saved.
 137
 138 When Emacs restarts with saved clock information, the file containing the
 139 running clock as well as all files mentioned in the clock history will
 140 be visited.
 141 All this depends on running `org-clock-persistence-insinuate' in .emacs"
 142   :group 'org-clock
 143   :type '(choice
 144           (const :tag "Just the running clock" clock)
 145           (const :tag "Clock and history" t)
 146           (const :tag "No persistence" nil)))
 147
 148 (defcustom org-clock-persist-file (convert-standard-filename
 149                                    "~/.emacs.d/org-clock-save.el")
 150   "File to save clock data to."
 151   :group 'org-clock
 152   :type 'string)
 153
 154 (defcustom org-clock-persist-query-save nil
 155   "When non-nil, ask before saving the current clock on exit."
 156   :group 'org-clock
 157   :type 'boolean)
 158
 159 (defcustom org-clock-persist-query-resume t
 160   "When non-nil, ask before resuming any stored clock during load."
 161   :group 'org-clock
 162   :type 'boolean)
 163
 164 (defcustom org-clock-sound nil
 165   "Sound that will used for notifications.
 166 Possible values:
 167
 168 nil        no sound played.
 169 t          standard Emacs beep
 170 file name  play this sound file.  If not possible, fall back to beep"
 171   :group 'org-clock
 172   :type '(choice
 173           (const :tag "No sound" nil)
 174           (const :tag "Standard beep" t)
 175           (file :tag "Play sound file")))
 176
 177 (defcustom org-clock-modeline-total 'auto
 178   "Default setting for the time included for the modeline clock.
 179 This can be overruled locally using the CLOCK_MODELINE_TOTAL property.
 180 Allowed values are:
 181
 182 current  Only the time in the current instance of the clock
 183 today    All time clocked inot this task today
 184 repeat   All time clocked into this task since last repeat
 185 all      All time ever recorded for this task
 186 auto     Automtically, either `all', or `repeat' for repeating tasks"
 187   :group 'org-clock
 188   :type '(choice
 189           (const :tag "Current clock" current)
 190           (const :tag "Today's task time" today)
 191           (const :tag "Since last repeat" repeat)
 192           (const :tag "All task time" all)
 193           (const :tag "Automatically, `all' or since `repeat'" auto)))
 194
 195 (defcustom org-show-notification-handler nil
 196   "Function or program to send notification with.
 197 The function or program will be called with the notification
 198 string as argument."
 199   :group 'org-clock
 200   :type '(choice
 201           (string :tag "Program")
 202           (function :tag "Function")))
 203
 204 (defvar org-clock-in-prepare-hook nil
 205   "Hook run when preparing the clock.
 206 This hook is run before anything happens to the task that
 207 you want to clock in.  For example, you can use this hook
 208 to add an effort property.")
 209 (defvar org-clock-in-hook nil
 210   "Hook run when starting the clock.")
 211 (defvar org-clock-out-hook nil
 212   "Hook run when stopping the current clock.")
 213
 214 (defvar org-clock-cancel-hook nil
 215   "Hook run when cancelling the current clock.")
 216 (defvar org-clock-goto-hook nil
 217   "Hook run when selecting the currently clocked-in entry.")
 218
 219 ;;; The clock for measuring work time.
 220
 221 (defvar org-mode-line-string "")
 222 (put 'org-mode-line-string 'risky-local-variable t)
 223
 224 (defvar org-clock-mode-line-timer nil)
 225 (defvar org-clock-heading "")
 226 (defvar org-clock-heading-for-remember "")
 227 (defvar org-clock-start-time "")
 228
 229 (defvar org-clock-effort ""
 230   "Effort estimate of the currently clocking task")
 231
 232 (defvar org-clock-total-time nil
 233   "Holds total time, spent previously on currently clocked item.
 234 This does not include the time in the currently running clock.")
 235
 236 (defvar org-clock-history nil
 237   "List of marker pointing to recent clocked tasks.")
 238
 239 (defvar org-clock-default-task (make-marker)
 240   "Marker pointing to the default task that should clock time.
 241 The clock can be made to switch to this task after clocking out
 242 of a different task.")
 243
 244 (defvar org-clock-interrupted-task (make-marker)
 245   "Marker pointing to the task that has been interrupted by the current clock.")
 246
 247 (defvar org-clock-mode-line-map (make-sparse-keymap))
 248 (define-key org-clock-mode-line-map [mode-line mouse-2] 'org-clock-goto)
 249 (define-key org-clock-mode-line-map [mode-line mouse-1] 'org-clock-menu)
 250
 251 (defun org-clock-menu ()
 252   (interactive)
 253   (popup-menu
 254    '("Clock"
 255      ["Clock out" org-clock-out t]
 256      ["Change effort estimate" org-clock-modify-effort-estimate t]
 257      ["Go to clock entry" org-clock-goto t]
 258      ["Switch task" (lambda () (interactive) (org-clock-in '(4))) :active t :keys "C-u C-c C-x C-i"])))
 259
 260 (defun org-clock-history-push (&optional pos buffer)
 261   "Push a marker to the clock history."
 262   (setq org-clock-history-length (max 1 (min 35 org-clock-history-length)))
 263   (let ((m (move-marker (make-marker) (or pos (point)) buffer)) n l)
 264     (while (setq n (member m org-clock-history))
 265       (move-marker (car n) nil))
 266     (setq org-clock-history
 267           (delq nil
 268                 (mapcar (lambda (x) (if (marker-buffer x) x nil))
 269                         org-clock-history)))
 270     (when (>= (setq l (length org-clock-history)) org-clock-history-length)
 271       (setq org-clock-history
 272             (nreverse
 273              (nthcdr (- l org-clock-history-length -1)
 274                      (nreverse org-clock-history)))))
 275     (push m org-clock-history)))
 276
 277 (defun org-clock-save-markers-for-cut-and-paste (beg end)
 278   "Save relative positions of markers in region."
 279   (org-check-and-save-marker org-clock-marker beg end)
 280   (org-check-and-save-marker org-clock-default-task beg end)
 281   (org-check-and-save-marker org-clock-interrupted-task beg end)
 282   (mapc (lambda (m) (org-check-and-save-marker m beg end))
 283         org-clock-history))
 284
 285 (defun org-clock-select-task (&optional prompt)
 286   "Select a task that recently was associated with clocking."
 287   (interactive)
 288   (let (sel-list rpl (i 0) s)
 289     (save-window-excursion
 290       (org-switch-to-buffer-other-window
 291        (get-buffer-create "*Clock Task Select*"))
 292       (erase-buffer)
 293       (when (marker-buffer org-clock-default-task)
 294         (insert (org-add-props "Default Task\n" nil 'face 'bold))
 295         (setq s (org-clock-insert-selection-line ?d org-clock-default-task))
 296         (push s sel-list))
 297       (when (marker-buffer org-clock-interrupted-task)
 298         (insert (org-add-props "The task interrupted by starting the last one\n" nil 'face 'bold))
 299         (setq s (org-clock-insert-selection-line ?i org-clock-interrupted-task))
 300         (push s sel-list))
 301       (when (marker-buffer org-clock-marker)
 302         (insert (org-add-props "Current Clocking Task\n" nil 'face 'bold))
 303         (setq s (org-clock-insert-selection-line ?c org-clock-marker))
 304         (push s sel-list))
 305       (insert (org-add-props "Recent Tasks\n" nil 'face 'bold))
 306       (mapc
 307        (lambda (m)
 308          (when (marker-buffer m)
 309            (setq i (1+ i)
 310                  s (org-clock-insert-selection-line
 311                     (if (< i 10)
 312                         (+ i ?0)
 313                       (+ i (- ?A 10))) m))
 314            (push s sel-list)))
 315        org-clock-history)
 316       (org-fit-window-to-buffer)
 317       (message (or prompt "Select task for clocking:"))
 318       (setq rpl (read-char-exclusive))
 319       (cond
 320        ((eq rpl ?q) nil)
 321        ((eq rpl ?x) nil)
 322        ((assoc rpl sel-list) (cdr (assoc rpl sel-list)))
 323        (t (error "Invalid task choice %c" rpl))))))
 324
 325 (defun org-clock-insert-selection-line (i marker)
 326   "Insert a line for the clock selection menu.
 327 And return a cons cell with the selection character integer and the marker
 328 pointing to it."
 329   (when (marker-buffer marker)
 330     (let (file cat task heading prefix)
 331       (with-current-buffer (org-base-buffer (marker-buffer marker))
 332         (save-excursion
 333           (save-restriction
 334             (widen)
 335             (goto-char marker)
 336             (setq file (buffer-file-name (marker-buffer marker))
 337                   cat (or (org-get-category)
 338                           (progn (org-refresh-category-properties)
 339                                  (org-get-category)))
 340                   heading (org-get-heading 'notags)
 341                   prefix (save-excursion
 342                            (org-back-to-heading t)
 343                            (looking-at "\\*+ ")
 344                            (match-string 0))
 345                   task (substring
 346                         (org-fontify-like-in-org-mode
 347                          (concat prefix heading)
 348                          org-odd-levels-only)
 349                         (length prefix))))))
 350       (when (and cat task)
 351         (insert (format "[%c] %-15s %s\n" i cat task))
 352         (cons i marker)))))
 353
 354 (defun org-clock-get-clock-string ()
 355   "Form a clock-string, that will be show in the mode line.
 356 If an effort estimate was defined for current item, use
 357 01:30/01:50 format (clocked/estimated).
 358 If not, show simply the clocked time like 01:50."
 359   (let* ((clocked-time (org-clock-get-clocked-time))
 360          (h (floor clocked-time 60))
 361          (m (- clocked-time (* 60 h)))
 362          )
 363     (if (and org-clock-effort)
 364         (let* ((effort-in-minutes (org-hh:mm-string-to-minutes org-clock-effort))
 365                (effort-h (floor effort-in-minutes 60))
 366                (effort-m (- effort-in-minutes (* effort-h 60)))
 367                )
 368           (format (concat "-[" org-time-clocksum-format "/" org-time-clocksum-format " (%s)]")
 369                   h m effort-h effort-m  org-clock-heading)
 370           )
 371       (format (concat "-[" org-time-clocksum-format " (%s)]")
 372               h m org-clock-heading))
 373     ))
 374
 375 (defun org-clock-update-mode-line ()
 376   (setq org-mode-line-string
 377         (org-propertize
 378          (let ((clock-string (org-clock-get-clock-string))
 379                (help-text "Org-mode clock is running.\nmouse-1 shows a menu\nmouse-2 will jump to task"))
 380            (if (and (> org-clock-string-limit 0)
 381                     (> (length clock-string) org-clock-string-limit))
 382                (org-propertize (substring clock-string 0 org-clock-string-limit)
 383                                'help-echo (concat help-text ": " org-clock-heading))
 384              (org-propertize clock-string 'help-echo help-text)))
 385          'local-map org-clock-mode-line-map
 386          'mouse-face (if (featurep 'xemacs) 'highlight 'mode-line-highlight)
 387          'face 'org-mode-line-clock))
 388   (if org-clock-effort (org-clock-notify-once-if-expired))
 389   (force-mode-line-update))
 390
 391 (defun org-clock-get-clocked-time ()
 392   "Get the clocked time for the current item in minutes.
 393 The time returned includes the the time spent on this task in
 394 previous clocking intervals."
 395   (let ((currently-clocked-time
 396          (floor (- (time-to-seconds (current-time))
 397                    (time-to-seconds org-clock-start-time)) 60)))
 398     (+ currently-clocked-time (or org-clock-total-time 0))))
 399
 400 (defun org-clock-modify-effort-estimate (&optional value)
 401  "Add to or set the effort estimate of the item currently being clocked.
 402 VALUE can be a number of minutes, or a string with forat hh:mm or mm.
 403 WHen the strig starts with a + or a - sign, the current value of the effort
 404 property will be changed by that amount.
 405 This will update the \"Effort\" property of currently clocked item, and
 406 the mode line."
 407  (interactive)
 408  (when (org-clock-is-active)
 409    (let ((current org-clock-effort) sign)
 410      (unless value
 411        ;; Prompt user for a value or a change
 412        (setq value
 413              (read-string
 414               (format "Set effort (hh:mm or mm%s): "
 415                       (if current
 416                           (format ", prefix + to add to %s" org-clock-effort)
 417                         "")))))
 418      (when (stringp value)
 419        ;; A string.  See if it is a delta
 420        (setq sign (string-to-char value))
 421        (if (member sign '(?- ?+))
 422            (setq current (org-hh:mm-string-to-minutes (substring current 1)))
 423          (setq current 0))
 424        (setq value (org-hh:mm-string-to-minutes value))
 425        (if (equal ?- sign)
 426            (setq value (- current value))
 427          (if (equal ?+ sign) (setq value (+ current value)))))
 428      (setq value (max 0 value)
 429            org-clock-effort (org-minutes-to-hh:mm-string value))
 430      (org-entry-put org-clock-marker "Effort" org-clock-effort)
 431      (org-clock-update-mode-line))))
 432
 433 (defvar org-clock-notification-was-shown nil
 434   "Shows if we have shown notification already.")
 435
 436 (defun org-clock-notify-once-if-expired ()
 437   "Show notification if we spent more time then we estimated before.
 438 Notification is shown only once."
 439   (when (marker-buffer org-clock-marker)
 440     (let ((effort-in-minutes (org-hh:mm-string-to-minutes org-clock-effort))
 441           (clocked-time (org-clock-get-clocked-time)))
 442       (if (>= clocked-time effort-in-minutes)
 443           (unless org-clock-notification-was-shown
 444             (setq org-clock-notification-was-shown t)
 445             (org-clock-play-sound)
 446             (org-show-notification
 447              (format "Task '%s' should be finished by now. (%s)"
 448                      org-clock-heading org-clock-effort)))
 449         (setq org-clock-notification-was-shown nil)))))
 450
 451 (defun org-show-notification (notification)
 452   "Show notification. Use libnotify, if available."
 453   (cond ((functionp org-show-notification-handler)
 454          (funcall org-show-notification-handler notification))
 455         ((stringp org-show-notification-handler)
 456          (start-process "emacs-timer-notification" nil
 457                         org-show-notification-handler notification))
 458         ((org-program-exists "notify-send")
 459          (start-process "emacs-timer-notification" nil
 460                         "notify-send" notification))
 461         ;; Maybe the handler will send a message, so only use message as
 462         ;; a fall back option
 463         (t (message notification))))
 464
 465 (defun org-clock-play-sound ()
 466   "Play sound as configured by `org-clock-sound'.
 467 Use alsa's aplay tool if available."
 468   (cond
 469    ((not org-clock-sound))
 470    ((eq org-clock-sound t) (beep t) (beep t))
 471    ((stringp org-clock-sound)
 472     (if (file-exists-p org-clock-sound)
 473         (if (org-program-exists "aplay")
 474             (start-process "org-clock-play-notification" nil
 475                            "aplay" org-clock-sound)
 476           (condition-case nil
 477               (play-sound-file org-clock-sound)
 478             (error (beep t) (beep t))))))))
 479
 480 (defun org-program-exists (program-name)
 481   "Checks whenever we can locate program and launch it."
 482   (if (eq system-type 'gnu/linux)
 483       (= 0 (call-process "which" nil nil nil program-name))
 484     ))
 485
 486
 487 (defvar org-clock-mode-line-entry nil
 488   "Information for the modeline about the running clock.")
 489
 490 (defun org-clock-in (&optional select)
 491   "Start the clock on the current item.
 492 If necessary, clock-out of the currently active clock.
 493 With prefix arg SELECT, offer a list of recently clocked tasks to
 494 clock into.  When SELECT is `C-u C-u', clock into the current task and mark
 495 is as the default task, a special task that will always be offered in
 496 the clocking selection, associated with the letter `d'."
 497   (interactive "P")
 498   (setq org-clock-notification-was-shown nil)
 499   (catch 'abort
 500     (let ((interrupting (marker-buffer org-clock-marker))
 501           ts selected-task target-pos (msg-extra ""))
 502       (when (equal select '(4))
 503         (setq selected-task (org-clock-select-task "Clock-in on task: "))
 504         (if selected-task
 505             (setq selected-task (copy-marker selected-task))
 506           (error "Abort")))
 507       (when interrupting
 508         ;; We are interrupting the clocking of a different task.
 509         ;; Save a marker to this task, so that we can go back.
 510         (move-marker org-clock-interrupted-task
 511                      (marker-position org-clock-marker)
 512                      (marker-buffer org-clock-marker))
 513         (org-clock-out t))
 514
 515       (when (equal select '(16))
 516         ;; Mark as default clocking task
 517         (org-clock-mark-default-task))
 518
 519       (setq target-pos (point))  ;; we want to clock in at this location
 520       (run-hooks 'org-clock-in-prepare-hook)
 521       (save-excursion
 522         (when (and selected-task (marker-buffer selected-task))
 523           ;; There is a selected task, move to the correct buffer
 524           ;; and set the new target position.
 525           (set-buffer (org-base-buffer (marker-buffer selected-task)))
 526           (setq target-pos (marker-position selected-task))
 527           (move-marker selected-task nil))
 528         (save-excursion
 529           (save-restriction
 530             (widen)
 531             (goto-char target-pos)
 532             (org-back-to-heading t)
 533             (or interrupting (move-marker org-clock-interrupted-task nil))
 534             (org-clock-history-push)
 535             (cond ((functionp org-clock-in-switch-to-state)
 536                    (looking-at org-complex-heading-regexp)
 537                    (let ((newstate (funcall org-clock-in-switch-to-state
 538                                             (match-string 2))))
 539                      (if newstate (org-todo newstate))))
 540                   ((and org-clock-in-switch-to-state
 541                         (not (looking-at (concat outline-regexp "[ \t]*"
 542                                                  org-clock-in-switch-to-state
 543                                                  "\\>"))))
 544                    (org-todo org-clock-in-switch-to-state)))
 545             (setq org-clock-heading-for-remember
 546                   (and (looking-at org-complex-heading-regexp)
 547                        (match-end 4)
 548                        (org-trim (buffer-substring (match-end 1)
 549                                                    (match-end 4)))))
 550             (setq org-clock-heading
 551                   (cond ((and org-clock-heading-function
 552                               (functionp org-clock-heading-function))
 553                          (funcall org-clock-heading-function))
 554                         ((looking-at org-complex-heading-regexp)
 555                          (match-string 4))
 556                         (t "???")))
 557             (setq org-clock-heading (org-propertize org-clock-heading
 558                                                     'face nil))
 559             (org-clock-find-position org-clock-in-resume)
 560             (cond
 561              ((and org-clock-in-resume
 562                    (looking-at
 563                     (concat "^[ \t]* " org-clock-string
 564                             " \\[\\([0-9]\\{4\\}-[0-9]\\{2\\}-[0-9]\\{2\\}"
 565                             " +\\sw+ +[012][0-9]:[0-5][0-9]\\)\\][ \t]*$")))
 566               (message "Matched %s" (match-string 1))
 567               (setq ts (concat "[" (match-string 1) "]"))
 568               (goto-char (match-end 1))
 569               (setq org-clock-start-time
 570                     (apply 'encode-time
 571                            (org-parse-time-string (match-string 1))))
 572               (setq org-clock-effort (org-get-effort))
 573               (setq org-clock-total-time (org-clock-sum-current-item
 574                                           (org-clock-get-sum-start))))
 575              ((eq org-clock-in-resume 'auto-restart)
 576               ;; called from org-clock-load during startup,
 577               ;; do not interrupt, but warn!
 578               (message "Cannot restart clock because task does not contain unfinished clock")
 579               (ding)
 580               (sit-for 2)
 581               (throw 'abort nil))
 582              (t
 583               (insert-before-markers "\n")
 584               (backward-char 1)
 585               (org-indent-line-function)
 586               (when (and (save-excursion
 587                            (end-of-line 0)
 588                            (org-in-item-p)))
 589                 (beginning-of-line 1)
 590                 (org-indent-line-to (- (org-get-indentation) 2)))
 591               (insert org-clock-string " ")
 592               (setq org-clock-effort (org-get-effort))
 593               (setq org-clock-total-time (org-clock-sum-current-item
 594                                           (org-clock-get-sum-start)))
 595               (setq org-clock-start-time (current-time))
 596               (setq ts (org-insert-time-stamp org-clock-start-time
 597                                               'with-hm 'inactive))))
 598             (move-marker org-clock-marker (point) (buffer-base-buffer))
 599             (or global-mode-string (setq global-mode-string '("")))
 600             (or (memq 'org-mode-line-string global-mode-string)
 601                 (setq global-mode-string
 602                       (append global-mode-string '(org-mode-line-string))))
 603             (org-clock-update-mode-line)
 604             (setq org-clock-mode-line-timer
 605                   (run-with-timer 60 60 'org-clock-update-mode-line))
 606             (message "Clock starts at %s - %s" ts msg-extra)
 607             (run-hooks 'org-clock-in-hook)))))))
 608
 609 (defun org-clock-mark-default-task ()
 610   "Mark current task as default task."
 611   (interactive)
 612   (save-excursion
 613     (org-back-to-heading t)
 614     (move-marker org-clock-default-task (point))))
 615
 616
 617 (defvar msg-extra)
 618 (defun org-clock-get-sum-start ()
 619   "Return the time from which clock times should be counted.
 620 This is for the currently running clock as it is displayed
 621 in the mode line.  This function looks at the properties
 622 LAST_REPEAT and in particular CLOCK_MODELINE_TOTAL and the
 623 corresponding variable `org-clock-modeline-total' and then
 624 decides which time to use."
 625   (let ((cmt (or (org-entry-get nil "CLOCK_MODELINE_TOTAL")
 626                  (symbol-name org-clock-modeline-total)))
 627         (lr (org-entry-get nil "LAST_REPEAT")))
 628     (cond
 629      ((equal cmt "current")
 630       (setq msg-extra "showing time in current clock instance")
 631       (current-time))
 632      ((equal cmt "today")
 633       (setq msg-extra "showing today's task time.")
 634       (let* ((dt (decode-time (current-time))))
 635         (setq dt (append (list 0 0 0) (nthcdr 3 dt)))
 636         (if org-extend-today-until
 637             (setf (nth 2 dt) org-extend-today-until))
 638         (apply 'encode-time dt)))
 639      ((or (equal cmt "all")
 640           (and (or (not cmt) (equal cmt "auto"))
 641                (not lr)))
 642       (setq msg-extra "showing entire task time.")
 643       nil)
 644      ((or (equal cmt "repeat")
 645           (and (or (not cmt) (equal cmt "auto"))
 646                lr))
 647       (setq msg-extra "showing task time since last repeat.")
 648       (if (not lr)
 649           nil
 650         (org-time-string-to-time lr)))
 651      (t nil))))
 652
 653 (defun org-clock-find-position (find-unclosed)
 654   "Find the location where the next clock line should be inserted.
 655 When FIND-UNCLOSED is non-nil, first check if there is an unclosed clock
 656 line and position cursor in that line."
 657   (org-back-to-heading t)
 658   (catch 'exit
 659     (let ((beg (save-excursion
 660                  (beginning-of-line 2)
 661                  (or (bolp) (newline))
 662                  (point)))
 663           (end (progn (outline-next-heading) (point)))
 664           (re (concat "^[ \t]*" org-clock-string))
 665           (cnt 0)
 666           (drawer (if (stringp org-clock-into-drawer)
 667                       org-clock-into-drawer "LOGBOOK"))
 668           first last ind-last)
 669       (goto-char beg)
 670       (when (and find-unclosed
 671                  (re-search-forward
 672                   (concat "^[ \t]* " org-clock-string
 673                           " \\[\\([0-9]\\{4\\}-[0-9]\\{2\\}-[0-9]\\{2\\}"
 674                           " +\\sw+ +[012][0-9]:[0-5][0-9]\\)\\][ \t]*$")
 675                   end t))
 676         (beginning-of-line 1)
 677         (throw 'exit t))
 678       (when (eobp) (newline) (setq end (max (point) end)))
 679       (when (re-search-forward (concat "^[ \t]*:" drawer ":") end t)
 680         ;; we seem to have a CLOCK drawer, so go there.
 681         (beginning-of-line 2)
 682         (or org-log-states-order-reversed
 683             (and (re-search-forward org-property-end-re nil t)
 684                  (goto-char (match-beginning 0))))
 685         (throw 'exit t))
 686       ;; Lets count the CLOCK lines
 687       (goto-char beg)
 688       (while (re-search-forward re end t)
 689         (setq first (or first (match-beginning 0))
 690               last (match-beginning 0)
 691               cnt (1+ cnt)))
 692       (when (and (integerp org-clock-into-drawer)
 693                  last
 694                  (>= (1+ cnt) org-clock-into-drawer))
 695         ;; Wrap current entries into a new drawer
 696         (goto-char last)
 697         (setq ind-last (org-get-indentation))
 698         (beginning-of-line 2)
 699         (if (and (>= (org-get-indentation) ind-last)
 700                  (org-at-item-p))
 701             (org-end-of-item))
 702         (insert ":END:\n")
 703         (beginning-of-line 0)
 704         (org-indent-line-to ind-last)
 705         (goto-char first)
 706         (insert ":" drawer ":\n")
 707         (beginning-of-line 0)
 708         (org-indent-line-function)
 709         (org-flag-drawer t)
 710         (beginning-of-line 2)
 711         (or org-log-states-order-reversed
 712             (and (re-search-forward org-property-end-re nil t)
 713                  (goto-char (match-beginning 0))))
 714         (throw 'exit nil))
 715
 716       (goto-char beg)
 717       (while (and (looking-at (concat "[ \t]*" org-keyword-time-regexp))
 718                   (not (equal (match-string 1) org-clock-string)))
 719         ;; Planning info, skip to after it
 720         (beginning-of-line 2)
 721         (or (bolp) (newline)))
 722       (when (or (eq org-clock-into-drawer t)
 723                 (stringp org-clock-into-drawer)
 724                 (and (integerp org-clock-into-drawer)
 725                      (< org-clock-into-drawer 2)))
 726         (insert ":" drawer ":\n:END:\n")
 727         (beginning-of-line -1)
 728         (org-indent-line-function)
 729         (org-flag-drawer t)
 730         (beginning-of-line 2)
 731         (org-indent-line-function)
 732         (beginning-of-line)
 733         (or org-log-states-order-reversed
 734             (and (re-search-forward org-property-end-re nil t)
 735                  (goto-char (match-beginning 0))))))))
 736
 737 (defun org-clock-out (&optional fail-quietly)
 738   "Stop the currently running clock.
 739 If there is no running clock, throw an error, unless FAIL-QUIETLY is set."
 740   (interactive)
 741   (catch 'exit
 742     (if (not (marker-buffer org-clock-marker))
 743         (if fail-quietly (throw 'exit t) (error "No active clock")))
 744     (let (ts te s h m remove)
 745       (save-excursion
 746         (set-buffer (marker-buffer org-clock-marker))
 747         (save-restriction
 748           (widen)
 749           (goto-char org-clock-marker)
 750           (beginning-of-line 1)
 751           (if (and (looking-at (concat "[ \t]*" org-keyword-time-regexp))
 752                    (equal (match-string 1) org-clock-string))
 753               (setq ts (match-string 2))
 754             (if fail-quietly (throw 'exit nil) (error "Clock start time is gone")))
 755           (goto-char (match-end 0))
 756           (delete-region (point) (point-at-eol))
 757           (insert "--")
 758           (setq te (org-insert-time-stamp (current-time) 'with-hm 'inactive))
 759           (setq s (- (time-to-seconds (apply 'encode-time (org-parse-time-string te)))
 760                      (time-to-seconds (apply 'encode-time (org-parse-time-string ts))))
 761                 h (floor (/ s 3600))
 762                 s (- s (* 3600 h))
 763                 m (floor (/ s 60))
 764                 s (- s (* 60 s)))
 765           (insert " => " (format "%2d:%02d" h m))
 766           (when (setq remove (and org-clock-out-remove-zero-time-clocks
 767                                   (= (+ h m) 0)))
 768             (beginning-of-line 1)
 769             (delete-region (point) (point-at-eol))
 770             (and (looking-at "\n") (> (point-max) (1+ (point)))
 771                  (delete-char 1)))
 772           (move-marker org-clock-marker nil)
 773           (when org-log-note-clock-out
 774             (org-add-log-setup 'clock-out nil nil nil nil
 775                                (concat "# Task: " (org-get-heading t) "\n\n")))
 776           (when org-clock-mode-line-timer
 777             (cancel-timer org-clock-mode-line-timer)
 778             (setq org-clock-mode-line-timer nil))
 779           (setq global-mode-string
 780                 (delq 'org-mode-line-string global-mode-string))
 781           (when org-clock-out-switch-to-state
 782             (save-excursion
 783               (org-back-to-heading t)
 784               (let ((org-inhibit-logging t))
 785                 (cond
 786                  ((functionp org-clock-out-switch-to-state)
 787                   (looking-at org-complex-heading-regexp)
 788                   (let ((newstate (funcall org-clock-out-switch-to-state
 789                                            (match-string 2))))
 790                     (if newstate (org-todo newstate))))
 791                  ((and org-clock-out-switch-to-state
 792                        (not (looking-at (concat outline-regexp "[ \t]*"
 793                                                 org-clock-out-switch-to-state
 794                                                 "\\>"))))
 795                   (org-todo org-clock-out-switch-to-state))))))
 796           (force-mode-line-update)
 797           (message (concat "Clock stopped at %s after HH:MM = " org-time-clocksum-format "%s") te h m
 798                    (if remove " => LINE REMOVED" ""))
 799           (run-hooks 'org-clock-out-hook))))))
 800
 801 (defun org-clock-cancel ()
 802   "Cancel the running clock be removing the start timestamp."
 803   (interactive)
 804   (if (not (marker-buffer org-clock-marker))
 805       (error "No active clock"))
 806   (save-excursion
 807     (set-buffer (marker-buffer org-clock-marker))
 808     (goto-char org-clock-marker)
 809     (delete-region (1- (point-at-bol)) (point-at-eol)))
 810   (setq global-mode-string
 811         (delq 'org-mode-line-string global-mode-string))
 812   (force-mode-line-update)
 813   (message "Clock canceled")
 814   (run-hooks 'org-clock-cancel-hook))
 815
 816 (defun org-clock-goto (&optional select)
 817   "Go to the currently clocked-in entry, or to the most recently clocked one.
 818 With prefix arg SELECT, offer recently clocked tasks for selection."
 819   (interactive "@P")
 820   (let* ((recent nil)
 821          (m (cond
 822              (select
 823               (or (org-clock-select-task "Select task to go to: ")
 824                   (error "No task selected")))
 825              ((marker-buffer org-clock-marker) org-clock-marker)
 826              ((and org-clock-goto-may-find-recent-task
 827                    (car org-clock-history)
 828                    (marker-buffer (car org-clock-history)))
 829               (setq recent t)
 830               (car org-clock-history))
 831              (t (error "No active or recent clock task")))))
 832     (switch-to-buffer (marker-buffer m))
 833     (if (or (< m (point-min)) (> m (point-max))) (widen))
 834     (goto-char m)
 835     (org-show-entry)
 836     (org-back-to-heading t)
 837     (org-cycle-hide-drawers 'children)
 838     (recenter)
 839     (if recent
 840         (message "No running clock, this is the most recently clocked task"))
 841     (run-hooks 'org-clock-goto-hook)))
 842
 843 (defvar org-clock-file-total-minutes nil
 844   "Holds the file total time in minutes, after a call to `org-clock-sum'.")
 845 (make-variable-buffer-local 'org-clock-file-total-minutes)
 846
 847 (defun org-clock-sum (&optional tstart tend)
 848   "Sum the times for each subtree.
 849 Puts the resulting times in minutes as a text property on each headline.
 850 TSTART and TEND can mark a time range to be considered."
 851   (interactive)
 852   (let* ((bmp (buffer-modified-p))
 853          (re (concat "^\\(\\*+\\)[ \t]\\|^[ \t]*"
 854                      org-clock-string
 855                      "[ \t]*\\(?:\\(\\[.*?\\]\\)-+\\(\\[.*?\\]\\)\\|=>[ \t]+\\([0-9]+\\):\\([0-9]+\\)\\)"))
 856          (lmax 30)
 857          (ltimes (make-vector lmax 0))
 858          (t1 0)
 859          (level 0)
 860          ts te dt
 861          time)
 862     (if (stringp tstart) (setq tstart (org-time-string-to-seconds tstart)))
 863     (if (stringp tend) (setq tend (org-time-string-to-seconds tend)))
 864     (if (consp tstart) (setq tstart (time-to-seconds tstart)))
 865     (if (consp tend) (setq tend (time-to-seconds tend)))
 866     (remove-text-properties (point-min) (point-max) '(:org-clock-minutes t))
 867     (save-excursion
 868       (goto-char (point-max))
 869       (while (re-search-backward re nil t)
 870         (cond
 871          ((match-end 2)
 872           ;; Two time stamps
 873           (setq ts (match-string 2)
 874                 te (match-string 3)
 875                 ts (time-to-seconds
 876                     (apply 'encode-time (org-parse-time-string ts)))
 877                 te (time-to-seconds
 878                     (apply 'encode-time (org-parse-time-string te)))
 879                 ts (if tstart (max ts tstart) ts)
 880                 te (if tend (min te tend) te)
 881                 dt (- te ts)
 882                 t1 (if (> dt 0) (+ t1 (floor (/ dt 60))) t1)))
 883          ((match-end 4)
 884           ;; A naked time
 885           (setq t1 (+ t1 (string-to-number (match-string 5))
 886                       (* 60 (string-to-number (match-string 4))))))
 887          (t ;; A headline
 888           (setq level (- (match-end 1) (match-beginning 1)))
 889           (when (or (> t1 0) (> (aref ltimes level) 0))
 890             (loop for l from 0 to level do
 891                   (aset ltimes l (+ (aref ltimes l) t1)))
 892             (setq t1 0 time (aref ltimes level))
 893             (loop for l from level to (1- lmax) do
 894                   (aset ltimes l 0))
 895             (goto-char (match-beginning 0))
 896             (put-text-property (point) (point-at-eol) :org-clock-minutes time)))))
 897       (setq org-clock-file-total-minutes (aref ltimes 0)))
 898     (set-buffer-modified-p bmp)))
 899
 900 (defun org-clock-sum-current-item (&optional tstart)
 901   "Returns time, clocked on current item in total"
 902   (save-excursion
 903     (save-restriction
 904       (org-narrow-to-subtree)
 905       (org-clock-sum tstart)
 906       org-clock-file-total-minutes)))
 907
 908 (defun org-clock-display (&optional total-only)
 909   "Show subtree times in the entire buffer.
 910 If TOTAL-ONLY is non-nil, only show the total time for the entire file
 911 in the echo area."
 912   (interactive)
 913   (org-clock-remove-overlays)
 914   (let (time h m p)
 915     (org-clock-sum)
 916     (unless total-only
 917       (save-excursion
 918         (goto-char (point-min))
 919         (while (or (and (equal (setq p (point)) (point-min))
 920                         (get-text-property p :org-clock-minutes))
 921                    (setq p (next-single-property-change
 922                             (point) :org-clock-minutes)))
 923           (goto-char p)
 924           (when (setq time (get-text-property p :org-clock-minutes))
 925             (org-clock-put-overlay time (funcall outline-level))))
 926         (setq h (/ org-clock-file-total-minutes 60)
 927               m (- org-clock-file-total-minutes (* 60 h)))
 928         ;; Arrange to remove the overlays upon next change.
 929         (when org-remove-highlights-with-change
 930           (org-add-hook 'before-change-functions 'org-clock-remove-overlays
 931                         nil 'local))))
 932     (message (concat "Total file time: " org-time-clocksum-format " (%d hours and %d minutes)") h m h m)))
 933
 934 (defvar org-clock-overlays nil)
 935 (make-variable-buffer-local 'org-clock-overlays)
 936
 937 (defun org-clock-put-overlay (time &optional level)
 938   "Put an overlays on the current line, displaying TIME.
 939 If LEVEL is given, prefix time with a corresponding number of stars.
 940 This creates a new overlay and stores it in `org-clock-overlays', so that it
 941 will be easy to remove."
 942   (let* ((c 60) (h (floor (/ time 60))) (m (- time (* 60 h)))
 943          (l (if level (org-get-valid-level level 0) 0))
 944          (fmt (concat "%s " org-time-clocksum-format "%s"))
 945          (off 0)
 946          ov tx)
 947     (org-move-to-column c)
 948     (unless (eolp) (skip-chars-backward "^ \t"))
 949     (skip-chars-backward " \t")
 950     (setq ov (org-make-overlay (1- (point)) (point-at-eol))
 951           tx (concat (buffer-substring (1- (point)) (point))
 952                      (make-string (+ off (max 0 (- c (current-column)))) ?.)
 953                      (org-add-props (format fmt
 954                                             (make-string l ?*) h m
 955                                             (make-string (- 16 l) ?\ ))
 956                          (list 'face 'org-clock-overlay))
 957                      ""))
 958     (if (not (featurep 'xemacs))
 959         (org-overlay-put ov 'display tx)
 960       (org-overlay-put ov 'invisible t)
 961       (org-overlay-put ov 'end-glyph (make-glyph tx)))
 962     (push ov org-clock-overlays)))
 963
 964 (defun org-clock-remove-overlays (&optional beg end noremove)
 965   "Remove the occur highlights from the buffer.
 966 BEG and END are ignored.  If NOREMOVE is nil, remove this function
 967 from the `before-change-functions' in the current buffer."
 968   (interactive)
 969   (unless org-inhibit-highlight-removal
 970     (mapc 'org-delete-overlay org-clock-overlays)
 971     (setq org-clock-overlays nil)
 972     (unless noremove
 973       (remove-hook 'before-change-functions
 974                    'org-clock-remove-overlays 'local))))
 975
 976 (defvar state) ;; dynamically scoped into this function
 977 (defun org-clock-out-if-current ()
 978   "Clock out if the current entry contains the running clock.
 979 This is used to stop the clock after a TODO entry is marked DONE,
 980 and is only done if the variable `org-clock-out-when-done' is not nil."
 981   (when (and org-clock-out-when-done
 982              (member state org-done-keywords)
 983              (equal (or (buffer-base-buffer (marker-buffer org-clock-marker))
 984                         (marker-buffer org-clock-marker))
 985                     (or (buffer-base-buffer (current-buffer))
 986                         (current-buffer)))
 987              (< (point) org-clock-marker)
 988              (> (save-excursion (outline-next-heading) (point))
 989                 org-clock-marker))
 990     ;; Clock out, but don't accept a logging message for this.
 991     (let ((org-log-note-clock-out nil))
 992       (org-clock-out))))
 993
 994 (add-hook 'org-after-todo-state-change-hook
 995           'org-clock-out-if-current)
 996
 997 ;;;###autoload
 998 (defun org-get-clocktable (&rest props)
 999   "Get a formatted clocktable with parameters according to PROPS.
1000 The table is created in a temporary buffer, fully formatted and
1001 fontified, and then returned."
1002   ;; Set the defaults
1003   (setq props (plist-put props :name "clocktable"))
1004   (unless (plist-member props :maxlevel)
1005     (setq props (plist-put props :maxlevel 2)))
1006   (unless (plist-member props :scope)
1007     (setq props (plist-put props :scope 'agenda)))
1008   (with-temp-buffer
1009     (org-mode)
1010     (org-create-dblock props)
1011     (org-update-dblock)
1012     (font-lock-fontify-buffer)
1013     (forward-line 2)
1014     (buffer-substring (point) (progn
1015                                 (re-search-forward "^#\\+END" nil t)
1016                                 (point-at-bol)))))
1017
1018 (defun org-clock-report (&optional arg)
1019   "Create a table containing a report about clocked time.
1020 If the cursor is inside an existing clocktable block, then the table
1021 will be updated.  If not, a new clocktable will be inserted.
1022 When called with a prefix argument, move to the first clock table in the
1023 buffer and update it."
1024   (interactive "P")
1025   (org-clock-remove-overlays)
1026   (when arg
1027     (org-find-dblock "clocktable")
1028     (org-show-entry))
1029   (if (org-in-clocktable-p)
1030       (goto-char (org-in-clocktable-p))
1031     (org-create-dblock (list :name "clocktable"
1032                              :maxlevel 2 :scope 'file)))
1033   (org-update-dblock))
1034
1035 (defun org-in-clocktable-p ()
1036   "Check if the cursor is in a clocktable."
1037   (let ((pos (point)) start)
1038     (save-excursion
1039       (end-of-line 1)
1040       (and (re-search-backward "^#\\+BEGIN:[ \t]+clocktable" nil t)
1041            (setq start (match-beginning 0))
1042            (re-search-forward "^#\\+END:.*" nil t)
1043            (>= (match-end 0) pos)
1044            start))))
1045
1046 (defun org-clock-special-range (key &optional time as-strings)
1047   "Return two times bordering a special time range.
1048 Key is a symbol specifying the range and can be one of `today', `yesterday',
1049 `thisweek', `lastweek', `thismonth', `lastmonth', `thisyear', `lastyear'.
1050 A week starts Monday 0:00 and ends Sunday 24:00.
1051 The range is determined relative to TIME.  TIME defaults to the current time.
1052 The return value is a cons cell with two internal times like the ones
1053 returned by `current time' or `encode-time'. if AS-STRINGS is non-nil,
1054 the returned times will be formatted strings."
1055   (if (integerp key) (setq key (intern (number-to-string key))))
1056   (let* ((tm (decode-time (or time (current-time))))
1057          (s 0) (m (nth 1 tm)) (h (nth 2 tm))
1058          (d (nth 3 tm)) (month (nth 4 tm)) (y (nth 5 tm))
1059          (dow (nth 6 tm))
1060          (skey (symbol-name key))
1061          (shift 0)
1062          s1 m1 h1 d1 month1 y1 diff ts te fm txt w date)
1063     (cond
1064      ((string-match "^[0-9]+$" skey)
1065       (setq y (string-to-number skey) m 1 d 1 key 'year))
1066      ((string-match "^\\([0-9]+\\)-\\([0-9]\\{1,2\\}\\)$" skey)
1067       (setq y (string-to-number (match-string 1 skey))
1068             month (string-to-number (match-string 2 skey))
1069             d 1 key 'month))
1070      ((string-match "^\\([0-9]+\\)-[wW]\\([0-9]\\{1,2\\}\\)$" skey)
1071       (require 'cal-iso)
1072       (setq y (string-to-number (match-string 1 skey))
1073             w (string-to-number (match-string 2 skey)))
1074       (setq date (calendar-gregorian-from-absolute
1075                   (calendar-absolute-from-iso (list w 1 y))))
1076       (setq d (nth 1 date) month (car date) y (nth 2 date)
1077             dow 1
1078             key 'week))
1079      ((string-match "^\\([0-9]+\\)-\\([0-9]\\{1,2\\}\\)-\\([0-9]\\{1,2\\}\\)$" skey)
1080       (setq y (string-to-number (match-string 1 skey))
1081             month (string-to-number (match-string 2 skey))
1082             d (string-to-number (match-string 3 skey))
1083             key 'day))
1084      ((string-match "\\([-+][0-9]+\\)$" skey)
1085       (setq shift (string-to-number (match-string 1 skey))
1086             key (intern (substring skey 0 (match-beginning 1))))))
1087     (when (= shift 0)
1088       (cond ((eq key 'yesterday) (setq key 'today shift -1))
1089             ((eq key 'lastweek)  (setq key 'week  shift -1))
1090             ((eq key 'lastmonth) (setq key 'month shift -1))
1091             ((eq key 'lastyear)  (setq key 'year  shift -1))))
1092     (cond
1093      ((memq key '(day today))
1094       (setq d (+ d shift) h 0 m 0 h1 24 m1 0))
1095      ((memq key '(week thisweek))
1096       (setq diff (+ (* -7 shift) (if (= dow 0) 6 (1- dow)))
1097             m 0 h 0 d (- d diff) d1 (+ 7 d)))
1098      ((memq key '(month thismonth))
1099       (setq d 1 h 0 m 0 d1 1 month (+ month shift) month1 (1+ month) h1 0 m1 0))
1100      ((memq key '(year thisyear))
1101       (setq m 0 h 0 d 1 month 1 y (+ y shift) y1 (1+ y)))
1102      (t (error "No such time block %s" key)))
1103     (setq ts (encode-time s m h d month y)
1104           te (encode-time (or s1 s) (or m1 m) (or h1 h)
1105                           (or d1 d) (or month1 month) (or y1 y)))
1106     (setq fm (cdr org-time-stamp-formats))
1107     (cond
1108      ((memq key '(day today))
1109       (setq txt (format-time-string "%A, %B %d, %Y" ts)))
1110      ((memq key '(week thisweek))
1111       (setq txt (format-time-string "week %G-W%V" ts)))
1112      ((memq key '(month thismonth))
1113       (setq txt (format-time-string "%B %Y" ts)))
1114      ((memq key '(year thisyear))
1115       (setq txt (format-time-string "the year %Y" ts))))
1116     (if as-strings
1117         (list (format-time-string fm ts) (format-time-string fm te) txt)
1118       (list ts te txt))))
1119
1120 (defun org-clocktable-shift (dir n)
1121   "Try to shift the :block date of the clocktable at point.
1122 Point must be in the #+BEGIN: line of a clocktable, or this function
1123 will throw an error.
1124 DIR is a direction, a symbol `left', `right', `up', or `down'.
1125 Both `left' and `down' shift the block toward the past, `up' and `right'
1126 push it toward the future.
1127 N is the number of shift steps to take.  The size of the step depends on
1128 the currently selected interval size."
1129   (setq n (prefix-numeric-value n))
1130   (and (memq dir '(left down)) (setq n (- n)))
1131   (save-excursion
1132     (goto-char (point-at-bol))
1133     (if (not (looking-at "#\\+BEGIN: clocktable\\>.*?:block[ \t]+\\(\\S-+\\)"))
1134         (error "Line needs a :block definition before this command works")
1135       (let* ((b (match-beginning 1)) (e (match-end 1))
1136              (s (match-string 1))
1137              block shift ins y mw d date wp m)
1138         (cond
1139          ((equal s "yesterday") (setq s "today-1"))
1140          ((equal s "lastweek") (setq s "thisweek-1"))
1141          ((equal s "lastmonth") (setq s "thismonth-1"))
1142          ((equal s "lastyear") (setq s "thisyear-1")))
1143         (cond
1144          ((string-match "^\\(today\\|thisweek\\|thismonth\\|thisyear\\)\\([-+][0-9]+\\)?$" s)
1145           (setq block (match-string 1 s)
1146                 shift (if (match-end 2)
1147                           (string-to-number (match-string 2 s))
1148                         0))
1149           (setq shift (+ shift n))
1150           (setq ins (if (= shift 0) block (format "%s%+d" block shift))))
1151          ((string-match "\\([0-9]+\\)\\(-\\([wW]?\\)\\([0-9]\\{1,2\\}\\)\\(-\\([0-9]\\{1,2\\}\\)\\)?\\)?" s)
1152           ;;               1        1  2   3       3  4                4  5   6                6  5   2
1153           (setq y (string-to-number (match-string 1 s))
1154                 wp (and (match-end 3) (match-string 3 s))
1155                 mw (and (match-end 4) (string-to-number (match-string 4 s)))
1156                 d (and (match-end 6) (string-to-number (match-string 6 s))))
1157           (cond
1158            (d (setq ins (format-time-string
1159                          "%Y-%m-%d"
1160                          (encode-time 0 0 0 (+ d n) m y))))
1161            ((and wp mw (> (length wp) 0))
1162             (require 'cal-iso)
1163             (setq date (calendar-gregorian-from-absolute (calendar-absolute-from-iso (list (+ mw n) 1 y))))
1164             (setq ins (format-time-string
1165                        "%G-W%V"
1166                        (encode-time 0 0 0 (nth 1 date) (car date) (nth 2 date)))))
1167            (mw
1168             (setq ins (format-time-string
1169                        "%Y-%m"
1170                        (encode-time 0 0 0 1 (+ mw n) y))))
1171            (y
1172             (setq ins (number-to-string (+ y n))))))
1173          (t (error "Cannot shift clocktable block")))
1174         (when ins
1175           (goto-char b)
1176           (insert ins)
1177           (delete-region (point) (+ (point) (- e b)))
1178           (beginning-of-line 1)
1179           (org-update-dblock)
1180           t)))))
1181
1182 (defun org-dblock-write:clocktable (params)
1183   "Write the standard clocktable."
1184   (catch 'exit
1185     (let* ((hlchars '((1 . "*") (2 . "/")))
1186            (ins (make-marker))
1187            (total-time nil)
1188            (scope (plist-get params :scope))
1189            (tostring (plist-get  params :tostring))
1190            (multifile (plist-get  params :multifile))
1191            (header (plist-get  params :header))
1192            (maxlevel (or (plist-get params :maxlevel) 3))
1193            (step (plist-get params :step))
1194            (emph (plist-get params :emphasize))
1195            (timestamp (plist-get params :timestamp))
1196            (ts (plist-get params :tstart))
1197            (te (plist-get params :tend))
1198            (block (plist-get params :block))
1199            (link (plist-get params :link))
1200            ipos time p level hlc hdl tsp props content recalc formula pcol
1201            cc beg end pos tbl tbl1 range-text rm-file-column scope-is-list st)
1202       (setq org-clock-file-total-minutes nil)
1203       (when step
1204         (unless (or block (and ts te))
1205           (error "Clocktable `:step' can only be used with `:block' or `:tstart,:end'"))
1206         (org-clocktable-steps params)
1207         (throw 'exit nil))
1208       (when block
1209         (setq cc (org-clock-special-range block nil t)
1210               ts (car cc) te (nth 1 cc) range-text (nth 2 cc)))
1211       (when (integerp ts) (setq ts (calendar-gregorian-from-absolute ts)))
1212       (when (integerp te) (setq te (calendar-gregorian-from-absolute te)))
1213       (when (and ts (listp ts))
1214         (setq ts (format "%4d-%02d-%02d" (nth 2 ts) (car ts) (nth 1 ts))))
1215       (when (and te (listp te))
1216         (setq te (format "%4d-%02d-%02d" (nth 2 te) (car te) (nth 1 te))))
1217       ;; Now the times are strings we can parse.
1218       (if ts (setq ts (time-to-seconds
1219                        (apply 'encode-time (org-parse-time-string ts)))))
1220       (if te (setq te (time-to-seconds
1221                        (apply 'encode-time (org-parse-time-string te)))))
1222       (move-marker ins (point))
1223       (setq ipos (point))
1224
1225       ;; Get the right scope
1226       (setq pos (point))
1227       (cond
1228        ((and scope (listp scope) (symbolp (car scope)))
1229         (setq scope (eval scope)))
1230        ((eq scope 'agenda)
1231         (setq scope (org-agenda-files t)))
1232        ((eq scope 'agenda-with-archives)
1233         (setq scope (org-agenda-files t))
1234         (setq scope (org-add-archive-files scope)))
1235        ((eq scope 'file-with-archives)
1236         (setq scope (org-add-archive-files (list (buffer-file-name)))
1237               rm-file-column t)))
1238       (setq scope-is-list (and scope (listp scope)))
1239       (save-restriction
1240         (cond
1241          ((not scope))
1242          ((eq scope 'file) (widen))
1243          ((eq scope 'subtree) (org-narrow-to-subtree))
1244          ((eq scope 'tree)
1245           (while (org-up-heading-safe))
1246           (org-narrow-to-subtree))
1247          ((and (symbolp scope) (string-match "^tree\\([0-9]+\\)$"
1248                                              (symbol-name scope)))
1249           (setq level (string-to-number (match-string 1 (symbol-name scope))))
1250           (catch 'exit
1251             (while (org-up-heading-safe)
1252               (looking-at outline-regexp)
1253               (if (<= (org-reduced-level (funcall outline-level)) level)
1254                   (throw 'exit nil))))
1255           (org-narrow-to-subtree))
1256          (scope-is-list
1257           (let* ((files scope)
1258                  (scope 'agenda)
1259                  (p1 (copy-sequence params))
1260                  file)
1261             (setq p1 (plist-put p1 :tostring t))
1262             (setq p1 (plist-put p1 :multifile t))
1263             (setq p1 (plist-put p1 :scope 'file))
1264             (org-prepare-agenda-buffers files)
1265             (while (setq file (pop files))
1266               (with-current-buffer (find-buffer-visiting file)
1267                 (setq tbl1 (org-dblock-write:clocktable p1))
1268                 (when tbl1
1269                   (push (org-clocktable-add-file
1270                          file
1271                          (concat "| |*File time*|*"
1272                                  (org-minutes-to-hh:mm-string
1273                                   org-clock-file-total-minutes)
1274                                  "*|\n"
1275                                  tbl1)) tbl)
1276                   (setq total-time (+ (or total-time 0)
1277                                       org-clock-file-total-minutes))))))))
1278         (goto-char pos)
1279
1280         (unless scope-is-list
1281           (org-clock-sum ts te)
1282           (goto-char (point-min))
1283           (setq st t)
1284           (while (or (and (bobp) (prog1 st (setq st nil))
1285                           (get-text-property (point) :org-clock-minutes)
1286                           (setq p (point-min)))
1287                      (setq p (next-single-property-change (point) :org-clock-minutes)))
1288             (goto-char p)
1289             (when (setq time (get-text-property p :org-clock-minutes))
1290               (save-excursion
1291                 (beginning-of-line 1)
1292                 (when (and (looking-at (org-re "\\(\\*+\\)[ \t]+\\(.*?\\)\\([ \t]+:[[:alnum:]_@:]+:\\)?[ \t]*$"))
1293                            (setq level (org-reduced-level
1294                                         (- (match-end 1) (match-beginning 1))))
1295                            (<= level maxlevel))
1296                   (setq hlc (if emph (or (cdr (assoc level hlchars)) "") "")
1297                         hdl (if (not link)
1298                                 (match-string 2)
1299                               (org-make-link-string
1300                                (format "file:%s::%s"
1301                                        (buffer-file-name)
1302                                        (save-match-data
1303                                          (org-make-org-heading-search-string
1304                                           (match-string 2))))
1305                                (match-string 2)))
1306                         tsp (when timestamp
1307                               (setq props (org-entry-properties (point)))
1308                               (or (cdr (assoc "SCHEDULED" props))
1309                                   (cdr (assoc "TIMESTAMP" props))
1310                                   (cdr (assoc "DEADLINE" props))
1311                                   (cdr (assoc "TIMESTAMP_IA" props)))))
1312                   (if (and (not multifile) (= level 1)) (push "|-" tbl))
1313                   (push (concat
1314                          "| " (int-to-string level) "|"
1315                          (if timestamp (concat tsp "|") "")
1316                          hlc hdl hlc " |"
1317                          (make-string (1- level) ?|)
1318                          hlc (org-minutes-to-hh:mm-string time) hlc
1319                          " |") tbl))))))
1320         (setq tbl (nreverse tbl))
1321         (if tostring
1322             (if tbl (mapconcat 'identity tbl "\n") nil)
1323           (goto-char ins)
1324           (insert-before-markers
1325            (or header
1326                (concat
1327                 "Clock summary at ["
1328                 (substring
1329                  (format-time-string (cdr org-time-stamp-formats))
1330                  1 -1)
1331                 "]"
1332                 (if block (concat ", for " range-text ".") "")
1333                 "\n\n"))
1334            (if scope-is-list "|File" "")
1335            "|L|" (if timestamp "Timestamp|" "") "Headline|Time|\n")
1336           (setq total-time (or total-time org-clock-file-total-minutes))
1337           (insert-before-markers
1338            "|-\n|"
1339            (if scope-is-list "|" "")
1340            (if timestamp "|Timestamp|" "|")
1341            "*Total time*| *"
1342            (org-minutes-to-hh:mm-string (or total-time 0))
1343            "*|\n|-\n")
1344           (setq tbl (delq nil tbl))
1345           (if (and (stringp (car tbl)) (> (length (car tbl)) 1)
1346                    (equal (substring (car tbl) 0 2) "|-"))
1347               (pop tbl))
1348           (insert-before-markers (mapconcat
1349                                   'identity (delq nil tbl)
1350                                   (if scope-is-list "\n|-\n" "\n")))
1351           (backward-delete-char 1)
1352           (if (setq formula (plist-get params :formula))
1353               (cond
1354                ((eq formula '%)
1355                 (setq pcol (+ (if scope-is-list 1 0) maxlevel 3))
1356                 (insert
1357                  (format
1358                   "\n#+TBLFM: $%d='(org-clock-time%% @%d$%d $%d..$%d);%%.1f"
1359                   pcol
1360                   2
1361                   (+ 3 (if scope-is-list 1 0))
1362                   (+ (if scope-is-list 1 0) 3)
1363                   (1- pcol)))
1364                 (setq recalc t))
1365                ((stringp formula)
1366                 (insert "\n#+TBLFM: " formula)
1367                 (setq recalc t))
1368                (t (error "invalid formula in clocktable")))
1369             ;; Should we rescue an old formula?
1370             (when (stringp (setq content (plist-get params :content)))
1371               (when (string-match "^\\([ \t]*#\\+TBLFM:.*\\)" content)
1372                 (setq recalc t)
1373                 (insert "\n" (match-string 1 (plist-get params :content)))
1374                 (beginning-of-line 0))))
1375           (goto-char ipos)
1376           (skip-chars-forward "^|")
1377           (org-table-align)
1378           (when recalc
1379             (if (eq formula '%)
1380                 (save-excursion (org-table-goto-column pcol nil 'force)
1381                                 (insert "%")))
1382             (org-table-recalculate 'all))
1383           (when rm-file-column
1384             (forward-char 1)
1385             (org-table-delete-column)))))))
1386
1387 (defun org-clocktable-steps (params)
1388   (let* ((p1 (copy-sequence params))
1389          (ts (plist-get p1 :tstart))
1390          (te (plist-get p1 :tend))
1391          (step0 (plist-get p1 :step))
1392          (step (cdr (assoc step0 '((day . 86400) (week . 604800)))))
1393          (block (plist-get p1 :block))
1394          cc range-text)
1395     (when block
1396       (setq cc (org-clock-special-range block nil t)
1397             ts (car cc) te (nth 1 cc) range-text (nth 2 cc)))
1398     (if ts (setq ts (time-to-seconds
1399                      (apply 'encode-time (org-parse-time-string ts)))))
1400     (if te (setq te (time-to-seconds
1401                      (apply 'encode-time (org-parse-time-string te)))))
1402     (setq p1 (plist-put p1 :header ""))
1403     (setq p1 (plist-put p1 :step nil))
1404     (setq p1 (plist-put p1 :block nil))
1405     (while (< ts te)
1406       (or (bolp) (insert "\n"))
1407       (setq p1 (plist-put p1 :tstart (format-time-string
1408                                       (org-time-stamp-format nil t)
1409                                       (seconds-to-time ts))))
1410       (setq p1 (plist-put p1 :tend (format-time-string
1411                                     (org-time-stamp-format nil t)
1412                                     (seconds-to-time (setq ts (+ ts step))))))
1413       (insert "\n" (if (eq step0 'day) "Daily report: " "Weekly report starting on: ")
1414               (plist-get p1 :tstart) "\n")
1415       (org-dblock-write:clocktable p1)
1416       (re-search-forward "#\\+END:")
1417       (end-of-line 0))))
1418
1419 (defun org-clocktable-add-file (file table)
1420   (if table
1421       (let ((lines (org-split-string table "\n"))
1422             (ff (file-name-nondirectory file)))
1423         (mapconcat 'identity
1424                    (mapcar (lambda (x)
1425                              (if (string-match org-table-dataline-regexp x)
1426                                  (concat "|" ff x)
1427                                x))
1428                            lines)
1429                    "\n"))))
1430
1431 (defun org-clock-time% (total &rest strings)
1432   "Compute a time fraction in percent.
1433 TOTAL s a time string like 10:21 specifying the total times.
1434 STRINGS is a list of strings that should be checked for a time.
1435 The first string that does have a time will be used.
1436 This function is made for clock tables."
1437   (let ((re "\\([0-9]+\\):\\([0-9]+\\)")
1438         tot s)
1439     (save-match-data
1440       (catch 'exit
1441         (if (not (string-match re total))
1442             (throw 'exit 0.)
1443           (setq tot (+ (string-to-number (match-string 2 total))
1444                        (* 60 (string-to-number (match-string 1 total)))))
1445           (if (= tot 0.) (throw 'exit 0.)))
1446         (while (setq s (pop strings))
1447           (if (string-match "\\([0-9]+\\):\\([0-9]+\\)" s)
1448               (throw 'exit
1449                      (/ (* 100.0 (+ (string-to-number (match-string 2 s))
1450                                     (* 60 (string-to-number (match-string 1 s)))))
1451                         tot))))
1452         0))))
1453
1454 (defun org-clock-save ()
1455   "Persist various clock-related data to disk.
1456 The details of what will be saved are regulated by the variable
1457 `org-clock-persist'."
1458   (when org-clock-persist
1459     (let (b)
1460       (with-current-buffer (find-file (expand-file-name org-clock-persist-file))
1461         (progn
1462           (delete-region (point-min) (point-max))
1463           ;;Store clock
1464           (insert (format ";; org-persist.el - %s at %s\n"
1465                           system-name (format-time-string
1466                                        (cdr org-time-stamp-formats))))
1467           (if (and (setq b (marker-buffer org-clock-marker))
1468                    (setq b (or (buffer-base-buffer b) b))
1469                    (buffer-live-p b)
1470                    (buffer-file-name b)
1471                    (or (not org-clock-persist-query-save)
1472                        (y-or-n-p (concat "Save current clock ("
1473                                          (substring-no-properties org-clock-heading)
1474                                          ") "))))
1475               (insert "(setq resume-clock '(\""
1476                       (buffer-file-name (marker-buffer org-clock-marker))
1477                       "\" . " (int-to-string (marker-position org-clock-marker))
1478                       "))\n"))
1479           ;; Store clocked task history. Tasks are stored reversed to make
1480           ;; reading simpler
1481           (when (and org-clock-history (eq org-clock-persist t))
1482             (insert
1483              "(setq stored-clock-history '("
1484              (mapconcat
1485               (lambda (m)
1486                 (when (and (setq b (marker-buffer m))
1487                            (setq b (or (buffer-base-buffer b) b))
1488                            (buffer-live-p b)
1489                            (buffer-file-name b))
1490                   (concat "(\"" (buffer-file-name b)
1491                           "\" . " (int-to-string (marker-position m))
1492                           ")")))
1493               (reverse org-clock-history) " ") "))\n"))
1494           (save-buffer)
1495           (kill-buffer (current-buffer)))))))
1496
1497 (defvar org-clock-loaded nil
1498   "Was the clock file loaded?")
1499
1500 (defun org-clock-load ()
1501   "Load clock-related data from disk, maybe resuming a stored clock."
1502   (when (and org-clock-persist (not org-clock-loaded))
1503     (let ((filename (expand-file-name org-clock-persist-file))
1504           (org-clock-in-resume 'auto-restart)
1505           resume-clock stored-clock-history)
1506       (if (not (file-readable-p filename))
1507           (message "Not restoring clock data; %s not found"
1508                    org-clock-persist-file)
1509         (message "%s" "Restoring clock data")
1510         (setq org-clock-loaded t)
1511         (load-file filename)
1512         ;; load history
1513         (when stored-clock-history
1514           (save-window-excursion
1515             (mapc (lambda (task)
1516                     (if (file-exists-p (car task))
1517                         (org-clock-history-push (cdr task)
1518                                                 (find-file (car task)))))
1519                   stored-clock-history)))
1520         ;; resume clock
1521         (when (and resume-clock org-clock-persist
1522                    (file-exists-p (car resume-clock))
1523                    (or (not org-clock-persist-query-resume)
1524                        (y-or-n-p
1525                         (concat
1526                          "Resume clock ("
1527                          (with-current-buffer (find-file (car resume-clock))
1528                            (save-excursion
1529                              (goto-char (cdr resume-clock))
1530                              (org-back-to-heading t)
1531                              (and (looking-at org-complex-heading-regexp)
1532                                   (match-string 4))))
1533                          ") "))))
1534           (when (file-exists-p (car resume-clock))
1535             (with-current-buffer (find-file (car resume-clock))
1536               (goto-char (cdr resume-clock))
1537               (org-clock-in)
1538               (if (org-invisible-p)
1539                   (org-show-context)))))))))
1540
1541 ;;;###autoload
1542 (defun org-clock-persistence-insinuate ()
1543   "Set up hooks for clock persistence"
1544   (add-hook 'org-mode-hook 'org-clock-load)
1545   (add-hook 'kill-emacs-hook 'org-clock-save))
1546
1547
1548 ;; Suggested bindings
1549 (org-defkey org-mode-map "\C-c\C-x\C-e" 'org-clock-modify-effort-estimate)
1550
1551 (provide 'org-clock)
1552
1553 ;; arch-tag: 7b42c5d4-9b36-48be-97c0-66a869daed4c
1554
1555 ;;; org-clock.el ends here