lisp/org-w3m.el

   1 ;;; org-w3m.el --- Support from copy and paste from w3m to Org-mode
   2
   3 ;; Copyright (C) 2008, 2009, 2010 Free Software Foundation, Inc.
   4
   5 ;; Author: Andy Stewart <lazycat dot manatee at gmail dot com>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: http://orgmode.org
   8 ;; Version: 6.36trans
   9 ;;
  10 ;; This file is part of GNU Emacs.
  11 ;;
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  25 ;;
  26 ;;; Commentary:
  27
  28 ;; This file implements copying HTML content from a w3m buffer and
  29 ;; transforming the text on the fly so that it can be pasted into
  30 ;; an org-mode buffer with hot links.  It will also work for regions
  31 ;; in gnus buffers that have ben washed with w3m.
  32
  33 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  34 ;;
  35 ;;; Acknowledgements:
  36
  37 ;; Richard Riley <rileyrgdev at googlemail dot com>
  38 ;;
  39 ;;      The idea of transforming the HTML content with org-mode style is
  40 ;;      proposed by Richard, I'm just coding it.
  41 ;;
  42
  43 (require 'org)
  44
  45 (defun org-w3m-copy-for-org-mode ()
  46   "Copy current buffer content or active region with `org-mode' style links.
  47 This will encode `link-title' and `link-location' with
  48 `org-make-link-string', and insert the transformed test into the kill ring,
  49 so that it can be yanked into an Org-mode buffer with links working correctly."
  50   (interactive)
  51   (let* ((regionp (org-region-active-p))
  52          (transform-start (point-min))
  53          (transform-end (point-max))
  54          return-content
  55          link-location link-title
  56          temp-position out-bound)
  57     (when regionp
  58       (setq transform-start (region-beginning))
  59       (setq transform-end (region-end))
  60       ;; Deactivate mark if current mark is activate.
  61       (if (fboundp 'deactivate-mark) (deactivate-mark)))
  62     (message "Transforming links...")
  63     (save-excursion
  64       (goto-char transform-start)
  65       (while (and (not out-bound)                 ; still inside region to copy
  66                   (not (org-w3m-no-next-link-p))) ; no next link current buffer
  67         ;; store current point before jump next anchor
  68         (setq temp-position (point))
  69         ;; move to next anchor when current point is not at anchor
  70         (or (get-text-property (point) 'w3m-href-anchor) (org-w3m-get-next-link-start))
  71         (if (<= (point) transform-end)  ; if point is inside transform bound
  72             (progn
  73               ;; get content between two links.
  74               (if (> (point) temp-position)
  75                   (setq return-content (concat return-content
  76                                                (buffer-substring
  77                                                 temp-position (point)))))
  78               ;; get link location at current point.
  79               (setq link-location (get-text-property (point) 'w3m-href-anchor))
  80               ;; get link title at current point.
  81               (setq link-title (buffer-substring (point)
  82                                                  (org-w3m-get-anchor-end)))
  83               ;; concat `org-mode' style url to `return-content'.
  84               (setq return-content (concat return-content
  85                                            (org-make-link-string
  86                                             link-location link-title))))
  87           (goto-char temp-position)     ; reset point before jump next anchor
  88           (setq out-bound t)            ; for break out `while' loop
  89           ))
  90       ;; add the rest until end of the region to be copied
  91       (if (< (point) transform-end)
  92           (setq return-content
  93                 (concat return-content
  94                         (buffer-substring (point) transform-end))))
  95       (org-kill-new return-content)
  96       (message "Transforming links...done, use C-y to insert text into Org-mode file")
  97       (message "Copy with link transformation complete."))))
  98
  99 (defun org-w3m-get-anchor-start ()
 100   "Move cursor to the start of current anchor.  Return point."
 101   ;; get start position of anchor or current point
 102   (goto-char (or (previous-single-property-change (point) 'w3m-anchor-sequence)
 103                  (point))))
 104
 105 (defun org-w3m-get-anchor-end ()
 106   "Move cursor to the end of current anchor.  Return point."
 107   ;; get end position of anchor or point
 108   (goto-char (or (next-single-property-change (point) 'w3m-anchor-sequence)
 109                  (point))))
 110
 111 (defun org-w3m-get-next-link-start ()
 112   "Move cursor to the start of next link.  Return point."
 113   (catch 'reach
 114     (while (next-single-property-change (point) 'w3m-anchor-sequence)
 115       ;; jump to next anchor
 116       (goto-char (next-single-property-change (point) 'w3m-anchor-sequence))
 117       (when (get-text-property (point) 'w3m-href-anchor)
 118         ;; return point when current is valid link
 119         (throw 'reach nil))))
 120   (point))
 121
 122 (defun org-w3m-get-prev-link-start ()
 123   "Move cursor to the start of previous link.  Return point."
 124   (catch 'reach
 125     (while (previous-single-property-change (point) 'w3m-anchor-sequence)
 126       ;; jump to previous anchor
 127       (goto-char (previous-single-property-change (point) 'w3m-anchor-sequence))
 128       (when (get-text-property (point) 'w3m-href-anchor)
 129         ;; return point when current is valid link
 130         (throw 'reach nil))))
 131   (point))
 132
 133 (defun org-w3m-no-next-link-p ()
 134   "Whether there is no next link after the cursor.
 135 Return t if there is no next link; otherwise, return nil."
 136   (save-excursion
 137     (equal (point) (org-w3m-get-next-link-start))))
 138
 139 (defun org-w3m-no-prev-link-p ()
 140   "Whether there is no previous link after the cursor.
 141 Return t if there is no previous link; otherwise, return nil."
 142   (save-excursion
 143     (equal (point) (org-w3m-get-prev-link-start))))
 144
 145 ;; Install keys into the w3m keymap
 146 (defvar w3m-mode-map)
 147 (defvar w3m-minor-mode-map)
 148 (when (and (boundp 'w3m-mode-map)
 149            (keymapp w3m-mode-map))
 150   (define-key w3m-mode-map "\C-c\C-x\M-w" 'org-w3m-copy-for-org-mode)
 151   (define-key w3m-mode-map "\C-c\C-x\C-w" 'org-w3m-copy-for-org-mode))
 152 (when (and (boundp 'w3m-minor-mode-map)
 153            (keymapp w3m-minor-mode-map))
 154   (define-key w3m-minor-mode-map "\C-c\C-x\M-w" 'org-w3m-copy-for-org-mode)
 155   (define-key w3m-minor-mode-map "\C-c\C-x\C-w" 'org-w3m-copy-for-org-mode))
 156 (add-hook
 157  'w3m-mode-hook
 158  (lambda ()
 159    (define-key w3m-mode-map "\C-c\C-x\M-w" 'org-w3m-copy-for-org-mode)
 160    (define-key w3m-mode-map "\C-c\C-x\C-w" 'org-w3m-copy-for-org-mode)))
 161 (add-hook
 162  'w3m-minor-mode-hook
 163  (lambda ()
 164    (define-key w3m-minor-mode-map "\C-c\C-x\M-w" 'org-w3m-copy-for-org-mode)
 165    (define-key w3m-minor-mode-map "\C-c\C-x\C-w" 'org-w3m-copy-for-org-mode)))
 166
 167 (provide 'org-w3m)
 168
 169 ;; arch-tag: 851d7447-488d-49f0-a14d-46c092e84352
 170
 171 ;;; org-w3m.el ends here