org-publish.el

   1 ;;; org-publish.el --- publish related org-mode files as a website
   2
   3 ;; Copyright (C) 2006, 2007, 2008  Free Software Foundation, Inc.
   4
   5 ;; Author: David O'Toole <dto@gnu.org>
   6 ;; Maintainer: Bastien Guerry <bzg AT altern DOT org>
   7 ;; Keywords: hypermedia, outlines, wp
   8 ;; Version: 1.81
   9
  10 ;; This file is part of GNU Emacs.
  11 ;;
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 3, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Requires at least version 4.27 of org.el
  30
  31 ;; This program allow configurable publishing of related sets of
  32 ;; Org-mode files as a complete website.
  33 ;;
  34 ;; org-publish.el can do the following:
  35 ;;
  36 ;; + Publish all one's org-files to HTML or LaTeX
  37 ;; + Upload HTML, images, attachments and other files to a web server
  38 ;; + Exclude selected private pages from publishing
  39 ;; + Publish a clickable index of pages
  40 ;; + Manage local timestamps for publishing only changed files
  41 ;; + Accept plugin functions to extend range of publishable content
  42 ;;
  43 ;; Special thanks to the org-mode maintainer Carsten Dominik for his
  44 ;; ideas, enthusiasm, and cooperation.
  45
  46 ;;; Installation:
  47
  48 ;; Put org-publish.el in your load path, byte-compile it, and then add
  49 ;; the following lines to your emacs initialization file:
  50
  51 ;; (autoload 'org-publish "org-publish" nil t)
  52 ;; (autoload 'org-publish "org-publish-all" nil t)
  53 ;; (autoload 'org-publish "org-publish-current-file" nil t)
  54 ;; (autoload 'org-publish "org-publish-current-project" nil t)
  55
  56 ;; NOTE: When org-publish.el is included with org.el, those forms are
  57 ;; already in the file org-install.el, and hence don't need to be put
  58 ;; in your emacs initialization file in this case.
  59
  60 ;;; Usage:
  61 ;;
  62 ;; The program's main configuration variable is
  63 ;; `org-publish-project-alist'. See below for example configurations
  64 ;; with commentary.
  65
  66 ;; The main interactive functions are:
  67 ;;
  68 ;; M-x org-publish
  69 ;; M-x org-publish-all
  70 ;; M-x org-publish-current-file
  71 ;; M-x org-publish-current-project
  72
  73 ;;;; Simple example configuration:
  74
  75 ;; (setq org-publish-project-alist
  76 ;;       (list
  77 ;;        '("org" . (:base-directory "~/org/"
  78 ;;                   :base-extension "org"
  79 ;;                   :publishing-directory "~/public_html"
  80 ;;                   :with-section-numbers nil
  81 ;;                   :table-of-contents nil
  82 ;;                   :recursive t
  83 ;;                   :style "<link rel=stylesheet href=\"../other/mystyle.css\" type=\"text/css\">")))
  84
  85 ;;;; More complex example configuration:
  86
  87 ;; Imagine your *.org files are kept in ~/org, your images in
  88 ;; ~/images, and stylesheets in ~/other. Now imagine you want to
  89 ;; publish the files through an ssh connection to a remote host, via
  90 ;; Tramp-mode. To maintain relative links from *.org files to /images
  91 ;; and /other, we should replicate the same directory structure in
  92 ;; your web server account's designated html root (in this case,
  93 ;; assumed to be ~/html)
  94
  95 ;; Once you've done created the proper directories, you can adapt the
  96 ;; following example configuration to your specific paths, run M-x
  97 ;; org-publish-all, and it should publish the files to the correct
  98 ;; directories on the web server, transforming the *.org files into
  99 ;; HTML, and leaving other files alone.
 100
 101 ;; (setq org-publish-project-alist
 102 ;;       (list
 103 ;;        '("orgfiles" :base-directory "~/org/"
 104 ;;                     :base-extension "org"
 105 ;;                     :publishing-directory "/ssh:user@host:~/html/notebook/"
 106 ;;                     :publishing-function org-publish-org-to-html
 107 ;;                     :exclude "PrivatePage.org"   ;; regexp
 108 ;;                     :headline-levels 3
 109 ;;                     :with-section-numbers nil
 110 ;;                     :table-of-contents nil
 111 ;;                     :style "<link rel=stylesheet href=\"../other/mystyle.css\" type=\"text/css\">"
 112 ;;                     :auto-preamble t
 113 ;;                     :auto-postamble nil)
 114 ;;         ("images" :base-directory "~/images/"
 115 ;;                   :base-extension "jpg\\|gif\\|png"
 116 ;;                   :publishing-directory "/ssh:user@host:~/html/images/"
 117 ;;                   :publishing-function org-publish-attachment)
 118 ;;         ("other"  :base-directory "~/other/"
 119 ;;                   :base-extension "css"
 120 ;;                   :publishing-directory "/ssh:user@host:~/html/other/"
 121 ;;                   :publishing-function org-publish-attachment)
 122 ;;         ("website" :components ("orgfiles" "images" "other"))))
 123
 124 ;; For more information, see the documentation for the variable
 125 ;; `org-publish-project-alist'.
 126
 127 ;; Of course, you don't have to publish to remote directories from
 128 ;; within emacs. You can always just publish to local folders, and
 129 ;; then use the synchronization/upload tool of your choice.
 130
 131 ;;; List of user-visible changes since version 1.27
 132
 133 ;; 1.78: Allow list-valued :publishing-function
 134 ;; 1.77: Added :preparation-function, this allows you to use GNU Make etc.
 135 ;; 1.65: Remove old "composite projects". They're redundant.
 136 ;; 1.64: Allow meta-projects with :components
 137 ;; 1.57: Timestamps flag is now called "org-publish-use-timestamps-flag"
 138 ;; 1.52: Properly set default for :index-filename
 139 ;; 1.48: Composite projects allowed.
 140 ;;       :include keyword allowed.
 141 ;; 1.43: Index no longer includes itself in the index.
 142 ;; 1.42: Fix "function definition is void" error
 143 ;;       when :publishing-function not set in org-publish-current-file.
 144 ;; 1.41: Fixed bug where index isn't published on first try.
 145 ;; 1.37: Added interactive function "org-publish". Prompts for particular
 146 ;;       project name to publish.
 147 ;; 1.34: Added force-publish option to all interactive functions.
 148 ;; 1.32: Fixed "index.org has changed on disk" error during index publishing.
 149 ;; 1.30: Fixed startup error caused by (require 'em-unix)
 150
 151 ;;; Code:
 152
 153 (eval-when-compile
 154   (require 'cl))
 155
 156 (require 'dired-aux)
 157
 158 (defgroup org-publish nil
 159         "Options for publishing a set of Org-mode and related files."
 160    :tag "Org Publishing"
 161    :group 'org)
 162
 163 (defcustom org-publish-project-alist nil
 164   "Association list to control publishing behavior.
 165 Each element of the alist is a publishing 'project.'  The CAR of
 166 each element is a string, uniquely identifying the project. The
 167 CDR of each element is in one of the following forms:
 168
 169   (:property value :property value ... )
 170
 171 OR,
 172
 173   (:components (\"project-1\" \"project-2\" ...))
 174
 175 When the CDR of an element of org-publish-project-alist is in
 176 this second form, the elements of the list after :components are
 177 taken to be components of the project, which group together files
 178 requiring different publishing options. When you publish such a
 179 project with M-x org-publish, the components all publish.
 180
 181 When a property is given a value in org-publish-project-alist, its
 182 setting overrides the value of the corresponding user variable
 183  (if any) during publishing. However, options set within a file
 184 override everything.
 185
 186 Most properties are optional, but some should always be set:
 187
 188   :base-directory        Directory containing publishing source files
 189   :base-extension        Extension (without the dot!) of source files.
 190                          This can be a regular expression.
 191   :publishing-directory  Directory (possibly remote) where output
 192                          files will be published
 193
 194 The :exclude property may be used to prevent certain files from
 195 being published. Its value may be a string or regexp matching
 196 file names you don't want to be published.
 197
 198 The :include property may be used to include extra files. Its
 199 value may be a list of filenames to include. The filenames are
 200 considered relative to the publishing directory.
 201
 202 When both :include and :exclude properties are given values, the
 203 exclusion step happens first.
 204
 205 One special property controls which back-end function to use for
 206 publishing files in the project. This can be used to extend the
 207 set of file types publishable by org-publish, as well as the set
 208 of output formats.
 209
 210   :publishing-function     Function to publish file. The default is
 211                            org-publish-org-to-html, but other
 212                            values are possible. May also be a
 213                            list of functions, in which case
 214                            each function in the list is invoked
 215                            in turn.
 216
 217 Another property allows you to insert code that prepares a
 218 project for publishing. For example, you could call GNU Make on a
 219 certain makefile, to ensure published files are built up to date.
 220
 221   :preparation-function   Function to be called before publishing
 222                           this project.
 223
 224 Some properties control details of the Org publishing process,
 225 and are equivalent to the corresponding user variables listed in
 226 the right column. See the documentation for those variables to
 227 learn more about their use and default values.
 228
 229   :language              org-export-default-language
 230   :headline-levels       org-export-headline-levels
 231   :section-numbers       org-export-with-section-numbers
 232   :table-of-contents     org-export-with-toc
 233   :emphasize             org-export-with-emphasize
 234   :sub-superscript       org-export-with-sub-superscripts
 235   :TeX-macros            org-export-with-TeX-macros
 236   :fixed-width           org-export-with-fixed-width
 237   :tables                org-export-with-tables
 238   :table-auto-headline   org-export-highlight-first-table-line
 239   :style                 org-export-html-style
 240   :convert-org-links     org-export-html-link-org-files-as-html
 241   :inline-images         org-export-html-inline-images
 242   :expand-quoted-html    org-export-html-expand
 243   :timestamp             org-export-html-with-timestamp
 244   :publishing-directory  org-export-publishing-directory
 245   :preamble              org-export-html-preamble
 246   :postamble             org-export-html-postamble
 247   :auto-preamble         org-export-html-auto-preamble
 248   :auto-postamble        org-export-html-auto-postamble
 249   :author                user-full-name
 250   :email                 user-mail-address
 251
 252 The following properties may be used to control publishing of an
 253 index of files or summary page for a given project.
 254
 255   :auto-index            Whether to publish an index during
 256                          org-publish-current-project or org-publish-all.
 257   :index-filename        Filename for output of index. Defaults
 258                          to 'index.org' (which becomes 'index.html')
 259   :index-title           Title of index page. Defaults to name of file.
 260   :index-function        Plugin function to use for generation of index.
 261                          Defaults to 'org-publish-org-index', which
 262                          generates a plain list of links to all files
 263                          in the project."
 264   :group 'org-publish
 265   :type 'alist)
 266
 267 (defcustom org-publish-use-timestamps-flag t
 268   "When non-nil, use timestamp checking to publish only changed files.
 269 When nil, do no timestamp checking and always publish all
 270 files."
 271   :group 'org-publish
 272   :type 'boolean)
 273
 274 (defcustom org-publish-timestamp-directory "~/.org-timestamps/"
 275   "Name of directory in which to store publishing timestamps."
 276   :group 'org-publish
 277   :type 'directory)
 278
 279
 280 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 281 ;;; Timestamp-related functions
 282
 283 (defun org-publish-timestamp-filename (filename)
 284   "Return path to timestamp file for filename FILENAME."
 285   (while (string-match
 286           (if (eq system-type 'windows-nt) "~\\|/\\|:" "~\\|/") filename)
 287     (setq filename (replace-match "_" nil t filename)))
 288   (concat org-publish-timestamp-directory filename ".timestamp"))
 289
 290 (defun org-publish-needed-p (filename)
 291   "Return `t' if FILENAME should be published."
 292   (if org-publish-use-timestamps-flag
 293       (if (file-exists-p org-publish-timestamp-directory)
 294           ;; first handle possible wrong timestamp directory
 295           (if (not (file-directory-p org-publish-timestamp-directory))
 296               (error "Org publish timestamp: %s is not a directory"
 297                      org-publish-timestamp-directory)
 298             ;; there is a timestamp, check if FILENAME is newer
 299             (file-newer-than-file-p
 300              filename (org-publish-timestamp-filename filename))))
 301     ;; don't use timestamps, always return t
 302     t))
 303
 304 (defun org-publish-update-timestamp (filename)
 305   "Update publishing timestamp for file FILENAME.
 306 If there is no timestamp, create one."
 307   (let ((timestamp-file (org-publish-timestamp-filename filename))
 308         newly-created-timestamp)
 309     (if (not (file-exists-p timestamp-file))
 310         ;; create timestamp file if needed
 311         (with-temp-buffer
 312           (make-directory (file-name-directory timestamp-file) t)
 313           (write-file timestamp-file)
 314           (setq newly-created-timestamp t)))
 315     ;; Emacs 21 doesn't have `set-file-times'
 316     (if (and (fboundp 'set-file-times)
 317              (not newly-created-timestamp))
 318         (set-file-times timestamp-file)
 319       (call-process "touch" nil 0 nil timestamp-file))))
 320
 321
 322 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 323 ;;; Mapping files to project names
 324
 325 (defvar org-publish-files-alist nil
 326   "Alist of files and their parent project.
 327 Each element of this alist is of the form:
 328
 329   (file-name . project-name)")
 330
 331 (defun org-publish-initialize-files-alist (&optional refresh)
 332   "Set `org-publish-files-alist' if it is not set.
 333 Also set it if the optional argument REFRESH is non-nil."
 334   (when (or (not org-publish-files-alist) refresh)
 335     (setq org-publish-files-alist
 336           (org-publish-get-files org-publish-project-alist))))
 337
 338 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 339 ;;; Compatibility aliases
 340
 341 ;; Delete-dups is not in Emacs <22
 342 (if (fboundp 'delete-dups)
 343     (defalias 'org-publish-delete-dups 'delete-dups)
 344   (defun org-publish-delete-dups (list)
 345     "Destructively remove `equal' duplicates from LIST.
 346 Store the result in LIST and return it.  LIST must be a proper list.
 347 Of several `equal' occurrences of an element in LIST, the first
 348 one is kept.
 349
 350 This is a compatibility function for Emacsen without `delete-dups'."
 351     ;; Code from `subr.el' in Emacs 22:
 352     (let ((tail list))
 353       (while tail
 354         (setcdr tail (delete (car tail) (cdr tail)))
 355         (setq tail (cdr tail))))
 356     list))
 357
 358 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 359 ;;; Getting project information out of org-publish-project-alist
 360
 361 (defun org-publish-get-files (projects-alist &optional no-exclusion)
 362   "Return the list of all publishable files for PROJECTS-ALIST.
 363 If NO-EXCLUSION is non-nil, don't exclude files."
 364   (let (all-files)
 365     ;; add all projects
 366     (mapc
 367      (lambda(p)
 368        (let* ((exclude (plist-get (cdr p) :exclude))
 369               (files (org-publish-get-base-files p exclude)))
 370          ;; add all files from this project
 371          (mapc (lambda(f)
 372                  (add-to-list 'all-files
 373                               (cons (expand-file-name f) (car p))))
 374                files)))
 375      (org-publish-expand-projects projects-alist))
 376     all-files))
 377
 378 (defun org-publish-expand-projects (projects-alist)
 379   "Expand projects contained in PROJECTS-ALIST."
 380   (let (without-component with-component)
 381     (mapc (lambda(p)
 382             (add-to-list
 383              (if (plist-get (cdr p) :components)
 384                  'with-component 'without-component) p))
 385           projects-alist)
 386     (org-publish-delete-dups
 387      (append without-component
 388              (car (mapcar (lambda(p) (org-publish-expand-components p))
 389                           with-component))))))
 390
 391 (defun org-publish-expand-components (project)
 392   "Expand PROJECT into an alist of its components."
 393   (let* ((components (plist-get (cdr project) :components)))
 394     (org-publish-delete-dups
 395      (mapcar (lambda(c) (assoc c org-publish-project-alist))
 396              components))))
 397
 398 (defun org-publish-get-base-files (project &optional exclude-regexp)
 399   "Return a list of all files in PROJECT.
 400 If EXCLUDE-REGEXP is set, this will be used to filter out
 401 matching filenames."
 402   (let* ((project-plist (cdr project))
 403          (base-dir (file-name-as-directory
 404                     (plist-get project-plist :base-directory)))
 405          (include-list (plist-get project-plist :include))
 406          (recursive-p (plist-get project-plist :recursive))
 407          (extension (or (plist-get project-plist :base-extension) "org"))
 408          (regexp (concat "^[^\\.].*\\.\\(" extension "\\)$"))
 409          alldirs allfiles files dir)
 410     ;; Get all files and directories in base-directory
 411     (setq files (dired-files-attributes base-dir))
 412     ;; Get all subdirectories if recursive-p
 413     (setq alldirs
 414           (if recursive-p
 415               (delq nil (mapcar (lambda(f) (if (caaddr f) (cadr f))) files))
 416             (list base-dir)))
 417     (while (setq dir (pop alldirs))
 418       (setq files (directory-files dir t regexp))
 419       ;; Exclude files
 420       (setq files
 421             (if (not exclude-regexp)
 422                 files
 423               (delq nil
 424                     (mapcar (lambda (x)
 425                               (if (string-match exclude-regexp x) nil x))
 426                             files))))
 427       ;; Include extra files
 428       (let (inc)
 429         (while (setq inc (pop include-list))
 430           (setq files (cons (expand-file-name inc dir) files))))
 431       (setq allfiles (append allfiles files)))
 432     allfiles))
 433
 434 (defun org-publish-get-project-from-filename (filename)
 435   "Return the project FILENAME belongs."
 436   (let* ((project-name (cdr (assoc (expand-file-name filename)
 437                                    org-publish-files-alist))))
 438     (assoc project-name org-publish-project-alist)))
 439
 440
 441 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 442 ;;; Pluggable publishing back-end functions
 443
 444 (defun org-publish-org-to (format plist filename pub-dir)
 445   "Publish an org file to FORMAT.
 446 PLIST is the property list for the given project.
 447 FILENAME is the filename of the org file to be published.
 448 PUB-DIR is the publishing directory."
 449   (require 'org)
 450   (unless (file-exists-p pub-dir)
 451     (make-directory pub-dir t))
 452   (find-file filename)
 453   (funcall (intern (concat "org-export-as-" format))
 454            (plist-get plist :headline-levels)
 455            nil plist nil nil pub-dir)
 456   (kill-buffer (current-buffer)))
 457
 458 (defun org-publish-org-to-latex (plist filename pub-dir)
 459   "Publish an org file to LaTeX.
 460 See `org-publish-org-to' to the list of arguments."
 461   (org-publish-org-to "latex" plist filename pub-dir))
 462
 463 (defun org-publish-org-to-html (plist filename pub-dir)
 464   "Publish an org file to HTML.
 465 See `org-publish-org-to' to the list of arguments."
 466   (org-publish-org-to "html" plist filename pub-dir))
 467
 468 (defun org-publish-attachment (plist filename)
 469   "Publish a file with no transformation of any kind.
 470 PLIST is the property list for the given project.
 471 FILENAME is the filename of the file to be published."
 472   ;; make sure eshell/cp code is loaded
 473   (eval-and-compile
 474     (require 'eshell)
 475     (require 'esh-maint)
 476     (require 'em-unix))
 477   (let ((destination (file-name-as-directory
 478                       (plist-get plist :publishing-directory))))
 479     (eshell/cp filename destination)))
 480
 481
 482 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 483 ;;; Publishing files, sets of files, and indices
 484
 485 (defun org-publish-file (filename &optional project)
 486   "Publish file FILENAME from PROJECT."
 487   (when (org-publish-needed-p filename)
 488     (let* ((project (or project (org-publish-get-project-from-filename filename)))
 489            (project-plist (cdr project))
 490            (publishing-function (or (plist-get project-plist :publishing-function)
 491                                     'org-publish-org-to-html))
 492            (base-dir (file-truename (plist-get project-plist :base-directory)))
 493            (pub-dir (file-truename (plist-get project-plist :publishing-directory)))
 494            tmp-pub-dir)
 495       (if (not project) (error "File %s is not part of any known project" filename))
 496       (setq tmp-pub-dir
 497             (file-name-directory
 498              (concat pub-dir
 499                      (and (string-match (regexp-quote base-dir) filename)
 500                           (substring filename (match-end 0))))))
 501       (if (listp publishing-function)
 502           ;; allow chain of publishing functions
 503           (mapc (lambda (f)
 504                   (funcall f project-plist filename tmp-pub-dir))
 505                 publishing-function)
 506         (funcall publishing-function project-plist filename tmp-pub-dir))
 507       (org-publish-update-timestamp filename))))
 508
 509 (defun org-publish-projects (projects)
 510   "Publish all files belonging to the PROJECTS alist.
 511 If :auto-index is set, publish the index too."
 512   (mapc
 513    (lambda (project)
 514      (let* ((project-plist (cdr project))
 515             (exclude-regexp (plist-get project-plist :exclude))
 516             (index-p (plist-get project-plist :auto-index))
 517             (index-filename (or (plist-get project-plist :index-filename)
 518                                 "index.org"))
 519             (index-function (or (plist-get project-plist :index-function)
 520                                 'org-publish-org-index))
 521             (preparation-function (plist-get project-plist :preparation-function))
 522             (files (org-publish-get-base-files project exclude-regexp)) file)
 523        (when preparation-function (funcall preparation-function))
 524        (if index-p (funcall index-function project index-filename))
 525        (while (setq file (pop files))
 526          (org-publish-file file project))))
 527    (org-publish-expand-projects projects)))
 528
 529 (defun org-publish-org-index (project &optional index-filename)
 530   "Create an index of pages in set defined by PROJECT.
 531 Optionally set the filename of the index with INDEX-FILENAME.
 532 Default for INDEX-FILENAME is 'index.org'."
 533   (let* ((project-plist (cdr project))
 534          (dir (file-name-as-directory
 535                (plist-get project-plist :base-directory)))
 536          (exclude-regexp (plist-get project-plist :exclude))
 537          (files (org-publish-get-base-files project exclude-regexp))
 538          (index-filename (concat dir (or index-filename "index.org")))
 539          (index-buffer (find-buffer-visiting index-filename))
 540          (ifn (file-name-nondirectory index-filename))
 541          file)
 542     ;; if buffer is already open, kill it to prevent error message
 543     (if index-buffer
 544         (kill-buffer index-buffer))
 545     (with-temp-buffer
 546       (while (setq file (pop files))
 547         (let ((fn (file-name-nondirectory file)))
 548           (unless (string= fn ifn) ;; index shouldn't index itself
 549             (insert (concat " + [[file:" fn "]["
 550                             (file-name-sans-extension fn)
 551                             "]]\n")))))
 552       (write-file index-filename)
 553       (kill-buffer (current-buffer)))))
 554
 555
 556 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 557 ;;; Interactive publishing functions
 558
 559 ;;;###autoload
 560 (defun org-publish (project &optional force)
 561   "Publish PROJECT."
 562   (interactive "P")
 563   (save-window-excursion
 564     (let* ((force current-prefix-arg)
 565            (org-publish-use-timestamps-flag
 566             (if force nil org-publish-use-timestamps-flag)))
 567       (org-publish-projects
 568        (list (or project
 569                  (assoc (completing-read
 570                          "Publish project: "
 571                          org-publish-project-alist nil t)
 572                         org-publish-project-alist)))))))
 573
 574 ;;;###autoload
 575 (defun org-publish-all (&optional force)
 576   "Publish all projects.
 577 With prefix argument, force publish all files."
 578   (interactive "P")
 579   (org-publish-initialize-files-alist)
 580   (save-window-excursion
 581     (let ((org-publish-use-timestamps-flag
 582            (if force nil org-publish-use-timestamps-flag)))
 583       (org-publish-projects org-publish-project-alist))))
 584
 585 ;;;###autoload
 586 (defun org-publish-current-file (&optional force)
 587   "Publish the current file.
 588 With prefix argument, force publish the file."
 589   (interactive "P")
 590   (org-publish-initialize-files-alist)
 591   (save-window-excursion
 592     (let ((org-publish-use-timestamps-flag
 593            (if force nil org-publish-use-timestamps-flag)))
 594       (org-publish-file (buffer-file-name)))))
 595
 596 ;;;###autoload
 597 (defun org-publish-current-project (&optional force)
 598   "Publish the project associated with the current file.
 599 With a prefix argument, force publishing of all files in
 600 the project."
 601   (interactive "P")
 602   (org-publish-initialize-files-alist)
 603   (save-window-excursion
 604     (let ((project (org-publish-get-project-from-filename (buffer-file-name)))
 605           (org-publish-use-timestamps-flag
 606            (if force nil org-publish-use-timestamps-flag)))
 607       (if (not project)
 608           (error "File %s is not part of any known project" (buffer-file-name)))
 609       (org-publish project))))
 610
 611 (provide 'org-publish)
 612
 613
 614 ;; arch-tag: 72807f3c-8af0-4a6b-8dca-c3376eb25adb
 615 ;;; org-publish.el ends here