lisp/org-footnote.el

   1 ;;; org-footnote.el --- Footnote support in Org and elsewhere
   2 ;;
   3 ;; Copyright (C) 2009-2012 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: http://orgmode.org
   8 ;;
   9 ;; This file is part of GNU Emacs.
  10 ;;
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  24 ;;
  25 ;;; Commentary:
  26
  27 ;; This file contains the code dealing with footnotes in Org-mode.
  28 ;; The code can also be used in arbitrary text modes to provide
  29 ;; footnotes.  Compared to Steven L Baur's footnote.el it provides
  30 ;; better support for resuming editing.  It is less configurable than
  31 ;; Steve's code, though.
  32
  33 ;;; Code:
  34
  35 (eval-when-compile
  36   (require 'cl))
  37 (require 'org-macs)
  38 (require 'org-compat)
  39
  40 (declare-function message-point-in-header-p "message" ())
  41 (declare-function org-back-over-empty-lines "org" ())
  42 (declare-function org-back-to-heading "org" (&optional invisible-ok))
  43 (declare-function org-combine-plists "org" (&rest plists))
  44 (declare-function org-end-of-subtree "org"  (&optional invisible-ok to-heading))
  45 (declare-function org-export-preprocess-string "org-exp"
  46                   (string &rest parameters))
  47 (declare-function org-fill-paragraph "org" (&optional justify))
  48 (declare-function org-icompleting-read "org" (&rest args))
  49 (declare-function org-id-uuid "org-id" ())
  50 (declare-function org-in-block-p "org" (names))
  51 (declare-function org-in-commented-line "org" ())
  52 (declare-function org-in-indented-comment-line "org" ())
  53 (declare-function org-in-regexp "org" (re &optional nlines visually))
  54 (declare-function org-in-verbatim-emphasis "org" ())
  55 (declare-function org-inside-LaTeX-fragment-p "org" ())
  56 (declare-function org-inside-latex-macro-p "org" ())
  57 (declare-function org-mark-ring-push "org" (&optional pos buffer))
  58 (declare-function org-show-context "org" (&optional key))
  59 (declare-function org-trim "org" (s))
  60 (declare-function org-skip-whitespace "org" ())
  61 (declare-function outline-next-heading "outline")
  62 (declare-function org-skip-whitespace "org" ())
  63
  64 (defvar org-outline-regexp-bol)         ; defined in org.el
  65 (defvar org-odd-levels-only)            ; defined in org.el
  66 (defvar org-bracket-link-regexp)        ; defined in org.el
  67 (defvar message-cite-prefix-regexp)     ; defined in message.el
  68 (defvar message-signature-separator)    ; defined in message.el
  69
  70 (defconst org-footnote-re
  71   ;; Only [1]-like footnotes are closed in this regexp, as footnotes
  72   ;; from other types might contain square brackets (i.e. links) in
  73   ;; their definition.
  74   ;;
  75   ;; `org-re' is used for regexp compatibility with XEmacs.
  76   (concat "\\[\\(?:"
  77           ;; Match inline footnotes.
  78           (org-re "fn:\\([-_[:word:]]+\\)?:\\|")
  79           ;; Match other footnotes.
  80           "\\(?:\\([0-9]+\\)\\]\\)\\|"
  81           (org-re "\\(fn:[-_[:word:]]+\\)")
  82           "\\)")
  83   "Regular expression for matching footnotes.")
  84
  85 (defconst org-footnote-definition-re
  86   (org-re "^\\[\\([0-9]+\\|fn:[-_[:word:]]+\\)\\]")
  87   "Regular expression matching the definition of a footnote.")
  88
  89 (defconst org-footnote-forbidden-blocks
  90   '("ascii" "beamer" "comment" "docbook" "example" "html" "latex" "odt" "src")
  91   "Names of blocks where footnotes are not allowed.")
  92
  93 (defgroup org-footnote nil
  94   "Footnotes in Org-mode."
  95   :tag "Org Footnote"
  96   :group 'org)
  97
  98 (defcustom org-footnote-section "Footnotes"
  99   "Outline heading containing footnote definitions before export.
 100 This can be nil, to place footnotes locally at the end of the current
 101 outline node.  If can also be the name of a special outline heading
 102 under which footnotes should be put.
 103 This variable defines the place where Org puts the definition
 104 automatically, i.e. when creating the footnote, and when sorting the notes.
 105 However, by hand you may place definitions *anywhere*.
 106 If this is a string, during export, all subtrees starting with this
 107 heading will be removed after extracting footnote definitions."
 108   :group 'org-footnote
 109   :type '(choice
 110           (string :tag "Collect footnotes under heading")
 111           (const :tag "Define footnotes locally" nil)))
 112
 113 (defcustom org-footnote-tag-for-non-org-mode-files "Footnotes:"
 114   "Tag marking the beginning of footnote section.
 115 The Org footnote engine can be used in arbitrary text files as well
 116 as in Org-mode.  Outside Org mode, new footnotes are always placed at
 117 the end of the file.  When you normalize the notes, any line containing
 118 only this tag will be removed, a new one will be inserted at the end
 119 of the file, followed by the collected and normalized footnotes.
 120
 121 If you don't want any tag in such buffers, set this variable to nil."
 122   :group 'org-footnote
 123   :type '(choice
 124           (string :tag "Collect footnotes under tag")
 125           (const :tag "Don't use a tag" nil)))
 126
 127 (defcustom org-footnote-define-inline nil
 128   "Non-nil means define footnotes inline, at reference location.
 129 When nil, footnotes will be defined in a special section near
 130 the end of the document.  When t, the [fn:label:definition] notation
 131 will be used to define the footnote at the reference position."
 132   :group 'org-footnote
 133   :type 'boolean)
 134
 135 (defcustom org-footnote-auto-label t
 136   "Non-nil means define automatically new labels for footnotes.
 137 Possible values are:
 138
 139 nil        prompt the user for each label
 140 t          create unique labels of the form [fn:1], [fn:2], ...
 141 confirm    like t, but let the user edit the created value.  In particular,
 142            the label can be removed from the minibuffer, to create
 143            an anonymous footnote.
 144 random     Automatically generate a unique, random label.
 145 plain      Automatically create plain number labels like [1]"
 146   :group 'org-footnote
 147   :type '(choice
 148           (const :tag "Prompt for label" nil)
 149           (const :tag "Create automatic [fn:N]" t)
 150           (const :tag "Offer automatic [fn:N] for editing" confirm)
 151           (const :tag "Create a random label" random)
 152           (const :tag "Create automatic [N]" plain)))
 153
 154 (defcustom org-footnote-auto-adjust nil
 155   "Non-nil means automatically adjust footnotes after insert/delete.
 156 When this is t, after each insertion or deletion of a footnote,
 157 simple fn:N footnotes will be renumbered, and all footnotes will be sorted.
 158 If you want to have just sorting or just renumbering, set this variable
 159 to `sort' or `renumber'.
 160
 161 The main values of this variable can be set with in-buffer options:
 162
 163 #+STARTUP: fnadjust
 164 #+STARTUP: nofnadjust"
 165   :group 'org-footnote
 166   :type '(choice
 167           (const :tag "Renumber" renumber)
 168           (const :tag "Sort" sort)
 169           (const :tag "Renumber and Sort" t)))
 170
 171 (defcustom org-footnote-fill-after-inline-note-extraction nil
 172   "Non-nil means fill paragraphs after extracting footnotes.
 173 When extracting inline footnotes, the lengths of lines can change a lot.
 174 When this option is set, paragraphs from which an inline footnote has been
 175 extracted will be filled again."
 176   :group 'org-footnote
 177   :type 'boolean)
 178
 179 (defun org-footnote-in-valid-context-p ()
 180   "Is point in a context where footnotes are allowed?"
 181   (save-match-data
 182     (not (or (org-in-commented-line)
 183              (org-in-indented-comment-line)
 184              (org-inside-LaTeX-fragment-p)
 185              ;; Avoid protected environments (LaTeX export)
 186              (get-text-property (point) 'org-protected)
 187              ;; Avoid literal example.
 188              (org-in-verbatim-emphasis)
 189              (save-excursion
 190                (beginning-of-line)
 191                (looking-at "[ \t]*:[ \t]+"))
 192              ;; Avoid cited text and headers in message-mode.
 193              (and (derived-mode-p 'message-mode)
 194                   (or (save-excursion
 195                         (beginning-of-line)
 196                         (looking-at message-cite-prefix-regexp))
 197                       (message-point-in-header-p)))
 198              ;; Avoid forbidden blocks.
 199              (org-in-block-p org-footnote-forbidden-blocks)))))
 200
 201 (defun org-footnote-at-reference-p ()
 202   "Is the cursor at a footnote reference?
 203
 204 If so, return a list containing its label, beginning and ending
 205 positions, and the definition, when inlined."
 206   (when (and (org-footnote-in-valid-context-p)
 207              (or (looking-at org-footnote-re)
 208                  (org-in-regexp org-footnote-re)
 209                  (save-excursion (re-search-backward org-footnote-re nil t)))
 210              (/= (match-beginning 0) (point-at-bol)))
 211     (let* ((beg (match-beginning 0))
 212            (label (or (org-match-string-no-properties 2)
 213                       (org-match-string-no-properties 3)
 214                       ;; Anonymous footnotes don't have labels
 215                       (and (match-string 1)
 216                            (concat "fn:" (org-match-string-no-properties 1)))))
 217            ;; Inline footnotes don't end at (match-end 0) as
 218            ;; `org-footnote-re' stops just after the second colon.
 219            ;; Find the real ending with `scan-sexps', so Org doesn't
 220            ;; get fooled by unrelated closing square brackets.
 221            (end (ignore-errors (scan-sexps beg 1))))
 222       ;; Point is really at a reference if it's located before true
 223       ;; ending of the footnote.
 224       (when (and end (< (point) end)
 225                  ;; Verify match isn't a part of a link.
 226                  (not (save-excursion
 227                         (goto-char beg)
 228                         (let ((linkp
 229                                (save-match-data
 230                                  (org-in-regexp org-bracket-link-regexp))))
 231                           (and linkp (< (point) (cdr linkp))))))
 232                  ;; Verify point doesn't belong to a LaTeX macro.
 233                  ;; Beware though, when two footnotes are side by
 234                  ;; side, once the first one is changed into LaTeX,
 235                  ;; the second one might then be considered as an
 236                  ;; optional argument of the command.  Thus, check
 237                  ;; the `org-protected' property of that command.
 238                  (or (not (org-inside-latex-macro-p))
 239                      (get-text-property (1- beg) 'org-protected)))
 240         (list label beg end
 241               ;; Definition: ensure this is an inline footnote first.
 242               (and (or (not label) (match-string 1))
 243                    (org-trim (buffer-substring-no-properties
 244                               (match-end 0) (1- end)))))))))
 245
 246 (defun org-footnote-at-definition-p ()
 247   "Is point within a footnote definition?
 248
 249 This matches only pure definitions like [1] or [fn:name] at the
 250 beginning of a line.  It does not match references like
 251 \[fn:name:definition], where the footnote text is included and
 252 defined locally.
 253
 254 The return value will be nil if not at a footnote definition, and
 255 a list with label, start, end and definition of the footnote
 256 otherwise."
 257   (when (save-excursion (beginning-of-line) (org-footnote-in-valid-context-p))
 258     (save-excursion
 259       (end-of-line)
 260       ;; Footnotes definitions are separated by new headlines or blank
 261       ;; lines.
 262       (let ((lim (save-excursion (re-search-backward
 263                                   (concat org-outline-regexp-bol
 264                                           "\\|^[ \t]*$") nil t))))
 265         (when (re-search-backward org-footnote-definition-re lim t)
 266           (let ((label (org-match-string-no-properties 1))
 267                 (beg (match-beginning 0))
 268                 (beg-def (match-end 0))
 269                 ;; In message-mode, do not search after signature.
 270                 (end (let ((bound (and (derived-mode-p 'message-mode)
 271                                        (save-excursion
 272                                          (goto-char (point-max))
 273                                          (re-search-backward
 274                                           message-signature-separator nil t)))))
 275                        (if (progn
 276                              (end-of-line)
 277                              (re-search-forward
 278                               (concat org-outline-regexp-bol "\\|"
 279                                       org-footnote-definition-re "\\|"
 280                                       "^[ \t]*$") bound 'move))
 281                            (match-beginning 0)
 282                          (point)))))
 283             (list label beg end
 284                   (org-trim (buffer-substring-no-properties beg-def end)))))))))
 285
 286 (defun org-footnote-get-next-reference (&optional label backward limit)
 287   "Return complete reference of the next footnote.
 288
 289 If LABEL is provided, get the next reference of that footnote.  If
 290 BACKWARD is non-nil, find previous reference instead.  LIMIT is
 291 the buffer position bounding the search.
 292
 293 Return value is a list like those provided by `org-footnote-at-reference-p'.
 294 If no footnote is found, return nil."
 295   (save-excursion
 296     (let* ((label-fmt (if label (format "\\[%s[]:]" label) org-footnote-re)))
 297       (catch 'exit
 298         (while t
 299           (unless (funcall (if backward #'re-search-backward #'re-search-forward)
 300                            label-fmt limit t)
 301             (throw 'exit nil))
 302           (unless backward (backward-char))
 303           (let ((ref (org-footnote-at-reference-p)))
 304             (when ref (throw 'exit ref))))))))
 305
 306 (defun org-footnote-next-reference-or-definition (limit)
 307   "Move point to next footnote reference or definition.
 308
 309 LIMIT is the buffer position bounding the search.
 310
 311 Return value is a list like those provided by
 312 `org-footnote-at-reference-p' or `org-footnote-at-definition-p'.
 313 If no footnote is found, return nil."
 314   (let* (ref (origin (point)))
 315     (catch 'exit
 316       (while t
 317         (unless (re-search-forward org-footnote-re limit t)
 318           (goto-char origin)
 319           (throw 'exit nil))
 320         ;; Beware: with [1]-like footnotes point will be just after
 321         ;; the closing square bracket.
 322         (backward-char)
 323         (cond
 324          ((setq ref (org-footnote-at-reference-p))
 325           (throw 'exit ref))
 326          ;; Definition: also grab the last square bracket, only
 327          ;; matched in `org-footnote-re' for [1]-like footnotes.
 328          ((save-match-data (org-footnote-at-definition-p))
 329           (let ((end (match-end 0)))
 330             (throw 'exit
 331                    (list nil (match-beginning 0)
 332                          (if (eq (char-before end) 93) end (1+ end)))))))))))
 333
 334 (defun org-footnote-get-definition (label)
 335   "Return label, boundaries and definition of the footnote LABEL."
 336   (let* ((label (regexp-quote (org-footnote-normalize-label label)))
 337          (re (format "^\\[%s\\]\\|.\\[%s:" label label))
 338          pos)
 339     (save-excursion
 340       (save-restriction
 341         (when (or (re-search-forward re nil t)
 342                   (and (goto-char (point-min))
 343                        (re-search-forward re nil t))
 344                   (and (progn (widen) t)
 345                        (goto-char (point-min))
 346                        (re-search-forward re nil t)))
 347           (let ((refp (org-footnote-at-reference-p)))
 348             (cond
 349              ((and (nth 3 refp) refp))
 350              ((org-footnote-at-definition-p)))))))))
 351
 352 (defun org-footnote-goto-definition (label)
 353   "Move point to the definition of the footnote LABEL.
 354 Return a non-nil value when a definition has been found."
 355   (interactive "sLabel: ")
 356   (org-mark-ring-push)
 357   (let ((def (org-footnote-get-definition label)))
 358     (if (not def)
 359         (error "Cannot find definition of footnote %s" label)
 360       (goto-char (nth 1 def))
 361       (looking-at (format "\\[%s\\]\\|\\[%s:" label label))
 362       (goto-char (match-end 0))
 363       (org-show-context 'link-search)
 364       (when (derived-mode-p 'org-mode)
 365         (message "Edit definition and go back with `C-c &' or, if unique, with `C-c C-c'."))
 366       t)))
 367
 368 (defun org-footnote-goto-previous-reference (label)
 369   "Find the first closest (to point) reference of footnote with label LABEL."
 370   (interactive "sLabel: ")
 371   (org-mark-ring-push)
 372   (let* ((label (org-footnote-normalize-label label)) ref)
 373     (save-excursion
 374       (setq ref (or (org-footnote-get-next-reference label t)
 375                     (org-footnote-get-next-reference label)
 376                     (save-restriction
 377                       (widen)
 378                       (or
 379                        (org-footnote-get-next-reference label t)
 380                        (org-footnote-get-next-reference label))))))
 381     (if (not ref)
 382         (error "Cannot find reference of footnote %s" label)
 383       (goto-char (nth 1 ref))
 384       (org-show-context 'link-search))))
 385
 386 (defun org-footnote-normalize-label (label)
 387   "Return LABEL as an appropriate string."
 388   (cond
 389    ((numberp label) (number-to-string label))
 390    ((equal "" label) nil)
 391    ((not (string-match "^[0-9]+$\\|^fn:" label))
 392     (concat "fn:" label))
 393    (t label)))
 394
 395 (defun org-footnote-all-labels (&optional with-defs)
 396   "Return list with all defined foot labels used in the buffer.
 397
 398 If WITH-DEFS is non-nil, also associate the definition to each
 399 label.  The function will then return an alist whose key is label
 400 and value definition."
 401   (let* (rtn
 402          (push-to-rtn
 403           (function
 404            ;; Depending on WITH-DEFS, store label or (label . def) of
 405            ;; footnote reference/definition given as argument in RTN.
 406            (lambda (el)
 407              (let ((lbl (car el)))
 408                (push (if with-defs (cons lbl (nth 3 el)) lbl) rtn))))))
 409     (save-excursion
 410       (save-restriction
 411         (widen)
 412         ;; Find all labels found in definitions.
 413         (goto-char (point-min))
 414         (let (def)
 415           (while (re-search-forward org-footnote-definition-re nil t)
 416             (when (setq def (org-footnote-at-definition-p))
 417               (funcall push-to-rtn def))))
 418         ;; Find all labels found in references.
 419         (goto-char (point-min))
 420         (let (ref)
 421           (while (setq ref (org-footnote-get-next-reference))
 422             (goto-char (nth 2 ref))
 423             (and (car ref)              ; ignore anonymous footnotes
 424                  (not (funcall (if with-defs #'assoc #'member) (car ref) rtn))
 425                  (funcall push-to-rtn ref))))))
 426     rtn))
 427
 428 (defun org-footnote-unique-label (&optional current)
 429   "Return a new unique footnote label.
 430
 431 The function returns the first \"fn:N\" or \"N\" label that is
 432 currently not used.
 433
 434 Optional argument CURRENT is the list of labels active in the
 435 buffer."
 436   (unless current (setq current (org-footnote-all-labels)))
 437   (let ((fmt (if (eq org-footnote-auto-label 'plain) "%d" "fn:%d"))
 438         (cnt 1))
 439     (while (member (format fmt cnt) current)
 440       (incf cnt))
 441     (format fmt cnt)))
 442
 443 (defun org-footnote-new ()
 444   "Insert a new footnote.
 445 This command prompts for a label.  If this is a label referencing an
 446 existing label, only insert the label.  If the footnote label is empty
 447 or new, let the user edit the definition of the footnote."
 448   (interactive)
 449   (unless (org-footnote-in-valid-context-p)
 450     (error "Cannot insert a footnote here"))
 451   (let* ((lbls (and (not (equal org-footnote-auto-label 'random))
 452                     (org-footnote-all-labels)))
 453          (propose (org-footnote-unique-label lbls))
 454          (label
 455           (org-footnote-normalize-label
 456            (cond
 457             ((member org-footnote-auto-label '(t plain))
 458              propose)
 459             ((equal org-footnote-auto-label 'random)
 460              (require 'org-id)
 461              (substring (org-id-uuid) 0 8))
 462             (t
 463              (org-icompleting-read
 464               "Label (leave empty for anonymous): "
 465               (mapcar 'list lbls) nil nil
 466               (if (eq org-footnote-auto-label 'confirm) propose nil)))))))
 467     (cond
 468      ((bolp) (error "Cannot create a footnote reference at left margin"))
 469      ((not label)
 470       (insert "[fn:: ]")
 471       (backward-char 1))
 472      ((member label lbls)
 473       (insert "[" label "]")
 474       (message "New reference to existing note"))
 475      (org-footnote-define-inline
 476       (insert "[" label ": ]")
 477       (backward-char 1)
 478       (org-footnote-auto-adjust-maybe))
 479      (t
 480       (insert "[" label "]")
 481       (org-footnote-create-definition label)
 482       (org-footnote-auto-adjust-maybe)))))
 483
 484 (defvar org-blank-before-new-entry) ; silence byte-compiler
 485 (defun org-footnote-create-definition (label)
 486   "Start the definition of a footnote with label LABEL."
 487   (interactive "sLabel: ")
 488   (let ((label (org-footnote-normalize-label label)))
 489     (cond
 490      ;; In an Org file.
 491      ((derived-mode-p 'org-mode)
 492       ;; If `org-footnote-section' is defined, find it, or create it
 493       ;; at the end of the buffer.
 494       (when org-footnote-section
 495         (goto-char (point-min))
 496         (let ((re (concat "^\\*+[ \t]+" org-footnote-section "[ \t]*$")))
 497           (unless (or (re-search-forward re nil t)
 498                       (and (progn (widen) t)
 499                            (re-search-forward re nil t)))
 500             (goto-char (point-max))
 501             (skip-chars-backward " \t\r\n")
 502             (unless (bolp) (newline))
 503             ;; Insert new section.  Separate it from the previous one
 504             ;; with a blank line, unless `org-blank-before-new-entry'
 505             ;; explicitly says no.
 506             (when (and (cdr (assq 'heading org-blank-before-new-entry))
 507                        (zerop (save-excursion (org-back-over-empty-lines))))
 508               (insert "\n"))
 509             (insert "* " org-footnote-section "\n"))))
 510       ;; Move to the end of this entry (which may be
 511       ;; `org-footnote-section' or the current one).
 512       (org-footnote-goto-local-insertion-point)
 513       (org-show-context 'link-search))
 514      (t
 515       ;; In a non-Org file.  Search for footnote tag, or create it if
 516       ;; specified (at the end of buffer, or before signature if in
 517       ;; Message mode).  Set point after any definition already there.
 518       (let ((tag (and org-footnote-tag-for-non-org-mode-files
 519                       (concat "^" (regexp-quote
 520                                    org-footnote-tag-for-non-org-mode-files)
 521                               "[ \t]*$")))
 522             (max (if (and (derived-mode-p 'message-mode)
 523                           (goto-char (point-max))
 524                           (re-search-backward
 525                            message-signature-separator nil t))
 526                      (progn
 527                        ;; Ensure one blank line separates last
 528                        ;; footnote from signature.
 529                        (beginning-of-line)
 530                        (open-line 2)
 531                        (point-marker))
 532                    (point-max-marker))))
 533         (set-marker-insertion-type max t)
 534         (goto-char max)
 535         ;; Check if the footnote tag is defined but missing.  In this
 536         ;; case, insert it, before any footnote or one blank line
 537         ;; after any previous text.
 538         (when (and tag (not (re-search-backward tag nil t)))
 539           (skip-chars-backward " \t\r\n")
 540           (while (re-search-backward org-footnote-definition-re nil t))
 541           (unless (bolp) (newline 2))
 542           (insert org-footnote-tag-for-non-org-mode-files "\n\n"))
 543         ;; Remove superfluous white space and clear marker.
 544         (goto-char max)
 545         (skip-chars-backward " \t\r\n")
 546         (delete-region (point) max)
 547         (unless (bolp) (newline))
 548         (set-marker max nil))))
 549     ;; Insert footnote label.
 550     (when (zerop (org-back-over-empty-lines)) (newline))
 551     (insert "[" label "] \n")
 552     (backward-char)
 553     ;; Only notify user about next possible action when in an Org
 554     ;; buffer, as the bindings may have different meanings otherwise.
 555     (when (derived-mode-p 'org-mode)
 556       (message
 557        "Edit definition and go back with `C-c &' or, if unique, with `C-c C-c'."))))
 558
 559 ;;;###autoload
 560 (defun org-footnote-action (&optional special)
 561   "Do the right thing for footnotes.
 562
 563 When at a footnote reference, jump to the definition.
 564
 565 When at a definition, jump to the references if they exist, offer
 566 to create them otherwise.
 567
 568 When neither at definition or reference, create a new footnote,
 569 interactively.
 570
 571 With prefix arg SPECIAL, offer additional commands in a menu."
 572   (interactive "P")
 573   (let (tmp c)
 574     (cond
 575      (special
 576       (message "Footnotes: [s]ort  |  [r]enumber fn:N  |  [S]=r+s |->[n]umeric  |  [d]elete")
 577       (setq c (read-char-exclusive))
 578       (cond
 579        ((eq c ?s) (org-footnote-normalize 'sort))
 580        ((eq c ?r) (org-footnote-renumber-fn:N))
 581        ((eq c ?S)
 582         (org-footnote-renumber-fn:N)
 583         (org-footnote-normalize 'sort))
 584        ((eq c ?n) (org-footnote-normalize))
 585        ((eq c ?d) (org-footnote-delete))
 586        (t (error "No such footnote command %c" c))))
 587      ((setq tmp (org-footnote-at-reference-p))
 588       (cond
 589        ;; Anonymous footnote: move point at the beginning of its
 590        ;; definition.
 591        ((not (car tmp))
 592         (goto-char (nth 1 tmp))
 593         (forward-char 5))
 594        ;; A definition exists: move to it.
 595        ((ignore-errors (org-footnote-goto-definition (car tmp))))
 596        ;; No definition exists: offer to create it.
 597        ((yes-or-no-p (format "No definition for %s.  Create one? " (car tmp)))
 598         (org-footnote-create-definition (car tmp)))))
 599      ((setq tmp (org-footnote-at-definition-p))
 600       (org-footnote-goto-previous-reference (car tmp)))
 601      (t (org-footnote-new)))))
 602
 603 (defvar org-footnote-insert-pos-for-preprocessor 'point-max
 604   "See `org-footnote-normalize'.")
 605
 606 (defvar org-export-footnotes-seen) ; silence byte-compiler
 607 (defvar org-export-footnotes-data) ; silence byte-compiler
 608
 609 ;;;###autoload
 610 (defun org-footnote-normalize (&optional sort-only export-props)
 611   "Collect the footnotes in various formats and normalize them.
 612
 613 This finds the different sorts of footnotes allowed in Org, and
 614 normalizes them to the usual [N] format that is understood by the
 615 Org-mode exporters.
 616
 617 When SORT-ONLY is set, only sort the footnote definitions into the
 618 referenced sequence.
 619
 620 If Org is amidst an export process, EXPORT-PROPS will hold the
 621 export properties of the buffer.
 622
 623 When EXPORT-PROPS is non-nil, the default action is to insert
 624 normalized footnotes towards the end of the pre-processing
 625 buffer.  Some exporters (docbook, odt...) expect footnote
 626 definitions to be available before any references to them.  Such
 627 exporters can let bind `org-footnote-insert-pos-for-preprocessor'
 628 to symbol `point-min' to achieve the desired behaviour.
 629
 630 Additional note on `org-footnote-insert-pos-for-preprocessor':
 631 1. This variable has not effect when FOR-PREPROCESSOR is nil.
 632 2. This variable (potentially) obviates the need for extra scan
 633    of pre-processor buffer as witnessed in
 634    `org-export-docbook-get-footnotes'."
 635   ;; This is based on Paul's function, but rewritten.
 636   ;;
 637   ;; Re-create `org-with-limited-levels', but not limited to Org
 638   ;; buffers.
 639   (let* ((limit-level
 640           (and (boundp 'org-inlinetask-min-level)
 641                org-inlinetask-min-level
 642                (1- org-inlinetask-min-level)))
 643          (nstars (and limit-level
 644                       (if org-odd-levels-only
 645                           (and limit-level (1- (* limit-level 2)))
 646                         limit-level)))
 647          (org-outline-regexp
 648           (concat "\\*" (if nstars (format "\\{1,%d\\} " nstars) "+ ")))
 649          ;; Determine the highest marker used so far.
 650          (ref-table (when export-props org-export-footnotes-seen))
 651          (count (if (and export-props ref-table)
 652                     (apply 'max (mapcar (lambda (e) (nth 1 e)) ref-table))
 653                   0))
 654          ins-point ref)
 655     (save-excursion
 656       ;; 1. Find every footnote reference, extract the definition, and
 657       ;;    collect that data in REF-TABLE.  If SORT-ONLY is nil, also
 658       ;;    normalize references.
 659       (goto-char (point-min))
 660       (while (setq ref (org-footnote-get-next-reference))
 661         (let* ((lbl (car ref))
 662                (pos (nth 1 ref))
 663                ;; When footnote isn't anonymous, check if it's label
 664                ;; (REF) is already stored in REF-TABLE.  In that case,
 665                ;; extract number used to identify it (MARKER).  If
 666                ;; footnote is unknown, increment the global counter
 667                ;; (COUNT) to create an unused identifier.
 668                (a (and lbl (assoc lbl ref-table)))
 669                (marker (or (nth 1 a) (incf count)))
 670                ;; Is the reference inline or pointing to an inline
 671                ;; footnote?
 672                (inlinep (or (stringp (nth 3 ref)) (nth 3 a))))
 673           ;; Replace footnote reference with [MARKER].  Maybe fill
 674           ;; paragraph once done.  If SORT-ONLY is non-nil, only move
 675           ;; to the end of reference found to avoid matching it twice.
 676           ;; If EXPORT-PROPS isn't nil, also add `org-footnote'
 677           ;; property to it, so it can be easily recognized by
 678           ;; exporters.
 679           (if sort-only (goto-char (nth 2 ref))
 680             (delete-region (nth 1 ref) (nth 2 ref))
 681             (goto-char (nth 1 ref))
 682             (let ((new-ref (format "[%d]" marker)))
 683               (when export-props (org-add-props new-ref '(org-footnote t)))
 684               (insert new-ref))
 685             (and inlinep
 686                  org-footnote-fill-after-inline-note-extraction
 687                  (org-fill-paragraph)))
 688           ;; Add label (REF), identifier (MARKER), definition (DEF)
 689           ;; type (INLINEP) and position (POS) to REF-TABLE if data
 690           ;; was unknown.
 691           (unless a
 692             (let ((def (or (nth 3 ref)  ; inline
 693                            (and export-props
 694                                 (cdr (assoc lbl org-export-footnotes-data)))
 695                            (nth 3 (org-footnote-get-definition lbl)))))
 696               (push (list lbl marker
 697                           ;; When exporting, each definition goes
 698                           ;; through `org-export-preprocess-string' so
 699                           ;; it is ready to insert in the
 700                           ;; backend-specific buffer.
 701                           (if (and export-props def)
 702                               (let ((parameters
 703                                      (org-combine-plists
 704                                       export-props
 705                                       '(:todo-keywords t :tags t :priority t))))
 706                                 (apply #'org-export-preprocess-string def parameters))
 707                             def)
 708                           ;; Reference beginning position is a marker
 709                           ;; to preserve it during further buffer
 710                           ;; modifications.
 711                           inlinep (copy-marker pos)) ref-table)))))
 712       ;; 2. Find and remove the footnote section, if any.  Also
 713       ;;    determine where footnotes shall be inserted (INS-POINT).
 714       (cond
 715        ((and org-footnote-section (derived-mode-p 'org-mode))
 716         (goto-char (point-min))
 717         (if (re-search-forward
 718              (concat "^\\*[ \t]+" (regexp-quote org-footnote-section)
 719                      "[ \t]*$") nil t)
 720             (delete-region (match-beginning 0) (org-end-of-subtree t t)))
 721         ;; A new footnote section is inserted by default at the end of
 722         ;; the buffer.
 723         (goto-char (point-max))
 724         (skip-chars-backward " \r\t\n")
 725         (forward-line)
 726         (unless (bolp) (newline)))
 727        ;; No footnote section set: Footnotes will be added at the end
 728        ;; of the section containing their first reference.
 729        ;; Nevertheless, in an export situation, set insertion point to
 730        ;; `point-max' by default.
 731        ((derived-mode-p 'org-mode)
 732         (when export-props
 733           (goto-char (point-max))
 734           (skip-chars-backward " \r\t\n")
 735           (forward-line)
 736           (delete-region (point) (point-max))))
 737        (t
 738         ;; Remove any left-over tag in the buffer, if one is set up.
 739         (when org-footnote-tag-for-non-org-mode-files
 740           (let ((tag (concat "^" (regexp-quote
 741                                   org-footnote-tag-for-non-org-mode-files)
 742                              "[ \t]*$")))
 743             (goto-char (point-min))
 744             (while (re-search-forward tag nil t)
 745               (replace-match "")
 746               (delete-region (point) (progn (forward-line) (point))))))
 747         ;; In Message mode, ensure footnotes are inserted before the
 748         ;; signature.
 749         (if (and (derived-mode-p 'message-mode)
 750                  (goto-char (point-max))
 751                  (re-search-backward message-signature-separator nil t))
 752             (beginning-of-line)
 753           (goto-char (point-max)))))
 754       ;; During export, `org-footnote-insert-pos-for-preprocessor' has
 755       ;; precedence over previously found position.
 756       (setq ins-point
 757             (copy-marker
 758              (if (and export-props
 759                       (eq org-footnote-insert-pos-for-preprocessor 'point-min))
 760                  (point-min)
 761                (point))))
 762       ;; 3. Clean-up REF-TABLE.
 763       (setq ref-table
 764             (delq nil
 765                   (mapcar
 766                    (lambda (x)
 767                      (cond
 768                       ;; When only sorting, ignore inline footnotes.
 769                       ;; Also clear position marker.
 770                       ((and sort-only (nth 3 x))
 771                        (set-marker (nth 4 x) nil) nil)
 772                       ;; No definition available: provide one.
 773                       ((not (nth 2 x))
 774                        (append
 775                         (list (car x) (nth 1 x)
 776                               (format "DEFINITION NOT FOUND: %s" (car x)))
 777                         (nthcdr 3 x)))
 778                       (t x)))
 779                    ref-table)))
 780       (setq ref-table (nreverse ref-table))
 781       ;; 4. Remove left-over definitions in the buffer.
 782       (mapc (lambda (x)
 783               (unless (nth 3 x) (org-footnote-delete-definitions (car x))))
 784             ref-table)
 785       ;; 5. Insert the footnotes again in the buffer, at the
 786       ;;    appropriate spot.
 787       (goto-char ins-point)
 788       (cond
 789        ;; No footnote: exit.
 790        ((not ref-table))
 791        ;; Cases when footnotes should be inserted in one place.
 792        ((or (not (derived-mode-p 'org-mode))
 793             org-footnote-section
 794             export-props)
 795         ;; Insert again the section title, if any.  Ensure that title,
 796         ;; or the subsequent footnotes, will be separated by a blank
 797         ;; lines from the rest of the document.  In an Org buffer,
 798         ;; separate section with a blank line, unless explicitly
 799         ;; stated in `org-blank-before-new-entry'.
 800         (cond
 801          ((not (derived-mode-p 'org-mode))
 802           (skip-chars-backward " \t\n\r")
 803           (delete-region (point) ins-point)
 804           (unless (bolp) (newline))
 805           (when org-footnote-tag-for-non-org-mode-files
 806             (insert "\n" org-footnote-tag-for-non-org-mode-files "\n")))
 807          ((and org-footnote-section (not export-props))
 808           (when (and (cdr (assq 'heading org-blank-before-new-entry))
 809                      (zerop (save-excursion (org-back-over-empty-lines))))
 810             (insert "\n"))
 811           (insert "* " org-footnote-section "\n")))
 812         (set-marker ins-point nil)
 813         ;; Insert the footnotes, separated by a blank line.
 814         (insert
 815          (mapconcat
 816           (lambda (x)
 817             ;; Clean markers.
 818             (set-marker (nth 4 x) nil)
 819             (format "\n[%s] %s" (nth (if sort-only 0 1) x) (nth 2 x)))
 820           ref-table "\n"))
 821         (unless (eobp) (insert "\n\n"))
 822         ;; When exporting, add newly inserted markers along with their
 823         ;; associated definition to `org-export-footnotes-seen'.
 824         (when export-props (setq org-export-footnotes-seen ref-table)))
 825        ;; Each footnote definition has to be inserted at the end of
 826        ;; the section where its first reference belongs.
 827        (t
 828         (mapc
 829          (lambda (x)
 830            (let ((pos (nth 4 x)))
 831              (goto-char pos)
 832              ;; Clean marker.
 833              (set-marker pos nil))
 834            (org-footnote-goto-local-insertion-point)
 835            (insert (format "\n[%s] %s\n"
 836                            (if sort-only (car x) (nth 1 x))
 837                            (nth 2 x))))
 838          ref-table))))))
 839
 840 (defun org-footnote-goto-local-insertion-point ()
 841   "Find insertion point for footnote, just before next outline heading."
 842   (org-with-limited-levels (outline-next-heading))
 843   (or (bolp) (newline))
 844   (beginning-of-line 0)
 845   (while (and (not (bobp)) (= (char-after) ?#))
 846     (beginning-of-line 0))
 847   (if (let ((case-fold-search t)) (looking-at "[ \t]*#\\+tblfm:")) (beginning-of-line 2))
 848   (end-of-line 1)
 849   (skip-chars-backward "\n\r\t ")
 850   (forward-line))
 851
 852 (defun org-footnote-delete-references (label)
 853   "Delete every reference to footnote LABEL.
 854 Return the number of footnotes removed."
 855   (save-excursion
 856     (goto-char (point-min))
 857     (let (ref (nref 0))
 858       (while (setq ref (org-footnote-get-next-reference label))
 859         (goto-char (nth 1 ref))
 860         (delete-region (nth 1 ref) (nth 2 ref))
 861         (incf nref))
 862       nref)))
 863
 864 (defun org-footnote-delete-definitions (label)
 865   "Delete every definition of the footnote LABEL.
 866 Return the number of footnotes removed."
 867   (save-excursion
 868     (goto-char (point-min))
 869     (let ((def-re (concat "^\\[" (regexp-quote label) "\\]"))
 870           (ndef 0))
 871       (while (re-search-forward def-re nil t)
 872         (let ((full-def (org-footnote-at-definition-p)))
 873           (when full-def
 874             ;; Remove the footnote, and all blank lines before it.
 875             (goto-char (nth 1 full-def))
 876             (skip-chars-backward " \r\t\n")
 877             (unless (bolp) (forward-line))
 878             (delete-region (point) (nth 2 full-def))
 879             (incf ndef))))
 880       ndef)))
 881
 882 (defun org-footnote-delete (&optional label)
 883   "Delete the footnote at point.
 884 This will remove the definition (even multiple definitions if they exist)
 885 and all references of a footnote label.
 886
 887 If LABEL is non-nil, delete that footnote instead."
 888   (catch 'done
 889     (let* ((nref 0) (ndef 0) x
 890            ;; 1. Determine LABEL of footnote at point.
 891            (label (cond
 892                    ;; LABEL is provided as argument.
 893                    (label)
 894                    ;; Footnote reference at point. If the footnote is
 895                    ;; anonymous, delete it and exit instead.
 896                    ((setq x (org-footnote-at-reference-p))
 897                     (or (car x)
 898                         (progn
 899                           (delete-region (nth 1 x) (nth 2 x))
 900                           (message "Anonymous footnote removed")
 901                           (throw 'done t))))
 902                    ;; Footnote definition at point.
 903                    ((setq x (org-footnote-at-definition-p))
 904                     (car x))
 905                    (t (error "Don't know which footnote to remove")))))
 906       ;; 2. Now that LABEL is non-nil, find every reference and every
 907       ;; definition, and delete them.
 908       (setq nref (org-footnote-delete-references label)
 909             ndef (org-footnote-delete-definitions label))
 910       ;; 3. Verify consistency of footnotes and notify user.
 911       (org-footnote-auto-adjust-maybe)
 912       (message "%d definition(s) of and %d reference(s) of footnote %s removed"
 913                ndef nref label))))
 914
 915 (defun org-footnote-renumber-fn:N ()
 916   "Renumber the simple footnotes like fn:17 into a sequence in the document."
 917   (interactive)
 918   (let (map (n 0))
 919     (org-with-wide-buffer
 920      (goto-char (point-min))
 921      (while (re-search-forward "\\[fn:\\([0-9]+\\)[]:]" nil t)
 922        (save-excursion
 923          (goto-char (match-beginning 0))
 924          ;; Ensure match is a footnote reference or definition.
 925          (when (save-match-data (if (bolp)
 926                                     (org-footnote-at-definition-p)
 927                                   (org-footnote-at-reference-p)))
 928            (let ((new-val (or (cdr (assoc (match-string 1) map))
 929                               (number-to-string (incf n)))))
 930              (unless (assoc (match-string 1) map)
 931                (push (cons (match-string 1) new-val) map))
 932              (replace-match new-val nil nil nil 1))))))))
 933
 934 (defun org-footnote-auto-adjust-maybe ()
 935   "Renumber and/or sort footnotes according to user settings."
 936   (when (memq org-footnote-auto-adjust '(t renumber))
 937     (org-footnote-renumber-fn:N))
 938   (when (memq org-footnote-auto-adjust '(t sort))
 939     (let ((label (car (org-footnote-at-definition-p))))
 940       (org-footnote-normalize 'sort)
 941       (when label
 942         (goto-char (point-min))
 943         (and (re-search-forward (concat "^\\[" (regexp-quote label) "\\]")
 944                                 nil t)
 945              (progn (insert " ")
 946                     (just-one-space)))))))
 947
 948 (provide 'org-footnote)
 949
 950 ;;; org-footnote.el ends here