lisp/org-bbdb.el

   1 ;;; org-bbdb.el --- Support for links to BBDB entries from within Org-mode
   2
   3 ;; Copyright (C) 2004-2011 Free Software Foundation, Inc.
   4
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>,
   6 ;;         Thomas Baumann <thomas dot baumann at ch dot tum dot de>
   7 ;; Keywords: outlines, hypermedia, calendar, wp
   8 ;; Homepage: http://orgmode.org
   9 ;;
  10 ;; This file is part of GNU Emacs.
  11 ;;
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  25 ;;
  26 ;;; Commentary:
  27
  28 ;; This file implements links to BBDB database entries from within Org-mode.
  29 ;; Org-mode loads this module by default - if this is not what you want,
  30 ;; configure the variable `org-modules'.
  31
  32 ;; It also implements an interface (based on Ivar Rummelhoff's
  33 ;; bbdb-anniv.el) for those org-mode users, who do not use the diary
  34 ;; but who do want to include the anniversaries stored in the BBDB
  35 ;; into the org-agenda.  If you already include the `diary' into the
  36 ;; agenda, you might want to prefer to include the anniversaries in
  37 ;; the diary using bbdb-anniv.el.
  38 ;;
  39 ;; Put the following in /somewhere/at/home/diary.org and make sure
  40 ;; that this file is in `org-agenda-files`
  41 ;;
  42 ;; %%(org-bbdb-anniversaries)
  43 ;;
  44 ;; For example my diary.org looks like:
  45 ;; * Anniversaries
  46 ;; #+CATEGORY: Anniv
  47 ;; %%(org-bbdb-anniversaries)
  48 ;;
  49 ;;
  50 ;; To add an anniversary to a BBDB record, press `C-o' in the record.
  51 ;; You will be prompted for the field name, in this case it must be
  52 ;; "anniversary".  If this is the first time you are using this field,
  53 ;; you need to confirm that it should be created.
  54 ;;
  55 ;; The format of an anniversary field stored in BBDB is the following
  56 ;; (items in {} are optional):
  57 ;;
  58 ;;     YYYY-MM-DD{ CLASS-OR-FORMAT-STRING}
  59 ;;     {\nYYYY-MM-DD CLASS-OR-FORMAT-STRING}...
  60 ;;
  61 ;; CLASS-OR-FORMAT-STRING is one of two things:
  62 ;;
  63 ;;  - an identifier for a class of anniversaries (eg. birthday or
  64 ;;    wedding) from `org-bbdb-anniversary-format-alist' which then
  65 ;;    defines the format string for this class
  66 ;;  - the (format) string displayed in the diary.
  67 ;;
  68 ;; You can enter multiple anniversaries for a single BBDB record by
  69 ;; separating them with a newline character.  At the BBDB prompt for
  70 ;; the field value, type `C-q C-j' to enter a newline between two
  71 ;; anniversaries.
  72 ;;
  73 ;; If you omit the CLASS-OR-FORMAT-STRING entirely, it defaults to the
  74 ;; value of `org-bbdb-default-anniversary-format' ("birthday" by
  75 ;; default).
  76 ;;
  77 ;; The substitutions in the format string are (in order):
  78 ;;  - the name of the record containing this anniversary
  79 ;;  - the number of years
  80 ;;  - an ordinal suffix (st, nd, rd, th) for the year
  81 ;;
  82 ;; See the documentation of `org-bbdb-anniversary-format-alist' for
  83 ;; further options.
  84 ;;
  85 ;; Example
  86 ;;
  87 ;;       1973-06-22
  88 ;;       20??-??-?? wedding
  89 ;;       1998-03-12 %s created bbdb-anniv.el %d years ago
  90 ;;
  91 ;; From Org's agenda, you can use `C-c C-o' to jump to the BBDB
  92 ;; link from which the entry at point originates.
  93 ;;
  94 ;;; Code:
  95
  96 (require 'org)
  97 (eval-when-compile
  98   (require 'cl))
  99
 100 ;; Declare external functions and variables
 101
 102 (declare-function bbdb "ext:bbdb-com" (string elidep))
 103 (declare-function bbdb-company "ext:bbdb-com" (string elidep))
 104 (declare-function bbdb-current-record "ext:bbdb-com"
 105                   (&optional planning-on-modifying))
 106 (declare-function bbdb-name "ext:bbdb-com" (string elidep))
 107 (declare-function bbdb-completing-read-record "ext:bbdb-com"
 108                   (prompt &optional omit-records))
 109 (declare-function bbdb-record-getprop "ext:bbdb" (record property))
 110 (declare-function bbdb-record-name "ext:bbdb" (record))
 111 (declare-function bbdb-records "ext:bbdb"
 112           (&optional dont-check-disk already-in-db-buffer))
 113 (declare-function bbdb-split "ext:bbdb" (string separators))
 114 (declare-function bbdb-string-trim "ext:bbdb" (string))
 115
 116 (declare-function calendar-leap-year-p "calendar" (year))
 117 (declare-function diary-ordinal-suffix "diary-lib" (n))
 118
 119 (defvar date)   ;; dynamically scoped from Org
 120
 121 ;; Customization
 122
 123 (defgroup org-bbdb-anniversaries nil
 124   "Customizations for including anniversaries from BBDB into Agenda."
 125   :group 'org-bbdb)
 126
 127 (defcustom org-bbdb-default-anniversary-format "birthday"
 128   "Default anniversary class."
 129   :type  'string
 130   :group 'org-bbdb-anniversaries
 131   :require 'bbdb)
 132
 133 (defcustom org-bbdb-anniversary-format-alist
 134   '(("birthday" lambda
 135      (name years suffix)
 136      (concat "Birthday: [[bbdb:" name "][" name " ("
 137              (format "%s" years)        ; handles numbers as well as strings
 138              suffix ")]]"))
 139     ("wedding" lambda
 140      (name years suffix)
 141      (concat "[[bbdb:" name "][" name "'s "
 142              (format "%s" years)
 143              suffix " wedding anniversary]]")))
 144   "How different types of anniversaries should be formatted.
 145 An alist of elements (STRING . FORMAT) where STRING is the name of an
 146 anniversary class and format is either:
 147 1) A format string with the following substitutions (in order):
 148     * the name of the record containing this anniversary
 149     * the number of years
 150     * an ordinal suffix (st, nd, rd, th) for the year
 151
 152 2) A function to be called with three arguments: NAME YEARS SUFFIX
 153    (string int string) returning a string for the diary or nil.
 154
 155 3) An Emacs Lisp form that should evaluate to a string (or nil) in the
 156    scope of variables NAME, YEARS and SUFFIX (among others)."
 157   :type 'sexp
 158   :group 'org-bbdb-anniversaries
 159   :require 'bbdb)
 160
 161 (defcustom org-bbdb-anniversary-field 'anniversary
 162   "The BBDB field which contains anniversaries.
 163 The anniversaries are stored in the following format
 164
 165 YYYY-MM-DD Class-or-Format-String
 166
 167 where class is one of the customized classes for anniversaries;
 168 birthday and wedding are predefined.  Format-String can take three
 169 substitutions 1) the name of the record containing this
 170 anniversary, 2) the number of years, and 3) an ordinal suffix for
 171 the year.
 172
 173 Multiple anniversaries can be separated by \\n."
 174   :type    'symbol
 175   :group   'org-bbdb-anniversaries
 176   :require 'bbdb)
 177
 178 (defcustom org-bbdb-extract-date-fun 'org-bbdb-anniv-extract-date
 179   "How to retrieve `month date year' from the anniversary field.
 180
 181 Customize if you have already filled your BBDB with dates
 182 different from YYYY-MM-DD.  The function must return a list (month
 183 date year)."
 184   :type 'function
 185   :group 'org-bbdb-anniversaries
 186   :require 'bbdb)
 187
 188
 189 ;; Install the link type
 190 (org-add-link-type "bbdb" 'org-bbdb-open 'org-bbdb-export)
 191 (add-hook 'org-store-link-functions 'org-bbdb-store-link)
 192
 193 ;; Implementation
 194 (defun org-bbdb-store-link ()
 195   "Store a link to a BBDB database entry."
 196   (when (eq major-mode 'bbdb-mode)
 197     ;; This is BBDB, we make this link!
 198     (let* ((name (bbdb-record-name (bbdb-current-record)))
 199            (company (bbdb-record-getprop (bbdb-current-record) 'company))
 200            (link (org-make-link "bbdb:" name)))
 201       (org-store-link-props :type "bbdb" :name name :company company
 202                             :link link :description name)
 203       link)))
 204
 205 (defun org-bbdb-export (path desc format)
 206   "Create the export version of a BBDB link specified by PATH or DESC.
 207 If exporting to either HTML or LaTeX FORMAT the link will be
 208 italicized, in all other cases it is left unchanged."
 209   (when (string= desc (format "bbdb:%s" path))
 210     (setq desc path))
 211   (cond
 212    ((eq format 'html) (format "<i>%s</i>" desc))
 213    ((eq format 'latex) (format "\\textit{%s}" desc))
 214    (t desc)))
 215
 216 (defun org-bbdb-open (name)
 217   "Follow a BBDB link to NAME."
 218   (require 'bbdb)
 219   (let ((inhibit-redisplay (not debug-on-error))
 220         (bbdb-electric-p nil))
 221     (catch 'exit
 222       ;; Exact match on name
 223       (bbdb-name (concat "\\`" name "\\'") nil)
 224       (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 225       ;; Exact match on name
 226       (bbdb-company (concat "\\`" name "\\'") nil)
 227       (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 228       ;; Partial match on name
 229       (bbdb-name name nil)
 230       (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 231       ;; Partial match on company
 232       (bbdb-company name nil)
 233       (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 234       ;; General match including network address and notes
 235       (bbdb name nil)
 236       (when (= 0 (buffer-size (get-buffer "*BBDB*")))
 237         (delete-window (get-buffer-window "*BBDB*"))
 238         (error "No matching BBDB record")))))
 239
 240 (defun org-bbdb-anniv-extract-date (time-str)
 241   "Convert YYYY-MM-DD to (month date year).
 242 Argument TIME-STR is the value retrieved from BBDB.  If YYYY- is omitted
 243 it will be considered unknown."
 244   (multiple-value-bind (a b c) (values-list (bbdb-split time-str "-"))
 245     (if (eq c nil)
 246         (list (string-to-number a)
 247               (string-to-number b)
 248               nil)
 249       (list (string-to-number b)
 250             (string-to-number c)
 251             (string-to-number a)))))
 252
 253 (defun org-bbdb-anniv-split (str)
 254   "Split multiple entries in the BBDB anniversary field.
 255 Argument STR is the anniversary field in BBDB."
 256   (let ((pos (string-match "[ \t]" str)))
 257     (if pos (list (substring str 0 pos)
 258                   (bbdb-string-trim (substring str pos)))
 259       (list str nil))))
 260
 261 (defvar org-bbdb-anniv-hash nil
 262   "A hash holding anniversaries extracted from BBDB.
 263 The hash table is created on first use.")
 264
 265 (defvar org-bbdb-updated-p t
 266   "This is non-nil if BBDB has been updated since we last built the hash.")
 267
 268 (defun org-bbdb-make-anniv-hash ()
 269   "Create a hash with anniversaries extracted from BBDB, for fast access.
 270 The anniversaries are assumed to be stored `org-bbdb-anniversary-field'."
 271
 272   (let (split tmp annivs)
 273     (clrhash org-bbdb-anniv-hash)
 274     (dolist (rec (bbdb-records))
 275       (when (setq annivs (bbdb-record-getprop
 276                           rec org-bbdb-anniversary-field))
 277         (setq annivs (bbdb-split annivs "\n"))
 278         (while annivs
 279           (setq split (org-bbdb-anniv-split (pop annivs)))
 280           (multiple-value-bind (m d y)
 281               (values-list (funcall org-bbdb-extract-date-fun (car split)))
 282             (setq tmp (gethash (list m d) org-bbdb-anniv-hash))
 283             (puthash (list m d) (cons (list y
 284                                             (bbdb-record-name rec)
 285                                             (cadr split))
 286                                       tmp)
 287                      org-bbdb-anniv-hash))))))
 288   (setq org-bbdb-updated-p nil))
 289
 290 (defun org-bbdb-updated (rec)
 291   "Record the fact that BBDB has been updated.
 292 This is used by Org to re-create the anniversary hash table."
 293   (setq org-bbdb-updated-p t))
 294
 295 (add-hook 'bbdb-after-change-hook 'org-bbdb-updated)
 296
 297 ;;;###autoload
 298 (defun org-bbdb-anniversaries()
 299   "Extract anniversaries from BBDB for display in the agenda."
 300   (require 'bbdb)
 301   (require 'diary-lib)
 302   (unless (hash-table-p org-bbdb-anniv-hash)
 303     (setq org-bbdb-anniv-hash
 304           (make-hash-table :test 'equal :size 366)))
 305
 306   (when (or org-bbdb-updated-p
 307             (= 0 (hash-table-count org-bbdb-anniv-hash)))
 308     (org-bbdb-make-anniv-hash))
 309
 310   (let* ((m (car date))    ; month
 311          (d (nth 1 date))  ; day
 312          (y (nth 2 date))  ; year
 313          (annivs (gethash (list m d) org-bbdb-anniv-hash))
 314          (text ())
 315          rec recs)
 316
 317     ;; we don't want to miss people born on Feb. 29th
 318     (when (and (= m 3) (= d 1)
 319                (not (null (gethash (list 2 29) org-bbdb-anniv-hash)))
 320                (not (calendar-leap-year-p y)))
 321       (setq recs (gethash (list 2 29) org-bbdb-anniv-hash))
 322       (while (setq rec (pop recs))
 323         (push rec annivs)))
 324
 325     (when annivs
 326       (while (setq rec (pop annivs))
 327         (when rec
 328           (let* ((class (or (nth 2 rec)
 329                             org-bbdb-default-anniversary-format))
 330                  (form (or (cdr (assoc-string
 331                                  class org-bbdb-anniversary-format-alist t))
 332                            class))      ; (as format string)
 333                  (name (nth 1 rec))
 334                  (years (if (eq (car rec) nil)
 335                             "unknown"
 336                           (- y (car rec))))
 337                  (suffix (if (eq (car rec) nil)
 338                              ""
 339                            (diary-ordinal-suffix years)))
 340                  (tmp (cond
 341                        ((functionp form)
 342                         (funcall form name years suffix))
 343                        ((listp form) (eval form))
 344                        (t (format form name years suffix)))))
 345             (org-add-props tmp nil 'org-bbdb-name name)
 346             (if text
 347                 (setq text (append text (list tmp)))
 348               (setq text (list tmp)))))
 349         ))
 350     text))
 351
 352 (defun org-bbdb-complete-link ()
 353   "Read a bbdb link with name completion."
 354   (require 'bbdb-com)
 355   (concat "bbdb:"
 356           (bbdb-record-name (car (bbdb-completing-read-record "Name: ")))))
 357
 358 (defun org-bbdb-anniv-export-ical ()
 359   "Extract anniversaries from BBDB and convert them to icalendar format."
 360   (require 'bbdb)
 361   (require 'diary-lib)
 362   (unless (hash-table-p org-bbdb-anniv-hash)
 363     (setq org-bbdb-anniv-hash
 364           (make-hash-table :test 'equal :size 366)))
 365   (when (or org-bbdb-updated-p
 366             (= 0 (hash-table-count org-bbdb-anniv-hash)))
 367     (org-bbdb-make-anniv-hash))
 368   (maphash 'org-bbdb-format-vevent org-bbdb-anniv-hash))
 369
 370 (defun org-bbdb-format-vevent (key recs)
 371   (let (rec categ)
 372     (while (setq rec (pop recs))
 373       (setq categ (or (nth 2 rec) org-bbdb-default-anniversary-format))
 374       (princ (format "BEGIN:VEVENT
 375 UID: ANNIV-%4i%02i%02i-%s
 376 DTSTART:%4i%02i%02i
 377 SUMMARY:%s
 378 DESCRIPTION:%s
 379 CATEGORIES:%s
 380 RRULE:FREQ=YEARLY
 381 END:VEVENT\n"
 382                      (nth 0 rec) (nth 0 key) (nth 1 key)
 383                      (mapconcat 'identity
 384                                 (org-split-string (nth 1 rec) "[^a-zA-Z0-90]+")
 385                                 "-")
 386                      (nth 0 rec) (nth 0 key) (nth 1 key)
 387                      (nth 1 rec)
 388                      (concat (capitalize categ) " " (nth 1 rec))
 389                      categ)))))
 390
 391 (provide 'org-bbdb)
 392
 393 ;;; org-bbdb.el ends here