lisp/ob-ruby.el

   1 ;;; ob-ruby.el --- org-babel functions for ruby evaluation
   2
   3 ;; Copyright (C) 2009, 2010  Free Software Foundation
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8 ;; Version: 7.5
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Org-Babel support for evaluating ruby source code.
  28
  29 ;;; Requirements:
  30
  31 ;; - ruby and irb executables :: http://www.ruby-lang.org/
  32 ;;
  33 ;; - ruby-mode :: Can be installed through ELPA, or from
  34 ;;   http://github.com/eschulte/rinari/raw/master/util/ruby-mode.el
  35 ;;
  36 ;; - inf-ruby mode :: Can be installed through ELPA, or from
  37 ;;   http://github.com/eschulte/rinari/raw/master/util/inf-ruby.el
  38
  39 ;;; Code:
  40 (require 'ob)
  41 (require 'ob-ref)
  42 (require 'ob-comint)
  43 (require 'ob-eval)
  44 (eval-when-compile (require 'cl))
  45
  46 (declare-function run-ruby "ext:inf-ruby" (&optional command name))
  47
  48 (add-to-list 'org-babel-tangle-lang-exts '("ruby" . "rb"))
  49
  50 (defvar org-babel-default-header-args:ruby '())
  51
  52 (defvar org-babel-ruby-command "ruby"
  53   "Name of command to use for executing ruby code.")
  54
  55 (defun org-babel-execute:ruby (body params)
  56   "Execute a block of Ruby code with Babel.
  57 This function is called by `org-babel-execute-src-block'."
  58   (let* ((session (org-babel-ruby-initiate-session
  59                    (cdr (assoc :session params))))
  60          (result-params (cdr (assoc :result-params params)))
  61          (result-type (cdr (assoc :result-type params)))
  62          (full-body (org-babel-expand-body:generic
  63                      body params (org-babel-variable-assignments:ruby params)))
  64          (result (org-babel-ruby-evaluate
  65                   session full-body result-type result-params)))
  66     (org-babel-reassemble-table
  67      result
  68      (org-babel-pick-name (cdr (assoc :colname-names params))
  69                           (cdr (assoc :colnames params)))
  70      (org-babel-pick-name (cdr (assoc :rowname-names params))
  71                           (cdr (assoc :rownames params))))))
  72
  73 (defun org-babel-prep-session:ruby (session params)
  74   "Prepare SESSION according to the header arguments specified in PARAMS."
  75   ;; (message "params=%S" params) ;; debugging
  76   (let* ((session (org-babel-ruby-initiate-session session))
  77          (var-lines (org-babel-variable-assignments:ruby params)))
  78     (org-babel-comint-in-buffer session
  79       (sit-for .5) (goto-char (point-max))
  80       (mapc (lambda (var)
  81               (insert var) (comint-send-input nil t)
  82               (org-babel-comint-wait-for-output session)
  83               (sit-for .1) (goto-char (point-max))) var-lines))
  84     session))
  85
  86 (defun org-babel-load-session:ruby (session body params)
  87   "Load BODY into SESSION."
  88   (save-window-excursion
  89     (let ((buffer (org-babel-prep-session:ruby session params)))
  90       (with-current-buffer buffer
  91         (goto-char (process-mark (get-buffer-process (current-buffer))))
  92         (insert (org-babel-chomp body)))
  93       buffer)))
  94
  95 ;; helper functions
  96
  97 (defun org-babel-variable-assignments:ruby (params)
  98   "Return list of ruby statements assigning the block's variables"
  99   (mapcar
 100    (lambda (pair)
 101      (format "%s=%s"
 102              (car pair)
 103              (org-babel-ruby-var-to-ruby (cdr pair))))
 104    (mapcar #'cdr (org-babel-get-header params :var))))
 105
 106 (defun org-babel-ruby-var-to-ruby (var)
 107   "Convert VAR into a ruby variable.
 108 Convert an elisp value into a string of ruby source code
 109 specifying a variable of the same value."
 110   (if (listp var)
 111       (concat "[" (mapconcat #'org-babel-ruby-var-to-ruby var ", ") "]")
 112     (format "%S" var)))
 113
 114 (defun org-babel-ruby-table-or-string (results)
 115   "Convert RESULTS into an appropriate elisp value.
 116 If RESULTS look like a table, then convert them into an
 117 Emacs-lisp table, otherwise return the results as a string."
 118   (org-babel-script-escape results))
 119
 120 (defun org-babel-ruby-initiate-session (&optional session params)
 121   "Initiate a ruby session.
 122 If there is not a current inferior-process-buffer in SESSION
 123 then create one.  Return the initialized session."
 124   (require 'inf-ruby)
 125   (unless (string= session "none")
 126     (let ((session-buffer (save-window-excursion
 127                             (run-ruby nil session) (current-buffer))))
 128       (if (org-babel-comint-buffer-livep session-buffer)
 129           (progn (sit-for .25) session-buffer)
 130         (sit-for .5)
 131         (org-babel-ruby-initiate-session session)))))
 132
 133 (defvar org-babel-ruby-eoe-indicator ":org_babel_ruby_eoe"
 134   "String to indicate that evaluation has completed.")
 135 (defvar org-babel-ruby-f-write
 136   "File.open('%s','w'){|f| f.write((_.class == String) ? _ : _.inspect)}")
 137 (defvar org-babel-ruby-pp-f-write
 138   "File.open('%s','w'){|f| $stdout = f; pp(results); $stdout = orig_out}")
 139 (defvar org-babel-ruby-wrapper-method
 140   "
 141 def main()
 142 %s
 143 end
 144 results = main()
 145 File.open('%s', 'w'){ |f| f.write((results.class == String) ? results : results.inspect) }
 146 ")
 147 (defvar org-babel-ruby-pp-wrapper-method
 148   "
 149 require 'pp'
 150 def main()
 151 %s
 152 end
 153 results = main()
 154 File.open('%s', 'w') do |f|
 155   $stdout = f
 156   pp results
 157 end
 158 ")
 159
 160 (defun org-babel-ruby-evaluate
 161   (buffer body &optional result-type result-params)
 162   "Pass BODY to the Ruby process in BUFFER.
 163 If RESULT-TYPE equals 'output then return a list of the outputs
 164 of the statements in BODY, if RESULT-TYPE equals 'value then
 165 return the value of the last statement in BODY, as elisp."
 166   (if (not buffer)
 167       ;; external process evaluation
 168       (case result-type
 169         (output (org-babel-eval org-babel-ruby-command body))
 170         (value (let ((tmp-file (org-babel-temp-file "ruby-")))
 171                  (org-babel-eval
 172                   org-babel-ruby-command
 173                   (format (if (member "pp" result-params)
 174                               org-babel-ruby-pp-wrapper-method
 175                             org-babel-ruby-wrapper-method)
 176                           body (org-babel-process-file-name tmp-file 'noquote)))
 177                  ((lambda (raw)
 178                     (if (or (member "code" result-params)
 179                             (member "pp" result-params))
 180                         raw
 181                       (org-babel-ruby-table-or-string raw)))
 182                   (org-babel-eval-read-file tmp-file)))))
 183     ;; comint session evaluation
 184     (case result-type
 185       (output
 186        (mapconcat
 187         #'identity
 188         (butlast
 189          (split-string
 190           (mapconcat
 191            #'org-babel-trim
 192            (butlast
 193             (org-babel-comint-with-output
 194                 (buffer org-babel-ruby-eoe-indicator t body)
 195               (mapc
 196                (lambda (line)
 197                  (insert (org-babel-chomp line)) (comint-send-input nil t))
 198                (list body org-babel-ruby-eoe-indicator))
 199               (comint-send-input nil t)) 2)
 200            "\n") "[\r\n]")) "\n"))
 201       (value
 202        ((lambda (results)
 203           (if (or (member "code" result-params) (member "pp" result-params))
 204               results
 205             (org-babel-ruby-table-or-string results)))
 206         (let* ((tmp-file (org-babel-temp-file "ruby-"))
 207                (ppp (or (member "code" result-params)
 208                         (member "pp" result-params))))
 209           (org-babel-comint-with-output
 210               (buffer org-babel-ruby-eoe-indicator t body)
 211             (when ppp (insert "require 'pp';") (comint-send-input nil t))
 212             (mapc
 213              (lambda (line)
 214                (insert (org-babel-chomp line)) (comint-send-input nil t))
 215              (append
 216               (list body)
 217               (if (not ppp)
 218                   (list (format org-babel-ruby-f-write
 219                                 (org-babel-process-file-name tmp-file 'noquote)))
 220                 (list
 221                  "results=_" "require 'pp'" "orig_out = $stdout"
 222                  (format org-babel-ruby-pp-f-write
 223                          (org-babel-process-file-name tmp-file 'noquote))))
 224               (list org-babel-ruby-eoe-indicator)))
 225             (comint-send-input nil t))
 226           (org-babel-eval-read-file tmp-file)))))))
 227
 228 (defun org-babel-ruby-read-string (string)
 229   "Strip \\\"s from around a ruby string."
 230   (if (string-match "^\"\\([^\000]+\\)\"$" string)
 231       (match-string 1 string)
 232     string))
 233
 234 (provide 'ob-ruby)
 235
 236 ;; arch-tag: 3e9726db-4520-49e2-b263-e8f571ac88f5
 237
 238 ;;; ob-ruby.el ends here