lisp/org-export-latex.el

   1 ;;; org-export-latex.el --- LaTeX exporter for org-mode
   2 ;;
   3 ;; Copyright (C) 2007, 2008 Free Software Foundation, Inc.
   4 ;;
   5 ;; Emacs Lisp Archive Entry
   6 ;; Filename: org-export-latex.el
   7 ;; Version: 6.14
   8 ;; Author: Bastien Guerry <bzg AT altern DOT org>
   9 ;; Maintainer: Bastien Guerry <bzg AT altern DOT org>
  10 ;; Keywords: org, wp, tex
  11 ;; Description: Converts an org-mode buffer into LaTeX
  12 ;; URL: http://www.cognition.ens.fr/~guerry/u/org-export-latex.el
  13
  14 ;; This file is part of GNU Emacs.
  15
  16 ;; GNU Emacs is free software: you can redistribute it and/or modify
  17 ;; it under the terms of the GNU General Public License as published by
  18 ;; the Free Software Foundation, either version 3 of the License, or
  19 ;; (at your option) any later version.
  20
  21 ;; GNU Emacs is distributed in the hope that it will be useful,
  22 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 ;; GNU General Public License for more details.
  25
  26 ;; You should have received a copy of the GNU General Public License
  27 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  28
  29 ;;; Commentary:
  30 ;;
  31 ;; This library implements a LaTeX exporter for org-mode.
  32 ;;
  33 ;; Put this file into your load-path and the following into your ~/.emacs:
  34 ;;   (require 'org-export-latex)
  35 ;;
  36 ;; The interactive functions are similar to those of the HTML exporter:
  37 ;;
  38 ;; M-x `org-export-as-latex'
  39 ;; M-x `org-export-as-pdf'
  40 ;; M-x `org-export-as-pdf-and-open'
  41 ;; M-x `org-export-as-latex-batch'
  42 ;; M-x `org-export-as-latex-to-buffer'
  43 ;; M-x `org-export-region-as-latex'
  44 ;; M-x `org-replace-region-by-latex'
  45 ;;
  46 ;;; Code:
  47
  48 (eval-when-compile
  49   (require 'cl))
  50
  51 (require 'footnote)
  52 (require 'org)
  53 (require 'org-exp)
  54
  55 ;;; Variables:
  56 (defvar org-export-latex-class nil)
  57 (defvar org-export-latex-header nil)
  58 (defvar org-export-latex-append-header nil)
  59 (defvar org-export-latex-options-plist nil)
  60 (defvar org-export-latex-todo-keywords-1 nil)
  61 (defvar org-export-latex-all-targets-re nil)
  62 (defvar org-export-latex-add-level 0)
  63 (defvar org-export-latex-sectioning "")
  64 (defvar org-export-latex-sectioning-depth 0)
  65 (defvar org-export-latex-special-string-regexps
  66   '(org-ts-regexp
  67     org-scheduled-string
  68     org-deadline-string
  69     org-clock-string)
  70   "A list of regexps to convert as special keywords.")
  71
  72 (defvar latexp)    ; dynamically scoped from org.el
  73 (defvar re-quote)  ; dynamically scoped from org.el
  74 (defvar commentsp) ; dynamically scoped from org.el
  75
  76 ;;; User variables:
  77
  78 (defgroup org-export-latex nil
  79   "Options for exporting Org-mode files to LaTeX."
  80   :tag "Org Export LaTeX"
  81   :group 'org-export)
  82
  83 (defcustom org-export-latex-default-class "article"
  84   "The default LaTeX class."
  85   :group 'org-export-latex
  86   :type '(string :tag "LaTeX class"))
  87
  88 (defcustom org-export-latex-classes
  89   '(("article"
  90      "\\documentclass[11pt,a4paper]{article}
  91 \\usepackage[utf8]{inputenc}
  92 \\usepackage[T1]{fontenc}
  93 \\usepackage{graphicx}
  94 \\usepackage{hyperref}"
  95      ("\\section{%s}" . "\\section*{%s}")
  96      ("\\subsection{%s}" . "\\subsection*{%s}")
  97      ("\\subsubsection{%s}" . "\\subsubsection*{%s}")
  98      ("\\paragraph{%s}" . "\\paragraph*{%s}")
  99      ("\\subparagraph{%s}" . "\\subparagraph*{%s}"))
 100     ("report"
 101      "\\documentclass[11pt,a4paper]{report}
 102 \\usepackage[utf8]{inputenc}
 103 \\usepackage[T1]{fontenc}
 104 \\usepackage{graphicx}
 105 \\usepackage{hyperref}"
 106      ("\\part{%s}" . "\\part*{%s}")
 107      ("\\chapter{%s}" . "\\chapter*{%s}")
 108      ("\\section{%s}" . "\\section*{%s}")
 109      ("\\subsection{%s}" . "\\subsection*{%s}")
 110      ("\\subsubsection{%s}" . "\\subsubsection*{%s}"))
 111     ("book"
 112      "\\documentclass[11pt,a4paper]{book}
 113 \\usepackage[utf8]{inputenc}
 114 \\usepackage[T1]{fontenc}
 115 \\usepackage{graphicx}
 116 \\usepackage{hyperref}"
 117      ("\\part{%s}" . "\\part*{%s}")
 118      ("\\chapter{%s}" . "\\chapter*{%s}")
 119      ("\\section{%s}" . "\\section*{%s}")
 120      ("\\subsection{%s}" . "\\subsection*{%s}")
 121      ("\\subsubsection{%s}" . "\\subsubsection*{%s}")))
 122   "Alist of LaTeX classes and associated header and structure.
 123 If #+LaTeX_CLASS is set in the buffer, use its value and the
 124 associated information.  Here is the structure of each cell:
 125
 126   \(class-name
 127     header-string
 128     (numbered-section . unnumbered-section\)
 129     ...\)
 130
 131 A %s formatter is mandatory in each section string and will be
 132 replaced by the title of the section.
 133
 134 Instead of a cons cell (numbered . unnumbered), you can also provide a list
 135 of 2-4 elements,
 136
 137   (numbered-open numbered-close)
 138
 139 or
 140
 141   (numbered-open numbered-close unnumbered-open unnumbered-close)
 142
 143 providing opening and closing strings for an environment that should
 144 represent the document section.  The opening clause should have a %s
 145 to represent the section title."
 146   :group 'org-export-latex
 147   :type '(repeat
 148           (list (string :tag "LaTeX class")
 149                 (string :tag "LaTeX header")
 150                 (repeat :tag "Levels" :inline t
 151                         (choice
 152                          (cons :tag "Heading"
 153                                (string :tag "numbered")
 154                                (string :tag "unnumbered)"))
 155                          (list :tag "Environment"
 156                                (string :tag "Opening (numbered)  ")
 157                                (string :tag "Closing (numbered)  ")
 158                                (string :tag "Opening (unnumbered)")
 159                                (string :tag "Closing (unnumbered)")))))))
 160
 161 (defcustom org-export-latex-emphasis-alist
 162   '(("*" "\\textbf{%s}" nil)
 163     ("/" "\\emph{%s}" nil)
 164     ("_" "\\underline{%s}" nil)
 165     ("+" "\\texttt{%s}" nil)
 166     ("=" "\\texttt{%s}" nil)
 167     ("~" "\\texttt{%s}" t))
 168   "Alist of LaTeX expressions to convert emphasis fontifiers.
 169 Each element of the list is a list of three elements.
 170 The first element is the character used as a marker for fontification.
 171 The second element is a formatting string to wrap fontified text with.
 172 The third element decides whether to protect converted text from other
 173 conversions."
 174   :group 'org-export-latex
 175   :type 'alist)
 176
 177 (defcustom org-export-latex-title-command "\\maketitle"
 178   "The command used to insert the title just after \\begin{document}.
 179 If this string contains the formatting specification \"%s\" then
 180 it will be used as a formatting string, passing the title as an
 181 argument."
 182   :group 'org-export-latex
 183   :type 'string)
 184
 185 (defcustom org-export-latex-date-format
 186   "%d %B %Y"
 187   "Format string for \\date{...}."
 188   :group 'org-export-latex
 189   :type 'string)
 190
 191 (defcustom org-export-latex-tables-verbatim nil
 192   "When non-nil, tables are exported verbatim."
 193   :group 'org-export-latex
 194   :type 'boolean)
 195
 196 (defcustom org-export-latex-tables-column-borders nil
 197   "When non-nil, group of columns are surrounded with borders."
 198   :group 'org-export-latex
 199   :type 'boolean)
 200
 201 (defcustom org-export-latex-packages-alist nil
 202   "Alist of packages to be inserted in the header.
 203 Each cell is of the forma \( \"option\" . \"package\" \)."
 204   :group 'org-export-latex
 205   :type 'alist)
 206
 207 (defcustom org-export-latex-low-levels 'description
 208   "How to convert sections below the current level of sectioning.
 209 This is specified by the `org-export-headline-levels' option or the
 210 value of \"H:\" in Org's #+OPTION line.
 211
 212 This can be either nil (skip the sections), 'description (convert
 213 the sections as descriptive lists) or a string to be used instead
 214 of \\section{%s}. In this latter case, the %s stands here for the
 215 inserted headline and is mandatory."
 216   :group 'org-export-latex
 217   :type '(choice (const :tag "Ignore" nil)
 218                  (symbol :tag "Convert as descriptive list" description)
 219                  (string :tag "Use a section string" :value "\\subparagraph{%s}")))
 220
 221 (defcustom org-export-latex-remove-from-headlines
 222   '(:todo t :priority t :tags t)
 223   "A plist of keywords to remove from headlines.
 224 Non-nil means remove this keyword type from the headline.
 225
 226 Don't remove the keys, just change their values."
 227   :type 'plist
 228   :group 'org-export-latex)
 229
 230 (defcustom org-export-latex-image-default-option "width=10em"
 231   "Default option for images."
 232   :group 'org-export-latex
 233   :type 'string)
 234
 235 (defcustom org-export-latex-coding-system nil
 236   "Coding system for the exported LaTex file."
 237   :group 'org-export-latex
 238   :type 'coding-system)
 239
 240 (defgroup org-export-pdf nil
 241   "Options for exporting Org-mode files to PDF, via LaTeX."
 242   :tag "Org Export LaTeX"
 243   :group 'org-export-latex
 244   :group 'org-export)
 245
 246 (defcustom org-export-pdf-remove-logfiles t
 247   "Non-nil means, remove the logfiles produced by PDF production.
 248 These are the .aux, .log, .out, and .toc files."
 249   :group 'org-export-latex
 250   :type 'boolean)
 251
 252 ;;; Autoload functions:
 253
 254 ;;;###autoload
 255 (defun org-export-as-latex-batch ()
 256   "Call `org-export-as-latex', may be used in batch processing.
 257 For example:
 258
 259 emacs   --batch
 260         --load=$HOME/lib/emacs/org.el
 261         --eval \"(setq org-export-headline-levels 2)\"
 262         --visit=MyFile --funcall org-export-as-latex-batch"
 263   (org-export-as-latex org-export-headline-levels 'hidden))
 264
 265 ;;;###autoload
 266 (defun org-export-as-latex-to-buffer (arg)
 267   "Call `org-exort-as-latex` with output to a temporary buffer.
 268 No file is created.  The prefix ARG is passed through to `org-export-as-latex'."
 269   (interactive "P")
 270   (org-export-as-latex arg nil nil "*Org LaTeX Export*")
 271   (switch-to-buffer-other-window "*Org LaTeX Export*"))
 272
 273 ;;;###autoload
 274 (defun org-replace-region-by-latex (beg end)
 275   "Replace the region from BEG to END with its LaTeX export.
 276 It assumes the region has `org-mode' syntax, and then convert it to
 277 LaTeX.  This can be used in any buffer.  For example, you could
 278 write an itemized list in `org-mode' syntax in an LaTeX buffer and
 279 then use this command to convert it."
 280   (interactive "r")
 281   (let (reg latex buf)
 282     (save-window-excursion
 283       (if (org-mode-p)
 284           (setq latex (org-export-region-as-latex
 285                        beg end t 'string))
 286         (setq reg (buffer-substring beg end)
 287               buf (get-buffer-create "*Org tmp*"))
 288         (save-excursion
 289           (set-buffer buf)
 290           (erase-buffer)
 291           (insert reg)
 292           (org-mode)
 293           (setq latex (org-export-region-as-latex
 294                        (point-min) (point-max) t 'string)))
 295         (kill-buffer buf)))
 296     (delete-region beg end)
 297     (insert latex)))
 298
 299 ;;;###autoload
 300 (defun org-export-region-as-latex (beg end &optional body-only buffer)
 301   "Convert region from BEG to END in `org-mode' buffer to LaTeX.
 302 If prefix arg BODY-ONLY is set, omit file header, footer, and table of
 303 contents, and only produce the region of converted text, useful for
 304 cut-and-paste operations.
 305 If BUFFER is a buffer or a string, use/create that buffer as a target
 306 of the converted LaTeX.  If BUFFER is the symbol `string', return the
 307 produced LaTeX as a string and leave not buffer behind.  For example,
 308 a Lisp program could call this function in the following way:
 309
 310   (setq latex (org-export-region-as-latex beg end t 'string))
 311
 312 When called interactively, the output buffer is selected, and shown
 313 in a window.  A non-interactive call will only retunr the buffer."
 314   (interactive "r\nP")
 315   (when (interactive-p)
 316     (setq buffer "*Org LaTeX Export*"))
 317   (let ((transient-mark-mode t) (zmacs-regions t)
 318         rtn)
 319     (goto-char end)
 320     (set-mark (point)) ;; to activate the region
 321     (goto-char beg)
 322     (setq rtn (org-export-as-latex
 323                nil nil nil
 324                buffer body-only))
 325     (if (fboundp 'deactivate-mark) (deactivate-mark))
 326     (if (and (interactive-p) (bufferp rtn))
 327         (switch-to-buffer-other-window rtn)
 328       rtn)))
 329
 330 ;;;###autoload
 331 (defun org-export-as-latex (arg &optional hidden ext-plist
 332                                 to-buffer body-only pub-dir)
 333   "Export current buffer to a LaTeX file.
 334 If there is an active region, export only the region.  The prefix
 335 ARG specifies how many levels of the outline should become
 336 headlines.  The default is 3.  Lower levels will be exported
 337 depending on `org-export-latex-low-levels'.  The default is to
 338 convert them as description lists.  When HIDDEN is non-nil, don't
 339 display the LaTeX buffer.  EXT-PLIST is a property list with
 340 external parameters overriding org-mode's default settings, but
 341 still inferior to file-local settings.  When TO-BUFFER is
 342 non-nil, create a buffer with that name and export to that
 343 buffer.  If TO-BUFFER is the symbol `string', don't leave any
 344 buffer behind but just return the resulting LaTeX as a string.
 345 When BODY-ONLY is set, don't produce the file header and footer,
 346 simply return the content of \begin{document}...\end{document},
 347 without even the \begin{document} and \end{document} commands.
 348 when PUB-DIR is set, use this as the publishing directory."
 349   (interactive "P")
 350   ;; Make sure we have a file name when we need it.
 351   (when (and (not (or to-buffer body-only))
 352              (not buffer-file-name))
 353     (if (buffer-base-buffer)
 354         (org-set-local 'buffer-file-name
 355                        (with-current-buffer (buffer-base-buffer)
 356                          buffer-file-name))
 357       (error "Need a file name to be able to export")))
 358
 359   (message "Exporting to LaTeX...")
 360   (org-update-radio-target-regexp)
 361   (org-export-latex-set-initial-vars ext-plist arg)
 362   (let* ((wcf (current-window-configuration))
 363          (opt-plist org-export-latex-options-plist)
 364          (region-p (org-region-active-p))
 365          (rbeg (and region-p (region-beginning)))
 366          (rend (and region-p (region-end)))
 367          (subtree-p
 368           (when region-p
 369             (save-excursion
 370               (goto-char rbeg)
 371               (and (org-at-heading-p)
 372                    (>= (org-end-of-subtree t t) rend)))))
 373          (opt-plist (if subtree-p
 374                         (org-export-add-subtree-options opt-plist rbeg)
 375                       opt-plist))
 376          ;; Make sure the variable contains the updated values.
 377          (org-export-latex-options-plist opt-plist)
 378          (title (or (and subtree-p (org-export-get-title-from-subtree))
 379                     (plist-get opt-plist :title)
 380                     (and (not
 381                           (plist-get opt-plist :skip-before-1st-heading))
 382                          (org-export-grab-title-from-buffer))
 383                     (file-name-sans-extension
 384                      (file-name-nondirectory buffer-file-name))))
 385          (filename (concat (file-name-as-directory
 386                             (or pub-dir
 387                                 (org-export-directory :LaTeX ext-plist)))
 388                            (file-name-sans-extension
 389                             (or (and subtree-p
 390                                      (org-entry-get rbeg "EXPORT_FILE_NAME" t))
 391                                 (file-name-nondirectory ;sans-extension
 392                                  buffer-file-name)))
 393                            ".tex"))
 394          (filename (if (equal (file-truename filename)
 395                               (file-truename buffer-file-name))
 396                        (concat filename ".tex")
 397                      filename))
 398          (buffer (if to-buffer
 399                      (cond
 400                       ((eq to-buffer 'string) (get-buffer-create
 401                                                "*Org LaTeX Export*"))
 402                       (t (get-buffer-create to-buffer)))
 403                    (find-file-noselect filename)))
 404          (odd org-odd-levels-only)
 405          (header (org-export-latex-make-header title opt-plist))
 406          (skip (cond (subtree-p nil)
 407                      (region-p t)
 408                  ;; never skip first lines when exporting a subtree
 409                      (t (plist-get opt-plist :skip-before-1st-heading))))
 410          (text (plist-get opt-plist :text))
 411          (first-lines (if skip "" (org-export-latex-first-lines)))
 412          (coding-system (and (boundp 'buffer-file-coding-system)
 413                              buffer-file-coding-system))
 414          (coding-system-for-write (or org-export-latex-coding-system
 415                                       coding-system))
 416          (save-buffer-coding-system (or org-export-latex-coding-system
 417                                         coding-system))
 418          (region (buffer-substring
 419                   (if region-p (region-beginning) (point-min))
 420                   (if region-p (region-end) (point-max))))
 421          (string-for-export
 422           (org-export-preprocess-string
 423            region :emph-multiline t
 424                   :for-LaTeX t
 425                   :comments nil
 426                   :tags (plist-get opt-plist :tags)
 427                   :priority (plist-get opt-plist :priority)
 428                   :todo-keywords (plist-get opt-plist :todo-keywords)
 429                   :add-text (if (eq to-buffer 'string) nil text)
 430                   :skip-before-1st-heading skip
 431                   :select-tags (plist-get opt-plist :select-tags)
 432                   :exclude-tags (plist-get opt-plist :exclude-tags)
 433                   :LaTeX-fragments nil)))
 434
 435     (set-buffer buffer)
 436     (erase-buffer)
 437
 438     (and (fboundp 'set-buffer-file-coding-system)
 439          (set-buffer-file-coding-system coding-system-for-write))
 440
 441     ;; insert the header and initial document commands
 442     (unless (or (eq to-buffer 'string) body-only)
 443       (insert header))
 444
 445     ;; insert text found in #+TEXT
 446     (when (and text (not (eq to-buffer 'string)))
 447       (insert (org-export-latex-content
 448                text '(lists tables fixed-width keywords))
 449                "\n\n"))
 450
 451     ;; insert lines before the first headline
 452     (unless (or skip (eq to-buffer 'string))
 453       (insert first-lines))
 454
 455     ;; handle the case where the region does not begin with a section
 456     (when region-p
 457       (insert (with-temp-buffer
 458                 (insert string-for-export)
 459                 (org-export-latex-first-lines))))
 460
 461     ;; export the content of headlines
 462     (org-export-latex-global
 463      (with-temp-buffer
 464        (insert string-for-export)
 465        (goto-char (point-min))
 466        (when (re-search-forward "^\\(\\*+\\) " nil t)
 467          (let* ((asters (length (match-string 1)))
 468                 (level (if odd (- asters 2) (- asters 1))))
 469            (setq org-export-latex-add-level
 470                  (if odd (1- (/ (1+ asters) 2)) (1- asters)))
 471            (org-export-latex-parse-global level odd)))))
 472
 473     ;; finalization
 474     (unless body-only (insert "\n\\end{document}"))
 475     (or to-buffer (save-buffer))
 476     (goto-char (point-min))
 477     (message "Exporting to LaTeX...done")
 478     (prog1
 479         (if (eq to-buffer 'string)
 480             (prog1 (buffer-substring (point-min) (point-max))
 481               (kill-buffer (current-buffer)))
 482           (current-buffer))
 483       (set-window-configuration wcf))))
 484
 485 ;;;###autoload
 486 (defun org-export-as-pdf (arg &optional hidden ext-plist
 487                               to-buffer body-only pub-dir)
 488   "Export as LaTeX, then process through to PDF."
 489   (interactive "P")
 490   (message "Exporting to PDF...")
 491   (let* ((wconfig (current-window-configuration))
 492          (lbuf (org-export-as-latex arg hidden ext-plist
 493                                     to-buffer body-only pub-dir))
 494          (file (buffer-file-name lbuf))
 495          (base (file-name-sans-extension (buffer-file-name lbuf)))
 496          (pdffile (concat base ".pdf")))
 497     (and (file-exists-p pdffile) (delete-file pdffile))
 498     (message "Processing LaTeX file...")
 499     (shell-command (format "pdflatex -interaction nonstopmode %s"
 500                            (shell-quote-argument file)))
 501     (shell-command (format "pdflatex -interaction nonstopmode %s"
 502                            (shell-quote-argument file)))
 503     (message "Processing LaTeX file...done")
 504     (if (not (file-exists-p pdffile))
 505         (error "PDF file was not produced")
 506       (set-window-configuration wconfig)
 507       (when org-export-pdf-remove-logfiles
 508         (dolist (ext '("aux" "log" "out" "toc"))
 509           (setq file (concat base "." ext))
 510           (and (file-exists-p file) (delete-file file))))
 511       (message "Exporting to PDF...done")
 512       pdffile)))
 513
 514 ;;;###autoload
 515 (defun org-export-as-pdf-and-open (arg)
 516   "Export as LaTeX, then process through to PDF, and open."
 517   (interactive "P")
 518   (let ((pdffile (org-export-as-pdf arg)))
 519     (if pdffile
 520         (org-open-file pdffile)
 521       (error "PDF file was not produced"))))
 522
 523 ;;; Parsing functions:
 524
 525 (defun org-export-latex-parse-global (level odd)
 526   "Parse the current buffer recursively, starting at LEVEL.
 527 If ODD is non-nil, assume the buffer only contains odd sections.
 528 Return a list reflecting the document structure."
 529   (save-excursion
 530     (goto-char (point-min))
 531     (let* ((cnt 0) output
 532            (depth org-export-latex-sectioning-depth))
 533       (while (re-search-forward
 534               (concat "^\\(\\(?:\\*\\)\\{"
 535                       (number-to-string (+ (if odd 2 1) level))
 536                       "\\}\\) \\(.*\\)$")
 537               ;; make sure that there is no upper heading
 538               (when (> level 0)
 539                 (save-excursion
 540                   (save-match-data
 541                     (re-search-forward
 542                      (concat "^\\(\\(?:\\*\\)\\{"
 543                              (number-to-string level)
 544                              "\\}\\) \\(.*\\)$") nil t)))) t)
 545         (setq cnt (1+ cnt))
 546         (let* ((pos (match-beginning 0))
 547                (heading (match-string 2))
 548                (nlevel (if odd (/ (+ 3 level) 2) (1+ level))))
 549           (save-excursion
 550             (narrow-to-region
 551              (point)
 552              (save-match-data
 553                (if (re-search-forward
 554                     (concat "^\\(\\(?:\\*\\)\\{"
 555                             (number-to-string (+ (if odd 2 1) level))
 556                             "\\}\\) \\(.*\\)$") nil t)
 557                    (match-beginning 0)
 558                  (point-max))))
 559             (goto-char (point-min))
 560             (setq output
 561                   (append output
 562                           (list
 563                            (list
 564                             `(pos . ,pos)
 565                             `(level . ,nlevel)
 566                             `(occur . ,cnt)
 567                             `(heading . ,heading)
 568                             `(content . ,(org-export-latex-parse-content))
 569                             `(subcontent . ,(org-export-latex-parse-subcontent
 570                                              level odd)))))))
 571           (widen)))
 572       (list output))))
 573
 574 (defun org-export-latex-parse-content ()
 575   "Extract the content of a section."
 576   (let ((beg (point))
 577         (end (if (re-search-forward "^\\(\\*\\)+ .*$" nil t)
 578                  (progn (beginning-of-line) (point))
 579                (point-max))))
 580     (buffer-substring beg end)))
 581
 582 (defun org-export-latex-parse-subcontent (level odd)
 583   "Extract the subcontent of a section at LEVEL.
 584 If ODD Is non-nil, assume subcontent only contains odd sections."
 585   (if (not (re-search-forward
 586             (concat "^\\(\\(?:\\*\\)\\{"
 587                     (number-to-string (+ (if odd 4 2) level))
 588                     "\\}\\) \\(.*\\)$")
 589             nil t))
 590       nil ; subcontent is nil
 591     (org-export-latex-parse-global (+ (if odd 2 1) level) odd)))
 592
 593 ;;; Rendering functions:
 594 (defun org-export-latex-global (content)
 595   "Export CONTENT to LaTeX.
 596 CONTENT is an element of the list produced by
 597 `org-export-latex-parse-global'."
 598   (if (eq (car content) 'subcontent)
 599       (mapc 'org-export-latex-sub (cdr content))
 600     (org-export-latex-sub (car content))))
 601
 602 (defun org-export-latex-sub (subcontent)
 603   "Export the list SUBCONTENT to LaTeX.
 604 SUBCONTENT is an alist containing information about the headline
 605 and its content."
 606   (let ((num (plist-get org-export-latex-options-plist :section-numbers)))
 607     (mapc (lambda(x) (org-export-latex-subcontent x num)) subcontent)))
 608
 609 (defun org-export-latex-subcontent (subcontent num)
 610   "Export each cell of SUBCONTENT to LaTeX.
 611 If NUM, export sections as numerical sections."
 612   (let* ((heading (org-export-latex-fontify-headline
 613                    (cdr (assoc 'heading subcontent))))
 614          (level (- (cdr (assoc 'level subcontent))
 615                    org-export-latex-add-level))
 616          (occur (number-to-string (cdr (assoc 'occur subcontent))))
 617          (content (cdr (assoc 'content subcontent)))
 618          (subcontent (cadr (assoc 'subcontent subcontent)))
 619          (label (org-get-text-property-any 0 'target heading))
 620          (label-list (cons label (cdr (assoc label
 621                                              org-export-target-aliases)))))
 622     (cond
 623      ;; Normal conversion
 624      ((<= level org-export-latex-sectioning-depth)
 625       (let* ((sec (nth (1- level) org-export-latex-sectioning))
 626              start end)
 627         (if (consp (cdr sec))
 628             (setq start (nth (if num 0 2) sec)
 629                   end (nth (if num 1 3) sec))
 630           (setq start (if num (car sec) (cdr sec))))
 631         (insert (format start heading) "\n")
 632         (when label
 633           (insert (mapconcat (lambda (l) (format "\\label{%s}" l))
 634                              label-list "\n") "\n"))
 635         (insert (org-export-latex-content content))
 636         (cond ((stringp subcontent) (insert subcontent))
 637               ((listp subcontent) (org-export-latex-sub subcontent)))
 638         (if end (insert end "\n"))))
 639      ;; At a level under the hl option: we can drop this subsection
 640      ((> level org-export-latex-sectioning-depth)
 641       (cond ((eq org-export-latex-low-levels 'description)
 642              (insert (format "\\begin{description}\n\n\\item[%s]%s\n\n"
 643                              heading
 644                              (if label (format "\\label{%s}" label) "")))
 645              (insert (org-export-latex-content content))
 646              (cond ((stringp subcontent) (insert subcontent))
 647                    ((listp subcontent) (org-export-latex-sub subcontent)))
 648              (insert "\\end{description}\n"))
 649             ((stringp org-export-latex-low-levels)
 650              (insert (format org-export-latex-low-levels heading) "\n")
 651              (when label (insert (format "\\label{%s}\n" label)))
 652              (insert (org-export-latex-content content))
 653              (cond ((stringp subcontent) (insert subcontent))
 654                    ((listp subcontent) (org-export-latex-sub subcontent)))))))))
 655
 656 ;;; Exporting internals:
 657 (defun org-export-latex-set-initial-vars (ext-plist level)
 658   "Store org local variables required for LaTeX export.
 659 EXT-PLIST is an optional additional plist.
 660 LEVEL indicates the default depth for export."
 661   (setq org-export-latex-todo-keywords-1 org-todo-keywords-1
 662         org-export-latex-all-targets-re
 663         (org-make-target-link-regexp (org-all-targets))
 664         org-export-latex-options-plist
 665         (org-combine-plists (org-default-export-plist) ext-plist
 666                             (org-infile-export-plist))
 667         org-export-latex-class
 668         (save-excursion
 669           (goto-char (point-min))
 670           (if (and (re-search-forward "^#\\+LaTeX_CLASS:[ \t]*\\([a-zA-Z]+\\)" nil t)
 671                    (assoc (match-string 1) org-export-latex-classes))
 672               (match-string 1)
 673             org-export-latex-default-class))
 674         org-export-latex-header
 675         (cadr (assoc org-export-latex-class org-export-latex-classes))
 676         org-export-latex-sectioning
 677         (cddr (assoc org-export-latex-class org-export-latex-classes))
 678         org-export-latex-sectioning-depth
 679         (or level
 680             (let ((hl-levels
 681                    (plist-get org-export-latex-options-plist :headline-levels))
 682                   (sec-depth (length org-export-latex-sectioning)))
 683               (if (> hl-levels sec-depth) sec-depth hl-levels)))))
 684
 685 (defun org-export-latex-make-header (title opt-plist)
 686   "Make the LaTeX header and return it as a string.
 687 TITLE is the current title from the buffer or region.
 688 OPT-PLIST is the options plist for current buffer."
 689   (let ((toc (plist-get opt-plist :table-of-contents))
 690         (author (plist-get opt-plist :author)))
 691     (concat
 692      (if (plist-get opt-plist :time-stamp-file)
 693          (format-time-string "% Created %Y-%m-%d %a %H:%M\n"))
 694      ;; insert LaTeX custom header
 695      org-export-latex-header
 696      "\n"
 697      ;; insert information on LaTeX packages
 698      (when org-export-latex-packages-alist
 699        (mapconcat (lambda(p)
 700                     (if (equal "" (car p))
 701                         (format "\\usepackage{%s}" (cadr p))
 702                       (format "\\usepackage[%s]{%s}"
 703                               (car p) (cadr p))))
 704                   org-export-latex-packages-alist "\n"))
 705      ;; insert additional commands in the header
 706      (plist-get opt-plist :latex-header-extra)
 707      org-export-latex-append-header
 708      ;; insert the title
 709      (format
 710       "\n\n\\title{%s}\n"
 711       ;; convert the title
 712       (org-export-latex-content
 713        title '(lists tables fixed-width keywords)))
 714      ;; insert author info
 715      (if (plist-get opt-plist :author-info)
 716          (format "\\author{%s}\n"
 717                  (or author user-full-name))
 718        (format "%%\\author{%s}\n"
 719                (or author user-full-name)))
 720      ;; insert the date
 721      (format "\\date{%s}\n"
 722              (format-time-string
 723               (or (plist-get opt-plist :date)
 724                   org-export-latex-date-format)))
 725      ;; beginning of the document
 726      "\n\\begin{document}\n\n"
 727      ;; insert the title command
 728      (if (string-match "%s" org-export-latex-title-command)
 729          (format org-export-latex-title-command title)
 730        org-export-latex-title-command)
 731      "\n\n"
 732      ;; table of contents
 733      (when (and org-export-with-toc
 734                 (plist-get opt-plist :section-numbers))
 735        (cond ((numberp toc)
 736               (format "\\setcounter{tocdepth}{%s}\n\\tableofcontents\n\n"
 737                       (min toc (plist-get opt-plist :headline-levels))))
 738              (toc (format "\\setcounter{tocdepth}{%s}\n\\tableofcontents\n\n"
 739                           (plist-get opt-plist :headline-levels))))))))
 740
 741 (defun org-export-latex-first-lines (&optional comments)
 742   "Export the first lines before first headline.
 743 COMMENTS is either nil to replace them with the empty string or a
 744 formatting string like %%%%s if we want to comment them out."
 745   (save-excursion
 746     (goto-char (point-min))
 747     (if (org-at-heading-p) (beginning-of-line 2))
 748     (let* ((pt (point))
 749            (end (if (and (re-search-forward "^\\* " nil t)
 750                          (not (eq pt (match-beginning 0))))
 751                     (goto-char (match-beginning 0))
 752                   (goto-char (point-max)))))
 753       (org-export-latex-content
 754        (org-export-preprocess-string
 755         (buffer-substring (point-min) end)
 756         :for-LaTeX t
 757         :emph-multiline t
 758         :add-text nil
 759         :comments nil
 760         :skip-before-1st-heading nil
 761         :LaTeX-fragments nil)))))
 762
 763 (defun org-export-latex-content (content &optional exclude-list)
 764   "Convert CONTENT string to LaTeX.
 765 Don't perform conversions that are in EXCLUDE-LIST.  Recognized
 766 conversion types are: quotation-marks, emphasis, sub-superscript,
 767 links, keywords, lists, tables, fixed-width"
 768   (with-temp-buffer
 769    (insert content)
 770    (unless (memq 'quotation-marks exclude-list)
 771      (org-export-latex-quotation-marks))
 772    (unless (memq 'emphasis exclude-list)
 773      (when (plist-get org-export-latex-options-plist :emphasize)
 774        (org-export-latex-fontify)))
 775    (unless (memq 'sub-superscript exclude-list)
 776      (org-export-latex-special-chars
 777       (plist-get org-export-latex-options-plist :sub-superscript)))
 778    (unless (memq 'links exclude-list)
 779      (org-export-latex-links))
 780    (unless (memq 'keywords exclude-list)
 781      (org-export-latex-keywords
 782       (plist-get org-export-latex-options-plist :timestamps)))
 783    (unless (memq 'lists exclude-list)
 784      (org-export-latex-lists))
 785    (unless (memq 'tables exclude-list)
 786      (org-export-latex-tables
 787       (plist-get org-export-latex-options-plist :tables)))
 788    (unless (memq 'fixed-width exclude-list)
 789      (org-export-latex-fixed-width
 790       (plist-get org-export-latex-options-plist :fixed-width)))
 791    ;; return string
 792    (buffer-substring (point-min) (point-max))))
 793
 794 (defun org-export-latex-protect-string (s)
 795   "Add the org-protected property to string S."
 796   (add-text-properties 0 (length s) '(org-protected t) s) s)
 797
 798 (defun org-export-latex-protect-char-in-string (char-list string)
 799   "Add org-protected text-property to char from CHAR-LIST in STRING."
 800   (with-temp-buffer
 801     (save-match-data
 802       (insert string)
 803       (goto-char (point-min))
 804       (while (re-search-forward (regexp-opt char-list) nil t)
 805         (add-text-properties (match-beginning 0)
 806                              (match-end 0) '(org-protected t)))
 807       (buffer-string))))
 808
 809 (defun org-export-latex-keywords-maybe (remove-list)
 810   "Maybe remove keywords depending on rules in REMOVE-LIST."
 811   (goto-char (point-min))
 812   (let ((re-todo (mapconcat 'identity org-export-latex-todo-keywords-1 "\\|"))
 813         (case-fold-search nil))
 814     ;; convert TODO keywords
 815     (when (re-search-forward (concat "^\\(" re-todo "\\)") nil t)
 816       (if (plist-get remove-list :todo)
 817           (replace-match "")
 818         (replace-match (format "\\texttt{%s}" (match-string 1)) t t)))
 819     ;; convert priority string
 820     (when (re-search-forward "\\[\\\\#.\\]" nil t)
 821       (if (plist-get remove-list :priority)
 822           (replace-match "")
 823         (replace-match (format "\\texttt{%s}" (match-string 0)) t t)))
 824     ;; convert tags
 825     (when (re-search-forward "\\(:[a-zA-Z0-9_@]+\\)+:" nil t)
 826       (if (or (not org-export-with-tags)
 827               (plist-get remove-list :tags))
 828           (replace-match "")
 829         (replace-match
 830          (org-export-latex-protect-string
 831           (format "\\texttt{%s}"
 832                   (save-match-data
 833                     (replace-regexp-in-string
 834                      "_" "\\\\_" (match-string 0)))))
 835          t t)))))
 836
 837 (defun org-export-latex-fontify-headline (string)
 838   "Fontify special words in STRING."
 839   (with-temp-buffer
 840     ;; FIXME: org-inside-LaTeX-fragment-p doesn't work when the $...$ is at
 841     ;; the beginning of the buffer - inserting "\n" is safe here though.
 842     (insert "\n" string)
 843     (goto-char (point-min))
 844     (when (plist-get org-export-latex-options-plist :emphasize)
 845       (org-export-latex-fontify))
 846     (org-export-latex-keywords-maybe
 847      org-export-latex-remove-from-headlines)
 848     (org-export-latex-special-chars
 849      (plist-get org-export-latex-options-plist :sub-superscript))
 850     (org-export-latex-links)
 851 ;    (org-trim (buffer-substring-no-properties (point-min) (point-max)))))
 852     (org-trim (buffer-string))))
 853
 854 (defun org-export-latex-quotation-marks ()
 855   "Export quotation marks depending on language conventions."
 856   (let* ((lang (plist-get org-export-latex-options-plist :language))
 857          (quote-rpl (if (equal lang "fr")
 858                         '(("\\(\\s-\\)\"" "«~")
 859                           ("\\(\\S-\\)\"" "~»")
 860                           ("\\(\\s-\\)'" "`"))
 861                       '(("\\(\\s-\\)\"" "``")
 862                         ("\\(\\S-\\)\"" "''")
 863                         ("\\(\\s-\\)'" "`")))))
 864     (mapc (lambda(l) (goto-char (point-min))
 865             (while (re-search-forward (car l) nil t)
 866               (let ((rpl (concat (match-string 1) (cadr l))))
 867                 (org-export-latex-protect-string rpl)
 868                 (org-if-unprotected
 869                  (replace-match rpl t t))))) quote-rpl)))
 870
 871 (defun org-export-latex-special-chars (sub-superscript)
 872   "Export special characters to LaTeX.
 873 If SUB-SUPERSCRIPT is non-nil, convert \\ and ^.
 874 See the `org-export-latex.el' code for a complete conversion table."
 875   (goto-char (point-min))
 876   (mapc (lambda(c)
 877           (goto-char (point-min))
 878           (while (re-search-forward c nil t)
 879             ;; Put the point where to check for org-protected
 880             (unless (or (get-text-property (match-beginning 2) 'org-protected)
 881                         (org-at-table-p))
 882               (cond ((member (match-string 2) '("\\$" "$"))
 883                      (if (equal (match-string 2) "\\$")
 884                          (replace-match (concat (match-string 1) "$"
 885                                                 (match-string 3)) t t)
 886                        (replace-match (concat (match-string 1) "\\$"
 887                                               (match-string 3)) t t)))
 888                     ((member (match-string 2) '("&" "%" "#"))
 889                      (if (equal (match-string 1) "\\")
 890                          (replace-match (match-string 2) t t)
 891                        (replace-match (concat (match-string 1) "\\"
 892                                               (match-string 2)) t t)))
 893                     ((equal (match-string 2) "...")
 894                      (replace-match
 895                       (concat (match-string 1)
 896                               (org-export-latex-protect-string "\\ldots{}")) t t))
 897                     ((equal (match-string 2) "~")
 898                      (cond ((equal (match-string 1) "\\") nil)
 899                            ((eq 'org-link (get-text-property 0 'face (match-string 2)))
 900                             (replace-match (concat (match-string 1) "\\~") t t))
 901                            (t (replace-match
 902                                (org-export-latex-protect-string
 903                                 (concat (match-string 1) "\\~{}")) t t))))
 904                     ((member (match-string 2) '("{" "}"))
 905                      (unless (save-match-data (org-inside-LaTeX-fragment-p))
 906                        (if (equal (match-string 1) "\\")
 907                            (replace-match (match-string 2) t t)
 908                          (replace-match (concat (match-string 1) "\\"
 909                                                 (match-string 2)) t t)))))
 910               (unless (save-match-data (org-inside-LaTeX-fragment-p))
 911                 (cond ((equal (match-string 2) "\\")
 912                        (replace-match (or (save-match-data
 913                                             (org-export-latex-treat-backslash-char
 914                                              (match-string 1)
 915                                              (match-string 3))) "") t t))
 916                       ((member (match-string 2) '("_" "^"))
 917                        (replace-match (or (save-match-data
 918                                             (org-export-latex-treat-sub-super-char
 919                                              sub-superscript
 920                                              (match-string 2)
 921                                              (match-string 1)
 922                                              (match-string 3))) "") t t)))))))
 923         '("^\\([^\n$]*?\\|^\\)\\(\\\\?\\$\\)\\([^\n$]*\\)$"
 924           "\\([a-za-z0-9]+\\|[ \t\n]\\|\\b\\|\\\\\\)\\(_\\|\\^\\)\\([a-za-z0-9]+\\|[ \t\n]\\|[:punct:]\\|{[a-za-z0-9]+}\\|([a-za-z0-9]+)\\)"
 925           "\\(.\\|^\\)\\(\\\\\\)\\([ \t\n]\\|[a-zA-Z&#%{}\"]+\\)"
 926           "\\(.\\|^\\)\\(&\\)"
 927           "\\(.\\|^\\)\\(#\\)"
 928           "\\(.\\|^\\)\\(%\\)"
 929           "\\(.\\|^\\)\\({\\)"
 930           "\\(.\\|^\\)\\(}\\)"
 931           "\\(.\\|^\\)\\(~\\)"
 932           "\\(.\\|^\\)\\(\\.\\.\\.\\)"
 933           ;; (?\< . "\\textless{}")
 934           ;; (?\> . "\\textgreater{}")
 935           )))
 936
 937 (defun org-export-latex-treat-sub-super-char
 938   (subsup char string-before string-after)
 939   "Convert the \"_\" and \"^\" characters to LaTeX.
 940 SUBSUP corresponds to the ^: option in the #+OPTIONS line.
 941 Convert CHAR depending on STRING-BEFORE and STRING-AFTER."
 942   (cond ((equal string-before "\\")
 943          (concat string-before char string-after))
 944         ;; this is part of a math formula
 945         ((and (string-match "\\S-+" string-before)
 946               (string-match "\\S-+" string-after))
 947          (cond ((eq 'org-link (get-text-property 0 'face char))
 948                 (concat string-before "\\" char string-after))
 949                ((save-match-data (org-inside-LaTeX-fragment-p))
 950                 (if subsup
 951                     (cond ((eq 1 (length string-after))
 952                            (concat string-before char string-after))
 953                           ((string-match "[({]?\\([^)}]+\\)[)}]?" string-after)
 954                            (format "%s%s{%s}" string-before char
 955                                    (match-string 1 string-after))))))
 956                ((and (> (length string-after) 1)
 957                      (or (eq subsup t)
 958                          (and (equal subsup '{}) (eq (string-to-char string-after) ?\{)))
 959                      (string-match "[({]?\\([^)}]+\\)[)}]?" string-after))
 960                 (format "%s$%s{%s}$" string-before char
 961                         (if (> (match-end 1) (1+ (match-beginning 1)))
 962                             (concat "\\mathrm{" (match-string 1 string-after) "}")
 963                         (match-string 1 string-after))))
 964                ((eq subsup t) (concat string-before "$" char string-after "$"))
 965                (t (org-export-latex-protect-string
 966                    (concat string-before "\\" char "{}" string-after)))))
 967         (t (org-export-latex-protect-string
 968             (concat string-before "\\" char "{}" string-after)))))
 969
 970 (defun org-export-latex-treat-backslash-char (string-before string-after)
 971   "Convert the \"$\" special character to LaTeX.
 972 The conversion is made depending of STRING-BEFORE and STRING-AFTER."
 973   (cond ((member (list string-after) org-html-entities)
 974          ;; backslash is part of a special entity (like "\alpha")
 975          (concat string-before "$\\"
 976                  (or (cdar (member (list string-after) org-html-entities))
 977                      string-after) "$"))
 978         ((and (not (string-match "^[ \n\t]" string-after))
 979               (not (string-match "[ \t]\\'\\|^" string-before)))
 980          ;; backslash is inside a word
 981          (org-export-latex-protect-string
 982           (concat string-before "\\textbackslash{}" string-after)))
 983         ((not (or (equal string-after "")
 984                   (string-match "^[ \t\n]" string-after)))
 985          ;; backslash might escape a character (like \#) or a user TeX
 986          ;; macro (like \setcounter)
 987          (org-export-latex-protect-string
 988           (concat string-before "\\" string-after)))
 989         ((and (string-match "^[ \t\n]" string-after)
 990               (string-match "[ \t\n]\\'" string-before))
 991          ;; backslash is alone, convert it to $\backslash$
 992          (org-export-latex-protect-string
 993           (concat string-before "\\textbackslash{}" string-after)))
 994         (t (org-export-latex-protect-string
 995             (concat string-before "\\textbackslash{}" string-after)))))
 996
 997 (defun org-export-latex-keywords (timestamps)
 998   "Convert special keywords to LaTeX.
 999 Regexps are those from `org-export-latex-special-string-regexps'.
1000 If TIMESTAMPS, convert timestamps, otherwise delete them."
1001   (let ((rg org-export-latex-special-string-regexps) r)
1002     (while (setq r (pop rg))
1003       (goto-char (point-min))
1004       (while (re-search-forward (eval r) nil t)
1005         (if (not timestamps)
1006             (replace-match (format "\\\\texttt{%s}" (match-string 0)) t)
1007           (replace-match ""))))))
1008
1009 (defun org-export-latex-fixed-width (opt)
1010   "When OPT is non-nil convert fixed-width sections to LaTeX."
1011   (goto-char (point-min))
1012   (while (re-search-forward "^[ \t]*:" nil t)
1013     (if opt
1014         (progn (goto-char (match-beginning 0))
1015                (insert "\\begin{verbatim}\n")
1016                (while (looking-at "^\\([ \t]*\\):\\(.*\\)$")
1017                  (replace-match (concat (match-string 1)
1018                                         (match-string 2)) t t)
1019                  (forward-line))
1020                (insert "\\end{verbatim}\n\n"))
1021       (progn (goto-char (match-beginning 0))
1022              (while (looking-at "^\\([ \t]*\\):\\(.*\\)$")
1023                (replace-match (concat "%" (match-string 1)
1024                                       (match-string 2)) t t)
1025                (forward-line))))))
1026
1027
1028 (defvar org-table-last-alignment) ; defined in org-table.el
1029 (declare-function orgtbl-to-latex "org-table" (table params) t)
1030 (defun org-export-latex-tables (insert)
1031   "Convert tables to LaTeX and INSERT it."
1032   (goto-char (point-min))
1033   (while (re-search-forward "^\\([ \t]*\\)|" nil t)
1034     ;; FIXME really need to save-excursion?
1035     (save-excursion (org-table-align))
1036     (let* ((beg (org-table-begin))
1037            (end (org-table-end))
1038            (raw-table (buffer-substring beg end))
1039            fnum fields line lines olines gr colgropen line-fmt align
1040            caption label attr floatp)
1041       (if org-export-latex-tables-verbatim
1042           (let* ((tbl (concat "\\begin{verbatim}\n" raw-table
1043                               "\\end{verbatim}\n")))
1044             (apply 'delete-region (list beg end))
1045             (insert (org-export-latex-protect-string tbl)))
1046         (progn
1047           (setq caption (org-find-text-property-in-string
1048                          'org-caption raw-table)
1049                 attr (org-find-text-property-in-string
1050                       'org-attributes raw-table)
1051                 label (org-find-text-property-in-string
1052                        'org-attributes raw-table)
1053                 floatp (or caption label))
1054           (setq lines (split-string raw-table "\n" t))
1055           (apply 'delete-region (list beg end))
1056           (when org-export-table-remove-special-lines
1057             (setq lines (org-table-clean-before-export lines)))
1058           ;; make a formatting string to reflect aligment
1059           (setq olines lines)
1060           (while (and (not line-fmt) (setq line (pop olines)))
1061             (unless (string-match "^[ \t]*|-" line)
1062               (setq fields (org-split-string line "[ \t]*|[ \t]*"))
1063               (setq fnum (make-vector (length fields) 0))
1064               (setq line-fmt
1065                     (mapconcat
1066                      (lambda (x)
1067                        (setq gr (pop org-table-colgroup-info))
1068                        (format "%s%%s%s"
1069                                (cond ((eq gr ':start)
1070                                       (prog1 (if colgropen "|" "")
1071                                         (setq colgropen t)))
1072                                      ((eq gr ':startend)
1073                                       (prog1 (if colgropen "|" "|")
1074                                         (setq colgropen nil)))
1075                                      (t ""))
1076                                (if (memq gr '(:end :startend))
1077                                    (progn (setq colgropen nil) "|")
1078                                  "")))
1079                      fnum ""))))
1080           ;; fix double || in line-fmt
1081           (setq line-fmt (replace-regexp-in-string "||" "|" line-fmt))
1082           ;; maybe remove the first and last "|"
1083           (when (and (not org-export-latex-tables-column-borders)
1084                      (string-match "^\\(|\\)?\\(.+\\)|$" line-fmt))
1085             (setq line-fmt (match-string 2 line-fmt)))
1086           ;; format alignment
1087           (setq align (apply 'format
1088                              (cons line-fmt
1089                                    (mapcar (lambda (x) (if x "r" "l"))
1090                                            org-table-last-alignment))))
1091           ;; prepare the table to send to orgtbl-to-latex
1092           (setq lines
1093                 (mapcar
1094                  (lambda(elem)
1095                    (or (and (string-match "[ \t]*|-+" elem) 'hline)
1096                        (split-string (org-trim elem) "|" t)))
1097                  lines))
1098           (when insert
1099             (insert (org-export-latex-protect-string
1100                      (concat
1101                       (if floatp "\\begin{table}[htb]\n")
1102                       (if floatp (format
1103                                   "\\caption{%s%s}\n"
1104                                   (if label (concat "\\\label{" label "}"))
1105                                   (or caption "")))
1106                       "\\begin{center}\n"
1107                       (orgtbl-to-latex
1108                        lines `(:tstart ,(concat "\\begin{tabular}{" align "}")))
1109                       "\n\\end{center}\n"
1110                       (if floatp "\\end{table}")))
1111                     "\n\n")))))))
1112
1113 (defun org-export-latex-fontify ()
1114   "Convert fontification to LaTeX."
1115   (goto-char (point-min))
1116   (while (re-search-forward org-emph-re nil t)
1117     ;; The match goes one char after the *string*
1118     (let ((emph (assoc (match-string 3)
1119                        org-export-latex-emphasis-alist))
1120           rpl)
1121       (unless (get-text-property (1- (point)) 'org-protected)
1122         (setq rpl (concat (match-string 1)
1123                           (format (org-export-latex-protect-char-in-string
1124                                    '("\\" "{" "}") (cadr emph))
1125                                   (match-string 4))
1126                           (match-string 5)))
1127         (if (caddr emph)
1128             (setq rpl (org-export-latex-protect-string rpl)))
1129         (replace-match rpl t t)))
1130     (backward-char)))
1131
1132 (defun org-export-latex-links ()
1133   ;; Make sure to use the LaTeX hyperref and graphicx package
1134   ;; or send some warnings.
1135   "Convert links to LaTeX."
1136   (goto-char (point-min))
1137   (while (re-search-forward org-bracket-link-analytic-regexp nil t)
1138     (org-if-unprotected
1139      (goto-char (match-beginning 0))
1140      (let* ((re-radio org-export-latex-all-targets-re)
1141             (remove (list (match-beginning 0) (match-end 0)))
1142             (raw-path (org-extract-attributes (match-string 3)))
1143             (full-raw-path (concat (match-string 1) raw-path))
1144             (desc (match-string 5))
1145             (type (or (match-string 2)
1146                       (if (or (file-name-absolute-p raw-path)
1147                               (string-match "^\\.\\.?/" raw-path))
1148                           "file")))
1149             (caption (org-find-text-property-in-string 'org-caption raw-path))
1150             (attr (org-find-text-property-in-string 'org-attributes raw-path))
1151             (label (org-find-text-property-in-string 'org-label raw-path))
1152             (floatp (or label caption))
1153             imgp radiop
1154             ;; define the path of the link
1155             (path (cond
1156                    ((member type '("http" "https" "ftp"))
1157                     (concat type ":" raw-path))
1158                    ((and re-radio (string-match re-radio raw-path))
1159                     (setq radiop t))
1160                    ((equal type "mailto")
1161                     (concat type ":" raw-path))
1162                    ((equal type "file")
1163                     (if (and (or (org-file-image-p (expand-file-name raw-path))
1164                                  (string-match "\\.\\(pdf\\|jpg\\|ps\\|eps\\)$"
1165                                                raw-path))
1166                              (equal desc full-raw-path))
1167                         (setq imgp t)
1168                       (progn (when (string-match "\\(.+\\)::.+" raw-path)
1169                                (setq raw-path (match-string 1 raw-path)))
1170                              (if (file-exists-p raw-path)
1171                                  (concat type "://" (expand-file-name raw-path))
1172                                (concat type "://" (org-export-directory
1173                                                    :LaTeX org-export-latex-options-plist)
1174                                        raw-path))))))))
1175        ;; process with link inserting
1176        (apply 'delete-region remove)
1177        (cond ((and imgp (plist-get org-export-latex-options-plist :inline-images))
1178               (insert
1179                (concat
1180                 (if floatp "\\begin{figure}[htb]\n")
1181                 (format "\\centerline{\\includegraphics[%s]{%s}}\n"
1182                         (or attr org-export-latex-image-default-option)
1183                         (expand-file-name raw-path))
1184                 (if floatp
1185                     (format "\\caption{%s%s}\n"
1186                             (if label (concat "\\label{" label "}"))
1187                             (or caption "")))
1188                 (if floatp "\\end{figure}\n"))))
1189              (radiop (insert (format "\\hyperref[%s]{%s}"
1190                                      (org-solidify-link-text raw-path) desc)))
1191              ((not type)
1192               (insert (format "\\hyperref[%s]{%s}"
1193                               (org-solidify-link-text raw-path) desc)))
1194              (path (insert (format "\\href{%s}{%s}" path desc)))
1195              (t (insert "\\texttt{" desc "}")))))))
1196
1197 (defvar org-latex-entities)   ; defined below
1198 (defvar org-latex-entities-regexp)   ; defined below
1199
1200 (defun org-export-latex-preprocess ()
1201   "Clean stuff in the LaTeX export."
1202
1203   ;; Preserve line breaks
1204   (goto-char (point-min))
1205   (while (re-search-forward "\\\\\\\\" nil t)
1206     (add-text-properties (match-beginning 0) (match-end 0)
1207                          '(org-protected t)))
1208
1209   ;; Preserve latex environments
1210   (goto-char (point-min))
1211   (while (re-search-forward "^[ \t]*\\begin{\\([a-zA-Z]+\\)}" nil t)
1212     (let* ((start (progn (beginning-of-line) (point)))
1213            (end (or (and (re-search-forward
1214                           (concat "^[ \t]*\\end{" (match-string 1) "}" nil t)
1215                           (point-at-eol)))
1216                     (point-max))))
1217       (add-text-properties start end '(org-protected t))))
1218
1219   ;; Convert LaTeX to \LaTeX{}
1220   (goto-char (point-min))
1221   (let ((case-fold-search nil) rpl)
1222     (while (re-search-forward "\\([^+_]\\)LaTeX" nil t)
1223     (replace-match (org-export-latex-protect-string
1224                     (concat (match-string 1) "\\LaTeX{}")) t t)))
1225
1226   ;; Convert blockquotes
1227   (goto-char (point-min))
1228   (while (search-forward "ORG-BLOCKQUOTE-START" nil t)
1229     (replace-match "\\begin{quote}" t t))
1230   (goto-char (point-min))
1231   (while (search-forward "ORG-BLOCKQUOTE-END" nil t)
1232     (replace-match "\\end{quote}" t t))
1233
1234   ;; Convert verse
1235   (goto-char (point-min))
1236   (while (search-forward "ORG-VERSE-START" nil t)
1237     (replace-match "\\begin{verse}" t t))
1238   (goto-char (point-min))
1239   (while (search-forward "ORG-VERSE-END" nil t)
1240     (replace-match "\\end{verse}" t t))
1241
1242   ;; Convert horizontal rules
1243   (goto-char (point-min))
1244   (while (re-search-forward "^----+.$" nil t)
1245     (replace-match (org-export-latex-protect-string "\\hrule") t t))
1246
1247   ;; Protect LaTeX commands like \commad[...]{...} or \command{...}
1248   (goto-char (point-min))
1249   (while (re-search-forward "\\\\[a-zA-Z]+\\(?:\\[.*\\]\\)?{.*}" nil t)
1250     (add-text-properties (match-beginning 0) (match-end 0)
1251                          '(org-protected t)))
1252
1253   ;; Protect LaTeX entities
1254   (goto-char (point-min))
1255   (while (re-search-forward org-latex-entities-regexp nil t)
1256     (add-text-properties (match-beginning 0) (match-end 0)
1257                          '(org-protected t)))
1258
1259   ;; Replace radio links
1260   (goto-char (point-min))
1261   (while (re-search-forward
1262           (concat "<<<?" org-export-latex-all-targets-re
1263                   ">>>?\\((INVISIBLE)\\)?") nil t)
1264     (replace-match
1265      (org-export-latex-protect-string
1266       (format "\\label{%s}%s" (save-match-data (org-solidify-link-text
1267                                                 (match-string 1)))
1268               (if (match-string 2) "" (match-string 1)))) t t))
1269
1270   ;; Delete @<...> constructs
1271   ;; Thanks to Daniel Clemente for this regexp
1272   (goto-char (point-min))
1273   (while (re-search-forward "@<\\(?:[^\"\n]\\|\".*\"\\)*?>" nil t)
1274     (replace-match ""))
1275
1276   ;; When converting to LaTeX, replace footnotes
1277   ;; FIXME: don't protect footnotes from conversion
1278   (when (plist-get org-export-latex-options-plist :footnotes)
1279     (goto-char (point-min))
1280     (while (re-search-forward "\\[[0-9]+\\]" nil t)
1281       (when (save-match-data
1282               (save-excursion (beginning-of-line)
1283                               (looking-at "[^:|#]")))
1284         (let ((foot-beg (match-beginning 0))
1285               (foot-end (match-end 0))
1286               (foot-prefix (match-string 0))
1287               footnote footnote-rpl)
1288           (save-excursion
1289             (when (search-forward foot-prefix nil t)
1290               (replace-match "")
1291               (let ((end (save-excursion
1292                            (if (re-search-forward "^$\\|^#.*$\\|\\[[0-9]+\\]" nil t)
1293                                (match-beginning 0) (point-max)))))
1294                 (setq footnote (concat (org-trim (buffer-substring (point) end))
1295                                        " ")) ; prevent last } being part of a link
1296                 (delete-region (point) end))
1297               (goto-char foot-beg)
1298             (delete-region foot-beg foot-end)
1299             (unless (null footnote)
1300               (setq footnote-rpl (format "\\footnote{%s}" footnote))
1301               (add-text-properties 0 10 '(org-protected t) footnote-rpl)
1302               (add-text-properties (1- (length footnote-rpl))
1303                                    (length footnote-rpl)
1304                                    '(org-protected t) footnote-rpl)
1305               (insert footnote-rpl)))))))
1306
1307     ;; Replace footnote section tag for LaTeX
1308     (goto-char (point-min))
1309     (while (re-search-forward
1310             (concat "^" footnote-section-tag-regexp) nil t)
1311       (replace-match ""))))
1312
1313 ;;; List handling:
1314
1315 (defun org-export-latex-lists ()
1316   "Replace plain text lists in current buffer into LaTeX lists."
1317   "Convert lists to LaTeX."
1318   (goto-char (point-min))
1319   (while (re-search-forward org-list-beginning-re nil t)
1320     (org-if-unprotected
1321      (beginning-of-line)
1322      (insert (org-list-to-latex (org-list-parse-list t)) "\n"))))
1323
1324 (defconst org-latex-entities
1325  '("\\!"
1326    "\\'"
1327    "\\+"
1328    "\\,"
1329    "\\-"
1330    "\\:"
1331    "\\;"
1332    "\\<"
1333    "\\="
1334    "\\>"
1335    "\\Huge"
1336    "\\LARGE"
1337    "\\Large"
1338    "\\Styles"
1339    "\\\\"
1340    "\\`"
1341    "\\addcontentsline"
1342    "\\address"
1343    "\\addtocontents"
1344    "\\addtocounter"
1345    "\\addtolength"
1346    "\\addvspace"
1347    "\\alph"
1348    "\\appendix"
1349    "\\arabic"
1350    "\\author"
1351    "\\begin{array}"
1352    "\\begin{center}"
1353    "\\begin{description}"
1354    "\\begin{enumerate}"
1355    "\\begin{eqnarray}"
1356    "\\begin{equation}"
1357    "\\begin{figure}"
1358    "\\begin{flushleft}"
1359    "\\begin{flushright}"
1360    "\\begin{itemize}"
1361    "\\begin{list}"
1362    "\\begin{minipage}"
1363    "\\begin{picture}"
1364    "\\begin{quotation}"
1365    "\\begin{quote}"
1366    "\\begin{tabbing}"
1367    "\\begin{table}"
1368    "\\begin{tabular}"
1369    "\\begin{thebibliography}"
1370    "\\begin{theorem}"
1371    "\\begin{titlepage}"
1372    "\\begin{verbatim}"
1373    "\\begin{verse}"
1374    "\\bf"
1375    "\\bf"
1376    "\\bibitem"
1377    "\\bigskip"
1378    "\\cdots"
1379    "\\centering"
1380    "\\circle"
1381    "\\cite"
1382    "\\cleardoublepage"
1383    "\\clearpage"
1384    "\\cline"
1385    "\\closing"
1386    "\\dashbox"
1387    "\\date"
1388    "\\ddots"
1389    "\\dotfill"
1390    "\\em"
1391    "\\fbox"
1392    "\\flushbottom"
1393    "\\fnsymbol"
1394    "\\footnote"
1395    "\\footnotemark"
1396    "\\footnotesize"
1397    "\\footnotetext"
1398    "\\frac"
1399    "\\frame"
1400    "\\framebox"
1401    "\\hfill"
1402    "\\hline"
1403    "\\hrulespace"
1404    "\\hspace"
1405    "\\huge"
1406    "\\hyphenation"
1407    "\\include"
1408    "\\includeonly"
1409    "\\indent"
1410    "\\input"
1411    "\\it"
1412    "\\kill"
1413    "\\label"
1414    "\\large"
1415    "\\ldots"
1416    "\\line"
1417    "\\linebreak"
1418    "\\linethickness"
1419    "\\listoffigures"
1420    "\\listoftables"
1421    "\\location"
1422    "\\makebox"
1423    "\\maketitle"
1424    "\\mark"
1425    "\\mbox"
1426    "\\medskip"
1427    "\\multicolumn"
1428    "\\multiput"
1429    "\\newcommand"
1430    "\\newcounter"
1431    "\\newenvironment"
1432    "\\newfont"
1433    "\\newlength"
1434    "\\newline"
1435    "\\newpage"
1436    "\\newsavebox"
1437    "\\newtheorem"
1438    "\\nocite"
1439    "\\nofiles"
1440    "\\noindent"
1441    "\\nolinebreak"
1442    "\\nopagebreak"
1443    "\\normalsize"
1444    "\\onecolumn"
1445    "\\opening"
1446    "\\oval"
1447    "\\overbrace"
1448    "\\overline"
1449    "\\pagebreak"
1450    "\\pagenumbering"
1451    "\\pageref"
1452    "\\pagestyle"
1453    "\\par"
1454    "\\parbox"
1455    "\\put"
1456    "\\raggedbottom"
1457    "\\raggedleft"
1458    "\\raggedright"
1459    "\\raisebox"
1460    "\\ref"
1461    "\\rm"
1462    "\\roman"
1463    "\\rule"
1464    "\\savebox"
1465    "\\sc"
1466    "\\scriptsize"
1467    "\\setcounter"
1468    "\\setlength"
1469    "\\settowidth"
1470    "\\sf"
1471    "\\shortstack"
1472    "\\signature"
1473    "\\sl"
1474    "\\small"
1475    "\\smallskip"
1476    "\\sqrt"
1477    "\\tableofcontents"
1478    "\\telephone"
1479    "\\thanks"
1480    "\\thispagestyle"
1481    "\\tiny"
1482    "\\title"
1483    "\\tt"
1484    "\\twocolumn"
1485    "\\typein"
1486    "\\typeout"
1487    "\\underbrace"
1488    "\\underline"
1489    "\\usebox"
1490    "\\usecounter"
1491    "\\value"
1492    "\\vdots"
1493    "\\vector"
1494    "\\verb"
1495    "\\vfill"
1496    "\\vline"
1497    "\\vspace")
1498  "A list of LaTeX commands to be protected when performing conversion.")
1499
1500 (defconst org-latex-entities-regexp
1501   (let (names rest)
1502     (dolist (x org-latex-entities)
1503       (if (string-match "[a-z][A-Z]$" x)
1504           (push x names)
1505         (push x rest)))
1506     (concat "\\(" (regexp-opt (nreverse names)) "\\>\\)"
1507             "\\|\\(" (regexp-opt (nreverse rest)) "\\)")))
1508
1509 (provide 'org-export-latex)
1510
1511 ;; arch-tag: 23c2b87d-da04-4c2d-ad2d-1eb6487bc3ad
1512
1513 ;;; org-export-latex.el ends here