lisp/ob-sql.el

   1 ;;; ob-sql.el --- org-babel functions for sql evaluation
   2
   3 ;; Copyright (C) 2009-2012  Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Org-Babel support for evaluating sql source code.
  27 ;; (see also ob-sqlite.el)
  28 ;;
  29 ;; SQL is somewhat unique in that there are many different engines for
  30 ;; the evaluation of sql (Mysql, PostgreSQL, etc...), so much of this
  31 ;; file will have to be implemented engine by engine.
  32 ;;
  33 ;; Also SQL evaluation generally takes place inside of a database.
  34 ;;
  35 ;; For now lets just allow a generic ':cmdline' header argument.
  36 ;;
  37 ;; TODO:
  38 ;;
  39 ;; - support for sessions
  40 ;; - add more useful header arguments (user, passwd, database, etc...)
  41 ;; - support for more engines (currently only supports mysql)
  42 ;; - what's a reasonable way to drop table data into SQL?
  43 ;;
  44
  45 ;;; Code:
  46 (require 'ob)
  47 (eval-when-compile (require 'cl))
  48
  49 (declare-function org-table-import "org-table" (file arg))
  50 (declare-function orgtbl-to-csv "org-table" (TABLE PARAMS))
  51
  52 (defvar org-babel-default-header-args:sql '())
  53
  54 (defvar org-babel-header-args:sql
  55   '((engine   . :any)
  56     (out-file . :any)))
  57
  58 (defun org-babel-expand-body:sql (body params)
  59   "Expand BODY according to the values of PARAMS."
  60   (org-babel-sql-expand-vars
  61    body (mapcar #'cdr (org-babel-get-header params :var))))
  62
  63 (defun org-babel-execute:sql (body params)
  64   "Execute a block of Sql code with Babel.
  65 This function is called by `org-babel-execute-src-block'."
  66   (let* ((result-params (cdr (assoc :result-params params)))
  67          (cmdline (cdr (assoc :cmdline params)))
  68          (engine (cdr (assoc :engine params)))
  69          (in-file (org-babel-temp-file "sql-in-"))
  70          (out-file (or (cdr (assoc :out-file params))
  71                        (org-babel-temp-file "sql-out-")))
  72          (header-delim "")
  73          (command (case (intern engine)
  74                     ('monetdb (format "mclient -f tab %s < %s > %s"
  75                                       (or cmdline "")
  76                                       (org-babel-process-file-name in-file)
  77                                       (org-babel-process-file-name out-file)))
  78                     ('msosql (format "osql %s -s \"\t\" -i %s -o %s"
  79                                      (or cmdline "")
  80                                      (org-babel-process-file-name in-file)
  81                                      (org-babel-process-file-name out-file)))
  82                     ('mysql (format "mysql %s < %s > %s"
  83                                     (or cmdline "")
  84                                     (org-babel-process-file-name in-file)
  85                                     (org-babel-process-file-name out-file)))
  86                     ('postgresql (format
  87                                   "psql -A -P footer=off -F \"\t\"  -f %s -o %s %s"
  88                                     (org-babel-process-file-name in-file)
  89                                     (org-babel-process-file-name out-file)
  90                                     (or cmdline "")))
  91                     (t (error "no support for the %s sql engine" engine)))))
  92     (with-temp-file in-file
  93       (insert (org-babel-expand-body:sql body params)))
  94     (message command)
  95     (shell-command command)
  96     (if (or (member "scalar" result-params)
  97             (member "verbatim" result-params)
  98             (member "html" result-params)
  99             (member "code" result-params)
 100             (equal (point-min) (point-max)))
 101         (with-temp-buffer
 102           (progn (insert-file-contents-literally out-file) (buffer-string)))
 103       (with-temp-buffer
 104         ;; need to figure out what the delimiter is for the header row
 105         (with-temp-buffer
 106           (insert-file-contents out-file)
 107           (goto-char (point-min))
 108           (when (re-search-forward "^\\(-+\\)[^-]" nil t)
 109             (setq header-delim (match-string-no-properties 1)))
 110           (goto-char (point-max))
 111           (forward-char -1)
 112           (while (looking-at "\n")
 113             (delete-char 1)
 114             (goto-char (point-max))
 115             (forward-char -1))
 116           (write-file out-file))
 117         (org-table-import out-file '(16))
 118         (org-babel-reassemble-table
 119          (mapcar (lambda (x)
 120                    (if (string= (car x) header-delim)
 121                        'hline
 122                      x))
 123                  (org-table-to-lisp))
 124          (org-babel-pick-name (cdr (assoc :colname-names params))
 125                               (cdr (assoc :colnames params)))
 126          (org-babel-pick-name (cdr (assoc :rowname-names params))
 127                               (cdr (assoc :rownames params))))))))
 128
 129 (defun org-babel-sql-expand-vars (body vars)
 130   "Expand the variables held in VARS in BODY."
 131   (mapc
 132    (lambda (pair)
 133      (setq body
 134            (replace-regexp-in-string
 135             (format "\$%s" (car pair))
 136             ((lambda (val)
 137                (if (listp val)
 138                    ((lambda (data-file)
 139                       (with-temp-file data-file
 140                         (insert (orgtbl-to-csv
 141                                  val '(:fmt (lambda (el) (if (stringp el)
 142                                                         el
 143                                                       (format "%S" el)))))))
 144                       data-file)
 145                     (org-babel-temp-file "sql-data-"))
 146                  (if (stringp val) val (format "%S" val))))
 147              (cdr pair))
 148             body)))
 149    vars)
 150   body)
 151
 152 (defun org-babel-prep-session:sql (session params)
 153   "Raise an error because Sql sessions aren't implemented."
 154   (error "sql sessions not yet implemented"))
 155
 156 (provide 'ob-sql)
 157
 158
 159
 160 ;;; ob-sql.el ends here