lisp/org-mouse.el

   1 ;;; org-mouse.el --- Better mouse support for org-mode
   2
   3 ;; Copyright (C) 2006-2011 Free Software Foundation
   4 ;;
   5 ;; Author: Piotr Zielinski <piotr dot zielinski at gmail dot com>
   6 ;; Maintainer: Carsten Dominik <carsten at orgmode dot org>
   7
   8 ;;
   9 ;; This file is part of GNU Emacs.
  10 ;;
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  24 ;;
  25 ;;; Commentary:
  26 ;;
  27 ;; Org-mouse provides mouse support for org-mode.
  28 ;;
  29 ;; http://orgmode.org
  30 ;;
  31 ;; Org-mouse implements the following features:
  32 ;; * following links with the left mouse button (in Emacs 22)
  33 ;; * subtree expansion/collapse (org-cycle) with the left mouse button
  34 ;; * several context menus on the right mouse button:
  35 ;;    + general text
  36 ;;    + headlines
  37 ;;    + timestamps
  38 ;;    + priorities
  39 ;;    + links
  40 ;;    + tags
  41 ;; * promoting/demoting/moving subtrees with mouse-3
  42 ;;    + if the drag starts and ends in the same line then promote/demote
  43 ;;    + otherwise move the subtree
  44 ;;
  45 ;; Use
  46 ;; ---
  47 ;;
  48 ;; To use this package, put the following line in your .emacs:
  49 ;;
  50 ;;    (require 'org-mouse)
  51 ;;
  52
  53 ;; FIXME:
  54 ;; + deal with folding / unfolding issues
  55
  56 ;; TODO (This list is only theoretical, if you'd like to have some
  57 ;; feature implemented or a bug fix please send me an email, even if
  58 ;; something similar appears in the list below.  This will help me get
  59 ;; the priorities right.):
  60 ;;
  61 ;; + org-store-link, insert link
  62 ;; + org tables
  63 ;; + occur with the current word/tag (same menu item)
  64 ;; + ctrl-c ctrl-c, for example, renumber the current list
  65 ;; + internal links
  66
  67 ;; Please email the maintainer with new feature suggestions / bugs
  68
  69 ;; History:
  70 ;;
  71 ;; Since version 5.10: Changes are listed in the general org-mode docs.
  72 ;;
  73 ;; Version 5.09;; + Version number synchronization with Org-mode.
  74 ;;
  75 ;; Version 0.25
  76 ;; + made compatible with org-mode 4.70 (thanks to Carsten for the patch)
  77 ;;
  78 ;; Version 0.24
  79 ;; + minor changes to the table menu
  80 ;;
  81 ;; Version 0.23
  82 ;; + preliminary support for tables and calculation marks
  83 ;; + context menu support for org-agenda-undo & org-sort-entries
  84 ;;
  85 ;; Version 0.22
  86 ;; + handles undo support for the agenda buffer (requires org-mode >=4.58)
  87 ;;
  88 ;; Version 0.21
  89 ;; + selected text activates its context menu
  90 ;; + shift-middleclick or right-drag inserts the text from the clipboard in the form of a link
  91 ;;
  92 ;; Version 0.20
  93 ;; + the new "TODO Status" submenu replaces the "Cycle TODO" menu item
  94 ;; + the TODO menu can now list occurrences of a specific TODO keyword
  95 ;; + #+STARTUP line is now recognized
  96 ;;
  97 ;; Version 0.19
  98 ;; + added support for dragging URLs to the org-buffer
  99 ;;
 100 ;; Version 0.18
 101 ;; + added support for agenda blocks
 102 ;;
 103 ;; Version 0.17
 104 ;; + toggle checkboxes with a single click
 105 ;;
 106 ;; Version 0.16
 107 ;; + added support for checkboxes
 108 ;;
 109 ;; Version 0.15
 110 ;; + org-mode now works with the Agenda buffer as well
 111 ;;
 112 ;; Version 0.14
 113 ;; + added a menu option that converts plain list items to outline items
 114 ;;
 115 ;; Version 0.13
 116 ;; + "Insert Heading" now inserts a sibling heading if the point is
 117 ;;   on "***" and a child heading otherwise
 118 ;;
 119 ;; Version 0.12
 120 ;; + compatible with Emacs 21
 121 ;; + custom agenda commands added to the main menu
 122 ;; + moving trees should now work between windows in the same frame
 123 ;;
 124 ;; Version 0.11
 125 ;; + fixed org-mouse-at-link (thanks to Carsten)
 126 ;; + removed [follow-link] bindings
 127 ;;
 128 ;; Version 0.10
 129 ;; + added a menu option to remove highlights
 130 ;; + compatible with org-mode 4.21 now
 131 ;;
 132 ;; Version 0.08:
 133 ;; + trees can be moved/promoted/demoted by dragging with the right
 134 ;;   mouse button (mouse-3)
 135 ;; + small changes in the above function
 136 ;;
 137 ;; Versions 0.01 -- 0.07: (I don't remember)
 138
 139 ;;; Code:
 140
 141 (eval-when-compile (require 'cl))
 142 (require 'org)
 143
 144 (defvar org-agenda-allow-remote-undo)
 145 (defvar org-agenda-undo-list)
 146 (defvar org-agenda-custom-commands)
 147 (declare-function org-agenda-change-all-lines "org-agenda"
 148                   (newhead hdmarker &optional fixface just-this))
 149 (declare-function org-verify-change-for-undo "org-agenda" (l1 l2))
 150 (declare-function org-apply-on-list "org-list" (function init-value &rest args))
 151 (declare-function org-agenda-earlier "org-agenda" (arg))
 152 (declare-function org-agenda-later "org-agenda" (arg))
 153
 154 (defvar org-mouse-plain-list-regexp "\\([ \t]*\\)\\([-+*]\\|[0-9]+[.)]\\) "
 155   "Regular expression that matches a plain list.")
 156 (defvar org-mouse-direct t
 157   "Internal variable indicating whether the current action is direct.
 158
 159 If t, then the current action has been invoked directly through the buffer
 160 it is intended to operate on.  If nil, then the action has been invoked
 161 indirectly, for example, through the agenda buffer.")
 162
 163 (defgroup org-mouse nil
 164   "Mouse support for org-mode."
 165   :tag "Org Mouse"
 166   :group 'org)
 167
 168 (defcustom org-mouse-punctuation ":"
 169   "Punctuation used when inserting text by drag and drop."
 170   :group 'org-mouse
 171   :type 'string)
 172
 173 (defcustom org-mouse-features
 174   '(context-menu yank-link activate-stars activate-bullets activate-checkboxes)
 175   "The features of org-mouse that should be activated.
 176 Changing this variable requires a restart of Emacs to get activated."
 177   :group 'org-mouse
 178   :type '(set :greedy t
 179               (const :tag "Mouse-3 shows context menu" context-menu)
 180               (const :tag "C-mouse-1 and mouse-3 move trees" move-tree)
 181               (const :tag "S-mouse-2 and drag-mouse-3 yank link" yank-link)
 182               (const :tag "Activate headline stars" activate-stars)
 183               (const :tag "Activate item bullets" activate-bullets)
 184               (const :tag "Activate checkboxes" activate-checkboxes)))
 185
 186 (defun org-mouse-re-search-line (regexp)
 187   "Search the current line for a given regular expression."
 188   (beginning-of-line)
 189   (re-search-forward regexp (point-at-eol) t))
 190
 191 (defun org-mouse-end-headline ()
 192   "Go to the end of current headline (ignoring tags)."
 193   (interactive)
 194   (end-of-line)
 195   (skip-chars-backward "\t ")
 196   (when (org-looking-back ":[A-Za-z]+:")
 197     (skip-chars-backward ":A-Za-z")
 198     (skip-chars-backward "\t ")))
 199
 200 (defvar org-mouse-context-menu-function nil
 201   "Function to create the context menu.
 202 The value of this variable is the function invoked by
 203 `org-mouse-context-menu' as the context menu.")
 204 (make-variable-buffer-local 'org-mouse-context-menu-function)
 205
 206 (defun org-mouse-show-context-menu (event prefix)
 207   "Invoke the context menu.
 208
 209 If the value of `org-mouse-context-menu-function' is a function, then
 210 this function is called.  Otherwise, the current major mode menu is used."
 211   (interactive "@e \nP")
 212   (if (and (= (event-click-count event) 1)
 213            (or (not mark-active)
 214                (sit-for (/ double-click-time 1000.0))))
 215       (progn
 216         (select-window (posn-window (event-start event)))
 217         (when (not (org-mouse-mark-active))
 218           (goto-char (posn-point (event-start event)))
 219           (when (not (eolp)) (save-excursion (run-hooks 'post-command-hook)))
 220           (let ((redisplay-dont-pause t))
 221             (sit-for 0)))
 222         (if (functionp org-mouse-context-menu-function)
 223             (funcall org-mouse-context-menu-function event)
 224           (if (fboundp 'mouse-menu-major-mode-map)
 225               (popup-menu (mouse-menu-major-mode-map) event prefix)
 226             (org-no-warnings ; don't warn about fallback, obsolete since 23.1
 227              (mouse-major-mode-menu event prefix)))))
 228     (setq this-command 'mouse-save-then-kill)
 229     (mouse-save-then-kill event)))
 230
 231 (defun org-mouse-line-position ()
 232   "Return `:beginning' or `:middle' or `:end', depending on the point position.
 233
 234 If the point is at the end of the line, return `:end'.
 235 If the point is separated from the beginning of the line only by white
 236 space and *'s (`org-mouse-bolp'), return `:beginning'.  Otherwise,
 237 return `:middle'."
 238   (cond
 239    ((eolp) :end)
 240    ((org-mouse-bolp) :beginning)
 241    (t :middle)))
 242
 243 (defun org-mouse-empty-line ()
 244   "Return non-nil iff the line contains only white space."
 245   (save-excursion (beginning-of-line) (looking-at "[ \t]*$")))
 246
 247 (defun org-mouse-next-heading ()
 248   "Go to the next heading.
 249 If there is none, ensure that the point is at the beginning of an empty line."
 250   (unless (outline-next-heading)
 251     (beginning-of-line)
 252     (unless (org-mouse-empty-line)
 253       (end-of-line)
 254       (newline))))
 255
 256 (defun org-mouse-insert-heading ()
 257   "Insert a new heading, as `org-insert-heading'.
 258
 259 If the point is at the :beginning (`org-mouse-line-position') of the line,
 260 insert the new heading before the current line.  Otherwise, insert it
 261 after the current heading."
 262   (interactive)
 263   (case (org-mouse-line-position)
 264     (:beginning (beginning-of-line)
 265             (org-insert-heading))
 266     (t (org-mouse-next-heading)
 267        (org-insert-heading))))
 268
 269 (defun org-mouse-timestamp-today (&optional shift units)
 270   "Change the timestamp into SHIFT UNITS in the future.
 271
 272 For the acceptable UNITS, see `org-timestamp-change'."
 273   (interactive)
 274   (flet ((org-read-date (&rest rest) (current-time)))
 275      (org-time-stamp nil))
 276   (when shift
 277     (org-timestamp-change shift units)))
 278
 279 (defun org-mouse-keyword-menu (keywords function &optional selected itemformat)
 280   "A helper function.
 281
 282 Returns a menu fragment consisting of KEYWORDS.  When a keyword
 283 is selected by the user, FUNCTION is called with the selected
 284 keyword as the only argument.
 285
 286 If SELECTED is nil, then all items are normal menu items.  If
 287 SELECTED is a function, then each item is a checkbox, which is
 288 enabled for a given keyword iff (funcall SELECTED keyword) return
 289 non-nil.  If SELECTED is neither nil nor a function, then the
 290 items are radio buttons.  A radio button is enabled for the
 291 keyword `equal' to SELECTED.
 292
 293 ITEMFORMAT governs formatting of the elements of KEYWORDS.  If it
 294 is a function, it is invoked with the keyword as the only
 295 argument.  If it is a string, it is interpreted as the format
 296 string to (format ITEMFORMAT keyword).  If it is neither a string
 297 nor a function, elements of KEYWORDS are used directly."
 298   (mapcar
 299    `(lambda (keyword)
 300      (vector (cond
 301               ((functionp ,itemformat) (funcall ,itemformat keyword))
 302               ((stringp ,itemformat) (format ,itemformat keyword))
 303               (t keyword))
 304              (list 'funcall ,function keyword)
 305              :style (cond
 306                      ((null ,selected) t)
 307                      ((functionp ,selected) 'toggle)
 308                      (t 'radio))
 309              :selected (if (functionp ,selected)
 310                            (and (funcall ,selected keyword) t)
 311                          (equal ,selected keyword))))
 312     keywords))
 313
 314 (defun org-mouse-remove-match-and-spaces ()
 315   "Remove the match, make just one space around the point."
 316   (interactive)
 317   (replace-match "")
 318   (just-one-space))
 319
 320 (defvar rest)
 321 (defun org-mouse-replace-match-and-surround (newtext &optional fixedcase
 322                                                      literal string subexp)
 323   "The same as `replace-match', but surrounds the replacement with spaces."
 324   (apply 'replace-match rest)
 325   (save-excursion
 326     (goto-char (match-beginning (or subexp 0)))
 327     (just-one-space)
 328     (goto-char (match-end (or subexp 0)))
 329     (just-one-space)))
 330
 331
 332 (defun org-mouse-keyword-replace-menu (keywords &optional group itemformat
 333                                                 nosurround)
 334   "A helper function.
 335
 336 Returns a menu fragment consisting of KEYWORDS.  When a keyword
 337 is selected, group GROUP of the current match is replaced by the
 338 keyword.  The method ensures that both ends of the replacement
 339 are separated from the rest of the text in the buffer by
 340 individual spaces (unless NOSURROUND is non-nil).
 341
 342 The final entry of the menu is always \"None\", which removes the
 343 match.
 344
 345 ITEMFORMAT governs formatting of the elements of KEYWORDS.  If it
 346 is a function, it is invoked with the keyword as the only
 347 argument.  If it is a string, it is interpreted as the format
 348 string to (format ITEMFORMAT keyword).  If it is neither a string
 349 nor a function, elements of KEYWORDS are used directly."
 350   (setq group (or group 0))
 351   (let ((replace (org-mouse-match-closure
 352                   (if nosurround 'replace-match
 353                     'org-mouse-replace-match-and-surround))))
 354     (append
 355      (org-mouse-keyword-menu
 356       keywords
 357       `(lambda (keyword) (funcall ,replace keyword t t nil ,group))
 358       (match-string group)
 359       itemformat)
 360      `(["None" org-mouse-remove-match-and-spaces
 361         :style radio
 362         :selected ,(not (member (match-string group) keywords))]))))
 363
 364 (defun org-mouse-show-headlines ()
 365   "Change the visibility of the current org buffer to only show headlines."
 366   (interactive)
 367   (let ((this-command 'org-cycle)
 368         (last-command 'org-cycle)
 369         (org-cycle-global-status nil))
 370     (org-cycle '(4))
 371     (org-cycle '(4))))
 372
 373 (defun org-mouse-show-overview ()
 374   "Change visibility of current org buffer to first-level headlines only."
 375   (interactive)
 376   (let ((org-cycle-global-status nil))
 377     (org-cycle '(4))))
 378
 379 (defun org-mouse-set-priority (priority)
 380   "Set the priority of the current headline to PRIORITY."
 381   (flet ((read-char-exclusive () priority))
 382     (org-priority)))
 383
 384 (defvar org-mouse-priority-regexp "\\[#\\([A-Z]\\)\\]"
 385   "Regular expression matching the priority indicator.
 386 Differs from `org-priority-regexp' in that it doesn't contain the
 387 leading '.*?'.")
 388
 389 (defun org-mouse-get-priority (&optional default)
 390   "Return the priority of the current headline.
 391 DEFAULT is returned if no priority is given in the headline."
 392   (save-excursion
 393     (if (org-mouse-re-search-line org-mouse-priority-regexp)
 394         (match-string 1)
 395       (when default (char-to-string org-default-priority)))))
 396
 397 ;; (defun org-mouse-at-link ()
 398 ;;   (and (eq (get-text-property (point) 'face) 'org-link)
 399 ;;        (save-excursion
 400 ;;          (goto-char (previous-single-property-change (point) 'face))
 401 ;;          (or (looking-at org-bracket-link-regexp)
 402 ;;              (looking-at org-angle-link-re)
 403 ;;              (looking-at org-plain-link-re)))))
 404
 405
 406 (defun org-mouse-delete-timestamp ()
 407   "Deletes the current timestamp as well as the preceding keyword.
 408 SCHEDULED: or DEADLINE: or ANYTHINGLIKETHIS:"
 409   (when (or (org-at-date-range-p) (org-at-timestamp-p))
 410     (replace-match "")                  ; delete the timestamp
 411     (skip-chars-backward " :A-Z")
 412     (when (looking-at " *[A-Z][A-Z]+:")
 413       (replace-match ""))))
 414
 415 (defun org-mouse-looking-at (regexp skipchars &optional movechars)
 416   (save-excursion
 417     (let ((point (point)))
 418       (if (looking-at regexp) t
 419         (skip-chars-backward skipchars)
 420         (forward-char (or movechars 0))
 421         (when (looking-at regexp)
 422           (> (match-end 0) point))))))
 423
 424 (defun org-mouse-priority-list ()
 425    (loop for priority from ?A to org-lowest-priority
 426          collect (char-to-string priority)))
 427
 428 (defun org-mouse-todo-menu (state)
 429   "Create the menu with TODO keywords."
 430   (append
 431    (let ((kwds org-todo-keywords-1))
 432      (org-mouse-keyword-menu
 433       kwds
 434       `(lambda (kwd) (org-todo kwd))
 435       (lambda (kwd) (equal state kwd))))))
 436
 437 (defun org-mouse-tag-menu ()            ;todo
 438   "Create the tags menu."
 439   (append
 440    (let ((tags (org-get-tags)))
 441      (org-mouse-keyword-menu
 442       (sort (mapcar 'car (org-get-buffer-tags)) 'string-lessp)
 443       `(lambda (tag)
 444          (org-mouse-set-tags
 445           (sort (if (member tag (quote ,tags))
 446                     (delete tag (quote ,tags))
 447                   (cons tag (quote ,tags)))
 448                 'string-lessp)))
 449       `(lambda (tag) (member tag (quote ,tags)))
 450       ))
 451    '("--"
 452      ["Align Tags Here" (org-set-tags nil t) t]
 453      ["Align Tags in Buffer" (org-set-tags t t) t]
 454      ["Set Tags ..." (org-set-tags) t])))
 455
 456
 457 (defun org-mouse-set-tags (tags)
 458   (save-excursion
 459     ;; remove existing tags first
 460     (beginning-of-line)
 461     (when (org-mouse-re-search-line ":\\(\\([A-Za-z_]+:\\)+\\)")
 462       (replace-match ""))
 463
 464     ;; set new tags if any
 465     (when tags
 466       (end-of-line)
 467       (insert " :" (mapconcat 'identity tags ":") ":")
 468       (org-set-tags nil t))))
 469
 470 (defun org-mouse-insert-checkbox ()
 471   (interactive)
 472   (and (org-at-item-p)
 473        (goto-char (match-end 0))
 474        (unless (org-at-item-checkbox-p)
 475          (delete-horizontal-space)
 476          (insert " [ ] "))))
 477
 478 (defun org-mouse-agenda-type (type)
 479   (case type
 480    ('tags "Tags: ")
 481    ('todo "TODO: ")
 482    ('tags-tree "Tags tree: ")
 483    ('todo-tree "TODO tree: ")
 484    ('occur-tree "Occur tree: ")
 485    (t "Agenda command ???")))
 486
 487
 488 (defun org-mouse-list-options-menu (alloptions &optional function)
 489   (let ((options (save-match-data
 490                    (split-string (match-string-no-properties 1)))))
 491     (print options)
 492     (loop for name in alloptions
 493           collect
 494           (vector name
 495                   `(progn
 496                      (replace-match
 497                       (mapconcat 'identity
 498                                  (sort (if (member ',name ',options)
 499                                            (delete ',name ',options)
 500                                          (cons ',name ',options))
 501                                        'string-lessp)
 502                                  " ")
 503                       nil nil nil 1)
 504                      (when (functionp ',function) (funcall ',function)))
 505                     :style 'toggle
 506                     :selected (and (member name options) t)))))
 507
 508 (defun org-mouse-clip-text (text maxlength)
 509   (if (> (length text) maxlength)
 510       (concat (substring text 0 (- maxlength 3)) "...")
 511     text))
 512
 513 (defun org-mouse-popup-global-menu ()
 514   (popup-menu
 515    `("Main Menu"
 516      ["Show Overview" org-mouse-show-overview t]
 517      ["Show Headlines" org-mouse-show-headlines t]
 518      ["Show All" show-all t]
 519      ["Remove Highlights" org-remove-occur-highlights
 520       :visible org-occur-highlights]
 521      "--"
 522      ["Check Deadlines"
 523       (if (functionp 'org-check-deadlines-and-todos)
 524           (org-check-deadlines-and-todos org-deadline-warning-days)
 525         (org-check-deadlines org-deadline-warning-days)) t]
 526      ["Check TODOs" org-show-todo-tree t]
 527      ("Check Tags"
 528       ,@(org-mouse-keyword-menu
 529          (sort (mapcar 'car (org-get-buffer-tags)) 'string-lessp)
 530          #'(lambda (tag) (org-tags-sparse-tree nil tag)))
 531       "--"
 532       ["Custom Tag ..." org-tags-sparse-tree t])
 533      ["Check Phrase ..." org-occur]
 534      "--"
 535      ["Display Agenda" org-agenda-list t]
 536      ["Display Timeline" org-timeline t]
 537      ["Display TODO List" org-todo-list t]
 538      ("Display Tags"
 539       ,@(org-mouse-keyword-menu
 540          (sort (mapcar 'car (org-get-buffer-tags)) 'string-lessp)
 541          #'(lambda (tag) (org-tags-view nil tag)))
 542       "--"
 543       ["Custom Tag ..." org-tags-view t])
 544      ["Display Calendar" org-goto-calendar t]
 545      "--"
 546      ,@(org-mouse-keyword-menu
 547         (mapcar 'car org-agenda-custom-commands)
 548         #'(lambda (key)
 549            (eval `(flet ((read-char-exclusive () (string-to-char ,key)))
 550                       (org-agenda nil))))
 551         nil
 552         #'(lambda (key)
 553            (let ((entry (assoc key org-agenda-custom-commands)))
 554              (org-mouse-clip-text
 555               (cond
 556                ((stringp (nth 1 entry)) (nth 1 entry))
 557                ((stringp (nth 2 entry))
 558                 (concat (org-mouse-agenda-type (nth 1 entry))
 559                         (nth 2 entry)))
 560                (t "Agenda Command '%s'"))
 561               30))))
 562      "--"
 563      ["Delete Blank Lines" delete-blank-lines
 564       :visible (org-mouse-empty-line)]
 565      ["Insert Checkbox" org-mouse-insert-checkbox
 566       :visible (and (org-at-item-p) (not (org-at-item-checkbox-p)))]
 567      ["Insert Checkboxes"
 568       (org-mouse-for-each-item 'org-mouse-insert-checkbox)
 569       :visible (and (org-at-item-p) (not (org-at-item-checkbox-p)))]
 570      ["Plain List to Outline" org-mouse-transform-to-outline
 571       :visible (org-at-item-p)])))
 572
 573
 574 (defun org-mouse-get-context (contextlist context)
 575   (let ((contextdata (assq context contextlist)))
 576     (when contextdata
 577       (save-excursion
 578         (goto-char (second contextdata))
 579         (re-search-forward ".*" (third contextdata))))))
 580
 581 (defun org-mouse-for-each-item (funct)
 582   ;; Functions called by `org-apply-on-list' need an argument
 583   (let ((wrap-fun (lambda (c) (funcall funct))))
 584     (when (ignore-errors (goto-char (org-in-item-p)))
 585       (save-excursion (org-apply-on-list wrap-fun nil)))))
 586
 587 (defun org-mouse-bolp ()
 588   "Return true if there only spaces, tabs, and '*' before point.
 589 This means, between the beginning of line and the point."
 590   (save-excursion
 591     (skip-chars-backward " \t*") (bolp)))
 592
 593 (defun org-mouse-insert-item (text)
 594   (case (org-mouse-line-position)
 595     (:beginning                 ; insert before
 596      (beginning-of-line)
 597      (looking-at "[ \t]*")
 598      (open-line 1)
 599      (org-indent-to-column (- (match-end 0) (match-beginning 0)))
 600      (insert "+ "))
 601
 602     (:middle                    ; insert after
 603      (end-of-line)
 604      (newline t)
 605      (indent-relative)
 606      (insert "+ "))
 607
 608     (:end                               ; insert text here
 609      (skip-chars-backward " \t")
 610      (kill-region (point) (point-at-eol))
 611      (unless (org-looking-back org-mouse-punctuation)
 612        (insert (concat org-mouse-punctuation " ")))))
 613
 614   (insert text)
 615   (beginning-of-line))
 616
 617 (defadvice dnd-insert-text (around org-mouse-dnd-insert-text activate)
 618   (if (eq major-mode 'org-mode)
 619       (org-mouse-insert-item text)
 620     ad-do-it))
 621
 622 (defadvice dnd-open-file (around org-mouse-dnd-open-file activate)
 623   (if (eq major-mode 'org-mode)
 624       (org-mouse-insert-item uri)
 625     ad-do-it))
 626
 627 (defun org-mouse-match-closure (function)
 628   (let ((match (match-data t)))
 629     `(lambda (&rest rest)
 630       (save-match-data
 631         (set-match-data ',match)
 632         (apply ',function rest)))))
 633
 634 (defun org-mouse-yank-link (click)
 635   (interactive "e")
 636   ;; Give temporary modes such as isearch a chance to turn off.
 637   (run-hooks 'mouse-leave-buffer-hook)
 638   (mouse-set-point click)
 639   (setq mouse-selection-click-count 0)
 640   (delete-horizontal-space)
 641   (insert-for-yank (concat " [[" (current-kill 0) "]] ")))
 642
 643 (defun org-mouse-context-menu (&optional event)
 644   (let ((stamp-prefixes (list org-deadline-string org-scheduled-string))
 645         (contextlist (org-context)))
 646     (flet ((get-context (context) (org-mouse-get-context contextlist context)))
 647   (cond
 648    ((org-mouse-mark-active)
 649     (let ((region-string (buffer-substring (region-beginning) (region-end))))
 650       (popup-menu
 651        `(nil
 652          ["Sparse Tree" (org-occur ',region-string)]
 653          ["Find in Buffer" (occur ',region-string)]
 654          ["Grep in Current Dir"
 655           (grep (format "grep -rnH -e '%s' *" ',region-string))]
 656          ["Grep in Parent Dir"
 657           (grep (format "grep -rnH -e '%s' ../*" ',region-string))]
 658          "--"
 659          ["Convert to Link"
 660           (progn (save-excursion (goto-char (region-beginning)) (insert "[["))
 661                  (save-excursion (goto-char (region-end)) (insert "]]")))]
 662          ["Insert Link Here" (org-mouse-yank-link ',event)]))))
 663
 664    ((save-excursion (beginning-of-line) (looking-at "#\\+STARTUP: \\(.*\\)"))
 665     (popup-menu
 666      `(nil
 667        ,@(org-mouse-list-options-menu (mapcar 'car org-startup-options)
 668                                       'org-mode-restart))))
 669    ((or (eolp)
 670         (and (looking-at "\\(  \\|\t\\)\\(+:[0-9a-zA-Z_:]+\\)?\\(  \\|\t\\)+$")
 671              (org-looking-back "  \\|\t")))
 672     (org-mouse-popup-global-menu))
 673    ((get-context :checkbox)
 674     (popup-menu
 675      '(nil
 676        ["Toggle" org-toggle-checkbox t]
 677        ["Remove" org-mouse-remove-match-and-spaces t]
 678        ""
 679        ["All Clear" (org-mouse-for-each-item
 680                      (lambda ()
 681                        (when (save-excursion (org-at-item-checkbox-p))
 682                          (replace-match "[ ]"))))]
 683        ["All Set" (org-mouse-for-each-item
 684                      (lambda ()
 685                        (when (save-excursion (org-at-item-checkbox-p))
 686                          (replace-match "[X]"))))]
 687        ["All Toggle" (org-mouse-for-each-item 'org-toggle-checkbox) t]
 688        ["All Remove" (org-mouse-for-each-item
 689                      (lambda ()
 690                        (when (save-excursion (org-at-item-checkbox-p))
 691                          (org-mouse-remove-match-and-spaces))))]
 692        )))
 693    ((and (org-mouse-looking-at "\\b\\w+" "a-zA-Z0-9_")
 694          (member (match-string 0) org-todo-keywords-1))
 695     (popup-menu
 696      `(nil
 697        ,@(org-mouse-todo-menu (match-string 0))
 698        "--"
 699        ["Check TODOs" org-show-todo-tree t]
 700        ["List all TODO keywords" org-todo-list t]
 701        [,(format "List only %s" (match-string 0))
 702         (org-todo-list (match-string 0)) t]
 703        )))
 704    ((and (org-mouse-looking-at "\\b[A-Z]+:" "A-Z")
 705          (member (match-string 0) stamp-prefixes))
 706     (popup-menu
 707      `(nil
 708        ,@(org-mouse-keyword-replace-menu stamp-prefixes)
 709        "--"
 710        ["Check Deadlines" org-check-deadlines t]
 711        )))
 712    ((org-mouse-looking-at org-mouse-priority-regexp "[]A-Z#") ; priority
 713     (popup-menu `(nil ,@(org-mouse-keyword-replace-menu
 714                          (org-mouse-priority-list) 1 "Priority %s" t))))
 715    ((get-context :link)
 716     (popup-menu
 717      '(nil
 718        ["Open" org-open-at-point t]
 719        ["Open in Emacs" (org-open-at-point t) t]
 720        "--"
 721        ["Copy link" (org-kill-new (match-string 0))]
 722        ["Cut link"
 723         (progn
 724           (kill-region (match-beginning 0) (match-end 0))
 725           (just-one-space))]
 726        "--"
 727        ["Grep for TODOs"
 728         (grep (format "grep -nH -i 'todo\\|fixme' %s*" (match-string 2)))]
 729 ;       ["Paste file link" ((insert "file:") (yank))]
 730        )))
 731    ((org-mouse-looking-at ":\\([A-Za-z0-9_]+\\):" "A-Za-z0-9_" -1) ;tags
 732     (popup-menu
 733      `(nil
 734        [,(format "Display '%s'" (match-string 1))
 735         (org-tags-view nil ,(match-string 1))]
 736        [,(format "Sparse Tree '%s'" (match-string 1))
 737         (org-tags-sparse-tree nil ,(match-string 1))]
 738        "--"
 739        ,@(org-mouse-tag-menu))))
 740    ((org-at-timestamp-p)
 741     (popup-menu
 742      '(nil
 743        ["Show Day" org-open-at-point t]
 744        ["Change Timestamp" org-time-stamp t]
 745        ["Delete Timestamp" (org-mouse-delete-timestamp) t]
 746        ["Compute Time Range" org-evaluate-time-range (org-at-date-range-p)]
 747        "--"
 748        ["Set for Today" org-mouse-timestamp-today]
 749        ["Set for Tomorrow" (org-mouse-timestamp-today 1 'day)]
 750        ["Set in 1 Week" (org-mouse-timestamp-today 7 'day)]
 751        ["Set in 2 Weeks" (org-mouse-timestamp-today 14 'day)]
 752        ["Set in a Month" (org-mouse-timestamp-today 1 'month)]
 753        "--"
 754        ["+ 1 Day" (org-timestamp-change 1 'day)]
 755        ["+ 1 Week" (org-timestamp-change 7 'day)]
 756        ["+ 1 Month" (org-timestamp-change 1 'month)]
 757        "--"
 758        ["- 1 Day" (org-timestamp-change -1 'day)]
 759        ["- 1 Week" (org-timestamp-change -7 'day)]
 760        ["- 1 Month" (org-timestamp-change -1 'month)])))
 761    ((get-context :table-special)
 762     (let ((mdata (match-data)))
 763       (incf (car mdata) 2)
 764       (store-match-data mdata))
 765     (message "match: %S" (match-string 0))
 766     (popup-menu `(nil ,@(org-mouse-keyword-replace-menu
 767                          '(" " "!" "^" "_" "$" "#" "*" "'") 0
 768                          (lambda (mark)
 769                            (case (string-to-char mark)
 770                              (?  "( ) Nothing Special")
 771                              (?! "(!) Column Names")
 772                              (?^ "(^) Field Names Above")
 773                              (?_ "(^) Field Names Below")
 774                              (?$ "($) Formula Parameters")
 775                              (?# "(#) Recalculation: Auto")
 776                              (?* "(*) Recalculation: Manual")
 777                              (?' "(') Recalculation: None"))) t))))
 778    ((assq :table contextlist)
 779     (popup-menu
 780      '(nil
 781        ["Align Table" org-ctrl-c-ctrl-c]
 782        ["Blank Field" org-table-blank-field]
 783        ["Edit Field" org-table-edit-field]
 784         "--"
 785         ("Column"
 786          ["Move Column Left" org-metaleft]
 787          ["Move Column Right" org-metaright]
 788          ["Delete Column" org-shiftmetaleft]
 789          ["Insert Column" org-shiftmetaright]
 790          "--"
 791          ["Enable Narrowing" (setq org-table-limit-column-width (not org-table-limit-column-width)) :selected org-table-limit-column-width :style toggle])
 792         ("Row"
 793          ["Move Row Up" org-metaup]
 794          ["Move Row Down" org-metadown]
 795          ["Delete Row" org-shiftmetaup]
 796          ["Insert Row" org-shiftmetadown]
 797          ["Sort lines in region" org-table-sort-lines (org-at-table-p)]
 798          "--"
 799          ["Insert Hline" org-table-insert-hline])
 800         ("Rectangle"
 801          ["Copy Rectangle" org-copy-special]
 802          ["Cut Rectangle" org-cut-special]
 803          ["Paste Rectangle" org-paste-special]
 804          ["Fill Rectangle" org-table-wrap-region])
 805         "--"
 806         ["Set Column Formula" org-table-eval-formula]
 807         ["Set Field Formula" (org-table-eval-formula '(4))]
 808         ["Edit Formulas" org-table-edit-formulas]
 809         "--"
 810         ["Recalculate Line" org-table-recalculate]
 811         ["Recalculate All" (org-table-recalculate '(4))]
 812         ["Iterate All" (org-table-recalculate '(16))]
 813         "--"
 814         ["Toggle Recalculate Mark" org-table-rotate-recalc-marks]
 815         ["Sum Column/Rectangle" org-table-sum
 816          :active (or (org-at-table-p) (org-region-active-p))]
 817         ["Field Info" org-table-field-info]
 818         ["Debug Formulas"
 819          (setq org-table-formula-debug (not org-table-formula-debug))
 820          :style toggle :selected org-table-formula-debug]
 821         )))
 822    ((and (assq :headline contextlist) (not (eolp)))
 823     (let ((priority (org-mouse-get-priority t)))
 824       (popup-menu
 825        `("Headline Menu"
 826          ("Tags and Priorities"
 827           ,@(org-mouse-keyword-menu
 828              (org-mouse-priority-list)
 829              #'(lambda (keyword)
 830                 (org-mouse-set-priority (string-to-char keyword)))
 831              priority "Priority %s")
 832           "--"
 833           ,@(org-mouse-tag-menu))
 834          ("TODO Status"
 835           ,@(org-mouse-todo-menu (org-get-todo-state)))
 836          ["Show Tags"
 837           (with-current-buffer org-mouse-main-buffer (org-agenda-show-tags))
 838           :visible (not org-mouse-direct)]
 839          ["Show Priority"
 840           (with-current-buffer org-mouse-main-buffer (org-agenda-show-priority))
 841           :visible (not org-mouse-direct)]
 842          ,@(if org-mouse-direct '("--") nil)
 843          ["New Heading" org-mouse-insert-heading :visible org-mouse-direct]
 844          ["Set Deadline"
 845           (progn (org-mouse-end-headline) (insert " ") (org-deadline))
 846           :active (not (save-excursion
 847                          (org-mouse-re-search-line org-deadline-regexp)))]
 848          ["Schedule Task"
 849           (progn (org-mouse-end-headline) (insert " ") (org-schedule))
 850           :active (not (save-excursion
 851                          (org-mouse-re-search-line org-scheduled-regexp)))]
 852          ["Insert Timestamp"
 853           (progn (org-mouse-end-headline) (insert " ") (org-time-stamp nil)) t]
 854 ;        ["Timestamp (inactive)" org-time-stamp-inactive t]
 855          "--"
 856          ["Archive Subtree" org-archive-subtree]
 857          ["Cut Subtree"  org-cut-special]
 858          ["Copy Subtree"  org-copy-special]
 859          ["Paste Subtree"  org-paste-special :visible org-mouse-direct]
 860          ("Sort Children"
 861           ["Alphabetically" (org-sort-entries nil ?a)]
 862           ["Numerically" (org-sort-entries nil ?n)]
 863           ["By Time/Date" (org-sort-entries nil ?t)]
 864           "--"
 865           ["Reverse Alphabetically" (org-sort-entries nil ?A)]
 866           ["Reverse Numerically" (org-sort-entries nil ?N)]
 867           ["Reverse By Time/Date" (org-sort-entries nil ?T)])
 868          "--"
 869          ["Move Trees" org-mouse-move-tree :active nil]
 870          ))))
 871    (t
 872     (org-mouse-popup-global-menu))))))
 873
 874 ;; (defun org-mouse-at-regexp (regexp)
 875 ;;   (save-excursion
 876 ;;     (let ((point (point))
 877 ;;        (bol (progn (beginning-of-line) (point)))
 878 ;;        (eol (progn (end-of-line) (point))))
 879 ;;       (goto-char point)
 880 ;;       (re-search-backward regexp bol 1)
 881 ;;       (and (not (eolp))
 882 ;;         (progn (forward-char)
 883 ;;                (re-search-forward regexp eol t))
 884 ;;         (<= (match-beginning 0) point)))))
 885
 886 (defun org-mouse-mark-active ()
 887   (and mark-active transient-mark-mode))
 888
 889 (defun org-mouse-in-region-p (pos)
 890   (and (org-mouse-mark-active)
 891        (>= pos (region-beginning))
 892        (<  pos (region-end))))
 893
 894 (defun org-mouse-down-mouse (event)
 895   (interactive "e")
 896   (setq this-command last-command)
 897   (unless (and (= 1 (event-click-count event))
 898                (org-mouse-in-region-p (posn-point (event-start event))))
 899     (mouse-drag-region event)))
 900
 901 (add-hook 'org-mode-hook
 902   #'(lambda ()
 903      (setq org-mouse-context-menu-function 'org-mouse-context-menu)
 904
 905      (when (memq 'context-menu org-mouse-features)
 906        (org-defkey org-mouse-map [mouse-3] nil)
 907        (org-defkey org-mode-map [mouse-3] 'org-mouse-show-context-menu))
 908      (org-defkey org-mode-map [down-mouse-1] 'org-mouse-down-mouse)
 909      (when (memq 'context-menu org-mouse-features)
 910        (org-defkey org-mouse-map [C-drag-mouse-1] 'org-mouse-move-tree)
 911        (org-defkey org-mouse-map [C-down-mouse-1] 'org-mouse-move-tree-start))
 912      (when (memq 'yank-link org-mouse-features)
 913        (org-defkey org-mode-map [S-mouse-2] 'org-mouse-yank-link)
 914        (org-defkey org-mode-map [drag-mouse-3] 'org-mouse-yank-link))
 915      (when (memq 'move-tree org-mouse-features)
 916        (org-defkey org-mouse-map [drag-mouse-3] 'org-mouse-move-tree)
 917        (org-defkey org-mouse-map [down-mouse-3] 'org-mouse-move-tree-start))
 918
 919      (when (memq 'activate-stars org-mouse-features)
 920        (font-lock-add-keywords
 921         nil
 922         `((,org-outline-regexp
 923            0 `(face org-link mouse-face highlight keymap ,org-mouse-map)
 924            'prepend))
 925         t))
 926
 927      (when (memq 'activate-bullets org-mouse-features)
 928        (font-lock-add-keywords
 929         nil
 930         `(("^[ \t]*\\([-+*]\\|[0-9]+[.)]\\) +"
 931            (1 `(face org-link keymap ,org-mouse-map mouse-face highlight)
 932               'prepend)))
 933         t))
 934
 935      (when (memq 'activate-checkboxes org-mouse-features)
 936        (font-lock-add-keywords
 937         nil
 938         `(("^[ \t]*\\([-+*]\\|[0-9]+[.)]\\) +\\(\\[[ X]\\]\\)"
 939            (2 `(face bold keymap ,org-mouse-map mouse-face highlight) t)))
 940         t))
 941
 942      (defadvice org-open-at-point (around org-mouse-open-at-point activate)
 943        (let ((context (org-context)))
 944          (cond
 945           ((assq :headline-stars context) (org-cycle))
 946           ((assq :checkbox context) (org-toggle-checkbox))
 947           ((assq :item-bullet context)
 948            (let ((org-cycle-include-plain-lists t)) (org-cycle)))
 949           (t ad-do-it))))))
 950
 951 (defun org-mouse-move-tree-start (event)
 952   (interactive "e")
 953   (message "Same line: promote/demote, (***):move before, (text): make a child"))
 954
 955
 956 (defun org-mouse-make-marker (position)
 957   (with-current-buffer (window-buffer (posn-window position))
 958     (copy-marker (posn-point position))))
 959
 960 (defun org-mouse-move-tree (event)
 961   ;; todo: handle movements between different buffers
 962   (interactive "e")
 963   (save-excursion
 964     (let* ((start (org-mouse-make-marker (event-start event)))
 965            (end (org-mouse-make-marker (event-end event)))
 966            (sbuf (marker-buffer start))
 967            (ebuf (marker-buffer end)))
 968
 969      (when (and sbuf ebuf)
 970       (set-buffer sbuf)
 971       (goto-char start)
 972       (org-back-to-heading)
 973       (if (and (eq sbuf ebuf)
 974                (equal
 975                 (point)
 976                 (save-excursion (goto-char end) (org-back-to-heading) (point))))
 977         ;; if the same line then promote/demote
 978         (if (>= end start) (org-demote-subtree) (org-promote-subtree))
 979       ;; if different lines then move
 980       (org-cut-subtree)
 981
 982       (set-buffer ebuf)
 983       (goto-char end)
 984       (org-back-to-heading)
 985       (when  (and (eq sbuf ebuf)
 986                   (equal
 987                    (point)
 988                    (save-excursion (goto-char start)
 989                                    (org-back-to-heading) (point))))
 990         (outline-end-of-subtree)
 991         (end-of-line)
 992         (if (eobp) (newline) (forward-char)))
 993
 994       (when (looking-at org-outline-regexp)
 995         (let ((level (- (match-end 0) (match-beginning 0))))
 996           (when (> end (match-end 0))
 997             (outline-end-of-subtree)
 998             (end-of-line)
 999             (if (eobp) (newline) (forward-char))
1000             (setq level (1+ level)))
1001           (org-paste-subtree level)
1002           (save-excursion
1003             (outline-end-of-subtree)
1004             (when (bolp) (delete-char -1))))))))))
1005
1006
1007 (defun org-mouse-transform-to-outline ()
1008   (interactive)
1009   (org-back-to-heading)
1010   (let ((minlevel 1000)
1011         (replace-text (concat (match-string 0) "* ")))
1012     (beginning-of-line 2)
1013     (save-excursion
1014       (while (not (or (eobp) (looking-at org-outline-regexp)))
1015         (when (looking-at org-mouse-plain-list-regexp)
1016           (setq minlevel (min minlevel (- (match-end 1) (match-beginning 1)))))
1017         (forward-line)))
1018     (while (not (or (eobp) (looking-at org-outline-regexp)))
1019       (when (and (looking-at org-mouse-plain-list-regexp)
1020                  (eq minlevel (- (match-end 1) (match-beginning 1))))
1021         (replace-match replace-text))
1022       (forward-line))))
1023
1024 (defvar _cmd) ;dynamically scoped from `org-with-remote-undo'.
1025
1026 (defun org-mouse-do-remotely (command)
1027 ;  (org-agenda-check-no-diary)
1028   (when (get-text-property (point) 'org-marker)
1029     (let* ((anticol (- (point-at-eol) (point)))
1030            (marker (get-text-property (point) 'org-marker))
1031            (buffer (marker-buffer marker))
1032            (pos (marker-position marker))
1033            (hdmarker (get-text-property (point) 'org-hd-marker))
1034            (buffer-read-only nil)
1035            (newhead "--- removed ---")
1036            (org-mouse-direct nil)
1037            (org-mouse-main-buffer (current-buffer)))
1038       (when (eq (with-current-buffer buffer major-mode) 'org-mode)
1039         (let ((endmarker (with-current-buffer buffer
1040                            (outline-end-of-subtree)
1041                            (forward-char 1)
1042                            (copy-marker (point)))))
1043           (org-with-remote-undo buffer
1044             (with-current-buffer buffer
1045               (widen)
1046               (goto-char pos)
1047               (org-show-hidden-entry)
1048               (save-excursion
1049                 (and (outline-next-heading)
1050                      (org-flag-heading nil)))   ; show the next heading
1051               (org-back-to-heading)
1052               (setq marker (copy-marker (point)))
1053               (goto-char (max (point-at-bol) (- (point-at-eol) anticol)))
1054               (funcall command)
1055               (message "_cmd: %S" _cmd)
1056               (message "this-command: %S" this-command)
1057               (unless (eq (marker-position marker) (marker-position endmarker))
1058                 (setq newhead (org-get-heading))))
1059
1060             (beginning-of-line 1)
1061             (save-excursion
1062               (org-agenda-change-all-lines newhead hdmarker 'fixface))))
1063         t))))
1064
1065 (defun org-mouse-agenda-context-menu (&optional event)
1066   (or (org-mouse-do-remotely 'org-mouse-context-menu)
1067       (popup-menu
1068        '("Agenda"
1069          ("Agenda Files")
1070          "--"
1071          ["Undo" (progn (message "last command: %S" last-command) (setq this-command 'org-agenda-undo) (org-agenda-undo))
1072           :visible (if (eq last-command 'org-agenda-undo)
1073                        org-agenda-pending-undo-list
1074                      org-agenda-undo-list)]
1075          ["Rebuild Buffer" org-agenda-redo t]
1076          ["New Diary Entry"
1077           org-agenda-diary-entry (org-agenda-check-type nil 'agenda 'timeline) t]
1078          "--"
1079          ["Goto Today" org-agenda-goto-today
1080           (org-agenda-check-type nil 'agenda 'timeline) t]
1081          ["Display Calendar" org-agenda-goto-calendar
1082           (org-agenda-check-type nil 'agenda 'timeline) t]
1083          ("Calendar Commands"
1084           ["Phases of the Moon" org-agenda-phases-of-moon
1085            (org-agenda-check-type nil 'agenda 'timeline)]
1086           ["Sunrise/Sunset" org-agenda-sunrise-sunset
1087            (org-agenda-check-type nil 'agenda 'timeline)]
1088           ["Holidays" org-agenda-holidays
1089            (org-agenda-check-type nil 'agenda 'timeline)]
1090           ["Convert" org-agenda-convert-date
1091            (org-agenda-check-type nil 'agenda 'timeline)]
1092           "--"
1093           ["Create iCalendar file" org-export-icalendar-combine-agenda-files t])
1094          "--"
1095          ["Day View" org-agenda-day-view
1096           :active (org-agenda-check-type nil 'agenda)
1097           :style radio :selected (eq org-agenda-current-span 'day)]
1098          ["Week View" org-agenda-week-view
1099           :active (org-agenda-check-type nil 'agenda)
1100           :style radio :selected (eq org-agenda-current-span 'week)]
1101          "--"
1102          ["Show Logbook entries" org-agenda-log-mode
1103           :style toggle :selected org-agenda-show-log
1104           :active (org-agenda-check-type nil 'agenda 'timeline)]
1105          ["Include Diary" org-agenda-toggle-diary
1106           :style toggle :selected org-agenda-include-diary
1107           :active (org-agenda-check-type nil 'agenda)]
1108          ["Use Time Grid" org-agenda-toggle-time-grid
1109           :style toggle :selected org-agenda-use-time-grid
1110           :active (org-agenda-check-type nil 'agenda)]
1111          ["Follow Mode" org-agenda-follow-mode
1112           :style toggle :selected org-agenda-follow-mode]
1113          "--"
1114          ["Quit" org-agenda-quit t]
1115          ["Exit and Release Buffers" org-agenda-exit t]
1116          ))))
1117
1118 (defun org-mouse-get-gesture (event)
1119   (let ((startxy (posn-x-y (event-start event)))
1120         (endxy (posn-x-y (event-end event))))
1121     (if (< (car startxy) (car endxy)) :right :left)))
1122
1123
1124 ; (setq org-agenda-mode-hook nil)
1125 (defvar org-agenda-mode-map)
1126 (add-hook 'org-agenda-mode-hook
1127    #'(lambda ()
1128      (setq org-mouse-context-menu-function 'org-mouse-agenda-context-menu)
1129      (org-defkey org-agenda-mode-map [mouse-3] 'org-mouse-show-context-menu)
1130      (org-defkey org-agenda-mode-map [down-mouse-3] 'org-mouse-move-tree-start)
1131      (org-defkey org-agenda-mode-map [C-mouse-4] 'org-agenda-earlier)
1132      (org-defkey org-agenda-mode-map [C-mouse-5] 'org-agenda-later)
1133      (org-defkey org-agenda-mode-map [drag-mouse-3]
1134        #'(lambda (event) (interactive "e")
1135           (case (org-mouse-get-gesture event)
1136             (:left (org-agenda-earlier 1))
1137             (:right (org-agenda-later 1)))))))
1138
1139 (provide 'org-mouse)
1140
1141 ;;; org-mouse.el ends here