lisp/ox-md.el

   1 ;;; ox-md.el --- Markdown Back-End for Org Export Engine
   2
   3 ;; Copyright (C) 2012-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Nicolas Goaziou <n.goaziou@gmail.com>
   6 ;; Keywords: org, wp, markdown
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This library implements a Markdown back-end (vanilla flavor) for
  26 ;; Org exporter, based on `html' back-end.  See Org manual for more
  27 ;; information.
  28
  29 ;;; Code:
  30
  31 (eval-when-compile (require 'cl))
  32 (require 'ox-html)
  33 (require 'ox-publish)
  34
  35 \f
  36 ;;; User-Configurable Variables
  37
  38 (defgroup org-export-md nil
  39   "Options specific to Markdown export back-end."
  40   :tag "Org Markdown"
  41   :group 'org-export
  42   :version "24.4"
  43   :package-version '(Org . "8.0"))
  44
  45 (defcustom org-md-headline-style 'atx
  46   "Style used to format headlines.
  47 This variable can be set to either `atx' or `setext'."
  48   :group 'org-export-md
  49   :type '(choice
  50           (const :tag "Use \"atx\" style" atx)
  51           (const :tag "Use \"Setext\" style" setext)))
  52
  53
  54 \f
  55 ;;; Define Back-End
  56
  57 (org-export-define-derived-backend 'md 'html
  58   :export-block '("MD" "MARKDOWN")
  59   :filters-alist '((:filter-parse-tree . org-md-separate-elements))
  60   :menu-entry
  61   '(?m "Export to Markdown"
  62        ((?M "To temporary buffer"
  63             (lambda (a s v b) (org-md-export-as-markdown a s v)))
  64         (?m "To file" (lambda (a s v b) (org-md-export-to-markdown a s v)))
  65         (?o "To file and open"
  66             (lambda (a s v b)
  67               (if a (org-md-export-to-markdown t s v)
  68                 (org-open-file (org-md-export-to-markdown nil s v)))))))
  69   :translate-alist '((bold . org-md-bold)
  70                      (code . org-md-verbatim)
  71                      (comment . (lambda (&rest args) ""))
  72                      (comment-block . (lambda (&rest args) ""))
  73                      (example-block . org-md-example-block)
  74                      (export-block . org-md-export-block)
  75                      (fixed-width . org-md-example-block)
  76                      (footnote-definition . ignore)
  77                      (footnote-reference . ignore)
  78                      (headline . org-md-headline)
  79                      (horizontal-rule . org-md-horizontal-rule)
  80                      (inline-src-block . org-md-verbatim)
  81                      (inner-template . org-md-inner-template)
  82                      (italic . org-md-italic)
  83                      (item . org-md-item)
  84                      (keyword . org-md-keyword)
  85                      (line-break . org-md-line-break)
  86                      (link . org-md-link)
  87                      (node-property . org-md-node-property)
  88                      (paragraph . org-md-paragraph)
  89                      (plain-list . org-md-plain-list)
  90                      (plain-text . org-md-plain-text)
  91                      (property-drawer . org-md-property-drawer)
  92                      (quote-block . org-md-quote-block)
  93                      (section . org-md-section)
  94                      (src-block . org-md-example-block)
  95                      (template . org-md-template)
  96                      (verbatim . org-md-verbatim))
  97   :options-alist '((:md-headline-style nil nil org-md-headline-style)))
  98
  99 \f
 100 ;;; Filters
 101
 102 (defun org-md-separate-elements (tree backend info)
 103   "Fix blank lines between elements.
 104
 105 TREE is the parse tree being exported.  BACKEND is the export
 106 back-end used.  INFO is a plist used as a communication channel.
 107
 108 Make sure there's no blank line before a plain list, unless it is
 109 located right after a paragraph.  Otherwise, add a blank line
 110 between elements.  Blank lines between items are preserved.
 111
 112 Assume BACKEND is `md'."
 113   (org-element-map tree (remq 'item org-element-all-elements)
 114     (lambda (elem)
 115       (org-element-put-property
 116        elem :post-blank
 117        (if (and (eq (org-element-type (org-export-get-next-element elem info))
 118                     'plain-list)
 119                 (not (and (eq (org-element-type elem) 'paragraph)
 120                           (org-export-get-previous-element elem info))))
 121            0
 122          1))))
 123   ;; Return updated tree.
 124   tree)
 125
 126
 127 \f
 128 ;;; Transcode Functions
 129
 130 ;;;; Bold
 131
 132 (defun org-md-bold (bold contents info)
 133   "Transcode BOLD object into Markdown format.
 134 CONTENTS is the text within bold markup.  INFO is a plist used as
 135 a communication channel."
 136   (format "**%s**" contents))
 137
 138
 139 ;;;; Code and Verbatim
 140
 141 (defun org-md-verbatim (verbatim contents info)
 142   "Transcode VERBATIM object into Markdown format.
 143 CONTENTS is nil.  INFO is a plist used as a communication
 144 channel."
 145   (let ((value (org-element-property :value verbatim)))
 146     (format (cond ((not (string-match "`" value)) "`%s`")
 147                   ((or (string-match "\\``" value)
 148                        (string-match "`\\'" value))
 149                    "`` %s ``")
 150                   (t "``%s``"))
 151             value)))
 152
 153
 154 ;;;; Example Block, Src Block and export Block
 155
 156 (defun org-md-example-block (example-block contents info)
 157   "Transcode EXAMPLE-BLOCK element into Markdown format.
 158 CONTENTS is nil.  INFO is a plist used as a communication
 159 channel."
 160   (replace-regexp-in-string
 161    "^" "    "
 162    (org-remove-indentation
 163     (org-export-format-code-default example-block info))))
 164
 165 (defun org-md-export-block (export-block contents info)
 166   "Transcode a EXPORT-BLOCK element from Org to Markdown.
 167 CONTENTS is nil.  INFO is a plist holding contextual information."
 168   (if (member (org-element-property :type export-block) '("MARKDOWN" "MD"))
 169       (org-remove-indentation (org-element-property :value export-block))
 170     ;; Also include HTML export blocks.
 171     (org-export-with-backend 'html export-block contents info)))
 172
 173
 174 ;;;; Headline
 175
 176 (defun org-md-headline (headline contents info)
 177   "Transcode HEADLINE element into Markdown format.
 178 CONTENTS is the headline contents.  INFO is a plist used as
 179 a communication channel."
 180   (unless (org-element-property :footnote-section-p headline)
 181     (let* ((level (org-export-get-relative-level headline info))
 182            (title (org-export-data (org-element-property :title headline) info))
 183            (todo (and (plist-get info :with-todo-keywords)
 184                       (let ((todo (org-element-property :todo-keyword
 185                                                         headline)))
 186                         (and todo (concat (org-export-data todo info) " ")))))
 187            (tags (and (plist-get info :with-tags)
 188                       (let ((tag-list (org-export-get-tags headline info)))
 189                         (and tag-list
 190                              (format "     :%s:"
 191                                      (mapconcat 'identity tag-list ":"))))))
 192            (priority
 193             (and (plist-get info :with-priority)
 194                  (let ((char (org-element-property :priority headline)))
 195                    (and char (format "[#%c] " char)))))
 196            (anchor
 197             (when (plist-get info :with-toc)
 198               (org-html--anchor
 199                (or (org-element-property :CUSTOM_ID headline)
 200                    (concat "sec-"
 201                            (mapconcat 'number-to-string
 202                                       (org-export-get-headline-number
 203                                        headline info) "-"))))))
 204            ;; Headline text without tags.
 205            (heading (concat todo priority title)))
 206       (cond
 207        ;; Cannot create a headline.  Fall-back to a list.
 208        ((or (org-export-low-level-p headline info)
 209             (not (memq org-md-headline-style '(atx setext)))
 210             (and (eq org-md-headline-style 'atx) (> level 6))
 211             (and (eq org-md-headline-style 'setext) (> level 2)))
 212         (let ((bullet
 213                (if (not (org-export-numbered-headline-p headline info)) "-"
 214                  (concat (number-to-string
 215                           (car (last (org-export-get-headline-number
 216                                       headline info))))
 217                          "."))))
 218           (concat bullet (make-string (- 4 (length bullet)) ? ) heading tags
 219                   "\n\n"
 220                   (and contents
 221                        (replace-regexp-in-string "^" "    " contents)))))
 222        ;; Use "Setext" style.
 223        ((eq org-md-headline-style 'setext)
 224         (concat heading tags anchor "\n"
 225                 (make-string (length heading) (if (= level 1) ?= ?-))
 226                 "\n\n"
 227                 contents))
 228        ;; Use "atx" style.
 229        (t (concat (make-string level ?#) " " heading tags anchor "\n\n" contents))))))
 230
 231
 232 ;;;; Horizontal Rule
 233
 234 (defun org-md-horizontal-rule (horizontal-rule contents info)
 235   "Transcode HORIZONTAL-RULE element into Markdown format.
 236 CONTENTS is the horizontal rule contents.  INFO is a plist used
 237 as a communication channel."
 238   "---")
 239
 240
 241 ;;;; Italic
 242
 243 (defun org-md-italic (italic contents info)
 244   "Transcode ITALIC object into Markdown format.
 245 CONTENTS is the text within italic markup.  INFO is a plist used
 246 as a communication channel."
 247   (format "*%s*" contents))
 248
 249
 250 ;;;; Item
 251
 252 (defun org-md-item (item contents info)
 253   "Transcode ITEM element into Markdown format.
 254 CONTENTS is the item contents.  INFO is a plist used as
 255 a communication channel."
 256   (let* ((type (org-element-property :type (org-export-get-parent item)))
 257          (struct (org-element-property :structure item))
 258          (bullet (if (not (eq type 'ordered)) "-"
 259                    (concat (number-to-string
 260                             (car (last (org-list-get-item-number
 261                                         (org-element-property :begin item)
 262                                         struct
 263                                         (org-list-prevs-alist struct)
 264                                         (org-list-parents-alist struct)))))
 265                            "."))))
 266     (concat bullet
 267             (make-string (- 4 (length bullet)) ? )
 268             (case (org-element-property :checkbox item)
 269               (on "[X] ")
 270               (trans "[-] ")
 271               (off "[ ] "))
 272             (let ((tag (org-element-property :tag item)))
 273               (and tag (format "**%s:** "(org-export-data tag info))))
 274             (and contents
 275                  (org-trim (replace-regexp-in-string "^" "    " contents))))))
 276
 277
 278
 279 ;;;; Keyword
 280
 281 (defun org-md-keyword (keyword contents info)
 282   "Transcode a KEYWORD element into Markdown format.
 283 CONTENTS is nil.  INFO is a plist used as a communication
 284 channel."
 285   (if (member (org-element-property :key keyword) '("MARKDOWN" "MD"))
 286       (org-element-property :value keyword)
 287     (org-export-with-backend 'html keyword contents info)))
 288
 289
 290 ;;;; Line Break
 291
 292 (defun org-md-line-break (line-break contents info)
 293   "Transcode LINE-BREAK object into Markdown format.
 294 CONTENTS is nil.  INFO is a plist used as a communication
 295 channel."
 296   "  \n")
 297
 298
 299 ;;;; Link
 300
 301 (defun org-md-link (link contents info)
 302   "Transcode LINE-BREAK object into Markdown format.
 303 CONTENTS is the link's description.  INFO is a plist used as
 304 a communication channel."
 305   (let ((link-org-files-as-md
 306          (function
 307           (lambda (raw-path)
 308             ;; Treat links to `file.org' as links to `file.md'.
 309             (if (string= ".org" (downcase (file-name-extension raw-path ".")))
 310                 (concat (file-name-sans-extension raw-path) ".md")
 311               raw-path))))
 312         (type (org-element-property :type link)))
 313     (cond ((member type '("custom-id" "id"))
 314            (let ((destination (org-export-resolve-id-link link info)))
 315              (if (stringp destination)  ; External file.
 316                  (let ((path (funcall link-org-files-as-md destination)))
 317                    (if (not contents) (format "<%s>" path)
 318                      (format "[%s](%s)" contents path)))
 319                (concat
 320                 (and contents (concat contents " "))
 321                 (format "(%s)"
 322                         (format (org-export-translate "See section %s" :html info)
 323                                 (mapconcat 'number-to-string
 324                                            (org-export-get-headline-number
 325                                             destination info)
 326                                            ".")))))))
 327           ((org-export-inline-image-p link org-html-inline-image-rules)
 328            (let ((path (let ((raw-path (org-element-property :path link)))
 329                          (if (not (file-name-absolute-p raw-path)) raw-path
 330                            (expand-file-name raw-path))))
 331                  (caption (org-export-data
 332                            (org-export-get-caption
 333                             (org-export-get-parent-element link)) info)))
 334              (format "![img](%s)"
 335                      (if (not (org-string-nw-p caption)) path
 336                        (format "%s \"%s\"" path caption)))))
 337           ((string= type "coderef")
 338            (let ((ref (org-element-property :path link)))
 339              (format (org-export-get-coderef-format ref contents)
 340                      (org-export-resolve-coderef ref info))))
 341           ((equal type "radio") contents)
 342           ((equal type "fuzzy")
 343            (let ((destination (org-export-resolve-fuzzy-link link info)))
 344              (if (org-string-nw-p contents) contents
 345                (when destination
 346                  (let ((number (org-export-get-ordinal destination info)))
 347                    (when number
 348                      (if (atom number) (number-to-string number)
 349                        (mapconcat 'number-to-string number "."))))))))
 350           (t (let* ((raw-path (org-element-property :path link))
 351                     (path
 352                      (cond
 353                       ((member type '("http" "https" "ftp"))
 354                        (concat type ":" raw-path))
 355                       ((string= type "file")
 356                        (let ((path (funcall link-org-files-as-md raw-path)))
 357                          (if (not (file-name-absolute-p path)) path
 358                            ;; If file path is absolute, prepend it
 359                            ;; with "file:" component.
 360                            (concat "file:" path))))
 361                       (t raw-path))))
 362                (if (not contents) (format "<%s>" path)
 363                  (format "[%s](%s)" contents path)))))))
 364
 365
 366 ;;;; Node Property
 367
 368 (defun org-md-node-property (node-property contents info)
 369   "Transcode a NODE-PROPERTY element into Markdown syntax.
 370 CONTENTS is nil.  INFO is a plist holding contextual
 371 information."
 372   (format "%s:%s"
 373           (org-element-property :key node-property)
 374           (let ((value (org-element-property :value node-property)))
 375             (if value (concat " " value) ""))))
 376
 377
 378 ;;;; Paragraph
 379
 380 (defun org-md-paragraph (paragraph contents info)
 381   "Transcode PARAGRAPH element into Markdown format.
 382 CONTENTS is the paragraph contents.  INFO is a plist used as
 383 a communication channel."
 384   (let ((first-object (car (org-element-contents paragraph))))
 385     ;; If paragraph starts with a #, protect it.
 386     (if (and (stringp first-object) (string-match "\\`#" first-object))
 387         (replace-regexp-in-string "\\`#" "\\#" contents nil t)
 388       contents)))
 389
 390
 391 ;;;; Plain List
 392
 393 (defun org-md-plain-list (plain-list contents info)
 394   "Transcode PLAIN-LIST element into Markdown format.
 395 CONTENTS is the plain-list contents.  INFO is a plist used as
 396 a communication channel."
 397   contents)
 398
 399
 400 ;;;; Plain Text
 401
 402 (defun org-md-plain-text (text info)
 403   "Transcode a TEXT string into Markdown format.
 404 TEXT is the string to transcode.  INFO is a plist holding
 405 contextual information."
 406   (when (plist-get info :with-smart-quotes)
 407     (setq text (org-export-activate-smart-quotes text :html info)))
 408   ;; Protect ambiguous #.  This will protect # at the beginning of
 409   ;; a line, but not at the beginning of a paragraph.  See
 410   ;; `org-md-paragraph'.
 411   (setq text (replace-regexp-in-string "\n#" "\n\\\\#" text))
 412   ;; Protect ambiguous !
 413   (setq text (replace-regexp-in-string "\\(!\\)\\[" "\\\\!" text nil nil 1))
 414   ;; Protect `, *, _ and \
 415   (setq text (replace-regexp-in-string "[`*_\\]" "\\\\\\&" text))
 416   ;; Handle special strings, if required.
 417   (when (plist-get info :with-special-strings)
 418     (setq text (org-html-convert-special-strings text)))
 419   ;; Handle break preservation, if required.
 420   (when (plist-get info :preserve-breaks)
 421     (setq text (replace-regexp-in-string "[ \t]*\n" "  \n" text)))
 422   ;; Return value.
 423   text)
 424
 425
 426 ;;;; Property Drawer
 427
 428 (defun org-md-property-drawer (property-drawer contents info)
 429   "Transcode a PROPERTY-DRAWER element into Markdown format.
 430 CONTENTS holds the contents of the drawer.  INFO is a plist
 431 holding contextual information."
 432   (and (org-string-nw-p contents)
 433        (replace-regexp-in-string "^" "    " contents)))
 434
 435
 436 ;;;; Quote Block
 437
 438 (defun org-md-quote-block (quote-block contents info)
 439   "Transcode QUOTE-BLOCK element into Markdown format.
 440 CONTENTS is the quote-block contents.  INFO is a plist used as
 441 a communication channel."
 442   (replace-regexp-in-string
 443    "^" "> "
 444    (replace-regexp-in-string "\n\\'" "" contents)))
 445
 446
 447 ;;;; Section
 448
 449 (defun org-md-section (section contents info)
 450   "Transcode SECTION element into Markdown format.
 451 CONTENTS is the section contents.  INFO is a plist used as
 452 a communication channel."
 453   contents)
 454
 455
 456 ;;;; Template
 457
 458 (defun org-md-inner-template (contents info)
 459   "Return body of document after converting it to Markdown syntax.
 460 CONTENTS is the transcoded contents string.  INFO is a plist
 461 holding export options."
 462   ;; Make sure CONTENTS is separated from table of contents and
 463   ;; footnotes with at least a blank line.
 464   (org-trim (org-html-inner-template (concat "\n" contents "\n") info)))
 465
 466 (defun org-md-template (contents info)
 467   "Return complete document string after Markdown conversion.
 468 CONTENTS is the transcoded contents string.  INFO is a plist used
 469 as a communication channel."
 470   contents)
 471
 472
 473 \f
 474 ;;; Interactive function
 475
 476 ;;;###autoload
 477 (defun org-md-export-as-markdown (&optional async subtreep visible-only)
 478   "Export current buffer to a Markdown buffer.
 479
 480 If narrowing is active in the current buffer, only export its
 481 narrowed part.
 482
 483 If a region is active, export that region.
 484
 485 A non-nil optional argument ASYNC means the process should happen
 486 asynchronously.  The resulting buffer should be accessible
 487 through the `org-export-stack' interface.
 488
 489 When optional argument SUBTREEP is non-nil, export the sub-tree
 490 at point, extracting information from the headline properties
 491 first.
 492
 493 When optional argument VISIBLE-ONLY is non-nil, don't export
 494 contents of hidden elements.
 495
 496 Export is done in a buffer named \"*Org MD Export*\", which will
 497 be displayed when `org-export-show-temporary-export-buffer' is
 498 non-nil."
 499   (interactive)
 500   (org-export-to-buffer 'md "*Org MD Export*"
 501     async subtreep visible-only nil nil (lambda () (text-mode))))
 502
 503 ;;;###autoload
 504 (defun org-md-convert-region-to-md ()
 505   "Assume the current region has org-mode syntax, and convert it to Markdown.
 506 This can be used in any buffer.  For example, you can write an
 507 itemized list in org-mode syntax in a Markdown buffer and use
 508 this command to convert it."
 509   (interactive)
 510   (org-export-replace-region-by 'md))
 511
 512
 513 ;;;###autoload
 514 (defun org-md-export-to-markdown (&optional async subtreep visible-only)
 515   "Export current buffer to a Markdown file.
 516
 517 If narrowing is active in the current buffer, only export its
 518 narrowed part.
 519
 520 If a region is active, export that region.
 521
 522 A non-nil optional argument ASYNC means the process should happen
 523 asynchronously.  The resulting file should be accessible through
 524 the `org-export-stack' interface.
 525
 526 When optional argument SUBTREEP is non-nil, export the sub-tree
 527 at point, extracting information from the headline properties
 528 first.
 529
 530 When optional argument VISIBLE-ONLY is non-nil, don't export
 531 contents of hidden elements.
 532
 533 Return output file's name."
 534   (interactive)
 535   (let ((outfile (org-export-output-file-name ".md" subtreep)))
 536     (org-export-to-file 'md outfile async subtreep visible-only)))
 537
 538 ;;;###autoload
 539 (defun org-md-publish-to-md (plist filename pub-dir)
 540   "Publish an org file to Markdown.
 541
 542 FILENAME is the filename of the Org file to be published.  PLIST
 543 is the property list for the given project.  PUB-DIR is the
 544 publishing directory.
 545
 546 Return output file name."
 547   (org-publish-org-to 'md filename ".md" plist pub-dir))
 548
 549 (provide 'ox-md)
 550
 551 ;; Local variables:
 552 ;; generated-autoload-file: "org-loaddefs.el"
 553 ;; End:
 554
 555 ;;; ox-md.el ends here