lisp/org-protocol.el

   1 ;;; org-protocol.el --- Intercept calls from emacsclient to trigger custom actions.
   2 ;;
   3 ;; Copyright (C) 2008, 2009, 2010
   4 ;;          Free Software Foundation, Inc.
   5 ;;
   6 ;; Author: Bastien Guerry <bzg AT altern DOT org>
   7 ;; Author: Daniel M German <dmg AT uvic DOT org>
   8 ;; Author: Sebastian Rose <sebastian_rose AT gmx DOT de>
   9 ;; Author: Ross Patterson <me AT rpatterson DOT net>
  10 ;; Maintainer: Sebastian Rose <sebastian_rose AT gmx DOT de>
  11 ;; Keywords: org, emacsclient, wp
  12 ;; Version: 6.36trans
  13
  14 ;; This file is part of GNU Emacs.
  15 ;;
  16 ;; GNU Emacs is free software: you can redistribute it and/or modify
  17 ;; it under the terms of the GNU General Public License as published by
  18 ;; the Free Software Foundation, either version 3 of the License, or
  19 ;; (at your option) any later version.
  20
  21 ;; GNU Emacs is distributed in the hope that it will be useful,
  22 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 ;; GNU General Public License for more details.
  25
  26 ;; You should have received a copy of the GNU General Public License
  27 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  28
  29 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  30 ;;; Commentary:
  31 ;;
  32 ;; Intercept calls from emacsclient to trigger custom actions.
  33 ;;
  34 ;; This is done by advising `server-visit-files' to scann the list of filenames
  35 ;; for `org-protocol-the-protocol' and sub-procols defined in
  36 ;; `org-protocol-protocol-alist' and `org-protocol-protocol-alist-default'.
  37 ;;
  38 ;; Any application that supports calling external programs with an URL
  39 ;; as argument may be used with this functionality.
  40 ;;
  41 ;;
  42 ;; Usage:
  43 ;; ------
  44 ;;
  45 ;;   1.) Add this to your init file (.emacs probably):
  46 ;;
  47 ;;       (add-to-list 'load-path "/path/to/org-protocol/")
  48 ;;       (require 'org-protocol)
  49 ;;
  50 ;;   3.) Ensure emacs-server is up and running.
  51 ;;   4.) Try this from the command line (adjust the URL as needed):
  52 ;;
  53 ;;       $ emacsclient \
  54 ;;         org-protocol://store-link://http:%2F%2Flocalhost%2Findex.html/The%20title
  55 ;;
  56 ;;   5.) Optionally add custom sub-protocols and handlers:
  57 ;;
  58 ;;       (setq org-protocol-protocol-alist
  59 ;;             '(("my-protocol"
  60 ;;                :protocol "my-protocol"
  61 ;;                :function my-protocol-handler-fuction)))
  62 ;;
  63 ;;       A "sub-protocol" will be found in URLs like this:
  64 ;;
  65 ;;           org-protocol://sub-protocol://data
  66 ;;
  67 ;; If it works, you can now setup other applications for using this feature.
  68 ;;
  69 ;;
  70 ;; As of March 2009 Firefox users follow the steps documented on
  71 ;; http://kb.mozillazine.org/Register_protocol, Opera setup is described here:
  72 ;; http://www.opera.com/support/kb/view/535/
  73 ;;
  74 ;;
  75 ;; Documentation
  76 ;; -------------
  77 ;;
  78 ;; org-protocol.el comes with and installs handlers to open sources of published
  79 ;; online content, store and insert the browser's URLs and cite online content
  80 ;; by clicking on a bookmark in Firefox, Opera and probably other browsers and
  81 ;; applications:
  82 ;;
  83 ;;   * `org-protocol-open-source' uses the sub-protocol \"open-source\" and maps
  84 ;;     URLs to local filenames defined in `org-protocol-project-alist'.
  85 ;;
  86 ;;   * `org-protocol-store-link' stores an Org-link (if Org-mode is present) and
  87 ;;     pushes the browsers URL to the `kill-ring' for yanking. This handler is
  88 ;;     triggered through the sub-protocol \"store-link\".
  89 ;;
  90 ;;   * Call `org-protocol-capture' by using the sub-protocol \"capture\".  If
  91 ;;     Org-mode is loaded, emacs will pop-up a capture buffer and fill the
  92 ;;     template with the data provided. I.e. the browser's URL is inserted as an
  93 ;;     Org-link of which the page title will be the description part. If text
  94 ;;     was select in the browser, that text will be the body of the entry.
  95 ;;
  96 ;;   * Call `org-protocol-remember' by using the sub-protocol \"remember\".
  97 ;;     This is provided for backward compatibility.
  98 ;;     You may read `org-capture' as `org-remember' throughout this file if
  99 ;;     you still use `org-remember'.
 100 ;;
 101 ;; You may use the same bookmark URL for all those standard handlers and just
 102 ;; adjust the sub-protocol used:
 103 ;;
 104 ;;     location.href='org-protocol://sub-protocol://'+
 105 ;;           encodeURIComponent(location.href)+'/'+
 106 ;;           encodeURIComponent(document.title)+'/'+
 107 ;;           encodeURIComponent(window.getSelection())
 108 ;;
 109 ;; The handler for the sub-protocol \"capture\" detects an optional template
 110 ;; char that, if present, triggers the use of a special template.
 111 ;; Example:
 112 ;;
 113 ;;     location.href='org-protocol://sub-protocol://x/'+ ...
 114 ;;
 115 ;;  use template ?x.
 116 ;;
 117 ;; Note, that using double slashes is optional from org-protocol.el's point of
 118 ;; view because emacsclient squashes the slashes to one.
 119 ;;
 120 ;;
 121 ;; provides: 'org-protocol
 122 ;;
 123 ;;; Code:
 124
 125 (require 'org)
 126 (eval-when-compile
 127   (require 'cl))
 128
 129 (declare-function org-publish-get-project-from-filename "org-publish"
 130                   (filename &optional up))
 131 (declare-function server-edit "server" (&optional arg))
 132
 133
 134 (defgroup org-protocol nil
 135   "Intercept calls from emacsclient to trigger custom actions.
 136
 137 This is done by advising `server-visit-files' to scann the list of filenames
 138 for `org-protocol-the-protocol' and sub-procols defined in
 139 `org-protocol-protocol-alist' and `org-protocol-protocol-alist-default'."
 140   :version "22.1"
 141   :group 'convenience
 142   :group 'org)
 143
 144
 145 ;;; Variables:
 146
 147 (defconst org-protocol-protocol-alist-default
 148   '(("org-remember"    :protocol "remember"    :function org-protocol-remember :kill-client t)
 149     ("org-capture"     :protocol "capture"     :function org-protocol-capture  :kill-client t)
 150     ("org-store-link"  :protocol "store-link"  :function org-protocol-store-link)
 151     ("org-open-source" :protocol "open-source" :function org-protocol-open-source))
 152   "Default protocols to use.
 153 See `org-protocol-protocol-alist' for a description of this variable.")
 154
 155
 156 (defconst org-protocol-the-protocol "org-protocol"
 157   "This is the protocol to detect if org-protocol.el is loaded.
 158 `org-protocol-protocol-alist-default' and `org-protocol-protocol-alist' hold the
 159 sub-protocols that trigger the required action. You will have to define just one
 160 protocol handler OS-wide (MS-Windows) or per application (Linux). That protocol
 161 handler should call emacsclient.")
 162
 163
 164 ;;; User variables:
 165
 166 (defcustom org-protocol-reverse-list-of-files t
 167   "* The filenames passed on the commandline are passed to the emacs-server in
 168 reversed order. Set to `t' (default) to re-reverse the list, i.e. use the
 169 sequence on the command line. If nil, the sequence of the filenames is
 170 unchanged."
 171   :group 'org-protocol
 172   :type 'boolean)
 173
 174
 175 (defcustom org-protocol-project-alist nil
 176   "* Map URLs to local filenames for `org-protocol-open-source' (open-source).
 177
 178 Each element of this list must be of the form:
 179
 180   (module-name :property value property: value ...)
 181
 182 where module-name is an arbitrary name. All the values are strings.
 183
 184 Possible properties are:
 185
 186   :online-suffix     - the suffix to strip from the published URLs
 187   :working-suffix    - the replacement for online-suffix
 188   :base-url          - the base URL, e.g. http://www.example.com/project/
 189                        Last slash required.
 190   :working-directory - the local working directory. This is, what base-url will
 191                        be replaced with.
 192   :redirects         - A list of cons cells, each of which maps a regular
 193                        expression to match to a path relative to :working-directory.
 194
 195 Example:
 196
 197    (setq org-protocol-project-alist
 198        '((\"http://orgmode.org/worg/\"
 199           :online-suffix \".php\"
 200           :working-suffix \".org\"
 201           :base-url \"http://orgmode.org/worg/\"
 202           :working-directory \"/home/user/org/Worg/\")
 203          (\"http://localhost/org-notes/\"
 204           :online-suffix \".html\"
 205           :working-suffix \".org\"
 206           :base-url \"http://localhost/org/\"
 207           :working-directory \"/home/user/org/\"
 208           :rewrites ((\"org/?$\" . \"index.php\")))))
 209
 210    The last line tells `org-protocol-open-source' to open
 211    /home/user/org/index.php, if the URL cannot be mapped to an existing
 212    file, and ends with either \"org\" or \"org/\".
 213
 214 Consider using the interactive functions `org-protocol-create' and
 215 `org-protocol-create-for-org' to help you filling this variable with valid contents."
 216   :group 'org-protocol
 217   :type 'alist)
 218
 219
 220 (defcustom org-protocol-protocol-alist nil
 221   "* Register custom handlers for org-protocol.
 222
 223 Each element of this list must be of the form:
 224
 225   (module-name :protocol protocol :function func :kill-client nil)
 226
 227 protocol - protocol to detect in a filename without trailing colon and slashes.
 228            See rfc1738 section 2.1 for more on this.
 229            If you define a protocol \"my-protocol\", `org-protocol-check-filename-for-protocol'
 230            will search filenames for \"org-protocol:/my-protocol:/\"
 231            and trigger your action for every match. `org-protocol' is defined in
 232            `org-protocol-the-protocol'. Double and tripple slashes are compressed
 233            to one by emacsclient.
 234
 235 function - function that handles requests with protocol and takes exactly one
 236            argument: the filename with all protocols stripped. If the function
 237            returns nil, emacsclient and -server do nothing. Any non-nil return
 238            value is considered a valid filename and thus passed to the server.
 239
 240            `org-protocol.el provides some support for handling those filenames,
 241            if you stay with the conventions used for the standard handlers in
 242            `org-protocol-protocol-alist-default'. See `org-protocol-split-data'.
 243
 244 kill-client - If t, kill the client immediately, once the sub-protocol is
 245            detected. This is necessary for actions that can be interrupted by
 246            `C-g' to avoid dangeling emacsclients. Note, that all other command
 247            line arguments but the this one will be discarded, greedy handlers
 248            still receive the whole list of arguments though.
 249
 250 Here is an example:
 251
 252   (setq org-protocol-protocol-alist
 253       '((\"my-protocol\"
 254          :protocol \"my-protocol\"
 255          :function my-protocol-handler-fuction)
 256         (\"your-protocol\"
 257          :protocol \"your-protocol\"
 258          :function your-protocol-handler-fuction)))"
 259   :group 'org-protocol
 260   :type '(alist))
 261
 262 (defcustom org-protocol-default-template-key "w"
 263   "The default org-remember-templates key to use."
 264   :group 'org-protocol
 265   :type 'string)
 266
 267 ;;; Helper functions:
 268
 269 (defun org-protocol-sanitize-uri (uri)
 270   "emacsclient compresses double and tripple slashes.
 271 Slashes are sanitized to double slashes here."
 272   (when (string-match "^\\([a-z]+\\):/" uri)
 273     (let* ((splitparts (split-string uri "/+")))
 274       (setq uri (concat (car splitparts) "//" (mapconcat 'identity (cdr splitparts) "/")))))
 275   uri)
 276
 277
 278 (defun org-protocol-split-data(data &optional unhexify separator)
 279   "Split, what a org-protocol handler function gets as only argument.
 280 data is that one argument. Data is splitted at each occurrence of separator
 281  (regexp). If no separator is specified or separator is nil, assume \"/+\".
 282 The results of that splitting are return as a list. If unhexify is non-nil,
 283 hex-decode each split part. If unhexify is a function, use that function to
 284 decode each split part."
 285   (let* ((sep (or separator "/+"))
 286          (split-parts (split-string data sep)))
 287     (if unhexify
 288         (if (fboundp unhexify)
 289             (mapcar unhexify split-parts)
 290           (mapcar 'org-protocol-unhex-string split-parts))
 291       split-parts)))
 292
 293 ;; This inline function is needed in org-protocol-unhex-compound to do
 294 ;; the right thing to decode UTF-8 char integer values.
 295 (eval-when-compile
 296   (if (>= emacs-major-version 23)
 297       (defsubst org-protocol-char-to-string(c)
 298         "Defsubst to decode UTF-8 character values in emacs 23 and beyond."
 299         (char-to-string c))
 300     (defsubst org-protocol-char-to-string (c)
 301       "Defsubst to decode UTF-8 character values in emacs 22."
 302       (string (decode-char 'ucs c)))))
 303
 304 (defun org-protocol-unhex-string(str)
 305   "Unhex hexified unicode strings as returned from the JavaScript function
 306 encodeURIComponent. E.g. `%C3%B6' is the german Umlaut `ü'."
 307   (setq str (or str ""))
 308   (let ((tmp "")
 309         (case-fold-search t))
 310     (while (string-match "\\(%[0-9a-f][0-9a-f]\\)+" str)
 311       (let* ((start (match-beginning 0))
 312              (end (match-end 0))
 313              (hex (match-string 0 str))
 314              (replacement (org-protocol-unhex-compound hex)))
 315         (setq tmp (concat tmp (substring str 0 start) replacement))
 316         (setq str (substring str end))))
 317     (setq tmp (concat tmp str))
 318     tmp))
 319
 320
 321 (defun org-protocol-unhex-compound (hex)
 322   "Unhexify unicode hex-chars. E.g. `%C3%B6' is the german Umlaut `ü'."
 323   (let* ((bytes (remove "" (split-string hex "%")))
 324          (ret "")
 325          (eat 0)
 326          (sum 0))
 327     (while bytes
 328       (let* ((b (pop bytes))
 329              (a (elt b 0))
 330              (b (elt b 1))
 331              (c1 (if (> a ?9) (+ 10 (- a ?A)) (- a ?0)))
 332              (c2 (if (> b ?9) (+ 10 (- b ?A)) (- b ?0)))
 333              (val (+ (lsh c1 4) c2))
 334              (shift
 335               (if (= 0 eat) ;; new byte
 336                   (if (>= val 252) 6
 337                     (if (>= val 248) 5
 338                       (if (>= val 240) 4
 339                         (if (>= val 224) 3
 340                           (if (>= val 192) 2 0)))))
 341                 6))
 342              (xor
 343               (if (= 0 eat) ;; new byte
 344                   (if (>= val 252) 252
 345                     (if (>= val 248) 248
 346                       (if (>= val 240) 240
 347                         (if (>= val 224) 224
 348                           (if (>= val 192) 192 0)))))
 349                 128)))
 350         (if (>= val 192) (setq eat shift))
 351         (setq val (logxor val xor))
 352         (setq sum (+ (lsh sum shift) val))
 353         (if (> eat 0) (setq eat (- eat 1)))
 354         (when (= 0 eat)
 355           (setq ret (concat ret (org-protocol-char-to-string sum)))
 356           (setq sum 0))
 357         )) ;; end (while bytes
 358     ret ))
 359
 360 (defun org-protocol-flatten-greedy (param-list &optional strip-path replacement)
 361   "Greedy handlers might receive a list like this from emacsclient:
 362  '( (\"/dir/org-protocol:/greedy:/~/path1\" (23 . 12)) (\"/dir/param\")
 363 where \"/dir/\" is the absolute path to emacsclients working directory.  This
 364 function transforms it into a flat list utilizing `org-protocol-flatten' and
 365 transforms the elements of that list as follows:
 366
 367 If strip-path is non-nil, remove the \"/dir/\" prefix from all members of
 368 param-list.
 369
 370 If replacement is string, replace the \"/dir/\" prefix with it.
 371
 372 The first parameter, the one that contains the protocols, is always changed.
 373 Everything up to the end of the protocols is stripped.
 374
 375 Note, that this function will always behave as if
 376 `org-protocol-reverse-list-of-files' was set to t and the returned list will
 377 reflect that. I.e. emacsclients first parameter will be the first one in the
 378 returned list."
 379 (let* ((l (org-protocol-flatten (if org-protocol-reverse-list-of-files
 380                                     param-list
 381                                   (reverse param-list))))
 382       (trigger (car l))
 383       (len 0)
 384       dir
 385       ret)
 386   (when (string-match "^\\(.*\\)\\(org-protocol:/+[a-zA-z0-9][-_a-zA-z0-9]*:/+\\)\\(.*\\)" trigger)
 387     (setq dir (match-string 1 trigger))
 388     (setq len (length dir))
 389     (setcar l (concat dir (match-string 3 trigger))))
 390   (if strip-path
 391       (progn
 392        (dolist (e l ret)
 393          (setq ret
 394                (append ret
 395                        (list
 396                         (if (stringp e)
 397                             (if (stringp replacement)
 398                                 (setq e (concat replacement (substring e len)))
 399                               (setq e (substring e len)))
 400                           e)))))
 401        ret)
 402     l)))
 403
 404
 405 (defun org-protocol-flatten (l)
 406   "Greedy handlers might receive a list like this from emacsclient:
 407  '( (\"/dir/org-protocol:/greedy:/~/path1\" (23 . 12)) (\"/dir/param\")
 408 where \"/dir/\" is the absolute path to emacsclients working directory.
 409 This function transforms it into a flat list."
 410   (if (null l) ()
 411     (if (listp l)
 412        (append (org-protocol-flatten (car l)) (org-protocol-flatten (cdr l)))
 413       (list l))))
 414
 415 ;;; Standard protocol handlers:
 416
 417 (defun org-protocol-store-link (fname)
 418   "Process an org-protocol://store-link:// style url
 419 and store a browser URL as an org link. Also pushes the links URL to the
 420 `kill-ring'.
 421
 422 The location for a browser's bookmark has to look like this:
 423
 424   javascript:location.href='org-protocol://store-link://'+ \\
 425         encodeURIComponent(location.href)
 426         encodeURIComponent(document.title)+'/'+ \\
 427
 428 Don't use `escape()'! Use `encodeURIComponent()' instead. The title of the page
 429 could contain slashes and the location definitely will.
 430
 431 The sub-protocol used to reach this function is set in
 432 `org-protocol-protocol-alist'."
 433   (let* ((splitparts (org-protocol-split-data fname t))
 434          (uri (org-protocol-sanitize-uri (car splitparts)))
 435          (title (cadr splitparts))
 436          orglink)
 437     (if (boundp 'org-stored-links)
 438       (setq org-stored-links (cons (list uri title) org-stored-links)))
 439     (kill-new uri)
 440     (message "`%s' to insert new org-link, `%s' to insert `%s'"
 441              (substitute-command-keys"\\[org-insert-link]")
 442              (substitute-command-keys"\\[yank]")
 443              uri))
 444   nil)
 445
 446 (defun org-protocol-remember  (info)
 447   "Process an org-protocol://remember:// style url.
 448
 449 The location for a browser's bookmark has to look like this:
 450
 451   javascript:location.href='org-protocol://remember://'+ \\
 452         encodeURIComponent(location.href)+'/' \\
 453         encodeURIComponent(document.title)+'/'+ \\
 454         encodeURIComponent(window.getSelection())
 455
 456 See the docs for `org-protocol-capture' for more information."
 457
 458   (if (and (boundp 'org-stored-links)
 459            (or (fboundp 'org-capture))
 460            (org-protocol-do-capture info 'org-remember))
 461       (message "Org-mode not loaded."))
 462   nil)
 463
 464 (defun org-protocol-capture  (info)
 465   "Process an org-protocol://capture:// style url.
 466
 467 The sub-protocol used to reach this function is set in
 468 `org-protocol-protocol-alist'.
 469
 470 This function detects an URL, title and optional text, separated by '/'
 471 The location for a browser's bookmark has to look like this:
 472
 473   javascript:location.href='org-protocol://capture://'+ \\
 474         encodeURIComponent(location.href)+'/' \\
 475         encodeURIComponent(document.title)+'/'+ \\
 476         encodeURIComponent(window.getSelection())
 477
 478 By default, it uses the character `org-protocol-default-template-key',
 479 which should be associated with a template in `org-capture-templates'.
 480 But you may prepend the encoded URL with a character and a slash like so:
 481
 482   javascript:location.href='org-protocol://capture://b/'+ ...
 483
 484 Now template ?b will be used."
 485   (if (and (boundp 'org-stored-links)
 486            (or (fboundp 'org-capture))
 487            (org-protocol-do-capture info 'org-capture))
 488       (message "Org-mode not loaded."))
 489   nil)
 490
 491 (defun org-protocol-do-capture (info capture-func)
 492   "Support `org-capture' and `org-remember' alike.
 493 CAPTURE-FUNC is either the symbol `org-remember' or `org-capture'."
 494   (let* ((parts (org-protocol-split-data info t))
 495          (template (or (and (= 1 (length (car parts))) (pop parts))
 496                        org-protocol-default-template-key))
 497          (url (org-protocol-sanitize-uri (car parts)))
 498          (type (if (string-match "^\\([a-z]+\\):" url)
 499                    (match-string 1 url)))
 500          (title(or (cadr parts) ""))
 501          (region (or (caddr parts) ""))
 502          (orglink (org-make-link-string
 503                    url (if (string-match "[^[:space:]]" title) title url)))
 504          (org-capture-link-is-already-stored t) ;; avoid call to org-store-link
 505          remember-annotation-functions)
 506     (setq org-stored-links
 507           (cons (list url title) org-stored-links))
 508     (kill-new orglink)
 509     (org-store-link-props :type type
 510                           :link url
 511                           :description title
 512                           :annotation orglink
 513                           :initial region)
 514     (raise-frame)
 515     (funcall capture-func nil template)))
 516
 517
 518 (defun org-protocol-open-source (fname)
 519   "Process an org-protocol://open-source:// style url.
 520
 521 Change a filename by mapping URLs to local filenames as set
 522 in `org-protocol-project-alist'.
 523
 524 The location for a browser's bookmark should look like this:
 525
 526   javascript:location.href='org-protocol://open-source://'+ \\
 527         encodeURIComponent(location.href)"
 528
 529   ;; As we enter this function for a match on our protocol, the return value
 530   ;; defaults to nil.
 531   (let ((result nil)
 532         (f (org-protocol-unhex-string fname)))
 533     (catch 'result
 534       (dolist (prolist org-protocol-project-alist)
 535         (let* ((base-url (plist-get (cdr prolist) :base-url))
 536                (wsearch (regexp-quote base-url)))
 537
 538           (when (string-match wsearch f)
 539             (let* ((wdir (plist-get (cdr prolist) :working-directory))
 540                    (strip-suffix (plist-get (cdr prolist) :online-suffix))
 541                    (add-suffix (plist-get (cdr prolist) :working-suffix))
 542                    ;; Strip "[?#].*$" if `f' is a redirect with another
 543                    ;; ending than strip-suffix here:
 544                    (f1 (substring f 0 (string-match "\\([\\?#].*\\)?$" f)))
 545                    (start-pos (+ (string-match wsearch f1) (length base-url)))
 546                    (end-pos (string-match
 547                              (regexp-quote strip-suffix) f1))
 548                    ;; We have to compare redirects without suffix below:
 549                    (f2 (concat wdir (substring f1 start-pos end-pos)))
 550                    (the-file (concat f2 add-suffix)))
 551
 552               ;; Note: the-file may still contain `%C3' et al here because browsers
 553               ;; tend to encode `&auml;' in URLs to `%25C3' - `%25' being `%'.
 554               ;; So the results may vary.
 555
 556               ;; -- start redirects --
 557               (unless (file-exists-p the-file)
 558                 (message "File %s does not exist.\nTesting for rewritten URLs." the-file)
 559                 (let ((rewrites (plist-get (cdr prolist) :rewrites)))
 560                   (when rewrites
 561                     (message "Rewrites found: %S" rewrites)
 562                     (mapc
 563                      (lambda (rewrite)
 564                        "Try to match a rewritten URL and map it to a real file."
 565                        ;; Compare redirects without suffix:
 566                        (if (string-match (car rewrite) f2)
 567                            (throw 'result (concat wdir (cdr rewrite)))))
 568                      rewrites))))
 569               ;; -- end of redirects --
 570
 571               (if (file-readable-p the-file)
 572                   (throw 'result the-file))
 573               (if (file-exists-p the-file)
 574                   (message "%s: permission denied!" the-file)
 575                 (message "%s: no such file or directory." the-file))))))
 576       result)))
 577
 578
 579 ;;; Core functions:
 580
 581 (defun org-protocol-check-filename-for-protocol (fname restoffiles client)
 582   "Detect if `org-protocol-the-protocol' and a known sub-protocol is used in fname.
 583 Sub-protocols are registered in `org-protocol-protocol-alist' and
 584 `org-protocol-protocol-alist-default'.
 585 This is, how the matching is done:
 586
 587   (string-match \"protocol:/+sub-protocol:/+\" ...)
 588
 589 protocol and sub-protocol are regexp-quoted.
 590
 591 If a matching protcol is found, the protcol is stripped from fname and the
 592 result is passed to the protocols function as the only parameter. If the
 593 function returns nil, the filename is removed from the list of filenames
 594 passed from emacsclient to the server.
 595 If the function returns a non nil value, that value is passed to the server
 596 as filename."
 597   (let ((sub-protocols (append org-protocol-protocol-alist org-protocol-protocol-alist-default)))
 598     (catch 'fname
 599       (let ((the-protocol (concat (regexp-quote org-protocol-the-protocol) ":/+")))
 600         (when (string-match the-protocol fname)
 601           (dolist (prolist sub-protocols)
 602             (let ((proto (concat the-protocol (regexp-quote (plist-get (cdr prolist) :protocol)) ":/+")))
 603               (when (string-match proto fname)
 604                 (let* ((func (plist-get (cdr prolist) :function))
 605                        (greedy (plist-get (cdr prolist) :greedy))
 606                        (splitted (split-string fname proto))
 607                        (result (if greedy restoffiles (cadr splitted))))
 608                   (when (plist-get (cdr prolist) :kill-client)
 609                     (message "Greedy org-protocol handler. Killing client.")
 610                     (server-edit))
 611                   (when (fboundp func)
 612                     (unless greedy
 613                       (throw 'fname (funcall func result)))
 614                     (funcall func result)
 615                     (throw 'fname t))))))))
 616       ;; (message "fname: %s" fname)
 617       fname)))
 618
 619
 620 (defadvice server-visit-files (before org-protocol-detect-protocol-server activate)
 621   "Advice server-visit-flist to call `org-protocol-modify-filename-for-protocol'."
 622   (let ((flist (if org-protocol-reverse-list-of-files
 623                    (reverse  (ad-get-arg 0))
 624                  (ad-get-arg 0)))
 625         (client (ad-get-arg 1)))
 626     (catch 'greedy
 627       (dolist (var flist)
 628         (let ((fname  (expand-file-name (car var)))) ;; `\' to `/' on windows. FIXME: could this be done any better?
 629           (setq fname (org-protocol-check-filename-for-protocol fname (member var flist)  client))
 630           (if (eq fname t) ;; greedy? We need the `t' return value.
 631               (progn
 632                 (ad-set-arg 0 nil)
 633                 (throw 'greedy t))
 634             (if (stringp fname) ;; probably filename
 635                 (setcar var fname)
 636               (ad-set-arg 0 (delq var (ad-get-arg 0))))))
 637         ))))
 638
 639 ;;; Org specific functions:
 640
 641 (defun org-protocol-create-for-org ()
 642   "Create a org-protocol project for the current file's Org-mode project.
 643 This works, if the file visited is part of a publishing project in
 644 `org-publish-project-alist'. This functions calls `org-protocol-create' to do
 645 most of the work."
 646   (interactive)
 647   (require 'org-publish)
 648   (let ((all (or (org-publish-get-project-from-filename buffer-file-name))))
 649     (if all (org-protocol-create (cdr all))
 650       (message "Not in an org-project. Did mean %s?"
 651                (substitute-command-keys"\\[org-protocol-create]")))))
 652
 653
 654 (defun org-protocol-create(&optional project-plist)
 655   "Create a new org-protocol project interactively.
 656 An org-protocol project is an entry in `org-protocol-project-alist'
 657 which is used by `org-protocol-open-source'.
 658 Optionally use project-plist to initialize the defaults for this project. If
 659 project-plist is the CDR of an element in `org-publish-project-alist', reuse
 660 :base-directory, :html-extension and :base-extension."
 661   (interactive)
 662   (let ((working-dir (expand-file-name(or (plist-get project-plist :base-directory) default-directory)))
 663         (base-url "http://orgmode.org/worg/")
 664         (strip-suffix (or (plist-get project-plist :html-extension) ".html"))
 665         (working-suffix (if (plist-get project-plist :base-extension)
 666                             (concat "." (plist-get project-plist :base-extension))
 667                           ".org"))
 668
 669         (worglet-buffer nil)
 670
 671         (insert-default-directory t)
 672         (minibuffer-allow-text-properties nil))
 673
 674     (setq base-url (read-string "Base URL of published content: " base-url nil base-url t))
 675     (if (not (string-match "\\/$" base-url))
 676         (setq base-url (concat base-url "/")))
 677
 678     (setq working-dir
 679           (expand-file-name
 680            (read-directory-name "Local working directory: " working-dir working-dir t)))
 681     (if (not (string-match "\\/$" working-dir))
 682         (setq working-dir (concat working-dir "/")))
 683
 684     (setq strip-suffix
 685           (read-string
 686            (concat "Extension to strip from published URLs ("strip-suffix"): ")
 687                    strip-suffix nil strip-suffix t))
 688
 689     (setq working-suffix
 690           (read-string
 691            (concat "Extension of editable files ("working-suffix"): ")
 692                    working-suffix nil working-suffix t))
 693
 694     (when (yes-or-no-p "Save the new org-protocol-project to your init file? ")
 695       (setq org-protocol-project-alist
 696             (cons `(,base-url . (:base-url ,base-url
 697                                  :working-directory ,working-dir
 698                                  :online-suffix ,strip-suffix
 699                                  :working-suffix ,working-suffix))
 700                   org-protocol-project-alist))
 701       (customize-save-variable 'org-protocol-project-alist org-protocol-project-alist))))
 702
 703 (provide 'org-protocol)
 704
 705 ;; arch-tag: b5c5c2ac-77cf-4a94-a649-2163dff95846
 706 ;;; org-protocol.el ends here