lisp/ob-python.el

   1 ;;; ob-python.el --- org-babel functions for python evaluation
   2
   3 ;; Copyright (C) 2009, 2010  Free Software Foundation
   4
   5 ;; Author: Eric Schulte, Dan Davison
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8 ;; Version: 0.01
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Org-Babel support for evaluating python source code.
  28
  29 ;;; Code:
  30 (require 'ob)
  31 (require 'ob-ref)
  32 (require 'ob-comint)
  33 (require 'ob-eval)
  34 (eval-when-compile (require 'cl))
  35
  36 (declare-function org-remove-indentation "org" )
  37 (declare-function py-shell "ext:python-mode" (&optional argprompt))
  38 (declare-function run-python "ext:python" (&optional cmd noshow new))
  39
  40 (add-to-list 'org-babel-tangle-lang-exts '("python" . "py"))
  41
  42 (defvar org-babel-default-header-args:python '())
  43
  44 (defvar org-babel-python-command "python"
  45   "Name of command for executing python code.")
  46
  47 (defvar org-babel-python-mode (if (featurep 'xemacs) 'python-mode 'python)
  48   "Preferred python mode for use in running python interactively.")
  49
  50 (defun org-babel-expand-body:python (body params &optional processed-params)
  51   "Expand BODY according to PARAMS, return the expanded body."
  52   (concat
  53    (mapconcat ;; define any variables
  54     (lambda (pair)
  55       (format "%s=%s"
  56               (car pair)
  57               (org-babel-python-var-to-python (cdr pair))))
  58     (nth 1 (or processed-params (org-babel-process-params params))) "\n")
  59    "\n" (org-babel-trim body) "\n"))
  60
  61 (defun org-babel-execute:python (body params)
  62   "Execute a block of Python code with Babel.
  63 This function is called by `org-babel-execute-src-block'."
  64   (let* ((processed-params (org-babel-process-params params))
  65          (session (org-babel-python-initiate-session (first processed-params)))
  66          (result-params (nth 2 processed-params))
  67          (result-type (nth 3 processed-params))
  68          (full-body (org-babel-expand-body:python
  69                      body params processed-params))
  70          (result (org-babel-python-evaluate
  71                   session full-body result-type result-params)))
  72     (or (cdr (assoc :file params))
  73         (org-babel-reassemble-table
  74          result
  75          (org-babel-pick-name (nth 4 processed-params)
  76                               (cdr (assoc :colnames params)))
  77          (org-babel-pick-name (nth 5 processed-params)
  78                               (cdr (assoc :rownames params)))))))
  79
  80 (defun org-babel-prep-session:python (session params)
  81   "Prepare SESSION according to the header arguments in PARAMS."
  82   (let* ((session (org-babel-python-initiate-session session))
  83          (vars (org-babel-ref-variables params))
  84          (var-lines (mapcar ;; define any variables
  85                      (lambda (pair)
  86                        (format "%s=%s"
  87                                (car pair)
  88                                (org-babel-python-var-to-python (cdr pair))))
  89                      vars)))
  90     (org-babel-comint-in-buffer session
  91       (mapc (lambda (var)
  92               (end-of-line 1) (insert var) (comint-send-input)
  93               (org-babel-comint-wait-for-output session)) var-lines))
  94     session))
  95
  96 (defun org-babel-load-session:python (session body params)
  97   "Load BODY into SESSION."
  98   (save-window-excursion
  99     (let ((buffer (org-babel-prep-session:python session params)))
 100       (with-current-buffer buffer
 101         (goto-char (process-mark (get-buffer-process (current-buffer))))
 102         (insert (org-babel-chomp body)))
 103       buffer)))
 104
 105 ;; helper functions
 106
 107 (defun org-babel-python-var-to-python (var)
 108   "Convert an elisp value to a python variable.
 109 Convert an elisp value, VAR, into a string of python source code
 110 specifying a variable of the same value."
 111   (if (listp var)
 112       (concat "[" (mapconcat #'org-babel-python-var-to-python var ", ") "]")
 113     (if (equal var 'hline) "None" (format "%S" var))))
 114
 115 (defun org-babel-python-table-or-string (results)
 116   "Convert RESULTS into an appropriate elisp value.
 117 If the results look like a list or tuple, then convert them into an
 118 Emacs-lisp table, otherwise return the results as a string."
 119   ((lambda (res)
 120      (if (listp res)
 121          (mapcar (lambda (el) (if (equal el 'None) 'hline el)) res)
 122        res))
 123    (org-babel-read
 124    (if (or (string-match "^\\[.+\\]$" results)
 125            (string-match "^(.+)$" results))
 126        (org-babel-read
 127         (concat "'"
 128                 (replace-regexp-in-string
 129                  "\\[" "(" (replace-regexp-in-string
 130                             "\\]" ")" (replace-regexp-in-string
 131                                        ", " " " (replace-regexp-in-string
 132                                                  "'" "\"" results t))))))
 133      results))))
 134
 135 (defvar org-babel-python-buffers '((:default . nil)))
 136
 137 (defun org-babel-python-session-buffer (session)
 138   "Return the buffer associated with SESSION."
 139   (cdr (assoc session org-babel-python-buffers)))
 140
 141 (defun org-babel-python-initiate-session-by-key (&optional session)
 142   "Initiate a python session.
 143 If there is not a current inferior-process-buffer in SESSION
 144 then create.  Return the initialized session."
 145   (require org-babel-python-mode)
 146   (save-window-excursion
 147     (let* ((session (if session (intern session) :default))
 148            (python-buffer (org-babel-python-session-buffer session)))
 149       (cond
 150        ((and (equal 'python org-babel-python-mode)
 151              (fboundp 'run-python)) ; python.el
 152         (run-python))
 153        ((and (equal 'python-mode org-babel-python-mode)
 154              (fboundp 'py-shell)) ; python-mode.el
 155         ;; `py-shell' creates a buffer whose name is the value of
 156         ;; `py-which-bufname' with '*'s at the beginning and end
 157         (let* ((bufname (if python-buffer
 158                             (replace-regexp-in-string ;; zap surrounding *
 159                              "^\\*\\([^*]+\\)\\*$" "\\1" python-buffer)
 160                           (concat "Python-" (symbol-name session))))
 161                (py-which-bufname bufname))
 162           (py-shell)
 163           (setq python-buffer (concat "*" bufname "*"))))
 164        (t
 165         (error "No function available for running an inferior python.")))
 166       (setq org-babel-python-buffers
 167             (cons (cons session python-buffer)
 168                   (assq-delete-all session org-babel-python-buffers)))
 169       session)))
 170
 171 (defun org-babel-python-initiate-session (&optional session params)
 172   "Create a session named SESSION according to PARAMS."
 173   (unless (string= session "none")
 174     (org-babel-python-session-buffer
 175      (org-babel-python-initiate-session-by-key session))))
 176
 177 (defvar org-babel-python-eoe-indicator "'org_babel_python_eoe'"
 178   "A string to indicate that evaluation has completed.")
 179 (defvar org-babel-python-wrapper-method
 180   "
 181 def main():
 182 %s
 183
 184 open('%s', 'w').write( str(main()) )")
 185 (defvar org-babel-python-pp-wrapper-method
 186   "
 187 import pprint
 188 def main():
 189 %s
 190
 191 open('%s', 'w').write( pprint.pformat(main()) )")
 192
 193 (defun org-babel-python-evaluate
 194   (buffer body &optional result-type result-params)
 195   "Pass BODY to the Python process in BUFFER.
 196 If RESULT-TYPE equals 'output then return a list of the outputs
 197 of the statements in BODY, if RESULT-TYPE equals 'value then
 198 return the value of the last statement in BODY, as elisp."
 199   (if (not buffer)
 200       ;; external process evaluation
 201       (case result-type
 202         (output (org-babel-eval org-babel-python-command body))
 203         (value (let ((tmp-file (make-temp-file "org-babel-python-results-")))
 204                  (org-babel-eval org-babel-python-command
 205                                  (format
 206                                   (if (member "pp" result-params)
 207                                       org-babel-python-pp-wrapper-method
 208                                     org-babel-python-wrapper-method)
 209                                   (mapconcat
 210                                    (lambda (line) (format "\t%s" line))
 211                                    (split-string
 212                                     (org-remove-indentation
 213                                      (org-babel-trim body))
 214                                     "[\r\n]") "\n")
 215                                   tmp-file))
 216                  ((lambda (raw)
 217                     (if (or (member "code" result-params)
 218                             (member "pp" result-params))
 219                         raw
 220                       (org-babel-python-table-or-string raw)))
 221                   (org-babel-eval-read-file tmp-file)))))
 222     ;; comint session evaluation
 223     (flet ((dump-last-value (tmp-file pp)
 224             (mapc
 225              (lambda (statement) (insert statement) (comint-send-input))
 226              (if pp
 227                  (list
 228                   "import pp"
 229                   (format "open('%s', 'w').write(pprint.pformat(_))" tmp-file))
 230                (list (format "open('%s', 'w').write(str(_))" tmp-file)))))
 231            (input-body (body)
 232             (mapc (lambda (statement) (insert statement) (comint-send-input))
 233                   (split-string (org-babel-trim body) "[\r\n]+"))
 234             (comint-send-input) (comint-send-input)))
 235       (case result-type
 236         (output
 237          (mapconcat
 238           #'org-babel-trim
 239           (butlast
 240            (org-babel-comint-with-output
 241                (buffer org-babel-python-eoe-indicator t body)
 242              (let ((comint-process-echoes nil))
 243                (input-body body)
 244                (insert org-babel-python-eoe-indicator)
 245                (comint-send-input))) 2) "\n"))
 246         (value
 247          ((lambda (results)
 248             (if (or (member "code" result-params) (member "pp" result-params))
 249                 results
 250               (org-babel-python-table-or-string results)))
 251           (let ((tmp-file (make-temp-file "org-babel-python-results-")))
 252             (org-babel-comint-with-output
 253                 (buffer org-babel-python-eoe-indicator t body)
 254               (let ((comint-process-echoes nil))
 255                 (input-body body)
 256                 (dump-last-value tmp-file (member "pp" result-params))
 257                 (comint-send-input) (comint-send-input)
 258                 (insert org-babel-python-eoe-indicator)
 259                 (comint-send-input)))
 260             (org-babel-eval-read-file tmp-file))))))))
 261
 262 (defun org-babel-python-read-string (string)
 263   "Strip 's from around python string"
 264   (if (string-match "^'\\([^\000]+\\)'$" string)
 265       (match-string 1 string)
 266     string))
 267
 268 (provide 'ob-python)
 269
 270 ;; arch-tag: f19b6c3d-dfcb-4a1a-9ce0-45ade1ebc212
 271
 272 ;;; ob-python.el ends here