lisp/org-mew.el

   1 ;;; org-mew.el --- Support for links to Mew messages from within Org-mode
   2
   3 ;; Copyright (C) 2008, 2009, 2010 Free Software Foundation, Inc.
   4
   5 ;; Author: Tokuya Kameshima <kames at fa2 dot so-net dot ne dot jp>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: http://orgmode.org
   8 ;; Version: 6.36trans
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  25 ;;
  26 ;;; Commentary:
  27
  28 ;; This file implements links to Mew messages from within Org-mode.
  29 ;; Org-mode loads this module by default - if this is not what you want,
  30 ;; configure the variable `org-modules'.
  31
  32 ;;; Code:
  33
  34 (require 'org)
  35
  36 (defgroup org-mew nil
  37   "Options concerning the Mew link."
  38   :tag "Org Startup"
  39   :group 'org-link)
  40
  41 (defcustom org-mew-link-to-refile-destination t
  42   "Create a link to the refile destination if the message is marked as refile."
  43   :group 'org-mew
  44   :type 'boolean)
  45
  46 ;; Declare external functions and variables
  47 (declare-function mew-cache-hit "ext:mew-cache" (fld msg &optional must-hit))
  48 (declare-function mew-case-folder "ext:mew-func" (case folder))
  49 (declare-function mew-header-get-value "ext:mew-header"
  50                   (field &optional as-list))
  51 (declare-function mew-init "ext:mew" ())
  52 (declare-function mew-refile-get "ext:mew-refile" (msg))
  53 (declare-function mew-sinfo-get-case "ext:mew-summary" ())
  54 (declare-function mew-summary-display "ext:mew-summary2" (&optional redisplay))
  55 (declare-function mew-summary-folder-name "ext:mew-syntax" (&optional ext))
  56 (declare-function mew-summary-get-mark "ext:mew-mark" ())
  57 (declare-function mew-summary-message-number2 "ext:mew-syntax" ())
  58 (declare-function mew-summary-pick-with-mewl "ext:mew-pick"
  59                   (pattern folder src-msgs))
  60 (declare-function mew-summary-search-msg "ext:mew-const" (msg))
  61 (declare-function mew-summary-set-message-buffer "ext:mew-summary3" (fld msg))
  62 (declare-function mew-summary-visit-folder "ext:mew-summary4"
  63                   (folder &optional goend no-ls))
  64 (declare-function mew-window-push "ext:mew" ())
  65 (defvar mew-init-p)
  66 (defvar mew-summary-goto-line-then-display)
  67
  68 ;; Install the link type
  69 (org-add-link-type "mew" 'org-mew-open)
  70 (add-hook 'org-store-link-functions 'org-mew-store-link)
  71
  72 ;; Implementation
  73 (defun org-mew-store-link ()
  74   "Store a link to a Mew folder or message."
  75   (when (memq major-mode '(mew-summary-mode mew-virtual-mode))
  76     (let* ((msgnum (mew-summary-message-number2))
  77            (mark-info (mew-summary-get-mark))
  78            (folder-name
  79             (if (and org-mew-link-to-refile-destination
  80                      (eq mark-info ?o)) ; marked as refile
  81                 (mew-case-folder (mew-sinfo-get-case)
  82                                  (nth 1 (mew-refile-get msgnum)))
  83               (mew-summary-folder-name)))
  84            message-id from to subject desc link)
  85       (save-window-excursion
  86         (if (fboundp 'mew-summary-set-message-buffer)
  87             (mew-summary-set-message-buffer folder-name msgnum)
  88           (set-buffer (mew-cache-hit folder-name msgnum t)))
  89         (setq message-id (mew-header-get-value "Message-Id:"))
  90         (setq from (mew-header-get-value "From:"))
  91         (setq to (mew-header-get-value "To:"))
  92         (setq subject (mew-header-get-value "Subject:")))
  93       (org-store-link-props :type "mew" :from from :to to
  94                             :subject subject :message-id message-id)
  95       (setq message-id (org-remove-angle-brackets message-id))
  96       (setq desc (org-email-link-description))
  97       (setq link (org-make-link "mew:" folder-name
  98                                 "#" message-id))
  99       (org-add-link-props :link link :description desc)
 100       link)))
 101
 102 (defun org-mew-open (path)
 103   "Follow the Mew message link specified by PATH."
 104   (let (folder msgnum)
 105     (cond ((string-match "\\`\\(+.*\\)+\\+\\([0-9]+\\)\\'" path) ; for Bastien's
 106            (setq folder (match-string 1 path))
 107            (setq msgnum (match-string 2 path)))
 108           ((string-match "\\`\\(\\(%#\\)?[^#]+\\)\\(#\\(.*\\)\\)?" path)
 109            (setq folder (match-string 1 path))
 110            (setq msgnum (match-string 4 path)))
 111           (t (error "Error in Mew link")))
 112     (require 'mew)
 113     (mew-window-push)
 114     (unless mew-init-p (mew-init))
 115     (mew-summary-visit-folder folder)
 116     (when msgnum
 117       (if (not (string-match "\\`[0-9]+\\'" msgnum))
 118           (let* ((pattern (concat "message-id=" msgnum))
 119                  (msgs (mew-summary-pick-with-mewl pattern folder nil)))
 120             (setq msgnum (car msgs))))
 121       (if (mew-summary-search-msg msgnum)
 122           (if mew-summary-goto-line-then-display
 123               (mew-summary-display))
 124         (error "Message not found")))))
 125
 126 (provide 'org-mew)
 127
 128 ;; arch-tag: 07ccdca7-6020-4941-a593-588a1e51b870
 129
 130 ;;; org-mew.el ends here