lisp/ob-tangle.el

   1 ;;; ob-tangle.el --- extract source code from org-mode files
   2
   3 ;; Copyright (C) 2009-2012  Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Extract the code from source blocks out into raw source-code files.
  27
  28 ;;; Code:
  29 (require 'ob)
  30 (require 'org-src)
  31 (eval-when-compile
  32   (require 'cl))
  33
  34 (declare-function org-link-escape "org" (text &optional table))
  35 (declare-function org-heading-components "org" ())
  36 (declare-function org-back-to-heading "org" (invisible-ok))
  37 (declare-function org-fill-template "org" (template alist))
  38 (declare-function org-babel-update-block-body "org" (new-body))
  39 (declare-function make-directory "files" (dir &optional parents))
  40
  41 ;;;###autoload
  42 (defcustom org-babel-tangle-lang-exts
  43   '(("emacs-lisp" . "el"))
  44   "Alist mapping languages to their file extensions.
  45 The key is the language name, the value is the string that should
  46 be inserted as the extension commonly used to identify files
  47 written in this language.  If no entry is found in this list,
  48 then the name of the language is used."
  49   :group 'org-babel-tangle
  50   :version "24.1"
  51   :type '(repeat
  52           (cons
  53            (string "Language name")
  54            (string "File Extension"))))
  55
  56 (defcustom org-babel-post-tangle-hook nil
  57   "Hook run in code files tangled by `org-babel-tangle'."
  58   :group 'org-babel
  59   :version "24.1"
  60   :type 'hook)
  61
  62 (defcustom org-babel-pre-tangle-hook '(save-buffer)
  63   "Hook run at the beginning of `org-babel-tangle'."
  64   :group 'org-babel
  65   :version "24.1"
  66   :type 'hook)
  67
  68 (defcustom org-babel-tangle-body-hook nil
  69   "Hook run over the contents of each code block body."
  70   :group 'org-babel
  71   :version "24.1"
  72   :type 'hook)
  73
  74 (defcustom org-babel-tangle-comment-format-beg "[[%link][%source-name]]"
  75   "Format of inserted comments in tangled code files.
  76 The following format strings can be used to insert special
  77 information into the output using `org-fill-template'.
  78 %start-line --- the line number at the start of the code block
  79 %file --------- the file from which the code block was tangled
  80 %link --------- Org-mode style link to the code block
  81 %source-name -- name of the code block
  82
  83 Whether or not comments are inserted during tangling is
  84 controlled by the :comments header argument."
  85   :group 'org-babel
  86   :version "24.1"
  87   :type 'string)
  88
  89 (defcustom org-babel-tangle-comment-format-end "%source-name ends here"
  90   "Format of inserted comments in tangled code files.
  91 The following format strings can be used to insert special
  92 information into the output using `org-fill-template'.
  93 %start-line --- the line number at the start of the code block
  94 %file --------- the file from which the code block was tangled
  95 %link --------- Org-mode style link to the code block
  96 %source-name -- name of the code block
  97
  98 Whether or not comments are inserted during tangling is
  99 controlled by the :comments header argument."
 100   :group 'org-babel
 101   :version "24.1"
 102   :type 'string)
 103
 104 (defcustom org-babel-process-comment-text #'org-babel-trim
 105   "Function called to process raw Org-mode text collected to be
 106 inserted as comments in tangled source-code files.  The function
 107 should take a single string argument and return a string
 108 result.  The default value is `org-babel-trim'."
 109   :group 'org-babel
 110   :version "24.1"
 111   :type 'function)
 112
 113 (defun org-babel-find-file-noselect-refresh (file)
 114   "Find file ensuring that the latest changes on disk are
 115 represented in the file."
 116   (find-file-noselect file)
 117   (with-current-buffer (get-file-buffer file)
 118     (revert-buffer t t t)))
 119
 120 (defmacro org-babel-with-temp-filebuffer (file &rest body)
 121   "Open FILE into a temporary buffer execute BODY there like
 122 `progn', then kill the FILE buffer returning the result of
 123 evaluating BODY."
 124   (declare (indent 1))
 125   (let ((temp-path (make-symbol "temp-path"))
 126         (temp-result (make-symbol "temp-result"))
 127         (temp-file (make-symbol "temp-file"))
 128         (visited-p (make-symbol "visited-p")))
 129     `(let* ((,temp-path ,file)
 130             (,visited-p (get-file-buffer ,temp-path))
 131             ,temp-result ,temp-file)
 132        (org-babel-find-file-noselect-refresh ,temp-path)
 133        (setf ,temp-file (get-file-buffer ,temp-path))
 134        (with-current-buffer ,temp-file
 135          (setf ,temp-result (progn ,@body)))
 136        (unless ,visited-p (kill-buffer ,temp-file))
 137        ,temp-result)))
 138 (def-edebug-spec org-babel-with-temp-filebuffer (form body))
 139
 140 ;;;###autoload
 141 (defun org-babel-load-file (file)
 142   "Load Emacs Lisp source code blocks in the Org-mode FILE.
 143 This function exports the source code using
 144 `org-babel-tangle' and then loads the resulting file using
 145 `load-file'."
 146   (interactive "fFile to load: ")
 147   (let* ((age (lambda (file)
 148                 (float-time
 149                  (time-subtract (current-time)
 150                                 (nth 5 (or (file-attributes (file-truename file))
 151                                            (file-attributes file)))))))
 152          (base-name (file-name-sans-extension file))
 153          (exported-file (concat base-name ".el")))
 154     ;; tangle if the org-mode file is newer than the elisp file
 155     (unless (and (file-exists-p exported-file)
 156                  (> (funcall age file) (funcall age exported-file)))
 157       (org-babel-tangle-file file exported-file "emacs-lisp"))
 158     (load-file exported-file)
 159     (message "Loaded %s" exported-file)))
 160
 161 ;;;###autoload
 162 (defun org-babel-tangle-file (file &optional target-file lang)
 163   "Extract the bodies of source code blocks in FILE.
 164 Source code blocks are extracted with `org-babel-tangle'.
 165 Optional argument TARGET-FILE can be used to specify a default
 166 export file for all source blocks.  Optional argument LANG can be
 167 used to limit the exported source code blocks by language."
 168   (interactive "fFile to tangle: \nP")
 169   (let ((visited-p (get-file-buffer (expand-file-name file)))
 170         to-be-removed)
 171     (save-window-excursion
 172       (find-file file)
 173       (setq to-be-removed (current-buffer))
 174       (org-babel-tangle nil target-file lang))
 175     (unless visited-p
 176       (kill-buffer to-be-removed))))
 177
 178 (defun org-babel-tangle-publish (_ filename pub-dir)
 179   "Tangle FILENAME and place the results in PUB-DIR."
 180   (mapc (lambda (el) (copy-file el pub-dir t)) (org-babel-tangle-file filename)))
 181
 182 ;;;###autoload
 183 (defun org-babel-tangle (&optional only-this-block target-file lang)
 184   "Write code blocks to source-specific files.
 185 Extract the bodies of all source code blocks from the current
 186 file into their own source-specific files.  Optional argument
 187 TARGET-FILE can be used to specify a default export file for all
 188 source blocks.  Optional argument LANG can be used to limit the
 189 exported source code blocks by language."
 190   (interactive "P")
 191   (run-hooks 'org-babel-pre-tangle-hook)
 192   ;; possibly restrict the buffer to the current code block
 193   (save-restriction
 194     (when only-this-block
 195       (unless (org-babel-where-is-src-block-head)
 196         (error "Point is not currently inside of a code block"))
 197       (save-match-data
 198         (unless (or (cdr (assoc :tangle (nth 2 (org-babel-get-src-block-info))))
 199                     target-file)
 200           (setq target-file
 201                 (read-from-minibuffer "Tangle to: " (buffer-file-name)))))
 202       (narrow-to-region (match-beginning 0) (match-end 0)))
 203     (save-excursion
 204       (let ((block-counter 0)
 205             (org-babel-default-header-args
 206              (if target-file
 207                  (org-babel-merge-params org-babel-default-header-args
 208                                          (list (cons :tangle target-file)))
 209                org-babel-default-header-args))
 210             path-collector)
 211         (mapc ;; map over all languages
 212          (lambda (by-lang)
 213            (let* ((lang (car by-lang))
 214                   (specs (cdr by-lang))
 215                   (ext (or (cdr (assoc lang org-babel-tangle-lang-exts)) lang))
 216                   (lang-f (intern
 217                            (concat
 218                             (or (and (cdr (assoc lang org-src-lang-modes))
 219                                      (symbol-name
 220                                       (cdr (assoc lang org-src-lang-modes))))
 221                                 lang)
 222                             "-mode")))
 223                   she-banged)
 224              (mapc
 225               (lambda (spec)
 226                 (let ((get-spec (lambda (name) (cdr (assoc name (nth 4 spec))))))
 227                   (let* ((tangle (funcall get-spec :tangle))
 228                          (she-bang ((lambda (sheb) (when (> (length sheb) 0) sheb))
 229                                     (funcall get-spec :shebang)))
 230                          (base-name (cond
 231                                      ((string= "yes" tangle)
 232                                       (file-name-sans-extension
 233                                        (buffer-file-name)))
 234                                      ((string= "no" tangle) nil)
 235                                      ((> (length tangle) 0) tangle)))
 236                          (file-name (when base-name
 237                                       ;; decide if we want to add ext to base-name
 238                                       (if (and ext (string= "yes" tangle))
 239                                           (concat base-name "." ext) base-name))))
 240                     (when file-name
 241                       ;; possibly create the parent directories for file
 242                       (when ((lambda (m) (and m (not (string= m "no"))))
 243                              (funcall get-spec :mkdirp))
 244                         (make-directory (file-name-directory file-name) 'parents))
 245                       ;; delete any old versions of file
 246                       (when (and (file-exists-p file-name)
 247                                  (not (member file-name path-collector)))
 248                         (delete-file file-name))
 249                       ;; drop source-block to file
 250                       (with-temp-buffer
 251                         (when (fboundp lang-f) (ignore-errors (funcall lang-f)))
 252                         (when (and she-bang (not (member file-name she-banged)))
 253                           (insert (concat she-bang "\n"))
 254                           (setq she-banged (cons file-name she-banged)))
 255                         (org-babel-spec-to-string spec)
 256                         ;; We avoid append-to-file as it does not work with tramp.
 257                         (let ((content (buffer-string)))
 258                           (with-temp-buffer
 259                             (if (file-exists-p file-name)
 260                                 (insert-file-contents file-name))
 261                             (goto-char (point-max))
 262                             (insert content)
 263                             (write-region nil nil file-name))))
 264                       ;; if files contain she-bangs, then make the executable
 265                       (when she-bang (set-file-modes file-name #o755))
 266                       ;; update counter
 267                       (setq block-counter (+ 1 block-counter))
 268                       (add-to-list 'path-collector file-name)))))
 269               specs)))
 270          (org-babel-tangle-collect-blocks lang))
 271         (message "Tangled %d code block%s from %s" block-counter
 272                  (if (= block-counter 1) "" "s")
 273                  (file-name-nondirectory
 274                   (buffer-file-name (or (buffer-base-buffer) (current-buffer)))))
 275         ;; run `org-babel-post-tangle-hook' in all tangled files
 276         (when org-babel-post-tangle-hook
 277           (mapc
 278            (lambda (file)
 279              (org-babel-with-temp-filebuffer file
 280                (run-hooks 'org-babel-post-tangle-hook)))
 281            path-collector))
 282         path-collector))))
 283
 284 (defun org-babel-tangle-clean ()
 285   "Remove comments inserted by `org-babel-tangle'.
 286 Call this function inside of a source-code file generated by
 287 `org-babel-tangle' to remove all comments inserted automatically
 288 by `org-babel-tangle'.  Warning, this comment removes any lines
 289 containing constructs which resemble org-mode file links or noweb
 290 references."
 291   (interactive)
 292   (goto-char (point-min))
 293   (while (or (re-search-forward "\\[\\[file:.*\\]\\[.*\\]\\]" nil t)
 294              (re-search-forward (org-babel-noweb-wrap) nil t))
 295     (delete-region (save-excursion (beginning-of-line 1) (point))
 296                    (save-excursion (end-of-line 1) (forward-char 1) (point)))))
 297
 298 (defvar org-stored-links)
 299 (defvar org-bracket-link-regexp)
 300 (defun org-babel-spec-to-string (spec)
 301   "Insert SPEC into the current file.
 302 Insert the source-code specified by SPEC into the current
 303 source code file.  This function uses `comment-region' which
 304 assumes that the appropriate major-mode is set.  SPEC has the
 305 form
 306
 307   (start-line file link source-name params body comment)"
 308   (let* ((start-line (nth 0 spec))
 309          (file (nth 1 spec))
 310          (link (nth 2 spec))
 311          (source-name (nth 3 spec))
 312          (body (nth 5 spec))
 313          (comment (nth 6 spec))
 314          (comments (cdr (assoc :comments (nth 4 spec))))
 315          (padline (not (string= "no" (cdr (assoc :padline (nth 4 spec))))))
 316          (link-p (or (string= comments "both") (string= comments "link")
 317                      (string= comments "yes") (string= comments "noweb")))
 318          (link-data (mapcar (lambda (el)
 319                               (cons (symbol-name el)
 320                                     ((lambda (le)
 321                                        (if (stringp le) le (format "%S" le)))
 322                                      (eval el))))
 323                             '(start-line file link source-name)))
 324          (insert-comment (lambda (text)
 325                            (when (and comments (not (string= comments "no"))
 326                                       (> (length text) 0))
 327                              (when padline (insert "\n"))
 328                              (comment-region (point) (progn (insert text) (point)))
 329                              (end-of-line nil) (insert "\n")))))
 330     (when comment (funcall insert-comment comment))
 331     (when link-p
 332       (funcall
 333        insert-comment
 334        (org-fill-template org-babel-tangle-comment-format-beg link-data)))
 335     (when padline (insert "\n"))
 336     (insert
 337      (format
 338       "%s\n"
 339       (replace-regexp-in-string
 340        "^," ""
 341        (org-babel-trim body (if org-src-preserve-indentation "[\f\n\r\v]")))))
 342     (when link-p
 343       (funcall
 344        insert-comment
 345        (org-fill-template org-babel-tangle-comment-format-end link-data)))))
 346
 347 (defun org-babel-tangle-collect-blocks (&optional language)
 348   "Collect source blocks in the current Org-mode file.
 349 Return an association list of source-code block specifications of
 350 the form used by `org-babel-spec-to-string' grouped by language.
 351 Optional argument LANG can be used to limit the collected source
 352 code blocks by language."
 353   (let ((block-counter 1) (current-heading "") blocks)
 354     (org-babel-map-src-blocks (buffer-file-name)
 355       ((lambda (new-heading)
 356          (if (not (string= new-heading current-heading))
 357              (progn
 358                (setq block-counter 1)
 359                (setq current-heading new-heading))
 360            (setq block-counter (+ 1 block-counter))))
 361        (replace-regexp-in-string "[ \t]" "-"
 362                                  (condition-case nil
 363                                      (nth 4 (org-heading-components))
 364                                    (error (buffer-file-name)))))
 365       (let* ((start-line (save-restriction (widen)
 366                                            (+ 1 (line-number-at-pos (point)))))
 367              (file (buffer-file-name))
 368              (info (org-babel-get-src-block-info 'light))
 369              (src-lang (nth 0 info)))
 370         (unless (string= (cdr (assoc :tangle (nth 2 info))) "no")
 371           (unless (and language (not (string= language src-lang)))
 372             (let* ((info (org-babel-get-src-block-info))
 373                    (params (nth 2 info))
 374                    (link ((lambda (link)
 375                             (and (string-match org-bracket-link-regexp link)
 376                                  (match-string 1 link)))
 377                           (org-babel-clean-text-properties
 378                            (org-store-link nil))))
 379                    (source-name
 380                     (intern (or (nth 4 info)
 381                                 (format "%s:%d"
 382                                         current-heading block-counter))))
 383                    (expand-cmd
 384                     (intern (concat "org-babel-expand-body:" src-lang)))
 385                    (assignments-cmd
 386                     (intern (concat "org-babel-variable-assignments:" src-lang)))
 387                    (body
 388                     ((lambda (body) ;; run the tangle-body-hook
 389                        (with-temp-buffer
 390                          (insert body)
 391                          (run-hooks 'org-babel-tangle-body-hook)
 392                          (buffer-string)))
 393                      ((lambda (body) ;; expand the body in language specific manner
 394                         (if (assoc :no-expand params)
 395                             body
 396                           (if (fboundp expand-cmd)
 397                               (funcall expand-cmd body params)
 398                             (org-babel-expand-body:generic
 399                              body params
 400                              (and (fboundp assignments-cmd)
 401                                   (funcall assignments-cmd params))))))
 402                       (if (org-babel-noweb-p params :tangle)
 403                           (org-babel-expand-noweb-references info)
 404                         (nth 1 info)))))
 405                    (comment
 406                     (when (or (string= "both" (cdr (assoc :comments params)))
 407                               (string= "org" (cdr (assoc :comments params))))
 408                       ;; from the previous heading or code-block end
 409                       (funcall
 410                        org-babel-process-comment-text
 411                        (buffer-substring
 412                         (max (condition-case nil
 413                                  (save-excursion
 414                                    (org-back-to-heading t)  ; sets match data
 415                                    (match-end 0))
 416                                (error (point-min)))
 417                              (save-excursion
 418                                (if (re-search-backward
 419                                     org-babel-src-block-regexp nil t)
 420                                    (match-end 0)
 421                                  (point-min))))
 422                         (point)))))
 423                    by-lang)
 424               ;; add the spec for this block to blocks under it's language
 425               (setq by-lang (cdr (assoc src-lang blocks)))
 426               (setq blocks (delq (assoc src-lang blocks) blocks))
 427               (setq blocks (cons
 428                             (cons src-lang
 429                                   (cons (list start-line file link
 430                                               source-name params body comment)
 431                                         by-lang)) blocks)))))))
 432     ;; ensure blocks in the correct order
 433     (setq blocks
 434           (mapcar
 435            (lambda (by-lang) (cons (car by-lang) (reverse (cdr by-lang))))
 436            blocks))
 437     blocks))
 438
 439 (defun org-babel-tangle-comment-links ( &optional info)
 440   "Return a list of begin and end link comments for the code block at point."
 441   (let* ((start-line (org-babel-where-is-src-block-head))
 442          (file (buffer-file-name))
 443          (link (org-link-escape (progn (call-interactively 'org-store-link)
 444                                        (org-babel-clean-text-properties
 445                                         (car (pop org-stored-links))))))
 446          (source-name (nth 4 (or info (org-babel-get-src-block-info 'light))))
 447          (link-data (mapcar (lambda (el)
 448                               (cons (symbol-name el)
 449                                     ((lambda (le)
 450                                        (if (stringp le) le (format "%S" le)))
 451                                      (eval el))))
 452                             '(start-line file link source-name))))
 453     (list (org-fill-template org-babel-tangle-comment-format-beg link-data)
 454           (org-fill-template org-babel-tangle-comment-format-end link-data))))
 455
 456 ;; de-tangling functions
 457 (defvar org-bracket-link-analytic-regexp)
 458 (defun org-babel-detangle (&optional source-code-file)
 459   "Propagate changes in source file back original to Org-mode file.
 460 This requires that code blocks were tangled with link comments
 461 which enable the original code blocks to be found."
 462   (interactive)
 463   (save-excursion
 464     (when source-code-file (find-file source-code-file))
 465     (goto-char (point-min))
 466     (let ((counter 0) new-body end)
 467       (while (re-search-forward org-bracket-link-analytic-regexp nil t)
 468         (when (re-search-forward
 469                (concat " " (regexp-quote (match-string 5)) " ends here"))
 470           (setq end (match-end 0))
 471           (forward-line -1)
 472           (save-excursion
 473             (when (setq new-body (org-babel-tangle-jump-to-org))
 474               (org-babel-update-block-body new-body)))
 475           (setq counter (+ 1 counter)))
 476         (goto-char end))
 477       (prog1 counter (message "Detangled %d code blocks" counter)))))
 478
 479 (defun org-babel-tangle-jump-to-org ()
 480   "Jump from a tangled code file to the related Org-mode file."
 481   (interactive)
 482   (let ((mid (point))
 483         start end done
 484         target-buffer target-char link path block-name body)
 485     (save-window-excursion
 486       (save-excursion
 487         (while (and (re-search-backward org-bracket-link-analytic-regexp nil t)
 488                     (not ; ever wider searches until matching block comments
 489                      (and (setq start (point-at-eol))
 490                           (setq link (match-string 0))
 491                           (setq path (match-string 3))
 492                           (setq block-name (match-string 5))
 493                           (save-excursion
 494                             (save-match-data
 495                               (re-search-forward
 496                                (concat " " (regexp-quote block-name)
 497                                        " ends here") nil t)
 498                               (setq end (point-at-bol))))))))
 499         (unless (and start (< start mid) (< mid end))
 500           (error "Not in tangled code"))
 501         (setq body (org-babel-trim (buffer-substring start end))))
 502       (when (string-match "::" path)
 503         (setq path (substring path 0 (match-beginning 0))))
 504       (find-file path) (setq target-buffer (current-buffer))
 505       (goto-char start) (org-open-link-from-string link)
 506       (if (string-match "[^ \t\n\r]:\\([[:digit:]]+\\)" block-name)
 507           (org-babel-next-src-block
 508            (string-to-number (match-string 1 block-name)))
 509         (org-babel-goto-named-src-block block-name))
 510       (setq target-char (point)))
 511     (pop-to-buffer target-buffer)
 512     (prog1 body (goto-char target-char))))
 513
 514 (provide 'ob-tangle)
 515
 516
 517
 518 ;;; ob-tangle.el ends here