lisp/ob-clojure.el

   1 ;;; ob-clojure.el --- Babel Functions for Clojure    -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2009-2015 Free Software Foundation, Inc.
   4
   5 ;; Author: Joel Boehland, Eric Schulte, Oleh Krehel
   6 ;;
   7 ;; Keywords: literate programming, reproducible research
   8 ;; Homepage: http://orgmode.org
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Support for evaluating clojure code
  28
  29 ;; Requirements:
  30
  31 ;; - clojure (at least 1.2.0)
  32 ;; - clojure-mode
  33 ;; - either cider or SLIME
  34
  35 ;; For Cider, see https://github.com/clojure-emacs/cider
  36
  37 ;; For SLIME, the best way to install these components is by following
  38 ;; the directions as set out by Phil Hagelberg (Technomancy) on the
  39 ;; web page: http://technomancy.us/126
  40
  41 ;;; Code:
  42 (require 'ob)
  43 (eval-when-compile
  44   (require 'cl))
  45
  46 (declare-function cider-current-connection "ext:cider-client" (&optional type))
  47 (declare-function cider-current-session "ext:cider-client" ())
  48 (declare-function nrepl-dict-get "ext:nrepl-client" (dict key))
  49 (declare-function nrepl-sync-request:eval "ext:nrepl-client"
  50                   (input connection session &optional ns))
  51 (declare-function slime-eval "ext:slime" (sexp &optional package))
  52
  53 (defvar org-babel-tangle-lang-exts)
  54 (add-to-list 'org-babel-tangle-lang-exts '("clojure" . "clj"))
  55
  56 (defvar org-babel-default-header-args:clojure '())
  57 (defvar org-babel-header-args:clojure '((package . :any)))
  58
  59 (defcustom org-babel-clojure-backend
  60   (cond ((featurep 'cider) 'cider)
  61         (t 'slime))
  62   "Backend used to evaluate Clojure code blocks."
  63   :group 'org-babel
  64   :type '(choice
  65           (const :tag "cider" cider)
  66           (const :tag "SLIME" slime)))
  67
  68 (defun org-babel-expand-body:clojure (body params)
  69   "Expand BODY according to PARAMS, return the expanded body."
  70   (let* ((vars (mapcar #'cdr (org-babel-get-header params :var)))
  71          (result-params (cdr (assoc :result-params params)))
  72          (print-level nil) (print-length nil)
  73          (body (org-babel-trim
  74                 (if (> (length vars) 0)
  75                     (concat "(let ["
  76                             (mapconcat
  77                              (lambda (var)
  78                                (format "%S (quote %S)" (car var) (cdr var)))
  79                              vars "\n      ")
  80                             "]\n" body ")")
  81                   body))))
  82     (if (or (member "code" result-params)
  83             (member "pp" result-params))
  84         (format "(clojure.pprint/pprint (do %s))" body)
  85       body)))
  86
  87 (defun org-babel-execute:clojure (body params)
  88   "Execute a block of Clojure code with Babel."
  89   (let ((expanded (org-babel-expand-body:clojure body params))
  90         result)
  91     (case org-babel-clojure-backend
  92       (cider
  93        (require 'cider)
  94        (let ((result-params (cdr (assoc :result-params params))))
  95          (setq result
  96                (nrepl-dict-get
  97                 (nrepl-sync-request:eval
  98                  expanded (cider-current-connection) (cider-current-session))
  99                 (if (or (member "output" result-params)
 100                         (member "pp" result-params))
 101                     "out"
 102                   "value")))))
 103       (slime
 104        (require 'slime)
 105        (with-temp-buffer
 106          (insert expanded)
 107          (setq result
 108                (slime-eval
 109                 `(swank:eval-and-grab-output
 110                   ,(buffer-substring-no-properties (point-min) (point-max)))
 111                 (cdr (assoc :package params)))))))
 112     (org-babel-result-cond (cdr (assoc :result-params params))
 113       result
 114       (condition-case nil (org-babel-script-escape result)
 115         (error result)))))
 116
 117 (provide 'ob-clojure)
 118
 119 ;;; ob-clojure.el ends here