lisp/org-pcomplete.el

   1 ;;; org-pcomplete.el --- In-buffer completion code
   2
   3 ;; Copyright (C) 2004-2015 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;;         John Wiegley <johnw at gnu dot org>
   7 ;; Keywords: outlines, hypermedia, calendar, wp
   8 ;; Homepage: http://orgmode.org
   9 ;;
  10 ;; This file is part of GNU Emacs.
  11 ;;
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  25 ;;
  26 ;;; Code:
  27
  28 ;;;; Require other packages
  29
  30 (eval-when-compile
  31   (require 'cl))
  32
  33 (require 'org-macs)
  34 (require 'org-compat)
  35 (require 'pcomplete)
  36
  37 (declare-function org-split-string "org" (string &optional separators))
  38 (declare-function org-make-org-heading-search-string "org"
  39                   (&optional string))
  40 (declare-function org-get-buffer-tags "org" ())
  41 (declare-function org-get-tags "org" ())
  42 (declare-function org-buffer-property-keys "org"
  43                   (&optional include-specials include-defaults include-columns))
  44 (declare-function org-entry-properties "org" (&optional pom which specific))
  45
  46 ;;;; Customization variables
  47
  48 (defgroup org-complete nil
  49   "Outline-based notes management and organizer."
  50   :tag "Org"
  51   :group 'org)
  52
  53 (defvar org-drawer-regexp)
  54 (defvar org-property-re)
  55
  56 (defun org-thing-at-point ()
  57   "Examine the thing at point and let the caller know what it is.
  58 The return value is a string naming the thing at point."
  59   (let ((beg1 (save-excursion
  60                 (skip-chars-backward (org-re "[:alnum:]-_@"))
  61                 (point)))
  62         (beg (save-excursion
  63                (skip-chars-backward "a-zA-Z0-9-_:$")
  64                (point)))
  65         (line-to-here (buffer-substring (point-at-bol) (point))))
  66     (cond
  67      ((string-match "\\`[ \t]*#\\+begin: clocktable[ \t]+" line-to-here)
  68       (cons "block-option" "clocktable"))
  69      ((string-match "\\`[ \t]*#\\+begin_src[ \t]+" line-to-here)
  70       (cons "block-option" "src"))
  71      ((save-excursion
  72         (re-search-backward "^[ \t]*#\\+\\([A-Z_]+\\):.*"
  73                             (line-beginning-position) t))
  74       (cons "file-option" (match-string-no-properties 1)))
  75      ((string-match "\\`[ \t]*#\\+[a-zA-Z_]*\\'" line-to-here)
  76       (cons "file-option" nil))
  77      ((equal (char-before beg) ?\[)
  78       (cons "link" nil))
  79      ((equal (char-before beg) ?\\)
  80       (cons "tex" nil))
  81      ((string-match "\\`\\*+[ \t]+\\'"
  82                     (buffer-substring (point-at-bol) beg))
  83       (cons "todo" nil))
  84      ((equal (char-before beg) ?*)
  85       (cons "searchhead" nil))
  86      ((and (equal (char-before beg1) ?:)
  87            (equal (char-after (point-at-bol)) ?*))
  88       (cons "tag" nil))
  89      ((and (equal (char-before beg1) ?:)
  90            (not (equal (char-after (point-at-bol)) ?*))
  91            (save-excursion
  92              (move-beginning-of-line 1)
  93              (skip-chars-backward "[ \t\n]")
  94              ;; org-drawer-regexp matches a whole line but while
  95              ;; looking-back, we just ignore trailing whitespaces
  96              (or (org-looking-back (substring org-drawer-regexp 0 -1)
  97                                    (line-beginning-position))
  98                  (org-looking-back org-property-re
  99                                    (line-beginning-position)))))
 100       (cons "prop" nil))
 101      ((and (equal (char-before beg1) ?:)
 102            (not (equal (char-after (point-at-bol)) ?*)))
 103       (cons "drawer" nil))
 104      (t nil))))
 105
 106 (defun org-command-at-point ()
 107   "Return the qualified name of the Org completion entity at point.
 108 When completing for #+STARTUP, for example, this function returns
 109 \"file-option/startup\"."
 110   (let ((thing (org-thing-at-point)))
 111     (cond
 112      ((string= "file-option" (car thing))
 113       (concat (car thing)
 114               (and (cdr thing) (concat "/" (downcase (cdr thing))))))
 115      ((string= "block-option" (car thing))
 116       (concat (car thing) "/" (downcase (cdr thing))))
 117      (t (car thing)))))
 118
 119 (defun org-parse-arguments ()
 120   "Parse whitespace separated arguments in the current region."
 121   (let ((begin (line-beginning-position))
 122         (end (line-end-position))
 123         begins args)
 124     (save-restriction
 125       (narrow-to-region begin end)
 126       (save-excursion
 127         (goto-char (point-min))
 128         (while (not (eobp))
 129           (skip-chars-forward " \t\n[")
 130           (setq begins (cons (point) begins))
 131           (skip-chars-forward "^ \t\n[")
 132           (setq args (cons (buffer-substring-no-properties
 133                             (car begins) (point))
 134                            args)))
 135         (cons (reverse args) (reverse begins))))))
 136
 137 (defun org-pcomplete-initial ()
 138   "Calls the right completion function for first argument completions."
 139   (ignore
 140    (funcall (or (pcomplete-find-completion-function
 141                  (car (org-thing-at-point)))
 142                 pcomplete-default-completion-function))))
 143
 144 (defvar org-options-keywords)            ; From org.el
 145 (defvar org-element-block-name-alist)    ; From org-element.el
 146 (defvar org-element-affiliated-keywords) ; From org-element.el
 147 (declare-function org-get-export-keywords "org" ())
 148 (defun pcomplete/org-mode/file-option ()
 149   "Complete against all valid file options."
 150   (require 'org-element)
 151   (pcomplete-here
 152    (org-pcomplete-case-double
 153     (append (mapcar (lambda (keyword) (concat keyword " "))
 154                     org-options-keywords)
 155             (mapcar (lambda (keyword) (concat keyword ": "))
 156                     org-element-affiliated-keywords)
 157             (let (block-names)
 158               (dolist (block-info org-element-block-name-alist block-names)
 159                 (let ((name (car block-info)))
 160                   (push (format "END_%s" name) block-names)
 161                   (push (concat "BEGIN_"
 162                                 name
 163                                 ;; Since language is compulsory in
 164                                 ;; source blocks, add a space.
 165                                 (and (equal name "SRC") " "))
 166                         block-names)
 167                   (push (format "ATTR_%s: " name) block-names))))
 168             (mapcar (lambda (keyword) (concat keyword ": "))
 169                     (org-get-export-keywords))))
 170    (substring pcomplete-stub 2)))
 171
 172 (defun pcomplete/org-mode/file-option/author ()
 173   "Complete arguments for the #+AUTHOR file option."
 174   (pcomplete-here (list user-full-name)))
 175
 176 (defvar org-time-stamp-formats)
 177 (defun pcomplete/org-mode/file-option/date ()
 178   "Complete arguments for the #+DATE file option."
 179   (pcomplete-here (list (format-time-string (car org-time-stamp-formats)))))
 180
 181 (defun pcomplete/org-mode/file-option/email ()
 182   "Complete arguments for the #+EMAIL file option."
 183   (pcomplete-here (list user-mail-address)))
 184
 185 (defvar org-export-exclude-tags)
 186 (defun pcomplete/org-mode/file-option/exclude_tags ()
 187   "Complete arguments for the #+EXCLUDE_TAGS file option."
 188   (require 'ox)
 189   (pcomplete-here
 190    (and org-export-exclude-tags
 191         (list (mapconcat 'identity org-export-exclude-tags " ")))))
 192
 193 (defvar org-file-tags)
 194 (defun pcomplete/org-mode/file-option/filetags ()
 195   "Complete arguments for the #+FILETAGS file option."
 196   (pcomplete-here (and org-file-tags (mapconcat 'identity org-file-tags " "))))
 197
 198 (defvar org-export-default-language)
 199 (defun pcomplete/org-mode/file-option/language ()
 200   "Complete arguments for the #+LANGUAGE file option."
 201   (require 'ox)
 202   (pcomplete-here
 203    (pcomplete-uniqify-list
 204     (list org-export-default-language "en"))))
 205
 206 (defvar org-default-priority)
 207 (defvar org-highest-priority)
 208 (defvar org-lowest-priority)
 209 (defun pcomplete/org-mode/file-option/priorities ()
 210   "Complete arguments for the #+PRIORITIES file option."
 211   (pcomplete-here (list (format "%c %c %c"
 212                                 org-highest-priority
 213                                 org-lowest-priority
 214                                 org-default-priority))))
 215
 216 (defvar org-export-select-tags)
 217 (defun pcomplete/org-mode/file-option/select_tags ()
 218   "Complete arguments for the #+SELECT_TAGS file option."
 219   (require 'ox)
 220   (pcomplete-here
 221    (and org-export-select-tags
 222         (list (mapconcat 'identity org-export-select-tags " ")))))
 223
 224 (defvar org-startup-options)
 225 (defun pcomplete/org-mode/file-option/startup ()
 226   "Complete arguments for the #+STARTUP file option."
 227   (while (pcomplete-here
 228           (let ((opts (pcomplete-uniqify-list
 229                        (mapcar 'car org-startup-options))))
 230             ;; Some options are mutually exclusive, and shouldn't be completed
 231             ;; against if certain other options have already been seen.
 232             (dolist (arg pcomplete-args)
 233               (cond
 234                ((string= arg "hidestars")
 235                 (setq opts (delete "showstars" opts)))))
 236             opts))))
 237
 238 (defvar org-tag-alist)
 239 (defun pcomplete/org-mode/file-option/tags ()
 240   "Complete arguments for the #+TAGS file option."
 241   (pcomplete-here
 242    (list
 243     (mapconcat (lambda (x)
 244                  (cond
 245                   ((eq :startgroup (car x)) "{")
 246                   ((eq :endgroup (car x)) "}")
 247                   ((eq :grouptags (car x)) ":")
 248                   ((eq :newline (car x)) "\\n")
 249                   ((cdr x) (format "%s(%c)" (car x) (cdr x)))
 250                   (t (car x))))
 251                org-tag-alist " "))))
 252
 253 (defun pcomplete/org-mode/file-option/title ()
 254   "Complete arguments for the #+TITLE file option."
 255   (pcomplete-here
 256    (let ((visited-file (buffer-file-name (buffer-base-buffer))))
 257      (list (or (and visited-file
 258                     (file-name-sans-extension
 259                      (file-name-nondirectory visited-file)))
 260                (buffer-name (buffer-base-buffer)))))))
 261
 262
 263 (declare-function org-export-backend-options "org-export" (cl-x))
 264 (defun pcomplete/org-mode/file-option/options ()
 265   "Complete arguments for the #+OPTIONS file option."
 266   (while (pcomplete-here
 267           (pcomplete-uniqify-list
 268            (append
 269             ;; Hard-coded OPTION items always available.
 270             '("H:" "\\n:" "num:" "timestamp:" "arch:" "author:" "c:"
 271               "creator:" "date:" "d:" "email:" "*:" "e:" "::" "f:"
 272               "inline:" "tex:" "p:" "pri:" "':" "-:" "stat:" "^:" "toc:"
 273               "|:" "tags:" "tasks:" "<:" "todo:")
 274             ;; OPTION items from registered back-ends.
 275             (let (items)
 276               (dolist (backend (org-bound-and-true-p
 277                                 org-export-registered-backends))
 278                 (dolist (option (org-export-backend-options backend))
 279                   (let ((item (nth 2 option)))
 280                     (when item (push (concat item ":") items)))))
 281               items))))))
 282
 283 (defun pcomplete/org-mode/file-option/infojs_opt ()
 284   "Complete arguments for the #+INFOJS_OPT file option."
 285   (while (pcomplete-here
 286           (pcomplete-uniqify-list
 287            (mapcar (lambda (item) (format "%s:" (car item)))
 288                    (org-bound-and-true-p org-html-infojs-opts-table))))))
 289
 290 (defun pcomplete/org-mode/file-option/bind ()
 291   "Complete arguments for the #+BIND file option, which are variable names."
 292   (let (vars)
 293     (mapatoms
 294      (lambda (a) (if (boundp a) (setq vars (cons (symbol-name a) vars)))))
 295     (pcomplete-here vars)))
 296
 297 (defvar org-link-abbrev-alist-local)
 298 (defvar org-link-abbrev-alist)
 299 (defun pcomplete/org-mode/link ()
 300   "Complete against defined #+LINK patterns."
 301   (pcomplete-here
 302    (pcomplete-uniqify-list
 303     (copy-sequence
 304      (append (mapcar 'car org-link-abbrev-alist-local)
 305              (mapcar 'car org-link-abbrev-alist))))))
 306
 307 (defvar org-entities)
 308 (defun pcomplete/org-mode/tex ()
 309   "Complete against TeX-style HTML entity names."
 310   (require 'org-entities)
 311   (while (pcomplete-here
 312           (pcomplete-uniqify-list (remove nil (mapcar 'car-safe org-entities)))
 313           (substring pcomplete-stub 1))))
 314
 315 (defvar org-todo-keywords-1)
 316 (defun pcomplete/org-mode/todo ()
 317   "Complete against known TODO keywords."
 318   (pcomplete-here (pcomplete-uniqify-list (copy-sequence org-todo-keywords-1))))
 319
 320 (defvar org-todo-line-regexp)
 321 (defun pcomplete/org-mode/searchhead ()
 322   "Complete against all headings.
 323 This needs more work, to handle headings with lots of spaces in them."
 324   (while
 325       (pcomplete-here
 326        (save-excursion
 327          (goto-char (point-min))
 328          (let (tbl)
 329            (while (re-search-forward org-todo-line-regexp nil t)
 330              (push (org-make-org-heading-search-string
 331                     (match-string-no-properties 3))
 332                    tbl))
 333            (pcomplete-uniqify-list tbl)))
 334        (substring pcomplete-stub 1))))
 335
 336 (defvar org-tag-alist)
 337 (defun pcomplete/org-mode/tag ()
 338   "Complete a tag name.  Omit tags already set."
 339   (while (pcomplete-here
 340           (mapcar (lambda (x)
 341                     (concat x ":"))
 342                   (let ((lst (pcomplete-uniqify-list
 343                               (or (remove
 344                                    nil
 345                                    (mapcar (lambda (x)
 346                                              (and (stringp (car x)) (car x)))
 347                                            org-tag-alist))
 348                                   (mapcar 'car (org-get-buffer-tags))))))
 349                     (dolist (tag (org-get-tags))
 350                       (setq lst (delete tag lst)))
 351                     lst))
 352           (and (string-match ".*:" pcomplete-stub)
 353                (substring pcomplete-stub (match-end 0))))))
 354
 355 (defun pcomplete/org-mode/prop ()
 356   "Complete a property name.  Omit properties already set."
 357   (pcomplete-here
 358    (mapcar (lambda (x)
 359              (concat x ": "))
 360            (let ((lst (pcomplete-uniqify-list
 361                        (copy-sequence
 362                         (org-buffer-property-keys nil t t)))))
 363              (dolist (prop (org-entry-properties))
 364                (setq lst (delete (car prop) lst)))
 365              lst))
 366    (substring pcomplete-stub 1)))
 367
 368 (defun pcomplete/org-mode/block-option/src ()
 369   "Complete the arguments of a begin_src block.
 370 Complete a language in the first field, the header arguments and switches."
 371   (pcomplete-here
 372    (mapcar
 373     (lambda(x) (symbol-name (nth 3 x)))
 374     (cdr (car (cdr (memq :key-type (plist-get
 375                                     (symbol-plist
 376                                      'org-babel-load-languages)
 377                                     'custom-type)))))))
 378   (while (pcomplete-here
 379           '("-n" "-r" "-l"
 380             ":cache" ":colnames" ":comments" ":dir" ":eval" ":exports"
 381             ":file" ":hlines" ":no-expand" ":noweb" ":results" ":rownames"
 382             ":session" ":shebang" ":tangle" ":tangle-mode" ":var"))))
 383
 384 (defun pcomplete/org-mode/block-option/clocktable ()
 385   "Complete keywords in a clocktable line."
 386   (while (pcomplete-here '(":maxlevel" ":scope" ":lang"
 387                            ":tstart" ":tend" ":block" ":step"
 388                            ":stepskip0" ":fileskip0"
 389                            ":emphasize" ":link" ":narrow" ":indent"
 390                            ":tcolumns" ":level" ":compact" ":timestamp"
 391                            ":formula" ":formatter" ":wstart" ":mstart"))))
 392
 393 (defun org-pcomplete-case-double (list)
 394   "Return list with both upcase and downcase version of all strings in LIST."
 395   (let (e res)
 396     (while (setq e (pop list))
 397       (setq res (cons (downcase e) (cons (upcase e) res))))
 398     (nreverse res)))
 399
 400 ;;;; Finish up
 401
 402 (provide 'org-pcomplete)
 403
 404 ;;; org-pcomplete.el ends here