lisp/org-crypt.el

   1 ;;; org-crypt.el --- Public key encryption for org-mode entries
   2
   3 ;; Copyright (C) 2007, 2009, 2010  Free Software Foundation, Inc.
   4
   5 ;; Emacs Lisp Archive Entry
   6 ;; Filename: org-crypt.el
   7 ;; Version: 7.4
   8 ;; Keywords: org-mode
   9 ;; Author: John Wiegley <johnw@gnu.org>
  10 ;; Maintainer: Peter Jones <pjones@pmade.com>
  11 ;; Description: Adds public key encryption to org-mode buffers
  12 ;; URL: http://www.newartisans.com/software/emacs.html
  13 ;; Compatibility: Emacs22
  14
  15 ;; This file is part of GNU Emacs.
  16 ;;
  17 ;; GNU Emacs is free software: you can redistribute it and/or modify
  18 ;; it under the terms of the GNU General Public License as published by
  19 ;; the Free Software Foundation, either version 3 of the License, or
  20 ;; (at your option) any later version.
  21
  22 ;; GNU Emacs is distributed in the hope that it will be useful,
  23 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  24 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  25 ;; GNU General Public License for more details.
  26
  27 ;; You should have received a copy of the GNU General Public License
  28 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  29
  30 ;;; Commentary:
  31
  32 ;; Right now this is just a set of functions to play with.  It depends
  33 ;; on the epg library.  Here's how you would use it:
  34 ;;
  35 ;; 1. To mark an entry for encryption, tag the heading with "crypt".
  36 ;;    You can change the tag to any complex tag matching string by
  37 ;;    setting the `org-crypt-tag-matcher' variable.
  38 ;;
  39 ;; 2. Set the encryption key to use in the `org-crypt-key' variable,
  40 ;;    or use `M-x org-set-property' to set the property CRYPTKEY to
  41 ;;    any address in your public keyring.  The text of the entry (but
  42 ;;    not its properties or headline) will be encrypted for this user.
  43 ;;    For them to read it, the corresponding secret key must be
  44 ;;    located in the secret key ring of the account where you try to
  45 ;;    decrypt it.  This makes it possible to leave secure notes that
  46 ;;    only the intended recipient can read in a shared-org-mode-files
  47 ;;    scenario.
  48 ;;    If the key is not set, org-crypt will default to symmetric encryption.
  49 ;;
  50 ;; 3. To later decrypt an entry, use `org-decrypt-entries' or
  51 ;;    `org-decrypt-entry'.  It might be useful to bind this to a key,
  52 ;;    like C-c C-/.  I hope that in the future, C-c C-r can be might
  53 ;;    overloaded to also decrypt an entry if it's encrypted, since
  54 ;;    that fits nicely with the meaning of "reveal".
  55 ;;
  56 ;; 4. To automatically encrypt all necessary entries when saving a
  57 ;;    file, call `org-crypt-use-before-save-magic' after loading
  58 ;;    org-crypt.el.
  59 ;;
  60 ;; TODO:
  61 ;;   - Allow symmetric encryption as well
  62
  63 ;;; Thanks:
  64
  65 ;; - Carsten Dominik
  66 ;; - Vitaly Ostanin
  67
  68 (require 'org)
  69
  70 ;;; Code:
  71
  72 (declare-function epg-decrypt-string "epg" (context cipher))
  73 (declare-function epg-list-keys "epg" (context &optional name mode))
  74 (declare-function epg-make-context "epg"
  75                   (&optional protocol armor textmode include-certs
  76                              cipher-algorithm digest-algorithm
  77                              compress-algorithm))
  78 (declare-function epg-encrypt-string "epg"
  79                   (context plain recipients &optional sign always-trust))
  80
  81 (defgroup org-crypt nil
  82   "Org Crypt"
  83   :tag "Org Crypt" :group 'org)
  84
  85 (defcustom org-crypt-tag-matcher "crypt"
  86   "The tag matcher used to find headings whose contents should be encrypted.
  87
  88 See the \"Match syntax\" section of the org manual for more details."
  89   :type 'string :group 'org-crypt)
  90
  91 (defcustom org-crypt-key nil
  92   "The default key to use when encrypting the contents of a heading.
  93
  94 This setting can also be overridden in the CRYPTKEY property."
  95   :type 'string :group 'org-crypt)
  96
  97 (defun org-crypt-key-for-heading ()
  98   "Return the encryption key for the current heading."
  99   (save-excursion
 100     (org-back-to-heading t)
 101     (or (org-entry-get nil "CRYPTKEY" 'selective)
 102         org-crypt-key
 103         (and (boundp 'epa-file-encrypt-to) epa-file-encrypt-to)
 104         (message "No crypt key set, using symmetric encryption."))))
 105
 106 (defun org-encrypt-string (str crypt-key)
 107   "Return STR encrypted with CRYPT-KEY."
 108   ;; Text and key have to be identical, otherwise we re-crypt.
 109   (if (and (string= crypt-key (get-text-property 0 'org-crypt-key str))
 110            (string= (sha1 str) (get-text-property 0 'org-crypt-checksum str)))
 111       (get-text-property 0 'org-crypt-text str)
 112     (let ((epg-context (epg-make-context nil t t)))
 113       (epg-encrypt-string epg-context str (epg-list-keys epg-context crypt-key)))))
 114
 115 (defun org-encrypt-entry ()
 116   "Encrypt the content of the current headline."
 117   (interactive)
 118   (require 'epg)
 119   (save-excursion
 120     (org-back-to-heading t)
 121     (let ((start-heading (point)))
 122       (forward-line)
 123       (when (not (looking-at "-----BEGIN PGP MESSAGE-----"))
 124         (let ((folded (outline-invisible-p))
 125               (epg-context (epg-make-context nil t t))
 126               (crypt-key (org-crypt-key-for-heading))
 127               (beg (point))
 128               end encrypted-text)
 129           (goto-char start-heading)
 130           (org-end-of-subtree t t)
 131           (org-back-over-empty-lines)
 132           (setq end (point)
 133                 encrypted-text
 134                 (org-encrypt-string (buffer-substring beg end) crypt-key))
 135           (delete-region beg end)
 136           (insert encrypted-text)
 137           (when folded
 138             (goto-char start-heading)
 139             (hide-subtree))
 140           nil)))))
 141
 142 (defun org-decrypt-entry ()
 143   "Decrypt the content of the current headline."
 144   (interactive)
 145   (require 'epg)
 146   (unless (org-before-first-heading-p)
 147     (save-excursion
 148       (org-back-to-heading t)
 149       (let ((heading-point (point))
 150             (heading-was-invisible-p
 151              (save-excursion
 152                (outline-end-of-heading)
 153                (outline-invisible-p))))
 154         (forward-line)
 155         (when (looking-at "-----BEGIN PGP MESSAGE-----")
 156           (let* ((end (save-excursion
 157                         (search-forward "-----END PGP MESSAGE-----")
 158                         (forward-line)
 159                         (point)))
 160                  (epg-context (epg-make-context nil t t))
 161                  (encrypted-text (buffer-substring-no-properties (point) end))
 162                  (decrypted-text
 163                   (decode-coding-string
 164                    (epg-decrypt-string
 165                     epg-context
 166                     encrypted-text)
 167                    'utf-8)))
 168             ;; Delete region starting just before point, because the
 169             ;; outline property starts at the \n of the heading.
 170             (delete-region (1- (point)) end)
 171             ;; Store a checksum of the decrypted and the encrypted
 172             ;; text value. This allow to reuse the same encrypted text
 173             ;; if the text does not change, and therefore avoid a
 174             ;; re-encryption process.
 175             (insert "\n" (propertize decrypted-text
 176                                      'org-crypt-checksum (sha1 decrypted-text)
 177                                      'org-crypt-key (org-crypt-key-for-heading)
 178                                      'org-crypt-text encrypted-text))
 179             (when heading-was-invisible-p
 180               (goto-char heading-point)
 181               (org-flag-subtree t))
 182             nil))))))
 183
 184 (defun org-encrypt-entries ()
 185   "Encrypt all top-level entries in the current buffer."
 186   (interactive)
 187   (org-scan-tags
 188    'org-encrypt-entry
 189    (cdr (org-make-tags-matcher org-crypt-tag-matcher))))
 190
 191 (defun org-decrypt-entries ()
 192   "Decrypt all entries in the current buffer."
 193   (interactive)
 194   (org-scan-tags
 195    'org-decrypt-entry
 196    (cdr (org-make-tags-matcher org-crypt-tag-matcher))))
 197
 198 (defun org-crypt-use-before-save-magic ()
 199   "Add a hook to automatically encrypt entries before a file is saved to disk."
 200   (add-hook
 201    'org-mode-hook
 202    (lambda () (add-hook 'before-save-hook 'org-encrypt-entries nil t))))
 203
 204 (add-hook 'org-reveal-start-hook 'org-decrypt-entry)
 205
 206 (provide 'org-crypt)
 207
 208 ;; arch-tag: 8202ed2c-221e-4001-9e4b-54674a7e846e
 209
 210 ;;; org-crypt.el ends here