lisp/ob-clojure.el

   1 ;;; ob-clojure.el --- org-babel functions for clojure evaluation
   2
   3 ;; Copyright (C) 2009, 2010  Free Software Foundation, Inc.
   4
   5 ;; Author: Joel Boehland, Eric Schulte
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8 ;; Version: 7.4
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;;; support for evaluating clojure code, relies on slime for all eval
  28
  29 ;;; Requirements:
  30
  31 ;;; - clojure (at least 1.2.0)
  32 ;;; - clojure-mode
  33 ;;; - slime
  34 ;;; - swank-clojure
  35
  36 ;;; By far, the best way to install these components is by following
  37 ;;; the directions as set out by Phil Hagelberg (Technomancy) on the
  38 ;;; web page: http://technomancy.us/126
  39
  40 ;;; Code:
  41 (require 'ob)
  42
  43 (declare-function slime-eval "ext:slime" (sexp &optional package))
  44
  45 (add-to-list 'org-babel-tangle-lang-exts '("clojure" . "clj"))
  46
  47 (defvar org-babel-default-header-args:clojure '())
  48 (defvar org-babel-header-arg-names:clojure '(package))
  49
  50 (defun org-babel-expand-body:clojure (body params)
  51   "Expand BODY according to PARAMS, return the expanded body."
  52   (let* ((vars (mapcar #'cdr (org-babel-get-header params :var)))
  53          (result-params (cdr (assoc :result-params params)))
  54          (print-level nil) (print-length nil)
  55          (body (org-babel-trim
  56                 (if (> (length vars) 0)
  57                     (concat "(let ["
  58                             (mapconcat
  59                              (lambda (var)
  60                                (format "%S (quote %S)" (car var) (cdr var)))
  61                              vars "\n      ")
  62                             "]\n" body ")")
  63                   body))))
  64     (if (or (member "code" result-params)
  65             (member "pp" result-params))
  66         (format (concat "(let [org-mode-print-catcher (java.io.StringWriter.)]"
  67                         "(clojure.pprint/with-pprint-dispatch %s-dispatch"
  68                         "(clojure.pprint/pprint %s org-mode-print-catcher)"
  69                         "(str org-mode-print-catcher)))")
  70                 (if (member "code" result-params) "code" "simple") body)
  71       body)))
  72
  73 (defun org-babel-execute:clojure (body params)
  74   "Execute a block of Clojure code with Babel."
  75   (require 'slime) (require 'swank-clojure)
  76   (with-temp-buffer
  77     (insert (org-babel-expand-body:clojure body params))
  78     (read
  79      (slime-eval
  80       `(swank:interactive-eval-region
  81         ,(buffer-substring-no-properties (point-min) (point-max)))
  82       (cdr (assoc :package params))))))
  83
  84 (provide 'ob-clojure)
  85
  86 ;; arch-tag: a43b33f2-653e-46b1-ac56-2805cf05b7d1
  87
  88 ;;; ob-clojure.el ends here