lisp/org-bibtex.el

   1 ;;; org-bibtex.el --- Org links to BibTeX entries
   2 ;;
   3 ;; Copyright (C) 2007-2012  Free Software Foundation, Inc.
   4 ;;
   5 ;; Authors: Bastien Guerry <bzg at altern dot org>
   6 ;;       Carsten Dominik <carsten dot dominik at gmail dot com>
   7 ;;       Eric Schulte <schulte dot eric at gmail dot com>
   8 ;; Keywords: org, wp, remember
   9 ;;
  10 ;; This file is part of GNU Emacs.
  11 ;;
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24 ;;
  25 ;;; Commentary:
  26 ;;
  27 ;; This file implements links to database entries in BibTeX files.
  28 ;; Instead of defining a special link prefix, it uses the normal file
  29 ;; links combined with a custom search mechanism to find entries
  30 ;; by reference key.  And it constructs a nice description tag for
  31 ;; the link that contains the author name, the year and a short title.
  32 ;;
  33 ;; It also stores detailed information about the entry so that
  34 ;; remember templates can access and enter this information easily.
  35 ;;
  36 ;; The available properties for each entry are listed here:
  37 ;;
  38 ;; :author        :publisher      :volume      :pages
  39 ;; :editor        :url            :number      :journal
  40 ;; :title         :year           :series      :address
  41 ;; :booktitle     :month          :annote      :abstract
  42 ;; :key           :btype
  43 ;;
  44 ;; Here is an example of a remember template that use some of this
  45 ;; information (:author :year :title :journal :pages):
  46 ;;
  47 ;; (setq org-remember-templates
  48 ;;   '((?b "* READ %?\n\n%a\n\n%:author (%:year): %:title\n   \
  49 ;;          In %:journal, %:pages.")))
  50 ;;
  51 ;; Let's say you want to remember this BibTeX entry:
  52 ;;
  53 ;; @Article{dolev83,
  54 ;;   author =    {Danny Dolev and Andrew C. Yao},
  55 ;;   title =     {On the security of public-key protocols},
  56 ;;   journal =   {IEEE Transaction on Information Theory},
  57 ;;   year =      1983,
  58 ;;   volume =    2,
  59 ;;   number =    29,
  60 ;;   pages =     {198--208},
  61 ;;   month =     {Mars}
  62 ;; }
  63 ;;
  64 ;; M-x `org-remember' on this entry will produce this buffer:
  65 ;;
  66 ;; =====================================================================
  67 ;; * READ <== [point here]
  68 ;;
  69 ;; [[file:file.bib::dolev83][Dolev & Yao 1983: security of public key protocols]]
  70 ;;
  71 ;; Danny Dolev and Andrew C. Yao (1983): On the security of public-key protocols
  72 ;; In IEEE Transaction on Information Theory, 198--208.
  73 ;; =====================================================================
  74 ;;
  75 ;; Additionally, the following functions are now available for storing
  76 ;; bibtex entries within Org-mode documents.
  77 ;;
  78 ;; - Run `org-bibtex' to export the current file to a .bib.
  79 ;;
  80 ;; - Run `org-bibtex-check' or `org-bibtex-check-all' to check and
  81 ;;   fill in missing field of either the current, or all headlines
  82 ;;
  83 ;; - Run `org-bibtex-create' to add a bibtex entry
  84 ;;
  85 ;; - Use `org-bibtex-read' to read a bibtex entry after `point' or in
  86 ;;   the active region, then call `org-bibtex-write' in a .org file to
  87 ;;   insert a heading for the read bibtex entry
  88 ;;
  89 ;; - All Bibtex information is taken from the document compiled by
  90 ;;   Andrew Roberts from the Bibtex manual, available at
  91 ;;   http://www.andy-roberts.net/misc/latex/sessions/bibtex/bibentries.pdf
  92 ;;
  93 ;;; History:
  94 ;;
  95 ;; The link creation part has been part of Org-mode for a long time.
  96 ;;
  97 ;; Creating better remember template information was inspired by a request
  98 ;; of Austin Frank: http://article.gmane.org/gmane.emacs.orgmode/4112
  99 ;; and then implemented by Bastien Guerry.
 100 ;;
 101 ;; Eric Schulte eventually added the functions for translating between
 102 ;; Org-mode headlines and Bibtex entries, and for fleshing out the Bibtex
 103 ;; fields of existing Org-mode headlines.
 104 ;;
 105 ;; Org-mode loads this module by default - if this is not what you want,
 106 ;; configure the variable `org-modules'.
 107
 108 ;;; Code:
 109
 110 (require 'org)
 111 (require 'bibtex)
 112 (eval-when-compile
 113   (require 'cl))
 114
 115 (defvar org-bibtex-description nil) ; dynamically scoped from org.el
 116 (defvar org-id-locations)
 117
 118 (declare-function bibtex-beginning-of-entry "bibtex" ())
 119 (declare-function bibtex-generate-autokey "bibtex" ())
 120 (declare-function bibtex-parse-entry "bibtex" (&optional content))
 121 (declare-function bibtex-url "bibtex" (&optional pos no-browse))
 122 (declare-function longlines-mode "longlines" (&optional arg))
 123 (declare-function org-babel-trim "ob" (string &optional regexp))
 124
 125 \f
 126 ;;; Bibtex data
 127 (defvar org-bibtex-types
 128   '((:article
 129      (:description . "An article from a journal or magazine")
 130      (:required :author :title :journal :year)
 131      (:optional :volume :number :pages :month :note))
 132     (:book
 133      (:description . "A book with an explicit publisher")
 134      (:required (:editor :author) :title :publisher :year)
 135      (:optional (:volume :number) :series :address :edition :month :note))
 136     (:booklet
 137      (:description . "A work that is printed and bound, but without a named publisher or sponsoring institution.")
 138      (:required :title)
 139      (:optional :author :howpublished :address :month :year :note))
 140     (:conference
 141      (:description . "")
 142      (:required :author :title :booktitle :year)
 143      (:optional :editor :pages :organization :publisher :address :month :note))
 144     (:inbook
 145      (:description . "A part of a book, which may be a chapter (or section or whatever) and/or a range of pages.")
 146      (:required (:author :editor) :title (:chapter :pages) :publisher :year)
 147      (:optional :crossref (:volume :number) :series :type :address :edition :month :note))
 148     (:incollection
 149      (:description . "A part of a book having its own title.")
 150      (:required :author :title :booktitle :publisher :year)
 151      (:optional :crossref :editor (:volume :number) :series :type :chapter :pages :address :edition :month :note))
 152     (:inproceedings
 153      (:description . "An article in a conference proceedings")
 154      (:required :author :title :booktitle :year)
 155      (:optional :crossref :editor (:volume :number) :series :pages :address :month :organization :publisher :note))
 156     (:manual
 157      (:description . "Technical documentation.")
 158      (:required :title)
 159      (:optional :author :organization :address :edition :month :year :note))
 160     (:mastersthesis
 161      (:description . "A Master’s thesis.")
 162      (:required :author :title :school :year)
 163      (:optional :type :address :month :note))
 164     (:misc
 165      (:description . "Use this type when nothing else fits.")
 166      (:required)
 167      (:optional :author :title :howpublished :month :year :note))
 168     (:phdthesis
 169      (:description . "A PhD thesis.")
 170      (:required :author :title :school :year)
 171      (:optional :type :address :month :note))
 172     (:proceedings
 173      (:description . "The proceedings of a conference.")
 174      (:required :title :year)
 175      (:optional :editor (:volume :number) :series :address :month :organization :publisher :note))
 176     (:techreport
 177      (:description . "A report published by a school or other institution.")
 178      (:required :author :title :institution :year)
 179      (:optional :type :address :month :note))
 180     (:unpublished
 181      (:description . "A document having an author and title, but not formally published.")
 182      (:required :author :title :note)
 183      (:optional :month :year)))
 184   "Bibtex entry types with required and optional parameters.")
 185
 186 (defvar org-bibtex-fields
 187   '((:address      . "Usually the address of the publisher or other type of institution. For major publishing houses, van Leunen recommends omitting the information entirely.  For small publishers, on the other hand, you can help the reader by giving the complete address.")
 188     (:annote       . "An annotation. It is not used by the standard bibliography styles, but may be used by others that produce an annotated bibliography.")
 189     (:author       . "The name(s) of the author(s), in the format described in the LaTeX book.  Remember, all names are separated with the and keyword, and not commas.")
 190     (:booktitle    . "Title of a book, part of which is being cited. See the LaTeX book for how to type titles. For book entries, use the title field instead.")
 191     (:chapter      . "A chapter (or section or whatever) number.")
 192     (:crossref     . "The database key of the entry being cross referenced.")
 193     (:edition      . "The edition of a book for example, 'Second'. This should be an ordinal, and should have the first letter capitalized, as shown here; the standard styles convert to lower case when necessary.")
 194     (:editor       . "Name(s) of editor(s), typed as indicated in the LaTeX book. If there is also an author field, then the editor field gives the editor of the book or collection in which the reference appears.")
 195     (:howpublished . "How something strange has been published. The first word should be capitalized.")
 196     (:institution  . "The sponsoring institution of a technical report.")
 197     (:journal      . "A journal name.")
 198     (:key          . "Used for alphabetizing, cross-referencing, and creating a label when the author information is missing. This field should not be confused with the key that appears in the \cite command and at the beginning of the database entry.")
 199     (:month        . "The month in which the work was published or, for an unpublished work, in which it was written. You should use the standard three-letter abbreviation,")
 200     (:note         . "Any additional information that can help the reader. The first word should be capitalized.")
 201     (:number       . "Any additional information that can help the reader. The first word should be capitalized.")
 202     (:organization . "The organization that sponsors a conference or that publishes a manual.")
 203     (:pages        . "One or more page numbers or range of numbers, such as 42-111 or 7,41,73-97 or 43+ (the ‘+’ in this last example indicates pages following that don’t form simple range). BibTEX requires double dashes for page ranges (--).")
 204     (:publisher    . "The publisher’s name.")
 205     (:school       . "The name of the school where a thesis was written.")
 206     (:series       . "The name of a series or set of books. When citing an entire book, the the title field gives its title and an optional series field gives the name of a series or multi-volume set in which the book is published.")
 207     (:title        . "The work’s title, typed as explained in the LaTeX book.")
 208     (:type         . "The type of a technical report for example, 'Research Note'.")
 209     (:volume       . "The volume of a journal or multi-volume book.")
 210     (:year         . "The year of publication or, for an unpublished work, the year it was written.  Generally it should consist of four numerals, such as 1984, although the standard styles can handle any year whose last four nonpunctuation characters are numerals, such as '(about 1984)'"))
 211   "Bibtex fields with descriptions.")
 212
 213 (defvar org-bibtex-entries nil
 214   "List to hold parsed bibtex entries.")
 215
 216 (defcustom org-bibtex-autogen-keys nil
 217   "Set to a truth value to use `bibtex-generate-autokey' to generate keys."
 218   :group 'org-bibtex
 219   :version "24.1"
 220   :type  'boolean)
 221
 222 (defcustom org-bibtex-prefix nil
 223   "Optional prefix for all bibtex property names.
 224 For example setting to 'BIB_' would allow interoperability with fireforg."
 225   :group 'org-bibtex
 226   :version "24.1"
 227   :type  'string)
 228
 229 (defcustom org-bibtex-treat-headline-as-title t
 230   "Treat headline text as title if title property is absent.
 231 If an entry is missing a title property, use the headline text as
 232 the property. If this value is t, `org-bibtex-check' will ignore
 233 a missing title field."
 234   :group 'org-bibtex
 235   :version "24.1"
 236   :type 'boolean)
 237
 238 (defcustom org-bibtex-export-arbitrary-fields nil
 239   "When converting to bibtex allow fields not defined in `org-bibtex-fields'.
 240 This only has effect if `org-bibtex-prefix' is defined, so as to
 241 ensure that other org-properties, such as CATEGORY or LOGGING are
 242 not placed in the exported bibtex entry."
 243   :group 'org-bibtex
 244   :version "24.1"
 245   :type 'boolean)
 246
 247 (defcustom org-bibtex-key-property "CUSTOM_ID"
 248   "Property that holds the bibtex key.
 249 By default, this is CUSTOM_ID, which enables easy linking to
 250 bibtex headlines from within an org file. This can be set to ID
 251 to enable global links, but only with great caution, as global
 252 IDs must be unique."
 253   :group 'org-bibtex
 254   :version "24.1"
 255   :type 'string)
 256
 257 (defcustom org-bibtex-tags nil
 258   "List of tag(s) that should be added to new bib entries."
 259   :group 'org-bibtex
 260   :version "24.1"
 261   :type '(repeat  :tag "Tag" (string)))
 262
 263 (defcustom org-bibtex-tags-are-keywords nil
 264   "Convert the value of the keywords field to tags and vice versa.
 265 If set to t, comma-separated entries in a bibtex entry's keywords
 266 field will be converted to org tags. Note: spaces will be escaped
 267 with underscores, and characters that are not permitted in org
 268 tags will be removed.
 269
 270 If t, local tags in an org entry will be exported as a
 271 comma-separated string of keywords when exported to bibtex. Tags
 272 defined in `org-bibtex-tags' or `org-bibtex-no-export-tags' will
 273 not be exported."
 274   :group 'org-bibtex
 275   :version "24.1"
 276   :type 'boolean)
 277
 278 (defcustom org-bibtex-no-export-tags nil
 279   "List of tag(s) that should not be converted to keywords.
 280 This variable is relevant only if `org-bibtex-export-tags-as-keywords` is t."
 281   :group 'org-bibtex
 282   :version "24.1"
 283   :type '(repeat :tag "Tag" (string)))
 284
 285 (defcustom org-bibtex-type-property-name "btype"
 286   "Property in which to store bibtex entry type (e.g., article)."
 287   :group 'org-bibtex
 288   :version "24.1"
 289   :type 'string)
 290
 291 \f
 292 ;;; Utility functions
 293 (defun org-bibtex-get (property)
 294   ((lambda (it) (when it (org-babel-trim it)))
 295    (let ((org-special-properties
 296           (delete "FILE" (copy-sequence org-special-properties))))
 297      (or
 298       (org-entry-get (point) (upcase property))
 299       (org-entry-get (point) (concat org-bibtex-prefix (upcase property)))))))
 300
 301 (defun org-bibtex-put (property value)
 302   (let ((prop (upcase (if (keywordp property)
 303                           (substring (symbol-name property) 1)
 304                         property))))
 305     (org-set-property
 306      (concat (unless (string= org-bibtex-key-property prop) org-bibtex-prefix)
 307              prop)
 308      value)))
 309
 310 (defun org-bibtex-headline ()
 311   "Return a bibtex entry of the given headline as a string."
 312   (org-labels
 313    ((val (key lst) (cdr (assoc key lst)))
 314     (to (string) (intern (concat ":" string)))
 315     (from (key) (substring (symbol-name key) 1))
 316     (flatten (&rest lsts)
 317              (apply #'append (mapcar
 318                               (lambda (e)
 319                                 (if (listp e) (apply #'flatten e) (list e)))
 320                               lsts))))
 321     (let ((notes (buffer-string))
 322           (id (org-bibtex-get org-bibtex-key-property))
 323           (type (org-bibtex-get org-bibtex-type-property-name))
 324           (tags (when org-bibtex-tags-are-keywords
 325                   (delq nil
 326                         (mapcar
 327                          (lambda (tag)
 328                            (unless (member tag
 329                                            (append org-bibtex-tags
 330                                                    org-bibtex-no-export-tags))
 331                              tag))
 332                          (org-get-local-tags-at))))))
 333       (when type
 334         (let ((entry (format
 335                       "@%s{%s,\n%s\n}\n" type id
 336                       (mapconcat
 337                        (lambda (pair)
 338                          (format "  %s={%s}" (car pair) (cdr pair)))
 339                        (remove nil
 340                          (if (and org-bibtex-export-arbitrary-fields
 341                                   org-bibtex-prefix)
 342                              (mapcar
 343                               (lambda (kv)
 344                                 (let ((key (car kv)) (val (cdr kv)))
 345                                   (when (and
 346                                          (string-match org-bibtex-prefix key)
 347                                          (not (string=
 348                                                (downcase (concat org-bibtex-prefix
 349                                                                  org-bibtex-type-property-name))
 350                                                (downcase key))))
 351                                     (cons (downcase (replace-regexp-in-string
 352                                                      org-bibtex-prefix "" key))
 353                                           val))))
 354                               (org-entry-properties nil 'standard))
 355                            (mapcar
 356                             (lambda (field)
 357                               (let ((value (or (org-bibtex-get (from field))
 358                                                (and (equal :title field)
 359                                                     (nth 4 (org-heading-components))))))
 360                                 (when value (cons (from field) value))))
 361                             (flatten
 362                              (val :required (val (to type) org-bibtex-types))
 363                              (val :optional (val (to type) org-bibtex-types))))))
 364                        ",\n"))))
 365           (with-temp-buffer
 366             (insert entry)
 367             (when tags
 368               (bibtex-beginning-of-entry)
 369               (if (re-search-forward "keywords.*=.*{\\(.*\\)}" nil t)
 370                   (progn (goto-char (match-end 1)) (insert ", "))
 371                 (bibtex-make-field "keywords" t t))
 372               (insert (mapconcat #'identity tags ", ")))
 373             (buffer-string)))))))
 374
 375 (defun org-bibtex-ask (field)
 376   (unless (assoc field org-bibtex-fields)
 377     (error "field:%s is not known" field))
 378   (save-window-excursion
 379     (let* ((name (substring (symbol-name field) 1))
 380            (buf-name (format "*Bibtex Help %s*" name)))
 381       (with-output-to-temp-buffer buf-name
 382         (princ (cdr (assoc field org-bibtex-fields))))
 383       (with-current-buffer buf-name (longlines-mode t))
 384       (org-fit-window-to-buffer (get-buffer-window buf-name))
 385       ((lambda (result) (when (> (length result) 0) result))
 386        (read-from-minibuffer (format "%s: " name))))))
 387
 388 (defun org-bibtex-autokey ()
 389   "Generate an autokey for the current headline."
 390   (org-bibtex-put org-bibtex-key-property
 391                   (if org-bibtex-autogen-keys
 392                       (let* ((entry (org-bibtex-headline))
 393                              (key
 394                               (with-temp-buffer
 395                                 (insert entry)
 396                                 (bibtex-generate-autokey))))
 397                         ;; test for duplicate IDs if using global ID
 398                         (when (and
 399                                (equal org-bibtex-key-property "ID")
 400                                (featurep 'org-id)
 401                                (hash-table-p org-id-locations)
 402                                (gethash key org-id-locations))
 403                           (warn "Another entry has the same ID"))
 404                         key)
 405                     (read-from-minibuffer "id: "))))
 406
 407 (defun org-bibtex-fleshout (type &optional optional)
 408   "Fleshout the current heading, ensuring that all required fields are present.
 409 With optional argument OPTIONAL, also prompt for optional fields."
 410   (org-flet ((val (key lst) (cdr (assoc key lst)))
 411          (keyword (name) (intern (concat ":" (downcase name))))
 412          (name (keyword) (substring (symbol-name keyword) 1)))
 413     (dolist (field (append
 414                     (if org-bibtex-treat-headline-as-title
 415                         (remove :title (val :required (val type org-bibtex-types)))
 416                       (val :required (val type org-bibtex-types)))
 417                     (when optional (val :optional (val type org-bibtex-types)))))
 418       (when (consp field) ; or'd pair of fields e.g., (:editor :author)
 419         (let ((present (first (remove nil
 420                                 (mapcar
 421                                  (lambda (f) (when (org-bibtex-get (name f)) f))
 422                                  field)))))
 423           (setf field (or present (keyword (org-icompleting-read
 424                                             "Field: " (mapcar #'name field)))))))
 425       (let ((name (name field)))
 426         (unless (org-bibtex-get name)
 427           (let ((prop (org-bibtex-ask field)))
 428             (when prop (org-bibtex-put name prop)))))))
 429   (when (and type (assoc type org-bibtex-types)
 430              (not (org-bibtex-get org-bibtex-key-property)))
 431     (org-bibtex-autokey)))
 432
 433 \f
 434 ;;; Bibtex link functions
 435 (org-add-link-type "bibtex" 'org-bibtex-open)
 436 (add-hook 'org-store-link-functions 'org-bibtex-store-link)
 437
 438 (defun org-bibtex-open (path)
 439   "Visit the bibliography entry on PATH."
 440   (let* ((search (when (string-match "::\\(.+\\)\\'" path)
 441                    (match-string 1 path)))
 442          (path (substring path 0 (match-beginning 0))))
 443     (org-open-file path t nil search)))
 444
 445 (defun org-bibtex-store-link ()
 446   "Store a link to a BibTeX entry."
 447   (when (eq major-mode 'bibtex-mode)
 448     (let* ((search (org-create-file-search-in-bibtex))
 449            (link (concat "file:" (abbreviate-file-name buffer-file-name)
 450                          "::" search))
 451            (entry (mapcar ; repair strings enclosed in "..." or {...}
 452                    (lambda(c)
 453                      (if (string-match
 454                           "^\\(?:{\\|\"\\)\\(.*\\)\\(?:}\\|\"\\)$" (cdr c))
 455                          (cons (car c) (match-string 1 (cdr c))) c))
 456                    (save-excursion
 457                      (bibtex-beginning-of-entry)
 458                      (bibtex-parse-entry)))))
 459       (org-store-link-props
 460        :key (cdr (assoc "=key=" entry))
 461        :author (or (cdr (assoc "author" entry)) "[no author]")
 462        :editor (or (cdr (assoc "editor" entry)) "[no editor]")
 463        :title (or (cdr (assoc "title" entry)) "[no title]")
 464        :booktitle (or (cdr (assoc "booktitle" entry)) "[no booktitle]")
 465        :journal (or (cdr (assoc "journal" entry)) "[no journal]")
 466        :publisher (or (cdr (assoc "publisher" entry)) "[no publisher]")
 467        :pages (or (cdr (assoc "pages" entry)) "[no pages]")
 468        :url (or (cdr (assoc "url" entry)) "[no url]")
 469        :year (or (cdr (assoc "year" entry)) "[no year]")
 470        :month (or (cdr (assoc "month" entry)) "[no month]")
 471        :address (or (cdr (assoc "address" entry)) "[no address]")
 472        :volume (or (cdr (assoc "volume" entry)) "[no volume]")
 473        :number (or (cdr (assoc "number" entry)) "[no number]")
 474        :annote (or (cdr (assoc "annote" entry)) "[no annotation]")
 475        :series (or (cdr (assoc "series" entry)) "[no series]")
 476        :abstract (or (cdr (assoc "abstract" entry)) "[no abstract]")
 477        :btype (or (cdr (assoc "=type=" entry)) "[no type]")
 478        :type "bibtex"
 479        :link link
 480        :description org-bibtex-description))))
 481
 482 (defun org-create-file-search-in-bibtex ()
 483   "Create the search string and description for a BibTeX database entry."
 484   ;; Make a good description for this entry, using names, year and the title
 485   ;; Put it into the `description' variable which is dynamically scoped.
 486   (let ((bibtex-autokey-names 1)
 487         (bibtex-autokey-names-stretch 1)
 488         (bibtex-autokey-name-case-convert-function 'identity)
 489         (bibtex-autokey-name-separator " & ")
 490         (bibtex-autokey-additional-names " et al.")
 491         (bibtex-autokey-year-length 4)
 492         (bibtex-autokey-name-year-separator " ")
 493         (bibtex-autokey-titlewords 3)
 494         (bibtex-autokey-titleword-separator " ")
 495         (bibtex-autokey-titleword-case-convert-function 'identity)
 496         (bibtex-autokey-titleword-length 'infty)
 497         (bibtex-autokey-year-title-separator ": "))
 498     (setq org-bibtex-description (bibtex-generate-autokey)))
 499   ;; Now parse the entry, get the key and return it.
 500   (save-excursion
 501     (bibtex-beginning-of-entry)
 502     (cdr (assoc "=key=" (bibtex-parse-entry)))))
 503
 504 (defun org-execute-file-search-in-bibtex (s)
 505   "Find the link search string S as a key for a database entry."
 506   (when (eq major-mode 'bibtex-mode)
 507     ;; Yes, we want to do the search in this file.
 508     ;; We construct a regexp that searches for "@entrytype{" followed by the key
 509     (goto-char (point-min))
 510     (and (re-search-forward (concat "@[a-zA-Z]+[ \t\n]*{[ \t\n]*"
 511                                     (regexp-quote s) "[ \t\n]*,") nil t)
 512          (goto-char (match-beginning 0)))
 513     (if (and (match-beginning 0) (equal current-prefix-arg '(16)))
 514         ;; Use double prefix to indicate that any web link should be browsed
 515         (let ((b (current-buffer)) (p (point)))
 516           ;; Restore the window configuration because we just use the web link
 517           (set-window-configuration org-window-config-before-follow-link)
 518           (with-current-buffer b
 519             (goto-char p)
 520             (bibtex-url)))
 521       (recenter 0))  ; Move entry start to beginning of window
 522     ;; return t to indicate that the search is done.
 523     t))
 524
 525 ;; Finally add the link search function to the right hook.
 526 (add-hook 'org-execute-file-search-functions 'org-execute-file-search-in-bibtex)
 527
 528 \f
 529 ;;; Bibtex <-> Org-mode headline translation functions
 530 (defun org-bibtex (&optional filename)
 531   "Export each headline in the current file to a bibtex entry.
 532 Headlines are exported using `org-bibtex-export-headline'."
 533   (interactive
 534    (list (read-file-name
 535           "Bibtex file: " nil nil nil
 536           (file-name-nondirectory
 537            (concat (file-name-sans-extension (buffer-file-name)) ".bib")))))
 538   ((lambda (error-point)
 539      (when error-point
 540        (goto-char error-point)
 541        (message "Bibtex error at %S" (nth 4 (org-heading-components)))))
 542    (catch 'bib
 543      (let ((bibtex-entries (remove nil (org-map-entries
 544                                         (lambda ()
 545                                           (condition-case foo
 546                                               (org-bibtex-headline)
 547                                             (error (throw 'bib (point)))))))))
 548        (with-temp-file filename
 549          (insert (mapconcat #'identity bibtex-entries "\n")))
 550        (message "Successfully exported %d bibtex entries to %s"
 551                 (length bibtex-entries) filename) nil))))
 552
 553 (defun org-bibtex-check (&optional optional)
 554   "Check the current headline for required fields.
 555 With prefix argument OPTIONAL also prompt for optional fields."
 556   (interactive "P")
 557   (save-restriction
 558     (org-narrow-to-subtree)
 559     (let ((type ((lambda (name) (when name (intern (concat ":" name))))
 560                  (org-bibtex-get org-bibtex-type-property-name))))
 561       (when type (org-bibtex-fleshout type optional)))))
 562
 563 (defun org-bibtex-check-all (&optional optional)
 564   "Check all headlines in the current file.
 565 With prefix argument OPTIONAL also prompt for optional fields."
 566   (interactive) (org-map-entries (lambda () (org-bibtex-check optional))))
 567
 568 (defun org-bibtex-create (&optional arg nonew)
 569   "Create a new entry at the given level.
 570 With a prefix arg, query for optional fields as well.
 571 If nonew is t, add data to the headline of the entry at point."
 572   (interactive "P")
 573   (let* ((type (org-icompleting-read
 574                 "Type: " (mapcar (lambda (type)
 575                                    (substring (symbol-name (car type)) 1))
 576                                  org-bibtex-types)
 577                 nil nil (when nonew
 578                           (org-bibtex-get org-bibtex-type-property-name))))
 579          (type (if (keywordp type) type (intern (concat ":" type))))
 580          (org-bibtex-treat-headline-as-title (if nonew nil t)))
 581     (unless (assoc type org-bibtex-types)
 582       (error "type:%s is not known" type))
 583     (if nonew
 584         (org-back-to-heading)
 585       (org-insert-heading)
 586       (let ((title (org-bibtex-ask :title)))
 587         (insert title)
 588         (org-bibtex-put "TITLE" title)))
 589     (org-bibtex-put org-bibtex-type-property-name
 590                     (substring (symbol-name type) 1))
 591     (org-bibtex-fleshout type arg)
 592     (mapc (lambda (tag) (org-toggle-tag tag 'on)) org-bibtex-tags)))
 593
 594 (defun org-bibtex-create-in-current-entry (&optional arg)
 595   "Add bibliographical data to the current entry.
 596 With a prefix arg, query for optional fields."
 597   (interactive "P")
 598   (org-bibtex-create arg t))
 599
 600 (defun org-bibtex-read ()
 601   "Read a bibtex entry and save to `org-bibtex-entries'.
 602 This uses `bibtex-parse-entry'."
 603   (interactive)
 604   (org-flet ((keyword (str) (intern (concat ":" (downcase str))))
 605          (clean-space (str) (replace-regexp-in-string
 606                              "[[:space:]\n\r]+" " " str))
 607          (strip-delim (str)          ; strip enclosing "..." and {...}
 608                       (dolist (pair '((34 . 34) (123 . 125) (123 . 125)))
 609                         (when (and (= (aref str 0) (car pair))
 610                                    (= (aref str (1- (length str))) (cdr pair)))
 611                           (setf str (substring str 1 (1- (length str)))))) str))
 612     (push (mapcar
 613            (lambda (pair)
 614              (cons (let ((field (keyword (car pair))))
 615                      (case field
 616                        (:=type= :type)
 617                        (:=key= :key)
 618                        (otherwise field)))
 619                    (clean-space (strip-delim (cdr pair)))))
 620            (save-excursion (bibtex-beginning-of-entry) (bibtex-parse-entry)))
 621           org-bibtex-entries)))
 622
 623 (defun org-bibtex-write ()
 624   "Insert a heading built from the first element of `org-bibtex-entries'."
 625   (interactive)
 626   (when (= (length org-bibtex-entries) 0)
 627     (error "No entries in `org-bibtex-entries'."))
 628   (let ((entry (pop org-bibtex-entries))
 629         (org-special-properties nil)) ; avoids errors with `org-entry-put'
 630     (org-flet ((val (field) (cdr (assoc field entry)))
 631            (togtag (tag) (org-toggle-tag tag 'on)))
 632       (org-insert-heading)
 633       (insert (val :title))
 634       (org-bibtex-put "TITLE" (val :title))
 635       (org-bibtex-put org-bibtex-type-property-name (downcase (val :type)))
 636       (dolist (pair entry)
 637         (case (car pair)
 638           (:title    nil)
 639           (:type     nil)
 640           (:key      (org-bibtex-put org-bibtex-key-property (cdr pair)))
 641           (:keywords (if org-bibtex-tags-are-keywords
 642                           (mapc
 643                            (lambda (kw)
 644                              (togtag
 645                               (replace-regexp-in-string
 646                                "[^[:alnum:]_@#%]" ""
 647                                (replace-regexp-in-string "[ \t]+" "_" kw))))
 648                            (split-string (cdr pair) ", *"))
 649                        (org-bibtex-put (car pair) (cdr pair))))
 650           (otherwise (org-bibtex-put (car pair)  (cdr pair)))))
 651       (mapc #'togtag org-bibtex-tags))))
 652
 653 (defun org-bibtex-yank ()
 654   "If kill ring holds a bibtex entry yank it as an Org-mode headline."
 655   (interactive)
 656   (let (entry)
 657     (with-temp-buffer (yank 1) (setf entry (org-bibtex-read)))
 658     (if entry
 659         (org-bibtex-write)
 660       (error "yanked text does not appear to contain a bibtex entry"))))
 661
 662 (defun org-bibtex-export-to-kill-ring ()
 663   "Export current headline to kill ring as bibtex entry."
 664   (interactive)
 665   (let ((result (org-bibtex-headline)))
 666     (kill-new result) result))
 667
 668 (defun org-bibtex-search (string)
 669   "Search for bibliographical entries in agenda files.
 670 This function relies `org-search-view' to locate results."
 671   (interactive "sSearch string: ")
 672   (let ((org-agenda-overriding-header "Bib search results:")
 673         (org-agenda-search-view-always-boolean t))
 674     (org-search-view nil
 675                      (format "%s +{:%s%s:}"
 676                              string org-bibtex-prefix
 677                              org-bibtex-type-property-name))))
 678
 679 (provide 'org-bibtex)
 680
 681 ;;; org-bibtex.el ends here