lisp/org-latex.el

   1 ;;; org-latex.el --- LaTeX exporter for org-mode
   2 ;;
   3 ;; Copyright (C) 2007-2011 Free Software Foundation, Inc.
   4 ;;
   5 ;; Emacs Lisp Archive Entry
   6 ;; Filename: org-latex.el
   7 ;; Author: Bastien Guerry <bzg AT gnu DOT org>
   8 ;; Maintainer: Carsten Dominik <carsten.dominik AT gmail DOT com>
   9 ;; Keywords: org, wp, tex
  10 ;; Description: Converts an org-mode buffer into LaTeX
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28 ;;
  29 ;; This library implements a LaTeX exporter for org-mode.
  30 ;;
  31 ;; It is part of Org and will be autoloaded
  32 ;;
  33 ;; The interactive functions are similar to those of the HTML exporter:
  34 ;;
  35 ;; M-x `org-export-as-latex'
  36 ;; M-x `org-export-as-pdf'
  37 ;; M-x `org-export-as-pdf-and-open'
  38 ;; M-x `org-export-as-latex-batch'
  39 ;; M-x `org-export-as-latex-to-buffer'
  40 ;; M-x `org-export-region-as-latex'
  41 ;; M-x `org-replace-region-by-latex'
  42 ;;
  43 ;;; Code:
  44
  45 (eval-when-compile
  46   (require 'cl))
  47
  48 (require 'footnote)
  49 (require 'org)
  50 (require 'org-exp)
  51 (require 'org-macs)
  52 (require 'org-beamer)
  53
  54 ;;; Variables:
  55 (defvar org-export-latex-class nil)
  56 (defvar org-export-latex-class-options nil)
  57 (defvar org-export-latex-header nil)
  58 (defvar org-export-latex-append-header nil)
  59 (defvar org-export-latex-options-plist nil)
  60 (defvar org-export-latex-todo-keywords-1 nil)
  61 (defvar org-export-latex-complex-heading-re nil)
  62 (defvar org-export-latex-not-done-keywords nil)
  63 (defvar org-export-latex-done-keywords nil)
  64 (defvar org-export-latex-display-custom-times nil)
  65 (defvar org-export-latex-all-targets-re nil)
  66 (defvar org-export-latex-add-level 0)
  67 (defvar org-export-latex-footmark-seen nil
  68   "List of footnotes markers seen so far by exporter.")
  69 (defvar org-export-latex-sectioning "")
  70 (defvar org-export-latex-sectioning-depth 0)
  71 (defvar org-export-latex-special-keyword-regexp
  72   (concat "\\<\\(" org-scheduled-string "\\|"
  73           org-deadline-string "\\|"
  74           org-closed-string"\\)")
  75   "Regexp matching special time planning keywords plus the time after it.")
  76 (defvar org-re-quote)  ; dynamically scoped from org.el
  77 (defvar org-commentsp) ; dynamically scoped from org.el
  78
  79 ;;; User variables:
  80
  81 (defgroup org-export-latex nil
  82   "Options for exporting Org-mode files to LaTeX."
  83   :tag "Org Export LaTeX"
  84   :group 'org-export)
  85
  86 (defcustom org-export-latex-default-class "article"
  87   "The default LaTeX class."
  88   :group 'org-export-latex
  89   :type '(string :tag "LaTeX class"))
  90
  91 (defcustom org-export-latex-classes
  92   '(("article"
  93      "\\documentclass[11pt]{article}"
  94      ("\\section{%s}" . "\\section*{%s}")
  95      ("\\subsection{%s}" . "\\subsection*{%s}")
  96      ("\\subsubsection{%s}" . "\\subsubsection*{%s}")
  97      ("\\paragraph{%s}" . "\\paragraph*{%s}")
  98      ("\\subparagraph{%s}" . "\\subparagraph*{%s}"))
  99     ("report"
 100      "\\documentclass[11pt]{report}"
 101      ("\\part{%s}" . "\\part*{%s}")
 102      ("\\chapter{%s}" . "\\chapter*{%s}")
 103      ("\\section{%s}" . "\\section*{%s}")
 104      ("\\subsection{%s}" . "\\subsection*{%s}")
 105      ("\\subsubsection{%s}" . "\\subsubsection*{%s}"))
 106     ("book"
 107      "\\documentclass[11pt]{book}"
 108      ("\\part{%s}" . "\\part*{%s}")
 109      ("\\chapter{%s}" . "\\chapter*{%s}")
 110      ("\\section{%s}" . "\\section*{%s}")
 111      ("\\subsection{%s}" . "\\subsection*{%s}")
 112      ("\\subsubsection{%s}" . "\\subsubsection*{%s}"))
 113     ("beamer"
 114      "\\documentclass{beamer}"
 115      org-beamer-sectioning
 116      ))
 117   "Alist of LaTeX classes and associated header and structure.
 118 If #+LaTeX_CLASS is set in the buffer, use its value and the
 119 associated information.  Here is the structure of each cell:
 120
 121   \(class-name
 122     header-string
 123     (numbered-section . unnumbered-section\)
 124     ...\)
 125
 126 The header string
 127 -----------------
 128
 129 The HEADER-STRING is the header that will be inserted into the LaTeX file.
 130 It should contain the \\documentclass macro, and anything else that is needed
 131 for this setup.  To this header, the following commands will be added:
 132
 133 - Calls to \\usepackage for all packages mentioned in the variables
 134   `org-export-latex-default-packages-alist' and
 135   `org-export-latex-packages-alist'.  Thus, your header definitions should
 136   avoid to also request these packages.
 137
 138 - Lines specified via \"#+LaTeX_HEADER:\"
 139
 140 If you need more control about the sequence in which the header is built
 141 up, or if you want to exclude one of these building blocks for a particular
 142 class, you can use the following macro-like placeholders.
 143
 144  [DEFAULT-PACKAGES]      \\usepackage statements for default packages
 145  [NO-DEFAULT-PACKAGES]   do not include any of the default packages
 146  [PACKAGES]              \\usepackage statements for packages
 147  [NO-PACKAGES]           do not include the packages
 148  [EXTRA]                 the stuff from #+LaTeX_HEADER
 149  [NO-EXTRA]              do not include #+LaTeX_HEADER stuff
 150  [BEAMER-HEADER-EXTRA]   the beamer extra headers
 151
 152 So a header like
 153
 154   \\documentclass{article}
 155   [NO-DEFAULT-PACKAGES]
 156   [EXTRA]
 157   \\providecommand{\\alert}[1]{\\textbf{#1}}
 158   [PACKAGES]
 159
 160 will omit the default packages, and will include the #+LaTeX_HEADER lines,
 161 then have a call to \\providecommand, and then place \\usepackage commands
 162 based on the content of `org-export-latex-packages-alist'.
 163
 164 If your header or `org-export-latex-default-packages-alist' inserts
 165 \"\\usepackage[AUTO]{inputenc}\", AUTO will automatically be replaced with
 166 a coding system derived from `buffer-file-coding-system'.  See also the
 167 variable `org-export-latex-inputenc-alist' for a way to influence this
 168 mechanism.
 169
 170 The sectioning structure
 171 ------------------------
 172
 173 The sectioning structure of the class is given by the elements following
 174 the header string.  For each sectioning level, a number of strings is
 175 specified.  A %s formatter is mandatory in each section string and will
 176 be replaced by the title of the section.
 177
 178 Instead of a cons cell (numbered . unnumbered), you can also provide a list
 179 of 2 or 4 elements,
 180
 181   (numbered-open numbered-close)
 182
 183 or
 184
 185   (numbered-open numbered-close unnumbered-open unnumbered-close)
 186
 187 providing opening and closing strings for a LaTeX environment that should
 188 represent the document section.  The opening clause should have a %s
 189 to represent the section title.
 190
 191 Instead of a list of sectioning commands, you can also specify a
 192 function name.  That function will be called with two parameters,
 193 the (reduced) level of the headline, and the headline text.  The function
 194 must return a cons cell with the (possibly modified) headline text, and the
 195 sectioning list in the cdr."
 196   :group 'org-export-latex
 197   :type '(repeat
 198           (list (string :tag "LaTeX class")
 199                 (string :tag "LaTeX header")
 200                 (repeat :tag "Levels" :inline t
 201                         (choice
 202                          (cons :tag "Heading"
 203                                (string :tag "  numbered")
 204                                (string :tag "unnumbered"))
 205                          (list :tag "Environment"
 206                                (string :tag "Opening   (numbered)")
 207                                (string :tag "Closing   (numbered)")
 208                                (string :tag "Opening (unnumbered)")
 209                                (string :tag "Closing (unnumbered)"))
 210                          (function :tag "Hook computing sectioning"))))))
 211
 212 (defcustom org-export-latex-inputenc-alist nil
 213   "Alist of inputenc coding system names, and what should really be used.
 214 For example, adding an entry
 215
 216       (\"utf8\" . \"utf8x\")
 217
 218 will cause \\usepackage[utf8x]{inputenc} to be used for buffers that
 219 are written as utf8 files."
 220   :group 'org-export-latex
 221   :type '(repeat
 222           (cons
 223            (string :tag "Derived from buffer")
 224            (string :tag "Use this instead"))))
 225
 226
 227 (defcustom org-export-latex-emphasis-alist
 228   '(("*" "\\textbf{%s}" nil)
 229     ("/" "\\emph{%s}" nil)
 230     ("_" "\\underline{%s}" nil)
 231     ("+" "\\st{%s}" nil)
 232     ("=" "\\protectedtexttt" t)
 233     ("~" "\\verb" t))
 234   "Alist of LaTeX expressions to convert emphasis fontifiers.
 235 Each element of the list is a list of three elements.
 236 The first element is the character used as a marker for fontification.
 237 The second element is a formatting string to wrap fontified text with.
 238 If it is \"\\verb\", Org will automatically select a delimiter
 239 character that is not in the string.  \"\\protectedtexttt\" will use \\texttt
 240 to typeset and try to protect special characters.
 241 The third element decides whether to protect converted text from other
 242 conversions."
 243   :group 'org-export-latex
 244   :type 'alist)
 245
 246 (defcustom org-export-latex-title-command "\\maketitle"
 247   "The command used to insert the title just after \\begin{document}.
 248 If this string contains the formatting specification \"%s\" then
 249 it will be used as a formatting string, passing the title as an
 250 argument."
 251   :group 'org-export-latex
 252   :type 'string)
 253
 254 (defcustom org-export-latex-import-inbuffer-stuff nil
 255   "Non-nil means define TeX macros for Org's inbuffer definitions.
 256 For example \orgTITLE for #+TITLE."
 257   :group 'org-export-latex
 258   :type 'boolean)
 259
 260 (defcustom org-export-latex-date-format
 261   "\\today"
 262   "Format string for \\date{...}."
 263   :group 'org-export-latex
 264   :type 'string)
 265
 266 (defcustom org-export-latex-todo-keyword-markup "\\textbf{%s}"
 267   "Markup for TODO keywords, as a printf format.
 268 This can be a single format for all keywords, a cons cell with separate
 269 formats for not-done and done states, or an association list with setup
 270 for individual keywords.  If a keyword shows up for which there is no
 271 markup defined, the first one in the association list will be used."
 272   :group 'org-export-latex
 273   :type '(choice
 274           (string :tag "Default")
 275           (cons :tag "Distinguish undone and done"
 276                 (string :tag "Not-DONE states")
 277                 (string :tag "DONE states"))
 278           (repeat :tag "Per keyword markup"
 279                   (cons
 280                    (string :tag "Keyword")
 281                    (string :tag "Markup")))))
 282
 283 (defcustom org-export-latex-tag-markup "\\textbf{%s}"
 284   "Markup for tags, as a printf format."
 285   :group 'org-export-latex
 286   :type 'string)
 287
 288 (defcustom org-export-latex-timestamp-markup "\\textit{%s}"
 289   "A printf format string to be applied to time stamps."
 290   :group 'org-export-latex
 291   :type 'string)
 292
 293 (defcustom org-export-latex-timestamp-inactive-markup "\\textit{%s}"
 294   "A printf format string to be applied to inactive time stamps."
 295   :group 'org-export-latex
 296   :type 'string)
 297
 298 (defcustom org-export-latex-timestamp-keyword-markup "\\texttt{%s}"
 299   "A printf format string to be applied to time stamps."
 300   :group 'org-export-latex
 301   :type 'string)
 302
 303 (defcustom org-export-latex-href-format "\\href{%s}{%s}"
 304   "A printf format string to be applied to href links.
 305 The format must contain either two %s instances or just one.
 306 If it contains two %s instances, the first will be filled with
 307 the link, the second with the link description.  If it contains
 308 only one, the %s will be filled with the link."
 309   :group 'org-export-latex
 310   :type 'string)
 311
 312 (defcustom org-export-latex-hyperref-format "\\hyperref[%s]{%s}"
 313   "A printf format string to be applied to hyperref links.
 314 The format must contain one or two %s instances.  The first one
 315 will be filled with the link, the second with its description."
 316   :group 'org-export-latex
 317   :type 'string)
 318
 319 (defcustom org-export-latex-footnote-separator "\\textsuperscript{,}\\,"
 320   "Text used to separate footnotes."
 321   :group 'org-export-latex
 322   :type 'string)
 323
 324 (defcustom org-export-latex-quotes
 325   '(("fr" ("\\(\\s-\\|[[(]\\)\"" . "«~") ("\\(\\S-\\)\"" . "~»") ("\\(\\s-\\|(\\)'" . "'"))
 326     ("en" ("\\(\\s-\\|[[(]\\)\"" . "``") ("\\(\\S-\\)\"" . "''") ("\\(\\s-\\|(\\)'" . "`")))
 327   "Alist for quotes to use when converting english double-quotes.
 328
 329 The CAR of each item in this alist is the language code.
 330 The CDR of each item in this alist is a list of three CONS:
 331 - the first CONS defines the opening quote;
 332 - the second CONS defines the closing quote;
 333 - the last CONS defines single quotes.
 334
 335 For each item in a CONS, the first string is a regexp
 336 for allowed characters before/after the quote, the second
 337 string defines the replacement string for this quote."
 338   :group 'org-export-latex
 339   :type '(list
 340           (cons :tag "Opening quote"
 341                 (string :tag "Regexp for char before")
 342                 (string :tag "Replacement quote     "))
 343           (cons :tag "Closing quote"
 344                 (string :tag "Regexp for char after ")
 345                 (string :tag "Replacement quote     "))
 346           (cons :tag "Single quote"
 347                 (string :tag "Regexp for char before")
 348                 (string :tag "Replacement quote     "))))
 349
 350 (defcustom org-export-latex-tables-verbatim nil
 351   "When non-nil, tables are exported verbatim."
 352   :group 'org-export-latex
 353   :type 'boolean)
 354
 355 (defcustom org-export-latex-tables-centered t
 356   "When non-nil, tables are exported in a center environment."
 357   :group 'org-export-latex
 358   :type 'boolean)
 359
 360 (defcustom org-export-latex-table-caption-above t
 361   "When non-nil, the caption is set above the table.  When nil,
 362 the caption is set below the table."
 363   :group 'org-export-latex
 364   :type 'boolean)
 365
 366 (defcustom org-export-latex-tables-column-borders nil
 367   "When non-nil, grouping columns can cause outer vertical lines in tables.
 368 When nil, grouping causes only separation lines between groups."
 369   :group 'org-export-latex
 370   :type 'boolean)
 371
 372 (defcustom org-export-latex-low-levels 'itemize
 373   "How to convert sections below the current level of sectioning.
 374 This is specified by the `org-export-headline-levels' option or the
 375 value of \"H:\" in Org's #+OPTION line.
 376
 377 This can be either nil (skip the sections), `description', `itemize',
 378 or `enumerate' (convert the sections as the corresponding list type), or
 379 a string to be used instead of \\section{%s}.  In this latter case,
 380 the %s stands here for the inserted headline and is mandatory.
 381
 382 It may also be a list of three string to define a user-defined environment
 383 that should be used.  The first string should be the like
 384 \"\\begin{itemize}\", the second should be like \"\\item %s %s\" with up
 385 to two occurrences of %s for the title and a label, respectively.  The third
 386 string should be like \"\\end{itemize\"."
 387   :group 'org-export-latex
 388   :type '(choice (const :tag "Ignore" nil)
 389                  (const :tag "Convert as descriptive list" description)
 390                  (const :tag "Convert as itemized list" itemize)
 391                  (const :tag "Convert as enumerated list" enumerate)
 392                  (list  :tag "User-defined environment"
 393                         :value ("\\begin{itemize}" "\\end{itemize}" "\\item %s")
 394                         (string :tag "Start")
 395                         (string :tag "End")
 396                         (string :tag "item"))
 397                  (string :tag "Use a section string" :value "\\subparagraph{%s}")))
 398
 399 (defcustom org-export-latex-list-parameters
 400   '(:cbon "$\\boxtimes$" :cboff "$\\Box$" :cbtrans "$\\boxminus$")
 401   "Parameters for the LaTeX list exporter.
 402 These parameters will be passed on to `org-list-to-latex', which in turn
 403 will pass them (combined with the LaTeX default list parameters) to
 404 `org-list-to-generic'."
 405   :group 'org-export-latex
 406   :type 'plist)
 407
 408 (defcustom org-export-latex-verbatim-wrap
 409   '("\\begin{verbatim}\n" . "\\end{verbatim}")
 410   "Environment to be wrapped around a fixed-width section in LaTeX export.
 411 This is a cons with two strings, to be added before and after the
 412 fixed-with text.
 413
 414 Defaults to \\begin{verbatim} and \\end{verbatim}."
 415   :group 'org-export-translation
 416   :group 'org-export-latex
 417   :type '(cons (string :tag "Open")
 418                (string :tag "Close")))
 419
 420 (defcustom org-export-latex-listings nil
 421   "Non-nil means export source code using the listings package.
 422 This package will fontify source code, possibly even with color.
 423 If you want to use this, you also need to make LaTeX use the
 424 listings package, and if you want to have color, the color
 425 package.  Just add these to `org-export-latex-packages-alist',
 426 for example using customize, or with something like
 427
 428   (require 'org-latex)
 429   (add-to-list 'org-export-latex-packages-alist '(\"\" \"listings\"))
 430   (add-to-list 'org-export-latex-packages-alist '(\"\" \"color\"))
 431
 432 Alternatively,
 433
 434   (setq org-export-latex-listings 'minted)
 435
 436 causes source code to be exported using the minted package as
 437 opposed to listings.  If you want to use minted, you need to add
 438 the minted package to `org-export-latex-packages-alist', for
 439 example using customize, or with
 440
 441   (require 'org-latex)
 442   (add-to-list 'org-export-latex-packages-alist '(\"\" \"minted\"))
 443
 444 In addition, it is necessary to install
 445 pygments (http://pygments.org), and to configure the variable
 446 `org-latex-to-pdf-process' so that the -shell-escape option is
 447 passed to pdflatex.
 448 "
 449   :group 'org-export-latex
 450   :type 'boolean)
 451
 452 (defcustom org-export-latex-listings-langs
 453   '((emacs-lisp "Lisp") (lisp "Lisp") (clojure "Lisp")
 454     (c "C") (cc "C++")
 455     (fortran "fortran")
 456     (perl "Perl") (cperl "Perl") (python "Python") (ruby "Ruby")
 457     (html "HTML") (xml "XML")
 458     (tex "TeX") (latex "TeX")
 459     (shell-script "bash")
 460     (gnuplot "Gnuplot")
 461     (ocaml "Caml") (caml "Caml")
 462     (sql "SQL") (sqlite "sql"))
 463   "Alist mapping languages to their listing language counterpart.
 464 The key is a symbol, the major mode symbol without the \"-mode\".
 465 The value is the string that should be inserted as the language parameter
 466 for the listings package.  If the mode name and the listings name are
 467 the same, the language does not need an entry in this list - but it does not
 468 hurt if it is present."
 469   :group 'org-export-latex
 470   :type '(repeat
 471           (list
 472            (symbol :tag "Major mode       ")
 473            (string :tag "Listings language"))))
 474
 475 (defcustom org-export-latex-listings-w-names t
 476   "Non-nil means export names of named code blocks.
 477 Code blocks exported with the listings package (controlled by the
 478 `org-export-latex-listings' variable) can be named in the style
 479 of noweb."
 480   :group 'org-export-latex
 481   :type 'boolean)
 482
 483 (defcustom org-export-latex-minted-langs
 484   '((emacs-lisp "common-lisp")
 485     (cc "c++")
 486     (cperl "perl")
 487     (shell-script "bash")
 488     (caml "ocaml"))
 489   "Alist mapping languages to their minted language counterpart.
 490 The key is a symbol, the major mode symbol without the \"-mode\".
 491 The value is the string that should be inserted as the language parameter
 492 for the minted package.  If the mode name and the listings name are
 493 the same, the language does not need an entry in this list - but it does not
 494 hurt if it is present.
 495
 496 Note that minted uses all lower case for language identifiers,
 497 and that the full list of language identifiers can be obtained
 498 with:
 499 pygmentize -L lexers
 500 "
 501   :group 'org-export-latex
 502   :type '(repeat
 503           (list
 504            (symbol :tag "Major mode       ")
 505            (string :tag "Listings language"))))
 506
 507 (defcustom org-export-latex-listings-options nil
 508   "Association list of options for the latex listings package.
 509
 510 These options are supplied as a comma-separated list to the
 511 \\lstset command. Each element of the association list should be
 512 a list containing two strings: the name of the option, and the
 513 value. For example,
 514
 515   (setq org-export-latex-listings-options
 516     '((\"basicstyle\" \"\\small\")
 517       (\"keywordstyle\" \"\\color{black}\\bfseries\\underbar\")))
 518
 519 will typeset the code in a small size font with underlined, bold
 520 black keywords.
 521
 522 Note that the same options will be applied to blocks of all
 523 languages."
 524   :group 'org-export-latex
 525   :type '(repeat
 526           (list
 527            (string :tag "Listings option name ")
 528            (string :tag "Listings option value"))))
 529
 530 (defcustom org-export-latex-minted-options nil
 531   "Association list of options for the latex minted package.
 532
 533 These options are supplied within square brackets in
 534 \\begin{minted} environments. Each element of the alist should be
 535 a list containing two strings: the name of the option, and the
 536 value. For example,
 537
 538   (setq org-export-latex-minted-options
 539     '((\"bgcolor\" \"bg\") (\"frame\" \"lines\")))
 540
 541 will result in src blocks being exported with
 542
 543 \\begin{minted}[bgcolor=bg,frame=lines]{<LANG>}
 544
 545 as the start of the minted environment. Note that the same
 546 options will be applied to blocks of all languages."
 547   :group 'org-export-latex
 548   :type '(repeat
 549           (list
 550            (string :tag "Minted option name ")
 551            (string :tag "Minted option value"))))
 552
 553 (defvar org-export-latex-custom-lang-environments nil
 554   "Association list mapping languages to language-specific latex
 555   environments used during export of src blocks by the listings
 556   and minted latex packages. For example,
 557
 558   (setq org-export-latex-custom-lang-environments
 559      '((python \"pythoncode\")))
 560
 561   would have the effect that if org encounters begin_src python
 562   during latex export it will output
 563
 564   \\begin{pythoncode}
 565   <src block body>
 566   \\end{pythoncode}")
 567
 568 (defcustom org-export-latex-remove-from-headlines
 569   '(:todo nil :priority nil :tags nil)
 570   "A plist of keywords to remove from headlines.  OBSOLETE.
 571 Non-nil means remove this keyword type from the headline.
 572
 573 Don't remove the keys, just change their values.
 574
 575 Obsolete, this variable is no longer used.  Use the separate
 576 variables `org-export-with-todo-keywords', `org-export-with-priority',
 577 and `org-export-with-tags' instead."
 578   :type 'plist
 579   :group 'org-export-latex)
 580
 581 (defcustom org-export-latex-image-default-option "width=.9\\linewidth"
 582   "Default option for images."
 583   :group 'org-export-latex
 584   :type 'string)
 585
 586 (defcustom org-latex-default-figure-position "htb"
 587   "Default position for latex figures."
 588   :group 'org-export-latex
 589   :type 'string)
 590
 591 (defcustom org-export-latex-tabular-environment "tabular"
 592   "Default environment used to build tables."
 593   :group 'org-export-latex
 594   :type 'string)
 595
 596 (defcustom org-export-latex-inline-image-extensions
 597   '("pdf" "jpeg" "jpg" "png" "ps" "eps")
 598   "Extensions of image files that can be inlined into LaTeX.
 599 Note that the image extension *actually* allowed depend on the way the
 600 LaTeX file is processed.  When used with pdflatex, pdf, jpg and png images
 601 are OK.  When processing through dvi to Postscript, only ps and eps are
 602 allowed.  The default we use here encompasses both."
 603   :group 'org-export-latex
 604   :type '(repeat (string :tag "Extension")))
 605
 606 (defcustom org-export-latex-coding-system nil
 607   "Coding system for the exported LaTeX file."
 608   :group 'org-export-latex
 609   :type 'coding-system)
 610
 611 (defgroup org-export-pdf nil
 612   "Options for exporting Org-mode files to PDF, via LaTeX."
 613   :tag "Org Export PDF"
 614   :group 'org-export-latex
 615   :group 'org-export)
 616
 617 (defcustom org-latex-to-pdf-process
 618   '("pdflatex -interaction nonstopmode -output-directory %o %f"
 619     "pdflatex -interaction nonstopmode -output-directory %o %f"
 620     "pdflatex -interaction nonstopmode -output-directory %o %f")
 621   "Commands to process a LaTeX file to a PDF file.
 622 This is a list of strings, each of them will be given to the shell
 623 as a command.  %f in the command will be replaced by the full file name, %b
 624 by the file base name (i.e. without extension) and %o by the base directory
 625 of the file.
 626
 627 The reason why this is a list is that it usually takes several runs of
 628 `pdflatex', maybe mixed with a call to `bibtex'.  Org does not have a clever
 629 mechanism to detect which of these commands have to be run to get to a stable
 630 result, and it also does not do any error checking.
 631
 632 By default, Org uses 3 runs of `pdflatex' to do the processing.  If you
 633 have texi2dvi on your system and if that does not cause the infamous
 634 egrep/locale bug:
 635
 636      http://lists.gnu.org/archive/html/bug-texinfo/2010-03/msg00031.html
 637
 638 then `texi2dvi' is the superior choice.  Org does offer it as one
 639 of the customize options.
 640
 641 Alternatively, this may be a Lisp function that does the processing, so you
 642 could use this to apply the machinery of AUCTeX or the Emacs LaTeX mode.
 643 This function should accept the file name as its single argument."
 644   :group 'org-export-pdf
 645   :type '(choice
 646           (repeat :tag "Shell command sequence"
 647                   (string :tag "Shell command"))
 648           (const :tag "2 runs of pdflatex"
 649                  ("pdflatex -interaction nonstopmode -output-directory %o %f"
 650                    "pdflatex -interaction nonstopmode -output-directory %o %f"))
 651           (const :tag "3 runs of pdflatex"
 652                  ("pdflatex -interaction nonstopmode -output-directory %o %f"
 653                    "pdflatex -interaction nonstopmode -output-directory %o %f"
 654                    "pdflatex -interaction nonstopmode -output-directory %o %f"))
 655           (const :tag "pdflatex,bibtex,pdflatex,pdflatex"
 656                  ("pdflatex -interaction nonstopmode -output-directory %o %f"
 657                    "bibtex %b"
 658                    "pdflatex -interaction nonstopmode -output-directory %o %f"
 659                    "pdflatex -interaction nonstopmode -output-directory %o %f"))
 660           (const :tag "texi2dvi"
 661                  ("texi2dvi -p -b -c -V %f"))
 662           (const :tag "rubber"
 663                  ("rubber -d --into %o %f"))
 664           (function)))
 665
 666 (defcustom org-export-pdf-logfiles
 667   '("aux" "idx" "log" "out" "toc" "nav" "snm" "vrb")
 668   "The list of file extensions to consider as LaTeX logfiles."
 669   :group 'org-export-pdf
 670   :type '(repeat (string :tag "Extension")))
 671
 672 (defcustom org-export-pdf-remove-logfiles t
 673   "Non-nil means remove the logfiles produced by PDF production.
 674 These are the .aux, .log, .out, and .toc files."
 675   :group 'org-export-pdf
 676   :type 'boolean)
 677
 678 ;;; Hooks
 679
 680 (defvar org-export-latex-after-initial-vars-hook nil
 681   "Hook run before LaTeX export.
 682 The exact moment is after the initial variables like org-export-latex-class
 683 have been determined from the environment.")
 684
 685 (defvar org-export-latex-after-blockquotes-hook nil
 686   "Hook run during LaTeX export, after blockquote, verse, center are done.")
 687
 688 (defvar org-export-latex-final-hook nil
 689   "Hook run in the finalized LaTeX buffer.")
 690
 691 (defvar org-export-latex-after-save-hook nil
 692   "Hook run in the finalized LaTeX buffer, after it has been saved.")
 693
 694 ;;; Autoload functions:
 695
 696 ;;;###autoload
 697 (defun org-export-as-latex-batch ()
 698   "Call `org-export-as-latex', may be used in batch processing.
 699 For example:
 700
 701 emacs   --batch
 702         --load=$HOME/lib/emacs/org.el
 703         --eval \"(setq org-export-headline-levels 2)\"
 704         --visit=MyFile --funcall org-export-as-latex-batch"
 705   (org-export-as-latex org-export-headline-levels 'hidden))
 706
 707 ;;;###autoload
 708 (defun org-export-as-latex-to-buffer (arg)
 709   "Call `org-export-as-latex` with output to a temporary buffer.
 710 No file is created.  The prefix ARG is passed through to `org-export-as-latex'."
 711   (interactive "P")
 712   (org-export-as-latex arg nil nil "*Org LaTeX Export*")
 713   (when org-export-show-temporary-export-buffer
 714     (switch-to-buffer-other-window "*Org LaTeX Export*")))
 715
 716 ;;;###autoload
 717 (defun org-replace-region-by-latex (beg end)
 718   "Replace the region from BEG to END with its LaTeX export.
 719 It assumes the region has `org-mode' syntax, and then convert it to
 720 LaTeX.  This can be used in any buffer.  For example, you could
 721 write an itemized list in `org-mode' syntax in an LaTeX buffer and
 722 then use this command to convert it."
 723   (interactive "r")
 724   (let (reg latex buf)
 725     (save-window-excursion
 726       (if (eq major-mode 'org-mode)
 727           (setq latex (org-export-region-as-latex
 728                        beg end t 'string))
 729         (setq reg (buffer-substring beg end)
 730               buf (get-buffer-create "*Org tmp*"))
 731         (with-current-buffer buf
 732           (erase-buffer)
 733           (insert reg)
 734           (org-mode)
 735           (setq latex (org-export-region-as-latex
 736                        (point-min) (point-max) t 'string)))
 737         (kill-buffer buf)))
 738     (delete-region beg end)
 739     (insert latex)))
 740
 741 ;;;###autoload
 742 (defun org-export-region-as-latex (beg end &optional body-only buffer)
 743   "Convert region from BEG to END in `org-mode' buffer to LaTeX.
 744 If prefix arg BODY-ONLY is set, omit file header, footer, and table of
 745 contents, and only produce the region of converted text, useful for
 746 cut-and-paste operations.
 747 If BUFFER is a buffer or a string, use/create that buffer as a target
 748 of the converted LaTeX.  If BUFFER is the symbol `string', return the
 749 produced LaTeX as a string and leave no buffer behind.  For example,
 750 a Lisp program could call this function in the following way:
 751
 752   (setq latex (org-export-region-as-latex beg end t 'string))
 753
 754 When called interactively, the output buffer is selected, and shown
 755 in a window.  A non-interactive call will only return the buffer."
 756   (interactive "r\nP")
 757   (when (org-called-interactively-p 'any)
 758     (setq buffer "*Org LaTeX Export*"))
 759   (let ((transient-mark-mode t) (zmacs-regions t)
 760         ext-plist rtn)
 761     (setq ext-plist (plist-put ext-plist :ignore-subtree-p t))
 762     (goto-char end)
 763     (set-mark (point)) ;; to activate the region
 764     (goto-char beg)
 765     (setq rtn (org-export-as-latex
 766                nil nil ext-plist
 767                buffer body-only))
 768     (if (fboundp 'deactivate-mark) (deactivate-mark))
 769     (if (and (org-called-interactively-p 'any) (bufferp rtn))
 770         (switch-to-buffer-other-window rtn)
 771       rtn)))
 772
 773 ;;;###autoload
 774 (defun org-export-as-latex (arg &optional hidden ext-plist
 775                                 to-buffer body-only pub-dir)
 776   "Export current buffer to a LaTeX file.
 777 If there is an active region, export only the region.  The prefix
 778 ARG specifies how many levels of the outline should become
 779 headlines.  The default is 3.  Lower levels will be exported
 780 depending on `org-export-latex-low-levels'.  The default is to
 781 convert them as description lists.
 782 HIDDEN is obsolete and does nothing.
 783 EXT-PLIST is a property list with
 784 external parameters overriding org-mode's default settings, but
 785 still inferior to file-local settings.  When TO-BUFFER is
 786 non-nil, create a buffer with that name and export to that
 787 buffer.  If TO-BUFFER is the symbol `string', don't leave any
 788 buffer behind but just return the resulting LaTeX as a string.
 789 When BODY-ONLY is set, don't produce the file header and footer,
 790 simply return the content of \\begin{document}...\\end{document},
 791 without even the \\begin{document} and \\end{document} commands.
 792 when PUB-DIR is set, use this as the publishing directory."
 793   (interactive "P")
 794   (when (and (not body-only) arg (listp arg)) (setq body-only t))
 795   (run-hooks 'org-export-first-hook)
 796
 797   ;; Make sure we have a file name when we need it.
 798   (when (and (not (or to-buffer body-only))
 799              (not buffer-file-name))
 800     (if (buffer-base-buffer)
 801         (org-set-local 'buffer-file-name
 802                        (with-current-buffer (buffer-base-buffer)
 803                          buffer-file-name))
 804       (error "Need a file name to be able to export")))
 805
 806   (message "Exporting to LaTeX...")
 807   (org-unmodified
 808    (let ((inhibit-read-only t))
 809      (remove-text-properties (point-min) (point-max)
 810                              '(:org-license-to-kill nil))))
 811   (org-update-radio-target-regexp)
 812   (org-export-latex-set-initial-vars ext-plist arg)
 813   (setq org-export-opt-plist org-export-latex-options-plist
 814         org-export-footnotes-data (org-footnote-all-labels 'with-defs)
 815         org-export-footnotes-seen nil
 816         org-export-latex-footmark-seen nil)
 817   (org-install-letbind)
 818   (run-hooks 'org-export-latex-after-initial-vars-hook)
 819   (let* ((wcf (current-window-configuration))
 820          (opt-plist
 821           (org-export-process-option-filters org-export-latex-options-plist))
 822          (region-p (org-region-active-p))
 823          (rbeg (and region-p (region-beginning)))
 824          (rend (and region-p (region-end)))
 825          (subtree-p
 826           (if (plist-get opt-plist :ignore-subtree-p)
 827               nil
 828             (when region-p
 829               (save-excursion
 830                 (goto-char rbeg)
 831                 (and (org-at-heading-p)
 832                      (>= (org-end-of-subtree t t) rend))))))
 833          (opt-plist (setq org-export-opt-plist
 834                           (if subtree-p
 835                               (org-export-add-subtree-options opt-plist rbeg)
 836                             opt-plist)))
 837          ;; Make sure the variable contains the updated values.
 838          (org-export-latex-options-plist (setq org-export-opt-plist opt-plist))
 839          ;; The following two are dynamically scoped into other
 840          ;; routines below.
 841          (org-current-export-dir
 842           (or pub-dir (org-export-directory :html opt-plist)))
 843          (org-current-export-file buffer-file-name)
 844          (title (or (and subtree-p (org-export-get-title-from-subtree))
 845                     (plist-get opt-plist :title)
 846                     (and (not
 847                           (plist-get opt-plist :skip-before-1st-heading))
 848                          (org-export-grab-title-from-buffer))
 849                     (and buffer-file-name
 850                          (file-name-sans-extension
 851                           (file-name-nondirectory buffer-file-name)))
 852                     "No Title"))
 853          (filename
 854           (and (not to-buffer)
 855                (concat
 856                 (file-name-as-directory
 857                  (or pub-dir
 858                      (org-export-directory :LaTeX ext-plist)))
 859                 (file-name-sans-extension
 860                  (or (and subtree-p
 861                           (org-entry-get rbeg "EXPORT_FILE_NAME" t))
 862                      (file-name-nondirectory ;sans-extension
 863                       (or buffer-file-name
 864                           (error "Don't know which export file to use")))))
 865                 ".tex")))
 866          (filename
 867           (and filename
 868                (if (equal (file-truename filename)
 869                           (file-truename (or buffer-file-name "dummy.org")))
 870                    (concat filename ".tex")
 871                  filename)))
 872          (buffer (if to-buffer
 873                      (cond
 874                       ((eq to-buffer 'string) (get-buffer-create
 875                                                "*Org LaTeX Export*"))
 876                       (t (get-buffer-create to-buffer)))
 877                    (find-file-noselect filename)))
 878          (odd org-odd-levels-only)
 879          (header (org-export-latex-make-header title opt-plist))
 880          (skip (cond (subtree-p nil)
 881                      (region-p nil)
 882                      (t (plist-get opt-plist :skip-before-1st-heading))))
 883          (text (plist-get opt-plist :text))
 884          (org-export-preprocess-hook
 885           (cons
 886            `(lambda () (org-set-local 'org-complex-heading-regexp
 887                                       ,org-export-latex-complex-heading-re))
 888            org-export-preprocess-hook))
 889          (first-lines (if skip "" (org-export-latex-first-lines
 890                                    opt-plist
 891                                    (if subtree-p
 892                                        (save-excursion
 893                                          (goto-char rbeg)
 894                                          (point-at-bol 2))
 895                                      rbeg)
 896                                    (if region-p rend))))
 897          (coding-system (and (boundp 'buffer-file-coding-system)
 898                              buffer-file-coding-system))
 899          (coding-system-for-write (or org-export-latex-coding-system
 900                                       coding-system))
 901          (save-buffer-coding-system (or org-export-latex-coding-system
 902                                         coding-system))
 903          (region (buffer-substring
 904                   (if region-p (region-beginning) (point-min))
 905                   (if region-p (region-end) (point-max))))
 906          (text
 907           (and text (string-match "\\S-" text)
 908                (org-export-preprocess-string
 909                 text
 910                 :emph-multiline t
 911                 :for-backend 'latex
 912                 :comments nil
 913                 :tags (plist-get opt-plist :tags)
 914                 :priority (plist-get opt-plist :priority)
 915                 :footnotes (plist-get opt-plist :footnotes)
 916                 :drawers (plist-get opt-plist :drawers)
 917                 :timestamps (plist-get opt-plist :timestamps)
 918                 :todo-keywords (plist-get opt-plist :todo-keywords)
 919                 :tasks (plist-get opt-plist :tasks)
 920                 :add-text nil
 921                 :skip-before-1st-heading skip
 922                 :select-tags nil
 923                 :exclude-tags nil
 924                 :LaTeX-fragments nil)))
 925          (string-for-export
 926           (org-export-preprocess-string
 927            region
 928            :emph-multiline t
 929            :for-backend 'latex
 930            :comments nil
 931            :tags (plist-get opt-plist :tags)
 932            :priority (plist-get opt-plist :priority)
 933            :footnotes (plist-get opt-plist :footnotes)
 934            :drawers (plist-get opt-plist :drawers)
 935            :timestamps (plist-get opt-plist :timestamps)
 936            :todo-keywords (plist-get opt-plist :todo-keywords)
 937            :tasks (plist-get opt-plist :tasks)
 938            :add-text (if (eq to-buffer 'string) nil text)
 939            :skip-before-1st-heading skip
 940            :select-tags (plist-get opt-plist :select-tags)
 941            :exclude-tags (plist-get opt-plist :exclude-tags)
 942            :LaTeX-fragments nil)))
 943
 944     (set-buffer buffer)
 945     (erase-buffer)
 946     (org-install-letbind)
 947
 948     (and (fboundp 'set-buffer-file-coding-system)
 949          (set-buffer-file-coding-system coding-system-for-write))
 950
 951     ;; insert the header and initial document commands
 952     (unless (or (eq to-buffer 'string) body-only)
 953       (insert header))
 954
 955     ;; insert text found in #+TEXT
 956     (when (and text (not (eq to-buffer 'string)))
 957       (insert (org-export-latex-content
 958                text '(lists tables fixed-width keywords))
 959                "\n\n"))
 960
 961     ;; insert lines before the first headline
 962     (unless (or skip (string-match "^\\*" first-lines))
 963       (insert first-lines))
 964
 965     ;; export the content of headlines
 966     (org-export-latex-global
 967      (with-temp-buffer
 968        (insert string-for-export)
 969        (goto-char (point-min))
 970        (when (re-search-forward "^\\(\\*+\\) " nil t)
 971          (let* ((asters (length (match-string 1)))
 972                 (level (if odd (- asters 2) (- asters 1))))
 973            (setq org-export-latex-add-level
 974                  (if odd (1- (/ (1+ asters) 2)) (1- asters)))
 975            (org-export-latex-parse-global level odd)))))
 976
 977     ;; finalization
 978     (unless body-only (insert "\n\\end{document}"))
 979
 980     ;; Attach description terms to the \item macro
 981     (goto-char (point-min))
 982     (while (re-search-forward "^[ \t]*\\\\item\\([ \t]+\\)\\[" nil t)
 983       (delete-region (match-beginning 1) (match-end 1)))
 984
 985     ;; Relocate the table of contents
 986     (goto-char (point-min))
 987     (when (re-search-forward "\\[TABLE-OF-CONTENTS\\]" nil t)
 988       (goto-char (point-min))
 989       (while (re-search-forward "\\\\tableofcontents\\>[ \t]*\n?" nil t)
 990         (replace-match ""))
 991       (goto-char (point-min))
 992       (and (re-search-forward "\\[TABLE-OF-CONTENTS\\]" nil t)
 993            (replace-match "\\tableofcontents" t t)))
 994
 995     ;; Cleanup forced line ends in items where they are not needed
 996     (goto-char (point-min))
 997     (while (re-search-forward
 998             "^[ \t]*\\\\item\\>.*\\(\\\\\\\\\\)[ \t]*\\(\n\\\\label.*\\)*\n\\\\begin"
 999             nil t)
1000       (delete-region (match-beginning 1) (match-end 1)))
1001     (goto-char (point-min))
1002     (while (re-search-forward
1003             "^[ \t]*\\\\item\\>.*\\(\\\\\\\\\\)[ \t]*\\(\n\\\\label.*\\)*"
1004             nil t)
1005       (if (looking-at "[\n \t]+")
1006           (replace-match "\n")))
1007
1008     (run-hooks 'org-export-latex-final-hook)
1009     (if to-buffer
1010         (unless (eq major-mode 'latex-mode) (latex-mode))
1011       (save-buffer))
1012     (org-export-latex-fix-inputenc)
1013     (run-hooks 'org-export-latex-after-save-hook)
1014     (goto-char (point-min))
1015     (or (org-export-push-to-kill-ring "LaTeX")
1016         (message "Exporting to LaTeX...done"))
1017     (prog1
1018         (if (eq to-buffer 'string)
1019             (prog1 (buffer-substring (point-min) (point-max))
1020               (kill-buffer (current-buffer)))
1021           (current-buffer))
1022       (set-window-configuration wcf))))
1023
1024 ;;;###autoload
1025 (defun org-export-as-pdf (arg &optional hidden ext-plist
1026                               to-buffer body-only pub-dir)
1027   "Export as LaTeX, then process through to PDF."
1028   (interactive "P")
1029   (message "Exporting to PDF...")
1030   (let* ((wconfig (current-window-configuration))
1031          (lbuf (org-export-as-latex arg hidden ext-plist
1032                                     to-buffer body-only pub-dir))
1033          (file (buffer-file-name lbuf))
1034          (base (file-name-sans-extension (buffer-file-name lbuf)))
1035          (pdffile (concat base ".pdf"))
1036          (cmds (if (eq org-export-latex-listings 'minted)
1037                    ;; automatically add -shell-escape when needed
1038                    (mapcar (lambda (cmd)
1039                              (replace-regexp-in-string
1040                               "pdflatex " "pdflatex -shell-escape " cmd))
1041                            org-latex-to-pdf-process)
1042                  org-latex-to-pdf-process))
1043          (outbuf (get-buffer-create "*Org PDF LaTeX Output*"))
1044          (bibtex-p (with-current-buffer lbuf
1045                      (save-excursion
1046                        (goto-char (point-min))
1047                        (re-search-forward "\\\\bibliography{" nil t))))
1048          cmd output-dir errors)
1049     (with-current-buffer outbuf (erase-buffer))
1050     (message (concat "Processing LaTeX file " file "..."))
1051     (setq output-dir (file-name-directory file))
1052     (with-current-buffer lbuf
1053       (save-excursion
1054         (if (and cmds (symbolp cmds))
1055             (funcall cmds (shell-quote-argument file))
1056           (while cmds
1057             (setq cmd (pop cmds))
1058             (while (string-match "%b" cmd)
1059               (setq cmd (replace-match
1060                          (save-match-data
1061                            (shell-quote-argument base))
1062                          t t cmd)))
1063             (while (string-match "%f" cmd)
1064               (setq cmd (replace-match
1065                          (save-match-data
1066                            (shell-quote-argument file))
1067                          t t cmd)))
1068             (while (string-match "%o" cmd)
1069               (setq cmd (replace-match
1070                          (save-match-data
1071                            (shell-quote-argument output-dir))
1072                          t t cmd)))
1073             (shell-command cmd outbuf)))))
1074     (message (concat "Processing LaTeX file " file "...done"))
1075     (setq errors (org-export-latex-get-error outbuf))
1076     (if (not (file-exists-p pdffile))
1077         (error (concat "PDF file " pdffile " was not produced"
1078                        (if errors (concat ":" errors "") "")))
1079       (set-window-configuration wconfig)
1080       (when org-export-pdf-remove-logfiles
1081         (dolist (ext org-export-pdf-logfiles)
1082           (setq file (concat base "." ext))
1083           (and (file-exists-p file) (delete-file file))))
1084       (message (concat
1085                 "Exporting to PDF...done"
1086                 (if errors
1087                     (concat ", with some errors:" errors)
1088                   "")))
1089       pdffile)))
1090
1091 (defun org-export-latex-get-error (buf)
1092   "Collect the kinds of errors that remain in pdflatex processing."
1093   (with-current-buffer buf
1094     (save-excursion
1095       (goto-char (point-max))
1096       (when (re-search-backward "^[ \t]*This is pdf.*?TeX.*?Version" nil t)
1097         ;; OK, we are at the location of the final run
1098         (let ((pos (point)) (errors "") (case-fold-search t))
1099           (if (re-search-forward "Reference.*?undefined" nil t)
1100               (setq errors (concat errors " [undefined reference]")))
1101           (goto-char pos)
1102           (if (re-search-forward "Citation.*?undefined" nil t)
1103               (setq errors (concat errors " [undefined citation]")))
1104           (goto-char pos)
1105           (if (re-search-forward "Undefined control sequence" nil t)
1106               (setq errors (concat errors " [undefined control sequence]")))
1107           (and (org-string-nw-p errors) errors))))))
1108
1109 ;;;###autoload
1110 (defun org-export-as-pdf-and-open (arg)
1111   "Export as LaTeX, then process through to PDF, and open."
1112   (interactive "P")
1113   (let ((pdffile (org-export-as-pdf arg)))
1114     (if pdffile
1115         (progn
1116           (org-open-file pdffile)
1117           (when org-export-kill-product-buffer-when-displayed
1118             (kill-buffer (find-buffer-visiting
1119                           (concat (file-name-sans-extension (buffer-file-name))
1120                                   ".tex")))))
1121       (error "PDF file was not produced"))))
1122
1123 ;;; Parsing functions:
1124
1125 (defun org-export-latex-parse-global (level odd)
1126   "Parse the current buffer recursively, starting at LEVEL.
1127 If ODD is non-nil, assume the buffer only contains odd sections.
1128 Return a list reflecting the document structure."
1129   (save-excursion
1130     (goto-char (point-min))
1131     (let* ((cnt 0) output
1132            (depth org-export-latex-sectioning-depth))
1133       (while (org-re-search-forward-unprotected
1134               (concat "^\\(\\(?:\\*\\)\\{"
1135                       (number-to-string (+ (if odd 2 1) level))
1136                       "\\}\\) \\(.*\\)$")
1137               ;; make sure that there is no upper heading
1138               (when (> level 0)
1139                 (save-excursion
1140                   (save-match-data
1141                     (org-re-search-forward-unprotected
1142                      (concat "^\\(\\(?:\\*\\)\\{"
1143                              (number-to-string level)
1144                              "\\}\\) \\(.*\\)$") nil t)))) t)
1145         (setq cnt (1+ cnt))
1146         (let* ((pos (match-beginning 0))
1147                (heading (match-string 2))
1148                (nlevel (if odd (/ (+ 3 level) 2) (1+ level))))
1149           (save-excursion
1150             (narrow-to-region
1151              (point)
1152              (save-match-data
1153                (if (org-re-search-forward-unprotected
1154                     (concat "^\\(\\(?:\\*\\)\\{"
1155                             (number-to-string (+ (if odd 2 1) level))
1156                             "\\}\\) \\(.*\\)$") nil t)
1157                    (match-beginning 0)
1158                  (point-max))))
1159             (goto-char (point-min))
1160             (setq output
1161                   (append output
1162                           (list
1163                            (list
1164                             `(pos . ,pos)
1165                             `(level . ,nlevel)
1166                             `(occur . ,cnt)
1167                             `(heading . ,heading)
1168                             `(content . ,(org-export-latex-parse-content))
1169                             `(subcontent . ,(org-export-latex-parse-subcontent
1170                                              level odd)))))))
1171           (widen)))
1172       (list output))))
1173
1174 (defun org-export-latex-parse-content ()
1175   "Extract the content of a section."
1176   (let ((beg (point))
1177         (end (if (org-re-search-forward-unprotected "^\\(\\*\\)+ .*$" nil t)
1178                  (progn (beginning-of-line) (point))
1179                (point-max))))
1180     (buffer-substring beg end)))
1181
1182 (defun org-export-latex-parse-subcontent (level odd)
1183   "Extract the subcontent of a section at LEVEL.
1184 If ODD Is non-nil, assume subcontent only contains odd sections."
1185   (if (not (org-re-search-forward-unprotected
1186             (concat "^\\(\\(?:\\*\\)\\{"
1187                     (number-to-string (+ (if odd 4 2) level))
1188                     "\\}\\) \\(.*\\)$")
1189             nil t))
1190       nil ; subcontent is nil
1191     (org-export-latex-parse-global (+ (if odd 2 1) level) odd)))
1192
1193 ;;; Rendering functions:
1194 (defun org-export-latex-global (content)
1195   "Export CONTENT to LaTeX.
1196 CONTENT is an element of the list produced by
1197 `org-export-latex-parse-global'."
1198   (if (eq (car content) 'subcontent)
1199       (mapc 'org-export-latex-sub (cdr content))
1200     (org-export-latex-sub (car content))))
1201
1202 (defun org-export-latex-sub (subcontent)
1203   "Export the list SUBCONTENT to LaTeX.
1204 SUBCONTENT is an alist containing information about the headline
1205 and its content."
1206   (let ((num (plist-get org-export-latex-options-plist :section-numbers)))
1207     (mapc (lambda(x) (org-export-latex-subcontent x num)) subcontent)))
1208
1209 (defun org-export-latex-subcontent (subcontent num)
1210   "Export each cell of SUBCONTENT to LaTeX.
1211 If NUM is non-nil export numbered sections, otherwise use unnumbered
1212 sections.  If NUM is an integer, export the highest NUM levels as
1213 numbered sections and lower levels as unnumbered sections."
1214   (let* ((heading (cdr (assoc 'heading subcontent)))
1215          (level (- (cdr (assoc 'level subcontent))
1216                    org-export-latex-add-level))
1217          (occur (number-to-string (cdr (assoc 'occur subcontent))))
1218          (content (cdr (assoc 'content subcontent)))
1219          (subcontent (cadr (assoc 'subcontent subcontent)))
1220          (label (org-get-text-property-any 0 'target heading))
1221          (label-list (cons label (cdr (assoc label
1222                                              org-export-target-aliases))))
1223          (sectioning org-export-latex-sectioning)
1224          (depth org-export-latex-sectioning-depth)
1225          main-heading sub-heading)
1226     (when (symbolp (car sectioning))
1227       (setq sectioning (funcall (car sectioning) level heading))
1228       (when sectioning
1229         (setq heading (car sectioning)
1230               sectioning (cdr sectioning)
1231               ;; target property migh have changed...
1232               label (org-get-text-property-any 0 'target heading)
1233               label-list (cons label (cdr (assoc label
1234                                                  org-export-target-aliases)))))
1235       (if sectioning (setq sectioning (make-list 10 sectioning)))
1236       (setq depth (if sectioning 10000 0)))
1237     (if (string-match "[ \t]*\\\\\\\\[ \t]*" heading)
1238         (setq main-heading (substring heading 0 (match-beginning 0))
1239               sub-heading (substring heading (match-end 0))))
1240     (setq heading (org-export-latex-fontify-headline heading)
1241           sub-heading (and sub-heading
1242                            (org-export-latex-fontify-headline sub-heading))
1243           main-heading (and main-heading
1244                             (org-export-latex-fontify-headline main-heading)))
1245     (cond
1246      ;; Normal conversion
1247      ((<= level depth)
1248       (let* ((sec (nth (1- level) sectioning))
1249              (num (if (integerp num)
1250                       (>= num level)
1251                     num))
1252              start end)
1253         (if (consp (cdr sec))
1254             (setq start (nth (if num 0 2) sec)
1255                   end (nth (if num 1 3) sec))
1256           (setq start (if num (car sec) (cdr sec))))
1257         (insert (format start (if main-heading main-heading heading)
1258                         (or sub-heading "")))
1259         (insert "\n")
1260         (when label
1261           (insert (mapconcat (lambda (l) (format "\\label{%s}" l))
1262                              label-list "\n") "\n"))
1263         (insert (org-export-latex-content content))
1264         (cond ((stringp subcontent) (insert subcontent))
1265               ((listp subcontent)
1266                (while (org-looking-back "\n\n") (backward-delete-char 1))
1267                (org-export-latex-sub subcontent)))
1268         (when (and end (string-match "[^ \t]" end))
1269           (let ((hook (org-get-text-property-any 0 'org-insert-hook end)))
1270             (and (functionp hook) (funcall hook)))
1271           (insert end "\n"))))
1272      ;; At a level under the hl option: we can drop this subsection
1273      ((> level depth)
1274       (cond ((eq org-export-latex-low-levels 'description)
1275              (if (string-match "% ends low level$"
1276                                (buffer-substring (point-at-bol 0) (point)))
1277                  (delete-region (point-at-bol 0) (point))
1278                (insert "\\begin{description}\n"))
1279              (insert (format "\n\\item[%s]%s~\n"
1280                              heading
1281                              (if label (format "\\label{%s}" label) "")))
1282              (insert (org-export-latex-content content))
1283              (cond ((stringp subcontent) (insert subcontent))
1284                    ((listp subcontent) (org-export-latex-sub subcontent)))
1285              (insert "\\end{description} % ends low level\n"))
1286             ((memq org-export-latex-low-levels '(itemize enumerate))
1287              (if (string-match "% ends low level$"
1288                                (buffer-substring (point-at-bol 0) (point)))
1289                  (delete-region (point-at-bol 0) (point))
1290                (insert (format "\\begin{%s}\n"
1291                                (symbol-name org-export-latex-low-levels))))
1292              (insert (format "\n\\item %s\\\\\n%s%%"
1293                              heading
1294                              (if label (format "\\label{%s}" label) "")))
1295              (insert (org-export-latex-content content))
1296              (cond ((stringp subcontent) (insert subcontent))
1297                    ((listp subcontent) (org-export-latex-sub subcontent)))
1298              (insert (format "\\end{%s} %% ends low level\n"
1299                              (symbol-name org-export-latex-low-levels))))
1300
1301             ((listp org-export-latex-low-levels)
1302              (if (string-match "% ends low level$"
1303                                (buffer-substring (point-at-bol 0) (point)))
1304                  (delete-region (point-at-bol 0) (point))
1305                (insert (car org-export-latex-low-levels) "\n"))
1306              (insert (format (nth 2 org-export-latex-low-levels)
1307                              heading
1308                              (if label (format "\\label{%s}" label) "")))
1309              (insert (org-export-latex-content content))
1310              (cond ((stringp subcontent) (insert subcontent))
1311                    ((listp subcontent) (org-export-latex-sub subcontent)))
1312              (insert (nth 1 org-export-latex-low-levels)
1313                      " %% ends low level\n"))
1314
1315             ((stringp org-export-latex-low-levels)
1316              (insert (format org-export-latex-low-levels heading) "\n")
1317              (when label (insert (format "\\label{%s}\n" label)))
1318              (insert (org-export-latex-content content))
1319              (cond ((stringp subcontent) (insert subcontent))
1320                    ((listp subcontent) (org-export-latex-sub subcontent)))))))))
1321
1322 ;;; Exporting internals:
1323 (defun org-export-latex-set-initial-vars (ext-plist level)
1324   "Store org local variables required for LaTeX export.
1325 EXT-PLIST is an optional additional plist.
1326 LEVEL indicates the default depth for export."
1327   (setq org-export-latex-todo-keywords-1 org-todo-keywords-1
1328         org-export-latex-done-keywords org-done-keywords
1329         org-export-latex-not-done-keywords org-not-done-keywords
1330         org-export-latex-complex-heading-re org-complex-heading-regexp
1331         org-export-latex-display-custom-times org-display-custom-times
1332         org-export-latex-all-targets-re
1333         (org-make-target-link-regexp (org-all-targets))
1334         org-export-latex-options-plist
1335         (org-combine-plists (org-default-export-plist) ext-plist
1336                             (org-infile-export-plist))
1337         org-export-latex-class
1338         (or (and (org-region-active-p)
1339                  (save-excursion
1340                    (goto-char (region-beginning))
1341                    (and (looking-at org-complex-heading-regexp)
1342                         (org-entry-get nil "LaTeX_CLASS" 'selective))))
1343             (save-excursion
1344               (save-restriction
1345                 (widen)
1346                 (goto-char (point-min))
1347                 (and (re-search-forward "^#\\+LaTeX_CLASS:[ \t]*\\([-a-zA-Z]+\\)" nil t)
1348                      (match-string 1))))
1349             (plist-get org-export-latex-options-plist :latex-class)
1350             org-export-latex-default-class)
1351         org-export-latex-class-options
1352         (or (and (org-region-active-p)
1353                  (save-excursion
1354                    (goto-char (region-beginning))
1355                    (and (looking-at org-complex-heading-regexp)
1356                         (org-entry-get nil "LaTeX_CLASS_OPTIONS" 'selective))))
1357             (save-excursion
1358               (save-restriction
1359                 (widen)
1360                 (goto-char (point-min))
1361                 (and (re-search-forward "^#\\+LaTeX_CLASS_OPTIONS:[ \t]*\\(.*?\\)[ \t]*$" nil t)
1362                      (match-string 1))))
1363             (plist-get org-export-latex-options-plist :latex-class-options))
1364         org-export-latex-class
1365         (or (car (assoc org-export-latex-class org-export-latex-classes))
1366             (error "No definition for class `%s' in `org-export-latex-classes'"
1367                    org-export-latex-class))
1368         org-export-latex-header
1369         (cadr (assoc org-export-latex-class org-export-latex-classes))
1370         org-export-latex-sectioning
1371         (cddr (assoc org-export-latex-class org-export-latex-classes))
1372         org-export-latex-sectioning-depth
1373         (or level
1374             (let ((hl-levels
1375                    (plist-get org-export-latex-options-plist :headline-levels))
1376                   (sec-depth (length org-export-latex-sectioning)))
1377               (if (> hl-levels sec-depth) sec-depth hl-levels))))
1378   (when (and org-export-latex-class-options
1379              (string-match "\\S-" org-export-latex-class-options)
1380              (string-match "^[ \t]*\\(\\\\documentclass\\)\\(\\[.*?\\]\\)?"
1381                            org-export-latex-header))
1382     (setq org-export-latex-header
1383           (concat (substring org-export-latex-header 0 (match-end 1))
1384                   org-export-latex-class-options
1385                   (substring org-export-latex-header (match-end 0))))))
1386
1387 (defvar org-export-latex-format-toc-function
1388   'org-export-latex-format-toc-default
1389   "The function formatting returning the string to create the table of contents.
1390 The function mus take one parameter, the depth of the table of contents.")
1391
1392 (defun org-export-latex-make-header (title opt-plist)
1393   "Make the LaTeX header and return it as a string.
1394 TITLE is the current title from the buffer or region.
1395 OPT-PLIST is the options plist for current buffer."
1396   (let ((toc (plist-get opt-plist :table-of-contents))
1397         (author (org-export-apply-macros-in-string
1398                  (plist-get opt-plist :author)))
1399         (email (replace-regexp-in-string
1400                 "_" "\\\\_"
1401                 (org-export-apply-macros-in-string
1402                  (plist-get opt-plist :email))))
1403         (description (org-export-apply-macros-in-string
1404                       (plist-get opt-plist :description)))
1405         (keywords (org-export-apply-macros-in-string
1406                    (plist-get opt-plist :keywords))))
1407     (concat
1408      (if (plist-get opt-plist :time-stamp-file)
1409          (format-time-string "%% Created %Y-%m-%d %a %H:%M\n"))
1410      ;; insert LaTeX custom header and packages from the list
1411      (org-splice-latex-header
1412       (org-export-apply-macros-in-string org-export-latex-header)
1413       org-export-latex-default-packages-alist
1414       org-export-latex-packages-alist nil
1415       (org-export-apply-macros-in-string
1416        (plist-get opt-plist :latex-header-extra)))
1417      ;; append another special variable
1418      (org-export-apply-macros-in-string org-export-latex-append-header)
1419      ;; define alert if not yet defined
1420      "\n\\providecommand{\\alert}[1]{\\textbf{#1}}"
1421      ;; insert the title
1422      (format
1423       "\n\n\\title{%s}\n"
1424       (org-export-latex-fontify-headline title))
1425      ;; insert author info
1426      (if (plist-get opt-plist :author-info)
1427          (format "\\author{%s%s}\n"
1428                  (org-export-latex-fontify-headline (or author user-full-name))
1429                  (if (and (plist-get opt-plist :email-info) email
1430                           (string-match "\\S-" email))
1431                      (format "\\thanks{%s}" email)
1432                    ""))
1433        (format "%%\\author{%s}\n"
1434                (org-export-latex-fontify-headline (or author user-full-name))))
1435      ;; insert the date
1436      (format "\\date{%s}\n"
1437              (format-time-string
1438               (or (plist-get opt-plist :date)
1439                   org-export-latex-date-format)))
1440      ;; add some hyperref options
1441      ;; FIXME: let's have a defcustom for this?
1442      (format "\\hypersetup{\n  pdfkeywords={%s},\n  pdfsubject={%s},\n  pdfcreator={%s}}\n"
1443          (org-export-latex-fontify-headline keywords)
1444          (org-export-latex-fontify-headline description)
1445          (concat "Emacs Org-mode version " org-version))
1446      ;; beginning of the document
1447      "\n\\begin{document}\n\n"
1448      ;; insert the title command
1449      (when (string-match "\\S-" title)
1450        (if (string-match "%s" org-export-latex-title-command)
1451            (format org-export-latex-title-command title)
1452          org-export-latex-title-command))
1453      "\n\n"
1454      ;; table of contents
1455      (when (and org-export-with-toc
1456                 (plist-get opt-plist :section-numbers))
1457        (funcall org-export-latex-format-toc-function
1458                 (cond ((numberp toc)
1459                        (min toc (plist-get opt-plist :headline-levels)))
1460                       (toc  (plist-get opt-plist :headline-levels))))))))
1461
1462 (defun org-export-latex-format-toc-default (depth)
1463   (when depth
1464     (format "\\setcounter{tocdepth}{%s}\n\\tableofcontents\n\\vspace*{1cm}\n"
1465             depth)))
1466
1467 (defun org-export-latex-first-lines (opt-plist &optional beg end)
1468   "Export the first lines before first headline.
1469 If BEG is non-nil, it is the beginning of the region.
1470 If END is non-nil, it is the end of the region."
1471   (save-excursion
1472     (goto-char (or beg (point-min)))
1473     (let* ((pt (point))
1474            (end (if (re-search-forward
1475                      (concat "^" (org-get-limited-outline-regexp)) end t)
1476                     (goto-char (match-beginning 0))
1477                   (goto-char (or end (point-max))))))
1478       (prog1
1479           (org-export-latex-content
1480            (org-export-preprocess-string
1481             (buffer-substring pt end)
1482             :for-backend 'latex
1483             :emph-multiline t
1484             :add-text nil
1485             :comments nil
1486             :skip-before-1st-heading nil
1487             :LaTeX-fragments nil
1488             :timestamps (plist-get opt-plist :timestamps)
1489             :footnotes (plist-get opt-plist :footnotes)))
1490         (org-unmodified
1491          (let ((inhibit-read-only t)
1492                (limit (max pt (1- end))))
1493            (add-text-properties pt limit
1494                                 '(:org-license-to-kill t))
1495            (save-excursion
1496              (goto-char pt)
1497              (while (re-search-forward "^[ \t]*#\\+.*\n?" limit t)
1498                (let ((case-fold-search t))
1499                  (unless (org-string-match-p
1500                           "^[ \t]*#\\+\\(attr_\\|caption\\>\\|label\\>\\)"
1501                           (match-string 0))
1502                    (remove-text-properties (match-beginning 0) (match-end 0)
1503                                            '(:org-license-to-kill t))))))))))))
1504
1505
1506 (defvar org-export-latex-header-defs nil
1507   "The header definitions that might be used in the LaTeX body.")
1508
1509 (defun org-export-latex-content (content &optional exclude-list)
1510   "Convert CONTENT string to LaTeX.
1511 Don't perform conversions that are in EXCLUDE-LIST.  Recognized
1512 conversion types are: quotation-marks, emphasis, sub-superscript,
1513 links, keywords, lists, tables, fixed-width"
1514   (with-temp-buffer
1515     (org-install-letbind)
1516     (insert content)
1517     (unless (memq 'timestamps exclude-list)
1518       (org-export-latex-time-stamps))
1519     (unless (memq 'quotation-marks exclude-list)
1520       (org-export-latex-quotation-marks))
1521     (unless (memq 'emphasis exclude-list)
1522       (when (plist-get org-export-latex-options-plist :emphasize)
1523         (org-export-latex-fontify)))
1524     (unless (memq 'sub-superscript exclude-list)
1525       (org-export-latex-special-chars
1526        (plist-get org-export-latex-options-plist :sub-superscript)))
1527     (unless (memq 'links exclude-list)
1528       (org-export-latex-links))
1529     (unless (memq 'keywords exclude-list)
1530       (org-export-latex-keywords))
1531     (unless (memq 'lists exclude-list)
1532       (org-export-latex-lists))
1533     (unless (memq 'tables exclude-list)
1534       (org-export-latex-tables
1535        (plist-get org-export-latex-options-plist :tables)))
1536     (unless (memq 'fixed-width exclude-list)
1537       (org-export-latex-fixed-width
1538        (plist-get org-export-latex-options-plist :fixed-width)))
1539    ;; return string
1540     (buffer-substring (point-min) (point-max))))
1541
1542 (defun org-export-latex-protect-string (s)
1543   "Add the org-protected property to string S."
1544   (add-text-properties 0 (length s) '(org-protected t) s) s)
1545
1546 (defun org-export-latex-protect-char-in-string (char-list string)
1547   "Add org-protected text-property to char from CHAR-LIST in STRING."
1548   (with-temp-buffer
1549     (save-match-data
1550       (insert string)
1551       (goto-char (point-min))
1552       (while (re-search-forward (regexp-opt char-list) nil t)
1553         (add-text-properties (match-beginning 0)
1554                              (match-end 0) '(org-protected t)))
1555       (buffer-string))))
1556
1557 (defun org-export-latex-keywords-maybe (&optional remove-list)
1558   "Maybe remove keywords depending on rules in REMOVE-LIST."
1559   (goto-char (point-min))
1560   (let ((re-todo (mapconcat 'identity org-export-latex-todo-keywords-1 "\\|"))
1561         (case-fold-search nil)
1562         (todo-markup org-export-latex-todo-keyword-markup)
1563         fmt)
1564     ;; convert TODO keywords
1565     (when (re-search-forward (concat "^\\(" re-todo "\\)") nil t)
1566       (if (plist-get remove-list :todo)
1567           (replace-match "")
1568         (setq fmt (cond
1569                    ((stringp todo-markup) todo-markup)
1570                    ((and (consp todo-markup) (stringp (car todo-markup)))
1571                     (if (member (match-string 1) org-export-latex-done-keywords)
1572                         (cdr todo-markup) (car todo-markup)))
1573                    (t (cdr (or (assoc (match-string 1) todo-markup)
1574                                (car todo-markup))))))
1575         (replace-match (org-export-latex-protect-string
1576                         (format fmt (match-string 1))) t t)))
1577     ;; convert priority string
1578     (when (re-search-forward "\\[\\\\#.\\]" nil t)
1579       (if (plist-get remove-list :priority)
1580           (replace-match "")
1581         (replace-match (format "\\textbf{%s}" (match-string 0)) t t)))
1582     ;; convert tags
1583     (when (re-search-forward "\\(:[a-zA-Z0-9_@#%]+\\)+:" nil t)
1584       (if (or (not org-export-with-tags)
1585               (plist-get remove-list :tags))
1586           (replace-match "")
1587         (replace-match
1588          (org-export-latex-protect-string
1589           (format org-export-latex-tag-markup
1590                   (save-match-data
1591                     (replace-regexp-in-string
1592                      "\\([_#]\\)" "\\\\\\1" (match-string 0)))))
1593          t t)))))
1594
1595 (defun org-export-latex-fontify-headline (string)
1596   "Fontify special words in STRING."
1597   (with-temp-buffer
1598     ;; FIXME: org-inside-LaTeX-fragment-p doesn't work when the $...$ is at
1599     ;; the beginning of the buffer - inserting "\n" is safe here though.
1600     (insert "\n" string)
1601
1602     ;; Preserve math snippets
1603
1604     (let* ((matchers (plist-get org-format-latex-options :matchers))
1605            (re-list org-latex-regexps)
1606            beg end re e m n block off)
1607       ;; Check the different regular expressions
1608       (while (setq e (pop re-list))
1609         (setq m (car e) re (nth 1 e) n (nth 2 e)
1610               block (if (nth 3 e) "\n\n" ""))
1611         (setq off (if (member m '("$" "$1")) 1 0))
1612         (when (and (member m matchers) (not (equal m "begin")))
1613           (goto-char (point-min))
1614           (while (re-search-forward re nil t)
1615             (setq beg (+ (match-beginning 0) off) end (- (match-end 0) 0))
1616             (add-text-properties beg end
1617                                  '(org-protected t org-latex-math t))))))
1618
1619     ;; Convert LaTeX to \LaTeX{} and TeX to \TeX{}
1620     (goto-char (point-min))
1621     (let ((case-fold-search nil))
1622       (while (re-search-forward "\\<\\(\\(La\\)?TeX\\)\\>" nil t)
1623         (unless (eq (char-before (match-beginning 1)) ?\\)
1624           (org-if-unprotected-1
1625            (replace-match (org-export-latex-protect-string
1626                            (concat "\\" (match-string 1)
1627                                    "{}")) t t)))))
1628     (goto-char (point-min))
1629     (let ((re (concat "\\\\\\([a-zA-Z]+\\)"
1630                       "\\(?:<[^<>\n]*>\\)*"
1631                       "\\(?:\\[[^][\n]*?\\]\\)*"
1632                       "\\(?:<[^<>\n]*>\\)*"
1633                       "\\("
1634                       (org-create-multibrace-regexp "{" "}" 3)
1635                       "\\)\\{1,3\\}")))
1636       (while (re-search-forward re nil t)
1637         (unless (or
1638                  ;; check for comment line
1639                  (save-excursion (goto-char (match-beginning 0))
1640                                  (org-in-indented-comment-line))
1641                  ;; Check if this is a defined entity, so that is may need conversion
1642                  (org-entity-get (match-string 1)))
1643           (add-text-properties (match-beginning 0) (match-end 0)
1644                                '(org-protected t)))))
1645     (when (plist-get org-export-latex-options-plist :emphasize)
1646       (org-export-latex-fontify))
1647     (org-export-latex-time-stamps)
1648     (org-export-latex-quotation-marks)
1649     (org-export-latex-keywords-maybe)
1650     (org-export-latex-special-chars
1651      (plist-get org-export-latex-options-plist :sub-superscript))
1652     (org-export-latex-links)
1653     (org-trim (buffer-string))))
1654
1655 (defun org-export-latex-time-stamps ()
1656   "Format time stamps."
1657   (goto-char (point-min))
1658   (let ((org-display-custom-times org-export-latex-display-custom-times))
1659     (while (re-search-forward org-ts-regexp-both nil t)
1660       (org-if-unprotected-at (1- (point))
1661        (replace-match
1662         (org-export-latex-protect-string
1663          (format (if (string= "<" (substring (match-string 0) 0 1))
1664                      org-export-latex-timestamp-markup
1665                    org-export-latex-timestamp-inactive-markup)
1666                  (substring (org-translate-time (match-string 0)) 1 -1)))
1667         t t)))))
1668
1669 (defun org-export-latex-quotation-marks ()
1670   "Export quotation marks depending on language conventions."
1671   (mapc (lambda(l)
1672           (goto-char (point-min))
1673           (while (re-search-forward (car l) nil t)
1674             (let ((rpl (concat (match-string 1)
1675                                (org-export-latex-protect-string
1676                                 (copy-sequence (cdr l))))))
1677               (org-if-unprotected-1
1678                (replace-match rpl t t)))))
1679         (cdr (or (assoc (plist-get org-export-latex-options-plist :language)
1680                         org-export-latex-quotes)
1681                  ;; falls back on english
1682                  (assoc "en" org-export-latex-quotes)))))
1683
1684 (defun org-export-latex-special-chars (sub-superscript)
1685   "Export special characters to LaTeX.
1686 If SUB-SUPERSCRIPT is non-nil, convert \\ and ^.
1687 See the `org-export-latex.el' code for a complete conversion table."
1688   (goto-char (point-min))
1689   (mapc (lambda(c)
1690           (goto-char (point-min))
1691           (while (re-search-forward c nil t)
1692             ;; Put the point where to check for org-protected
1693             (unless (or (get-text-property (match-beginning 2) 'org-protected)
1694                         (save-match-data (org-at-table.el-p)))
1695               (cond ((member (match-string 2) '("\\$" "$"))
1696                      (if (equal (match-string 2) "\\$")
1697                          nil
1698                        (replace-match "\\$" t t)))
1699                     ((member (match-string 2) '("&" "%" "#"))
1700                      (if (equal (match-string 1) "\\")
1701                          (replace-match (match-string 2) t t)
1702                        (replace-match (concat (match-string 1) "\\"
1703                                               (match-string 2)) t t)
1704                        (backward-char 1)))
1705                     ((equal (match-string 2) "...")
1706                      (replace-match
1707                       (concat (match-string 1)
1708                               (org-export-latex-protect-string "\\ldots{}")) t t))
1709                     ((equal (match-string 2) "~")
1710                      (cond ((equal (match-string 1) "\\") nil)
1711                            ((eq 'org-link (get-text-property 0 'face (match-string 2)))
1712                             (replace-match (concat (match-string 1) "\\~") t t))
1713                            (t (replace-match
1714                                (org-export-latex-protect-string
1715                                 (concat (match-string 1) "\\~{}")) t t))))
1716                     ((member (match-string 2) '("{" "}"))
1717                      (unless (save-match-data (org-inside-latex-math-p))
1718                        (if (equal (match-string 1) "\\")
1719                            (replace-match (match-string 2) t t)
1720                          (replace-match (concat (match-string 1) "\\"
1721                                                 (match-string 2)) t t)))))
1722               (unless (save-match-data (org-inside-latex-math-p))
1723                 (cond ((equal (match-string 2) "\\")
1724                        (replace-match (or (save-match-data
1725                                             (org-export-latex-treat-backslash-char
1726                                              (match-string 1)
1727                                              (or (match-string 3) "")))
1728                                           "") t t)
1729                        (when (and (get-text-property (1- (point)) 'org-entity)
1730                                   (looking-at "{}"))
1731                          ;; OK, this was an entity replacement, and the user
1732                          ;; had terminated the entity with {}.  Make sure
1733                          ;; {} is protected as well, and remove the extra {}
1734                          ;; inserted by the conversion.
1735                          (put-text-property (point) (+ 2 (point)) 'org-protected t)
1736                          (if (save-excursion (goto-char (max (- (point) 2) (point-min)))
1737                                              (looking-at "{}"))
1738                              (replace-match ""))
1739                          (forward-char 2))
1740                        (backward-char 1))
1741                       ((member (match-string 2) '("_" "^"))
1742                        (replace-match (or (save-match-data
1743                                             (org-export-latex-treat-sub-super-char
1744                                              sub-superscript
1745                                              (match-string 2)
1746                                              (match-string 1)
1747                                              (match-string 3))) "") t t)
1748                        (backward-char 1)))))))
1749         '(;"^\\([^\n$]*?\\|^\\)\\(\\\\?\\$\\)\\([^\n$]*\\)$"
1750           "\\(\\(\\\\?\\$\\)\\)"
1751           "\\([a-zA-Z0-9()]+\\|[ \t\n]\\|\\b\\|\\\\\\)\\(_\\|\\^\\)\\({[^{}]+}\\|[a-zA-Z0-9]+\\|[ \t\n]\\|[:punct:]\\|)\\|{[a-zA-Z0-9]+}\\|([a-zA-Z0-9]+)\\)"
1752           "\\(.\\|^\\)\\(\\\\\\)\\([ \t\n]\\|\\([&#%{}\"]\\|[a-zA-Z][a-zA-Z0-9]*\\)\\)"
1753           "\\(^\\|.\\)\\([&#%{}~]\\|\\.\\.\\.\\)"
1754           ;; (?\< . "\\textless{}")
1755           ;; (?\> . "\\textgreater{}")
1756           )))
1757
1758 (defun org-inside-latex-math-p ()
1759   (get-text-property (point) 'org-latex-math))
1760
1761 (defun org-export-latex-treat-sub-super-char
1762   (subsup char string-before string-after)
1763   "Convert the \"_\" and \"^\" characters to LaTeX.
1764 SUBSUP corresponds to the ^: option in the #+OPTIONS line.
1765 Convert CHAR depending on STRING-BEFORE and STRING-AFTER."
1766   (cond ((equal string-before "\\")
1767          (concat string-before char string-after))
1768         ((and (string-match "\\S-+" string-after))
1769          ;; this is part of a math formula
1770          (cond ((eq 'org-link (get-text-property 0 'face char))
1771                 (concat string-before "\\" char string-after))
1772                ((save-match-data (org-inside-latex-math-p))
1773                 (if subsup
1774                     (cond ((eq 1 (length string-after))
1775                            (concat string-before char string-after))
1776                           ((string-match "[({]?\\([^)}]+\\)[)}]?" string-after)
1777                            (format "%s%s{%s}" string-before char
1778                                    (match-string 1 string-after))))))
1779                ((and (> (length string-after) 1)
1780                      (or (eq subsup t)
1781                          (and (equal subsup '{}) (eq (string-to-char string-after) ?\{)))
1782                      (or (string-match "[{]?\\([^}]+\\)[}]?" string-after)
1783                          (string-match "[(]?\\([^)]+\\)[)]?" string-after)))
1784
1785                 (org-export-latex-protect-string
1786                  (format "%s$%s{%s}$" string-before char
1787                          (if (and (> (match-end 1) (1+ (match-beginning 1)))
1788                                   (not (equal (substring string-after 0 2) "{\\")))
1789                              (concat "\\mathrm{" (match-string 1 string-after) "}")
1790                            (match-string 1 string-after)))))
1791                ((eq subsup t) (concat string-before "$" char string-after "$"))
1792                (t (org-export-latex-protect-string
1793                    (concat string-before "\\" char "{}" string-after)))))
1794         (t (org-export-latex-protect-string
1795             (concat string-before "\\" char "{}" string-after)))))
1796
1797 (defun org-export-latex-treat-backslash-char (string-before string-after)
1798   "Convert the \"$\" special character to LaTeX.
1799 The conversion is made depending of STRING-BEFORE and STRING-AFTER."
1800   (let  ((ass (org-entity-get string-after)))
1801     (cond
1802      (ass (org-add-props
1803               (if (nth 2 ass)
1804                   (concat string-before
1805                           (org-export-latex-protect-string
1806                            (concat "$" (nth 1 ass) "$")))
1807                 (concat string-before (org-export-latex-protect-string
1808                                        (nth 1 ass))))
1809               nil 'org-entity t))
1810      ((and (not (string-match "^[ \n\t]" string-after))
1811            (not (string-match "[ \t]\\'\\|^" string-before)))
1812       ;; backslash is inside a word
1813       (concat string-before
1814               (org-export-latex-protect-string
1815                (concat "\\textbackslash{}" string-after))))
1816      ((not (or (equal string-after "")
1817                (string-match "^[ \t\n]" string-after)))
1818       ;; backslash might escape a character (like \#) or a user TeX
1819       ;; macro (like \setcounter)
1820       (concat string-before
1821               (org-export-latex-protect-string (concat "\\" string-after))))
1822      ((and (string-match "^[ \t\n]" string-after)
1823            (string-match "[ \t\n]\\'" string-before))
1824       ;; backslash is alone, convert it to $\backslash$
1825       (org-export-latex-protect-string
1826        (concat string-before "\\textbackslash{}" string-after)))
1827      (t (org-export-latex-protect-string
1828          (concat string-before "\\textbackslash{}" string-after))))))
1829
1830 (defun org-export-latex-keywords ()
1831   "Convert special keywords to LaTeX."
1832   (goto-char (point-min))
1833   (while (re-search-forward org-export-latex-special-keyword-regexp nil t)
1834     (replace-match (format org-export-latex-timestamp-keyword-markup
1835                            (match-string 0)) t t)
1836     (save-excursion
1837       (beginning-of-line 1)
1838       (unless (looking-at ".*\n[ \t]*\n")
1839         (end-of-line 1)
1840         (insert "\n")))))
1841
1842 (defun org-export-latex-fixed-width (opt)
1843   "When OPT is non-nil convert fixed-width sections to LaTeX."
1844   (goto-char (point-min))
1845   (while (re-search-forward "^[ \t]*:\\([ \t]\\|$\\)" nil t)
1846     (unless (get-text-property (point) 'org-example)
1847      (if opt
1848          (progn (goto-char (match-beginning 0))
1849                 (insert "\\begin{verbatim}\n")
1850                 (while (looking-at "^\\([ \t]*\\):\\(\\([ \t]\\|$\\).*\\)$")
1851                   (replace-match (concat (match-string 1)
1852                                          (match-string 2)) t t)
1853                   (forward-line))
1854                 (insert "\\end{verbatim}\n"))
1855        (progn (goto-char (match-beginning 0))
1856               (while (looking-at "^\\([ \t]*\\):\\(\\([ \t]\\|$\\).*\\)$")
1857                 (replace-match (concat "%" (match-string 1)
1858                                        (match-string 2)) t t)
1859                 (forward-line)))))))
1860
1861 (defvar org-table-last-alignment) ; defined in org-table.el
1862 (defvar org-table-last-column-widths) ; defined in org-table.el
1863 (declare-function orgtbl-to-latex "org-table" (table params) t)
1864 (defun org-export-latex-tables (insert)
1865   "Convert tables to LaTeX and INSERT it."
1866   ;; First, get the table.el tables
1867   (goto-char (point-min))
1868   (while (re-search-forward "^[ \t]*\\(\\+-[-+]*\\+\\)[ \t]*\n[ \t]*|" nil t)
1869     (org-if-unprotected
1870      (require 'table)
1871      (org-export-latex-convert-table.el-table)))
1872
1873   ;; And now the Org-mode tables
1874   (goto-char (point-min))
1875   (while (re-search-forward "^\\([ \t]*\\)|" nil t)
1876     (org-if-unprotected-at (1- (point))
1877       (org-table-align)
1878       (let* ((beg (org-table-begin))
1879              (end (org-table-end))
1880              (raw-table (buffer-substring beg end))
1881              (org-table-last-alignment (copy-sequence org-table-last-alignment))
1882              (org-table-last-column-widths (copy-sequence
1883                                             org-table-last-column-widths))
1884              fnum fields line lines olines gr colgropen line-fmt align
1885              caption width shortn label attr floatp placement
1886              longtblp tblenv tabular-env)
1887         (if org-export-latex-tables-verbatim
1888             (let* ((tbl (concat "\\begin{verbatim}\n" raw-table
1889                                 "\\end{verbatim}\n")))
1890               (apply 'delete-region (list beg end))
1891               (insert (org-export-latex-protect-string tbl)))
1892           (progn
1893             (setq caption (org-find-text-property-in-string
1894                            'org-caption raw-table)
1895                   shortn (org-find-text-property-in-string
1896                           'org-caption-shortn raw-table)
1897                   attr (org-find-text-property-in-string
1898                         'org-attributes raw-table)
1899                   label (org-find-text-property-in-string
1900                          'org-label raw-table)
1901                   longtblp (and attr (stringp attr)
1902                                 (string-match "\\<longtable\\>" attr))
1903                   tblenv (if (and attr (stringp attr)
1904                                   (or (string-match (regexp-quote "table*") attr)
1905                                       (string-match "\\<multicolumn\\>" attr)))
1906                              "table*" "table")
1907                   tabular-env
1908                   (if (and attr (stringp attr)
1909                            (string-match "\\(tabular.\\)" attr))
1910                       (match-string 1 attr)
1911                     org-export-latex-tabular-environment)
1912                   width (and attr (stringp attr)
1913                              (string-match "\\<width=\\([^ \t\n\r]+\\)" attr)
1914                              (match-string 1 attr))
1915                   align (and attr (stringp attr)
1916                              (string-match "\\<align=\\([^ \t\n\r]+\\)" attr)
1917                              (match-string 1 attr))
1918                   floatp (or caption label (string= "table*" tblenv))
1919                   placement     (if (and attr
1920                                          (stringp attr)
1921                                          (string-match "[ \t]*\\<placement=\\(\\S-+\\)" attr))
1922                                     (match-string 1 attr)
1923                                   (concat
1924                                    "[" org-latex-default-figure-position "]")))
1925             (setq caption (and caption (org-export-latex-fontify-headline caption)))
1926             (setq lines (org-split-string raw-table "\n"))
1927             (apply 'delete-region (list beg end))
1928             (when org-export-table-remove-special-lines
1929               (setq lines (org-table-clean-before-export lines 'maybe-quoted)))
1930             (when org-table-clean-did-remove-column
1931               (pop org-table-last-alignment)
1932               (pop org-table-last-column-widths))
1933             ;; make a formatting string to reflect alignment
1934             (setq olines lines)
1935             (while (and (not line-fmt) (setq line (pop olines)))
1936               (unless (string-match "^[ \t]*|-" line)
1937                 (setq fields (org-split-string line "[ \t]*|[ \t]*"))
1938                 (setq fnum (make-vector (length fields) 0))
1939                 (setq line-fmt
1940                       (mapconcat
1941                        (lambda (x)
1942                          (setq gr (pop org-table-colgroup-info))
1943                          (format "%s%%s%s"
1944                                  (cond ((eq gr :start)
1945                                         (prog1 (if colgropen "|" "|")
1946                                           (setq colgropen t)))
1947                                        ((eq gr :startend)
1948                                         (prog1 (if colgropen "|" "|")
1949                                           (setq colgropen nil)))
1950                                        (t ""))
1951                                  (if (memq gr '(:end :startend))
1952                                      (progn (setq colgropen nil) "|")
1953                                    "")))
1954                        fnum ""))))
1955             ;; fix double || in line-fmt
1956             (setq line-fmt (replace-regexp-in-string "||" "|" line-fmt))
1957             ;; maybe remove the first and last "|"
1958             (when (and (not org-export-latex-tables-column-borders)
1959                        (string-match "^\\(|\\)?\\(.+\\)|$" line-fmt))
1960               (setq line-fmt (match-string 2 line-fmt)))
1961             ;; format alignment
1962             (unless align
1963               (setq align (apply 'format
1964                                  (cons line-fmt
1965                                        (mapcar (lambda (x) (if x "r" "l"))
1966                                                org-table-last-alignment)))))
1967             ;; prepare the table to send to orgtbl-to-latex
1968             (setq lines
1969                   (mapcar
1970                    (lambda(elem)
1971                      (or (and (string-match "[ \t]*|-+" elem) 'hline)
1972                          (org-split-string
1973                           (progn (set-text-properties 0 (length elem) nil elem)
1974                                  (org-trim elem)) "|")))
1975                    lines))
1976             (when insert
1977               (insert (org-export-latex-protect-string
1978                        (concat
1979                         (if longtblp
1980                             (concat "\\begin{longtable}{" align "}\n")
1981                           (if floatp
1982                               (format "\\begin{%s}%s\n" tblenv placement)))
1983                         (if (and floatp org-export-latex-table-caption-above)
1984                             (format
1985                              "\\caption%s{%s} %s"
1986                              (if shortn (concat "[" shortn "]") "")
1987                              (or caption "")
1988                              (if label (format "\\label{%s}" label) "")))
1989                         (if (and longtblp caption) "\\\\\n" "\n")
1990                         (if (and org-export-latex-tables-centered (not longtblp))
1991                             "\\begin{center}\n")
1992                         (if (not longtblp)
1993                             (format "\\begin{%s}%s{%s}\n"
1994                                     tabular-env
1995                                     (if width (format "{%s}" width) "")
1996                                     align))
1997                         (orgtbl-to-latex
1998                          lines
1999                          `(:tstart nil :tend nil
2000                                    :hlend ,(if longtblp
2001                                                (format "\\\\
2002 \\hline
2003 \\endhead
2004 \\hline\\multicolumn{%d}{r}{Continued on next page}\\
2005 \\endfoot
2006 \\endlastfoot" (length org-table-last-alignment))
2007                                              nil)))
2008                         (if (not longtblp) (format "\n\\end{%s}" tabular-env))
2009                         (if longtblp "\n" (if org-export-latex-tables-centered
2010                                               "\n\\end{center}\n" "\n"))
2011                         (if (and floatp (not org-export-latex-table-caption-above))
2012                             (format
2013                              "\\caption%s{%s} %s"
2014                              (if shortn (concat "[" shortn "]") "")
2015                              (or caption "")
2016                              (if label (format "\\label{%s}" label) "")))
2017                         (if longtblp
2018                             "\\end{longtable}"
2019                           (if floatp (format "\\end{%s}" tblenv)))))
2020                       "\n\n"))))))))
2021
2022 (defun org-export-latex-convert-table.el-table ()
2023   "Replace table.el table at point with LaTeX code."
2024   (let (tbl caption shortn label line floatp attr align rmlines)
2025     (setq line (buffer-substring (point-at-bol) (point-at-eol))
2026           label (org-get-text-property-any 0 'org-label line)
2027           caption (org-get-text-property-any 0 'org-caption line)
2028           shortn (org-get-text-property-any 0 'org-caption-shortn line)
2029           attr (org-get-text-property-any 0 'org-attributes line)
2030           align (and attr (stringp attr)
2031                      (string-match "\\<align=\\([^ \t\n\r,]+\\)" attr)
2032                      (match-string 1 attr))
2033           rmlines (and attr (stringp attr)
2034                        (string-match "\\<rmlines\\>" attr))
2035           floatp (or label caption))
2036     (and (get-buffer "*org-export-table*")
2037          (kill-buffer (get-buffer "*org-export-table*")))
2038     (table-generate-source 'latex "*org-export-table*" "caption")
2039     (setq tbl (with-current-buffer "*org-export-table*"
2040                 (buffer-string)))
2041     (while (string-match "^%.*\n" tbl)
2042       (setq tbl (replace-match "" t t tbl)))
2043     ;; fix the hlines
2044     (when rmlines
2045       (let ((n 0) lines)
2046         (setq lines (mapcar (lambda (x)
2047                               (if (string-match "^\\\\hline$" x)
2048                                   (progn
2049                                     (setq n (1+ n))
2050                                     (if (= n 2) x nil))
2051                                 x))
2052                             (org-split-string tbl "\n")))
2053         (setq tbl (mapconcat 'identity (delq nil lines) "\n"))))
2054     (when (and align (string-match "\\\\begin{tabular}{.*}" tbl))
2055       (setq tbl (replace-match (concat "\\begin{tabular}{" align "}")
2056                                t t tbl)))
2057     (and (get-buffer "*org-export-table*")
2058          (kill-buffer (get-buffer "*org-export-table*")))
2059     (beginning-of-line 0)
2060     (while (looking-at "[ \t]*\\(|\\|\\+-\\)")
2061       (delete-region (point) (1+ (point-at-eol))))
2062     (when org-export-latex-tables-centered
2063       (setq tbl (concat "\\begin{center}\n" tbl "\\end{center}")))
2064     (when floatp
2065       (setq tbl (concat "\\begin{table}\n"
2066                         (if (not org-export-latex-table-caption-above) tbl)
2067                         (format "\\caption%s{%s%s}\n"
2068                                 (if shortn (format "[%s]" shortn) "")
2069                                 (if label (format "\\label{%s}" label) "")
2070                                 (or caption ""))
2071                         (if org-export-latex-table-caption-above tbl)
2072                         "\n\\end{table}\n")))
2073     (insert (org-export-latex-protect-string tbl))))
2074
2075 (defun org-export-latex-fontify ()
2076   "Convert fontification to LaTeX."
2077   (goto-char (point-min))
2078   (while (re-search-forward org-emph-re nil t)
2079     ;; The match goes one char after the *string*, except at the end of a line
2080     (let ((emph (assoc (match-string 3)
2081                        org-export-latex-emphasis-alist))
2082           (beg (match-beginning 0))
2083           (end (match-end 0))
2084           rpl s)
2085       (unless emph
2086         (message "`org-export-latex-emphasis-alist' has no entry for formatting triggered by \"%s\""
2087                  (match-string 3)))
2088       (unless (or (and (get-text-property (- (point) 2) 'org-protected)
2089                        (not (get-text-property
2090                              (- (point) 2) 'org-verbatim-emph)))
2091                   (equal (char-after (match-beginning 3))
2092                          (char-after (1+ (match-beginning 3))))
2093                   (save-excursion
2094                     (goto-char (match-beginning 1))
2095                     (save-match-data
2096                       (and (org-at-table-p)
2097                            (string-match
2098                             "[|\n]" (buffer-substring beg end)))))
2099                   (and (equal (match-string 3) "+")
2100                        (save-match-data
2101                          (string-match "\\`-+\\'" (match-string 4)))))
2102         (setq s (match-string 4))
2103         (setq rpl (concat (match-string 1)
2104                           (org-export-latex-emph-format (cadr emph)
2105                                                         (match-string 4))
2106                           (match-string 5)))
2107         (if (caddr emph)
2108             (setq rpl (org-export-latex-protect-string rpl))
2109           (save-match-data
2110             (if (string-match "\\`.?\\(\\\\[a-z]+{\\)\\(.*\\)\\(}\\).?\\'" rpl)
2111                 (progn
2112                   (add-text-properties (match-beginning 1) (match-end 1)
2113                                        '(org-protected t) rpl)
2114                   (add-text-properties (match-beginning 3) (match-end 3)
2115                                        '(org-protected t) rpl)))))
2116         (replace-match rpl t t)))
2117     (backward-char)))
2118
2119 (defun org-export-latex-emph-format (format string)
2120   "Format an emphasis string and handle the \\verb special case."
2121   (when (member format '("\\verb" "\\protectedtexttt"))
2122     (save-match-data
2123       (if (equal format "\\verb")
2124           (let ((ll "~,./?;':\"|!@#%^&-_=+abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ<>()[]{}"))
2125             (catch 'exit
2126               (loop for i from 0 to (1- (length ll)) do
2127                     (if (not (string-match (regexp-quote (substring ll i (1+ i)))
2128                                            string))
2129                         (progn
2130                           (setq format (concat "\\verb" (substring ll i (1+ i))
2131                                                "%s" (substring ll i (1+ i))))
2132                           (throw 'exit nil))))))
2133         (let ((start 0)
2134               (trans '(("\\" . "\\textbackslash{}")
2135                        ("~" . "\\textasciitilde{}")
2136                        ("^" . "\\textasciicircum{}")))
2137               (rtn "") char)
2138           (while (string-match "[\\{}$%&_#~^]" string)
2139             (setq char (match-string 0 string))
2140             (if (> (match-beginning 0) 0)
2141                 (setq rtn (concat rtn (substring string
2142                                                  0 (match-beginning 0)))))
2143             (setq string (substring string (1+ (match-beginning 0))))
2144             (setq char (or (cdr (assoc char trans)) (concat "\\" char))
2145                   rtn (concat rtn char)))
2146           (setq string (concat rtn string) format "\\texttt{%s}")
2147           (while (string-match "--" string)
2148             (setq string (replace-match "-{}-" t t string)))))))
2149   (format format string))
2150
2151 (defun org-export-latex-links ()
2152   ;; Make sure to use the LaTeX hyperref and graphicx package
2153   ;; or send some warnings.
2154   "Convert links to LaTeX."
2155   (goto-char (point-min))
2156   (while (re-search-forward org-bracket-link-analytic-regexp++ nil t)
2157     (org-if-unprotected-1
2158      (goto-char (match-beginning 0))
2159      (let* ((re-radio org-export-latex-all-targets-re)
2160             (remove (list (match-beginning 0) (match-end 0)))
2161             (raw-path (org-extract-attributes (match-string 3)))
2162             (full-raw-path (concat (match-string 1) raw-path))
2163             (desc (match-string 5))
2164             (type (or (match-string 2)
2165                       (if (or (file-name-absolute-p raw-path)
2166                               (string-match "^\\.\\.?/" raw-path))
2167                           "file")))
2168             (coderefp (equal type "coderef"))
2169             (caption (org-find-text-property-in-string 'org-caption raw-path))
2170             (shortn (org-find-text-property-in-string 'org-caption-shortn raw-path))
2171             (attr (or (org-find-text-property-in-string 'org-attributes raw-path)
2172                       (plist-get org-export-latex-options-plist :latex-image-options)))
2173             (label (org-find-text-property-in-string 'org-label raw-path))
2174             imgp radiop fnc
2175             ;; define the path of the link
2176             (path (cond
2177                    ((member type '("coderef"))
2178                     raw-path)
2179                    ((member type '("http" "https" "ftp"))
2180                     (concat type ":" raw-path))
2181                    ((and re-radio (string-match re-radio raw-path))
2182                     (setq radiop t))
2183                    ((equal type "mailto")
2184                     (concat type ":" raw-path))
2185                    ((equal type "file")
2186                     (if (and (org-file-image-p
2187                               (expand-file-name
2188                                raw-path)
2189                               org-export-latex-inline-image-extensions)
2190                              (or (get-text-property 0 'org-no-description
2191                                                     raw-path)
2192                                  (equal desc full-raw-path)))
2193                         (setq imgp t)
2194                       (progn (when (string-match "\\(.+\\)::.+" raw-path)
2195                                (setq raw-path (match-string 1 raw-path)))
2196                              (if (file-exists-p raw-path)
2197                                  (concat type "://" (expand-file-name raw-path))
2198                                (concat type "://" (org-export-directory
2199                                                    :LaTeX org-export-latex-options-plist)
2200                                        raw-path))))))))
2201        ;; process with link inserting
2202        (apply 'delete-region remove)
2203        (setq caption (and caption (org-export-latex-fontify-headline caption)))
2204        (cond ((and imgp
2205                    (plist-get org-export-latex-options-plist :inline-images))
2206               ;; OK, we need to inline an image
2207               (insert
2208                (org-export-latex-format-image raw-path caption label attr shortn)))
2209              (coderefp
2210               (insert (format
2211                        (org-export-get-coderef-format path desc)
2212                        (cdr (assoc path org-export-code-refs)))))
2213              (radiop (insert (format org-export-latex-hyperref-format
2214                                      (org-solidify-link-text raw-path) desc)))
2215              ((not type)
2216               (insert (format org-export-latex-hyperref-format
2217                               (org-remove-initial-hash
2218                                (org-solidify-link-text raw-path))
2219                               desc)))
2220              (path
2221               (when (org-at-table-p)
2222                 ;; There is a strange problem when we have a link in a table,
2223                 ;; ampersands then cause a problem.  I think this must be
2224                 ;; a LaTeX issue, but we here implement a work-around anyway.
2225                 (setq path (org-export-latex-protect-amp path)
2226                       desc (org-export-latex-protect-amp desc)))
2227               (insert
2228                (if (string-match "%s.*%s" org-export-latex-href-format)
2229                    (format org-export-latex-href-format path desc)
2230                  (format org-export-latex-href-format path))))
2231
2232              ((functionp (setq fnc (nth 2 (assoc type org-link-protocols))))
2233               ;; The link protocol has a function for formatting the link
2234               (insert
2235                (save-match-data
2236                  (funcall fnc (org-link-unescape raw-path) desc 'latex))))
2237
2238              (t (insert "\\texttt{" desc "}")))))))
2239
2240
2241 (defun org-export-latex-format-image (path caption label attr &optional shortn)
2242   "Format the image element, depending on user settings."
2243   (let (ind floatp wrapp multicolumnp placement figenv)
2244     (setq floatp (or caption label))
2245     (setq ind (org-get-text-property-any 0 'original-indentation path))
2246     (when (and attr (stringp attr))
2247       (if (string-match "[ \t]*\\<wrap\\>" attr)
2248           (setq wrapp t floatp nil attr (replace-match "" t t attr)))
2249       (if (string-match "[ \t]*\\<float\\>" attr)
2250           (setq wrapp nil floatp t attr (replace-match "" t t attr)))
2251       (if (string-match "[ \t]*\\<multicolumn\\>" attr)
2252           (setq multicolumnp t attr (replace-match "" t t attr))))
2253
2254     (setq placement
2255           (cond
2256            (wrapp "{l}{0.5\\textwidth}")
2257            (floatp (concat "[" org-latex-default-figure-position "]"))
2258            (t "")))
2259
2260     (when (and attr (stringp attr)
2261                (string-match "[ \t]*\\<placement=\\(\\S-+\\)" attr))
2262       (setq placement (match-string 1 attr)
2263             attr (replace-match "" t t attr)))
2264     (setq attr (and attr (org-trim attr)))
2265     (when (or (not attr) (= (length attr) 0))
2266       (setq attr (cond (floatp "width=0.7\\textwidth")
2267                        (wrapp "width=0.48\\textwidth")
2268                        (t attr))))
2269     (setq figenv
2270           (cond
2271            (wrapp "\\begin{wrapfigure}%placement
2272 \\centering
2273 \\includegraphics[%attr]{%path}
2274 \\caption%shortn{%labelcmd%caption}
2275 \\end{wrapfigure}")
2276            (multicolumnp "\\begin{figure*}%placement
2277 \\centering
2278 \\includegraphics[%attr]{%path}
2279 \\caption%shortn{%labelcmd%caption}
2280 \\end{figure*}")
2281            (floatp "\\begin{figure}%placement
2282 \\centering
2283 \\includegraphics[%attr]{%path}
2284 \\caption%shortn{%labelcmd%caption}
2285 \\end{figure}")
2286            (t "\\includegraphics[%attr]{%path}")))
2287
2288
2289     (setq figenv (mapconcat 'identity (split-string figenv "\n")
2290                             (save-excursion (beginning-of-line 1)
2291                                             (looking-at "[ \t]*")
2292                                             (concat "\n" (match-string 0)))))
2293
2294     (if (and (not label) (not caption)
2295              (string-match "^\\\\caption{.*\n" figenv))
2296         (setq figenv (replace-match "" t t figenv)))
2297     (org-add-props
2298         (org-fill-template
2299          figenv
2300          (list (cons "path"
2301                      (if (file-name-absolute-p path)
2302                          (expand-file-name path)
2303                        path))
2304                (cons "attr" attr)
2305                (cons "shortn" (if shortn (format "[%s]" shortn) ""))
2306                (cons "labelcmd" (if label (format "\\label{%s}"
2307                                                   label)""))
2308                (cons "caption" (or caption ""))
2309                (cons "placement" (or placement ""))))
2310         nil 'original-indentation ind)))
2311
2312 (defun org-export-latex-protect-amp (s)
2313   (while (string-match "\\([^\\\\]\\)\\(&\\)" s)
2314     (setq s (replace-match (concat (match-string 1 s) "\\" (match-string 2 s))
2315                            t t s)))
2316   s)
2317
2318 (defun org-remove-initial-hash (s)
2319   (if (string-match "\\`#" s)
2320       (substring s 1)
2321     s))
2322 (defvar org-latex-entities)   ; defined below
2323 (defvar org-latex-entities-regexp)   ; defined below
2324
2325 (defun org-export-latex-preprocess (parameters)
2326   "Clean stuff in the LaTeX export."
2327   ;; Replace footnotes.
2328   (when (plist-get parameters :footnotes)
2329     (goto-char (point-min))
2330     (let (ref)
2331       (while (setq ref (org-footnote-get-next-reference))
2332         (let* ((beg (nth 1 ref))
2333                (lbl (car ref))
2334                (def (nth 1 (assoc (string-to-number lbl)
2335                                   (mapcar (lambda (e) (cdr e))
2336                                           org-export-footnotes-seen)))))
2337           ;; Fix body for footnotes ending on a link or a list and
2338           ;; remove definition from buffer.
2339           (setq def
2340                 (concat def
2341                         (if (string-match "ORG-LIST-END-MARKER\\'" def)
2342                             "\n" " ")))
2343           (org-footnote-delete-definitions lbl)
2344           ;; Compute string to insert (FNOTE), and protect the outside
2345           ;; macro from further transformation.  When footnote at
2346           ;; point is referring to a previously defined footnote, use
2347           ;; \footnotemark. Otherwise, use \footnote.
2348           (let ((fnote (if (member lbl org-export-latex-footmark-seen)
2349                            (org-export-latex-protect-string
2350                             (format "\\footnotemark[%s]" lbl))
2351                          (push lbl org-export-latex-footmark-seen)
2352                          (concat (org-export-latex-protect-string "\\footnote{")
2353                                  def
2354                                  (org-export-latex-protect-string "}"))))
2355                 ;; Check if another footnote is immediately following.
2356                 ;; If so, add a separator in-between.
2357                 (sep (org-export-latex-protect-string
2358                       (if (save-excursion (goto-char (1- (nth 2 ref)))
2359                                           (let ((next (org-footnote-get-next-reference)))
2360                                             (and next (= (nth 1 next) (nth 2 ref)))))
2361                           org-export-latex-footnote-separator ""))))
2362             (when (org-on-heading-p)
2363               (setq fnote (concat (org-export-latex-protect-string "\\protect")
2364                                   fnote)))
2365             ;; Ensure a footnote at column 0 cannot end a list
2366             ;; containing it.
2367             (put-text-property 0 (length fnote) 'original-indentation 1000 fnote)
2368             ;; Replace footnote reference with FNOTE and, maybe, SEP.
2369             ;; `save-excursion' is required if there are two footnotes
2370             ;; in a row.  In that case, point would be left at the
2371             ;; beginning of the second one, and
2372             ;; `org-footnote-get-next-reference' would then skip it.
2373             (goto-char beg)
2374             (delete-region beg (nth 2 ref))
2375             (save-excursion (insert fnote sep)))))))
2376
2377   ;; Remove footnote section tag for LaTeX
2378   (goto-char (point-min))
2379   (while (re-search-forward
2380           (concat "^" footnote-section-tag-regexp) nil t)
2381     (org-if-unprotected
2382      (replace-match "")))
2383   ;; Remove any left-over footnote definition.
2384   (mapc (lambda (fn) (org-footnote-delete-definitions (car fn)))
2385         org-export-footnotes-data)
2386   (mapc (lambda (fn) (org-footnote-delete-definitions fn))
2387         org-export-latex-footmark-seen)
2388
2389   ;; Preserve line breaks
2390   (goto-char (point-min))
2391   (while (re-search-forward "\\\\\\\\" nil t)
2392     (add-text-properties (match-beginning 0) (match-end 0)
2393                          '(org-protected t)))
2394
2395   ;; Preserve latex environments
2396   (goto-char (point-min))
2397   (while (re-search-forward "^[ \t]*\\\\begin{\\([a-zA-Z]+\\*?\\)}" nil t)
2398     (org-if-unprotected
2399      (let* ((start (progn (beginning-of-line) (point)))
2400             (end (and (re-search-forward
2401                        (concat "^[ \t]*\\\\end{"
2402                                (regexp-quote (match-string 1))
2403                                "}") nil t)
2404                       (point-at-eol))))
2405        (if end
2406            (add-text-properties start end '(org-protected t))
2407          (goto-char (point-at-eol))))))
2408
2409   ;; Preserve math snippets
2410   (let* ((matchers (plist-get org-format-latex-options :matchers))
2411          (re-list org-latex-regexps)
2412          beg end re e m n block off)
2413     ;; Check the different regular expressions
2414     (while (setq e (pop re-list))
2415       (setq m (car e) re (nth 1 e) n (nth 2 e)
2416             block (if (nth 3 e) "\n\n" ""))
2417       (setq off (if (member m '("$" "$1")) 1 0))
2418       (when (and (member m matchers) (not (equal m "begin")))
2419         (goto-char (point-min))
2420         (while (re-search-forward re nil t)
2421           (setq beg (+ (match-beginning 0) off) end (- (match-end 0) 0))
2422           (add-text-properties beg end '(org-protected t org-latex-math t))))))
2423
2424   ;; Convert LaTeX to \LaTeX{} and TeX to \TeX{}
2425   (goto-char (point-min))
2426   (let ((case-fold-search nil))
2427     (while (re-search-forward "\\<\\(\\(La\\)?TeX\\)\\>" nil t)
2428       (unless (eq (char-before (match-beginning 1)) ?\\)
2429         (org-if-unprotected-1
2430          (replace-match (org-export-latex-protect-string
2431                          (concat "\\" (match-string 1)
2432                                  "{}")) t t)))))
2433
2434   ;; Convert blockquotes
2435   (goto-char (point-min))
2436   (while (search-forward "ORG-BLOCKQUOTE-START" nil t)
2437     (org-replace-match-keep-properties "\\begin{quote}" t t))
2438   (goto-char (point-min))
2439   (while (search-forward "ORG-BLOCKQUOTE-END" nil t)
2440     (org-replace-match-keep-properties "\\end{quote}" t t))
2441
2442   ;; Convert verse
2443   (goto-char (point-min))
2444   (while (search-forward "ORG-VERSE-START" nil t)
2445     (org-replace-match-keep-properties "\\begin{verse}" t t)
2446     (beginning-of-line 2)
2447     (while (and (not (looking-at "[ \t]*ORG-VERSE-END.*")) (not (eobp)))
2448       (when (looking-at "\\([ \t]+\\)\\([^ \t\n]\\)")
2449         (goto-char (match-end 1))
2450         (org-replace-match-keep-properties
2451          (org-export-latex-protect-string
2452           (concat "\\hspace*{1cm}" (match-string 2))) t t)
2453         (beginning-of-line 1))
2454       (if (looking-at "[ \t]*$")
2455           (insert (org-export-latex-protect-string "\\vspace*{1em}"))
2456         (unless (looking-at ".*?[^ \t\n].*?\\\\\\\\[ \t]*$")
2457           (end-of-line 1)
2458           (insert "\\\\")))
2459       (beginning-of-line 2))
2460     (and (looking-at "[ \t]*ORG-VERSE-END.*")
2461          (org-replace-match-keep-properties "\\end{verse}" t t)))
2462
2463   ;; Convert #+INDEX to LaTeX \\index.
2464   (goto-char (point-min))
2465   (let ((case-fold-search t) entry)
2466     (while (re-search-forward
2467             "^[ \t]*#\\+index:[ \t]*\\([^ \t\r\n].*?\\)[ \t]*$"
2468             nil t)
2469       (setq entry
2470             (save-match-data
2471               (org-export-latex-protect-string
2472                (org-export-latex-fontify-headline (match-string 1)))))
2473       (replace-match (format "\\index{%s}" entry) t t)))
2474
2475   ;; Convert center
2476   (goto-char (point-min))
2477   (while (search-forward "ORG-CENTER-START" nil t)
2478     (org-replace-match-keep-properties "\\begin{center}" t t))
2479   (goto-char (point-min))
2480   (while (search-forward "ORG-CENTER-END" nil t)
2481     (org-replace-match-keep-properties "\\end{center}" t t))
2482
2483   (run-hooks 'org-export-latex-after-blockquotes-hook)
2484
2485   ;; Convert horizontal rules
2486   (goto-char (point-min))
2487   (while (re-search-forward "^[ \t]*-\\{5,\\}[ \t]*$" nil t)
2488     (org-if-unprotected
2489      (replace-match (org-export-latex-protect-string "\\hrule") t t)))
2490
2491   ;; Protect LaTeX commands like \command[...]{...} or \command{...}
2492   (goto-char (point-min))
2493   (let ((re (concat
2494              "\\\\\\([a-zA-Z]+\\*?\\)"
2495              "\\(?:<[^<>\n]*>\\)*"
2496              "\\(?:\\[[^][\n]*?\\]\\)*"
2497              "\\(?:<[^<>\n]*>\\)*"
2498              "\\(" (org-create-multibrace-regexp "{" "}" 3) "\\)\\{1,3\\}")))
2499     (while (re-search-forward re nil t)
2500       (unless (or
2501                ;; Check for comment line.
2502                (save-excursion (goto-char (match-beginning 0))
2503                                (org-in-indented-comment-line))
2504                ;; Check if this is a defined entity, so that is may
2505                ;; need conversion.
2506                (org-entity-get (match-string 1))
2507                ;; Do not protect interior of footnotes.  Those have
2508                ;; already been taken care of earlier in the function.
2509                ;; Yet, keep looking inside them for more commands.
2510                (and (equal (match-string 1) "footnote")
2511                     (goto-char (match-end 1))))
2512         (add-text-properties (match-beginning 0) (match-end 0)
2513                              '(org-protected t)))))
2514
2515   ;; Special case for \nbsp
2516   (goto-char (point-min))
2517   (while (re-search-forward "\\\\nbsp\\({}\\|\\>\\)" nil t)
2518     (org-if-unprotected
2519      (replace-match (org-export-latex-protect-string "~"))))
2520
2521   ;; Protect LaTeX entities
2522   (goto-char (point-min))
2523   (while (re-search-forward org-latex-entities-regexp nil t)
2524     (org-if-unprotected
2525      (add-text-properties (match-beginning 0) (match-end 0)
2526                           '(org-protected t))))
2527
2528   ;; Replace radio links
2529   (goto-char (point-min))
2530   (while (re-search-forward
2531           (concat "<<<?" org-export-latex-all-targets-re
2532                   ">>>?\\((INVISIBLE)\\)?") nil t)
2533     (org-if-unprotected-at (+ (match-beginning 0) 2)
2534       (replace-match
2535        (concat
2536         (org-export-latex-protect-string
2537          (format "\\label{%s}" (save-match-data (org-solidify-link-text
2538                                                  (match-string 1)))))
2539         (if (match-string 2) "" (match-string 1)))
2540        t t)))
2541
2542   ;; Delete @<...> constructs
2543   ;; Thanks to Daniel Clemente for this regexp
2544   (goto-char (point-min))
2545   (while (re-search-forward "@<\\(?:[^\"\n]\\|\".*\"\\)*?>" nil t)
2546     (org-if-unprotected
2547      (replace-match ""))))
2548
2549 (defun org-export-latex-fix-inputenc ()
2550   "Set the coding system in inputenc to what the buffer is."
2551   (let* ((cs buffer-file-coding-system)
2552          (opt (or (ignore-errors (latexenc-coding-system-to-inputenc cs))
2553                   "utf8")))
2554     (when opt
2555       ;; Translate if that is requested
2556       (setq opt (or (cdr (assoc opt org-export-latex-inputenc-alist)) opt))
2557       ;; find the \usepackage statement and replace the option
2558       (goto-char (point-min))
2559       (while (re-search-forward "\\\\usepackage\\[\\(AUTO\\)\\]{inputenc}"
2560                                 nil t)
2561         (goto-char (match-beginning 1))
2562         (delete-region (match-beginning 1) (match-end 1))
2563         (insert opt))
2564       (and buffer-file-name
2565            (save-buffer)))))
2566
2567 ;;; List handling:
2568
2569 (defun org-export-latex-lists ()
2570   "Convert plain text lists in current buffer into LaTeX lists."
2571   ;; `org-list-end-re' output has changed since preprocess from
2572   ;; org-exp.el. Make sure it is taken into account.
2573   (let ((org-list-ending-method
2574          (if (eq org-list-ending-method 'regexp) 'regexp 'both))
2575         (org-list-end-re "^ORG-LIST-END-MARKER\n"))
2576     (mapc
2577      (lambda (e)
2578        ;; For each type of context allowed for list export (E), find
2579        ;; every list, parse it, delete it and insert resulting
2580        ;; conversion to latex (RES), while keeping the same
2581        ;; `original-indentation' property.
2582        (let (res)
2583          (goto-char (point-min))
2584          (while (re-search-forward (org-item-beginning-re) nil t)
2585            (when (and (eq (get-text-property (point) 'list-context) e)
2586                       (not (get-text-property (point) 'org-example)))
2587              (beginning-of-line)
2588              (setq res
2589                    (org-list-to-latex
2590                     ;; Narrowing is needed because we're converting
2591                     ;; from inner functions to outer ones.
2592                     (save-restriction
2593                       (narrow-to-region (point) (point-max))
2594                       (org-list-parse-list t))
2595                     org-export-latex-list-parameters))
2596              ;; Extend previous value of original-indentation to the
2597              ;; whole string
2598              (insert (org-add-props res nil 'original-indentation
2599                                     (org-find-text-property-in-string
2600                                      'original-indentation res)))))))
2601      ;; List of allowed contexts for export, and the default one.
2602      (append org-list-export-context '(nil)))))
2603
2604 (defconst org-latex-entities
2605  '("\\!"
2606    "\\'"
2607    "\\+"
2608    "\\,"
2609    "\\-"
2610    "\\:"
2611    "\\;"
2612    "\\<"
2613    "\\="
2614    "\\>"
2615    "\\Huge"
2616    "\\LARGE"
2617    "\\Large"
2618    "\\Styles"
2619    "\\\\"
2620    "\\`"
2621    "\\\""
2622    "\\addcontentsline"
2623    "\\address"
2624    "\\addtocontents"
2625    "\\addtocounter"
2626    "\\addtolength"
2627    "\\addvspace"
2628    "\\alph"
2629    "\\appendix"
2630    "\\arabic"
2631    "\\author"
2632    "\\begin{array}"
2633    "\\begin{center}"
2634    "\\begin{description}"
2635    "\\begin{enumerate}"
2636    "\\begin{eqnarray}"
2637    "\\begin{equation}"
2638    "\\begin{figure}"
2639    "\\begin{flushleft}"
2640    "\\begin{flushright}"
2641    "\\begin{itemize}"
2642    "\\begin{list}"
2643    "\\begin{minipage}"
2644    "\\begin{picture}"
2645    "\\begin{quotation}"
2646    "\\begin{quote}"
2647    "\\begin{tabbing}"
2648    "\\begin{table}"
2649    "\\begin{tabular}"
2650    "\\begin{thebibliography}"
2651    "\\begin{theorem}"
2652    "\\begin{titlepage}"
2653    "\\begin{verbatim}"
2654    "\\begin{verse}"
2655    "\\bf"
2656    "\\bf"
2657    "\\bibitem"
2658    "\\bigskip"
2659    "\\cdots"
2660    "\\centering"
2661    "\\circle"
2662    "\\cite"
2663    "\\cleardoublepage"
2664    "\\clearpage"
2665    "\\cline"
2666    "\\closing"
2667    "\\dashbox"
2668    "\\date"
2669    "\\ddots"
2670    "\\dotfill"
2671    "\\em"
2672    "\\fbox"
2673    "\\flushbottom"
2674    "\\fnsymbol"
2675    "\\footnote"
2676    "\\footnotemark"
2677    "\\footnotesize"
2678    "\\footnotetext"
2679    "\\frac"
2680    "\\frame"
2681    "\\framebox"
2682    "\\hfill"
2683    "\\hline"
2684    "\\hrulespace"
2685    "\\hspace"
2686    "\\huge"
2687    "\\hyphenation"
2688    "\\include"
2689    "\\includeonly"
2690    "\\indent"
2691    "\\input"
2692    "\\it"
2693    "\\kill"
2694    "\\label"
2695    "\\large"
2696    "\\ldots"
2697    "\\line"
2698    "\\linebreak"
2699    "\\linethickness"
2700    "\\listoffigures"
2701    "\\listoftables"
2702    "\\location"
2703    "\\makebox"
2704    "\\maketitle"
2705    "\\mark"
2706    "\\mbox"
2707    "\\medskip"
2708    "\\multicolumn"
2709    "\\multiput"
2710    "\\newcommand"
2711    "\\newcounter"
2712    "\\newenvironment"
2713    "\\newfont"
2714    "\\newlength"
2715    "\\newline"
2716    "\\newpage"
2717    "\\newsavebox"
2718    "\\newtheorem"
2719    "\\nocite"
2720    "\\nofiles"
2721    "\\noindent"
2722    "\\nolinebreak"
2723    "\\nopagebreak"
2724    "\\normalsize"
2725    "\\onecolumn"
2726    "\\opening"
2727    "\\oval"
2728    "\\overbrace"
2729    "\\overline"
2730    "\\pagebreak"
2731    "\\pagenumbering"
2732    "\\pageref"
2733    "\\pagestyle"
2734    "\\par"
2735    "\\parbox"
2736    "\\put"
2737    "\\raggedbottom"
2738    "\\raggedleft"
2739    "\\raggedright"
2740    "\\raisebox"
2741    "\\ref"
2742    "\\rm"
2743    "\\roman"
2744    "\\rule"
2745    "\\savebox"
2746    "\\sc"
2747    "\\scriptsize"
2748    "\\setcounter"
2749    "\\setlength"
2750    "\\settowidth"
2751    "\\sf"
2752    "\\shortstack"
2753    "\\signature"
2754    "\\sl"
2755    "\\small"
2756    "\\smallskip"
2757    "\\sqrt"
2758    "\\tableofcontents"
2759    "\\telephone"
2760    "\\thanks"
2761    "\\thispagestyle"
2762    "\\tiny"
2763    "\\title"
2764    "\\tt"
2765    "\\twocolumn"
2766    "\\typein"
2767    "\\typeout"
2768    "\\underbrace"
2769    "\\underline"
2770    "\\usebox"
2771    "\\usecounter"
2772    "\\value"
2773    "\\vdots"
2774    "\\vector"
2775    "\\verb"
2776    "\\vfill"
2777    "\\vline"
2778    "\\vspace")
2779  "A list of LaTeX commands to be protected when performing conversion.")
2780
2781 (defconst org-latex-entities-regexp
2782   (let (names rest)
2783     (dolist (x org-latex-entities)
2784       (if (string-match "[a-zA-Z]$" x)
2785           (push x names)
2786         (push x rest)))
2787     (concat "\\(" (regexp-opt (nreverse names)) "\\>\\)"
2788             "\\|\\(" (regexp-opt (nreverse rest)) "\\)")))
2789
2790 (provide 'org-export-latex)
2791 (provide 'org-latex)
2792
2793 ;;; org-latex.el ends here