lisp/ob-sqlite.el

   1 ;;; ob-sqlite.el --- org-babel functions for sqlite database interaction
   2
   3 ;; Copyright (C) 2010  Free Software Foundation
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8 ;; Version: 7.4
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Org-Babel support for evaluating sqlite source code.
  28
  29 ;;; Code:
  30 (require 'ob)
  31 (require 'ob-eval)
  32 (require 'ob-ref)
  33
  34 (declare-function org-fill-template "org" (template alist))
  35 (declare-function org-table-convert-region "org-table"
  36                   (beg0 end0 &optional separator))
  37 (declare-function orgtbl-to-csv "org-table" (TABLE PARAMS))
  38
  39 (defvar org-babel-default-header-args:sqlite '())
  40
  41 (defvar org-babel-header-arg-names:sqlite
  42   '(db header echo bail csv column html line list separator nullvalue)
  43   "Sqlite specific header args.")
  44
  45 (defun org-babel-expand-body:sqlite (body params)
  46   "Expand BODY according to the values of PARAMS."
  47   (org-babel-sqlite-expand-vars
  48    body (mapcar #'cdr (org-babel-get-header params :var))))
  49
  50 (defvar org-babel-sqlite3-command "sqlite3")
  51
  52 (defun org-babel-execute:sqlite (body params)
  53   "Execute a block of Sqlite code with Babel.
  54 This function is called by `org-babel-execute-src-block'."
  55   (let ((result-params (split-string (or (cdr (assoc :results params)) "")))
  56         (db (cdr (assoc :db params)))
  57         (separator (cdr (assoc :separator params)))
  58         (nullvalue (cdr (assoc :nullvalue params)))
  59         (headers-p (equal "yes" (cdr (assoc :colnames params))))
  60         (others (delq nil (mapcar
  61                            (lambda (arg) (car (assoc arg params)))
  62                            (list :header :echo :bail :column
  63                                  :csv :html :line :list))))
  64         exit-code)
  65     (unless db (error "ob-sqlite: can't evaluate without a database."))
  66     (with-temp-buffer
  67       (insert
  68        (org-babel-eval
  69         (org-fill-template
  70          "%cmd %header %separator %nullvalue %others %csv %db "
  71          (list
  72           (cons "cmd" org-babel-sqlite3-command)
  73           (cons "header" (if headers-p "-header" "-noheader"))
  74           (cons "separator"
  75                 (if separator (format "-separator %s" separator) ""))
  76           (cons "nullvalue"
  77                 (if nullvalue (format "-nullvalue %s" nullvalue) ""))
  78           (cons "others"
  79                 (mapconcat
  80                  (lambda (arg) (format "-%s" (substring (symbol-name arg) 1)))
  81                  others " "))
  82           ;; for easy table parsing, default header type should be -csv
  83           (cons "csv" (if (or (member :csv others) (member :column others)
  84                               (member :line others) (member :list others)
  85                               (member :html others) separator)
  86                           ""
  87                         "-csv"))
  88           (cons "db " db)))
  89         ;; body of the code block
  90         (org-babel-expand-body:sqlite body params)))
  91       (if (or (member "scalar" result-params)
  92               (member "html" result-params)
  93               (member "code" result-params)
  94               (equal (point-min) (point-max)))
  95           (buffer-string)
  96         (org-table-convert-region (point-min) (point-max))
  97         (org-babel-sqlite-table-or-scalar
  98          (org-babel-sqlite-offset-colnames
  99           (org-table-to-lisp) headers-p))))))
 100
 101 (defun org-babel-sqlite-expand-vars (body vars)
 102   "Expand the variables held in VARS in BODY."
 103   (mapc
 104    (lambda (pair)
 105      (setq body
 106            (replace-regexp-in-string
 107             (format "\$%s" (car pair))
 108             ((lambda (val)
 109                (if (listp val)
 110                    ((lambda (data-file)
 111                       (with-temp-file data-file
 112                         (insert (orgtbl-to-csv
 113                                  val '(:fmt (lambda (el) (if (stringp el)
 114                                                         el
 115                                                       (format "%S" el)))))))
 116                       data-file)
 117                     (org-babel-temp-file "sqlite-data-"))
 118                  (if (stringp val) val (format "%S" val))))
 119              (cdr pair))
 120             body)))
 121    vars)
 122   body)
 123
 124 (defun org-babel-sqlite-table-or-scalar (result)
 125   "If RESULT looks like a trivial table, then unwrap it."
 126   (if (and (equal 1 (length result))
 127            (equal 1 (length (car result))))
 128       (org-babel-read (caar result))
 129     (mapcar (lambda (row)
 130               (if (equal 'hline row)
 131                   'hline
 132                 (mapcar #'org-babel-read row))) result)))
 133
 134 (defun org-babel-sqlite-offset-colnames (table headers-p)
 135   "If HEADERS-P is non-nil then offset the first row as column names."
 136   (if headers-p
 137       (cons (car table) (cons 'hline (cdr table)))
 138     table))
 139
 140 (defun org-babel-prep-session:sqlite (session params)
 141   "Raise an error because support for sqlite sessions isn't implemented.
 142 Prepare SESSION according to the header arguments specified in PARAMS."
 143   (error "sqlite sessions not yet implemented"))
 144
 145 (provide 'ob-sqlite)
 146
 147 ;; arch-tag: 5c03d7f2-0f72-48b8-bbd1-35aafea248ac
 148
 149 ;;; ob-sqlite.el ends here