lisp/org-jsinfo.el

   1 ;;; org-jsinfo.el --- Support for org-info.js Javascript in Org HTML export
   2
   3 ;; Copyright (C) 2004, 2005, 2006, 2007, 2008, 2009
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   7 ;; Keywords: outlines, hypermedia, calendar, wp
   8 ;; Homepage: http://orgmode.org
   9 ;; Version: 6.22b
  10 ;;
  11 ;; This file is part of GNU Emacs.
  12 ;;
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  26 ;;
  27 ;;; Commentary:
  28
  29 ;; This file implements the support for Sebastian Rose's Javascript
  30 ;; org-info.js to display an org-mode file exported to HTML in an
  31 ;; Info-like way, or using folding similar to the outline structure
  32 ;; org org-mode itself.
  33
  34 ;; Documentation for using this module is in the Org manual. The script
  35 ;; itself is documented by Sebastian Rose in a file distributed with
  36 ;; the script.  FIXME: Accurate pointers!
  37
  38 ;; Org-mode loads this module by default - if this is not what you want,
  39 ;; configure the variable `org-modules'.
  40
  41 ;;; Code:
  42
  43 (require 'org-exp)
  44
  45 (add-to-list 'org-export-inbuffer-options-extra '("INFOJS_OPT" :infojs-opt))
  46 (add-hook 'org-export-options-filters 'org-infojs-handle-options)
  47
  48 (defgroup org-infojs nil
  49   "Options specific for using org-info.js in HTML export of Org-mode files."
  50   :tag "Org Export HTML INFOJS"
  51   :group 'org-export-html)
  52
  53 (defcustom org-export-html-use-infojs 'when-configured
  54   "Should Sebastian Rose's Java Script org-info.js be linked into HTML files?
  55 This option can be nil or t to never or always use the script.  It can
  56 also be the symbol `when-configured', meaning that the script will be
  57 linked into the export file if and only if there is a \"#+INFOJS_OPT:\"
  58 line in the buffer.  See also the variable `org-infojs-options'."
  59   :group 'org-export-html
  60   :group 'org-infojs
  61   :type '(choice
  62           (const :tag "Never" nil)
  63           (const :tag "When configured in buffer" when-configured)
  64           (const :tag "Always" t)))
  65
  66 (defconst org-infojs-opts-table
  67   '((path PATH "http://orgmode.org/org-info.js")
  68     (view VIEW "info")
  69     (toc TOC :table-of-contents)
  70     (ftoc FIXED_TOC "0")
  71     (tdepth TOC_DEPTH "max")
  72     (sdepth SECTION_DEPTH "max")
  73     (mouse MOUSE_HINT "underline")
  74     (buttons VIEW_BUTTONS "0")
  75     (ltoc LOCAL_TOC "1")
  76     (up LINK_UP :link-up)
  77     (home LINK_HOME :link-home))
  78   "JavaScript options, long form for script, default values.")
  79
  80 (defvar org-infojs-options)
  81 (when (and (boundp 'org-infojs-options)
  82            (assq 'runs org-infojs-options))
  83   (setq org-infojs-options (delq (assq 'runs org-infojs-options)
  84                                  org-infojs-options)))
  85
  86 (defcustom org-infojs-options
  87   (mapcar (lambda (x) (cons (car x) (nth 2 x)))
  88           org-infojs-opts-table)
  89   "Options settings for the INFOJS Javascript.
  90 Each of the options must have an entry in `org-export-html/infojs-opts-table'.
  91 The value can either be a string that will be passed to the script, or
  92 a property.  This property is then assumed to be a property that is defined
  93 by the Export/Publishing setup of Org.
  94 The `sdepth' and `tdepth' parameters can also be set to \"max\", which
  95 means to use the maximum value consistent with other options."
  96   :group 'org-infojs
  97   :type
  98   `(set :greedy t :inline t
  99         ,@(mapcar
 100            (lambda (x)
 101              (list 'cons (list 'const (car x))
 102                    '(choice
 103                             (symbol :tag "Publishing/Export property")
 104                             (string :tag "Value"))))
 105            org-infojs-opts-table)))
 106
 107 (defcustom org-infojs-template
 108   "<script type=\"text/javascript\" src=\"%SCRIPT_PATH\"></script>
 109 <script type=\"text/javascript\" >
 110 <!--/*--><![CDATA[/*><!--*/
 111 %MANAGER_OPTIONS
 112 org_html_manager.setup();  // activate after the parameters are set
 113 /*]]>*/-->
 114 </script>"
 115   "The template for the export style additions when org-info.js is used.
 116 Option settings will replace the %MANAGER-OPTIONS cookie."
 117   :group 'org-infojs
 118   :type 'string)
 119
 120 (defun org-infojs-handle-options (exp-plist)
 121   "Analyze JavaScript options in INFO-PLIST and modify EXP-PLIST accordingly."
 122   (if (or (not org-export-html-use-infojs)
 123           (and (eq org-export-html-use-infojs 'when-configured)
 124                (or (not (plist-get exp-plist :infojs-opt))
 125                    (string-match "\\<view:nil\\>"
 126                                  (plist-get exp-plist :infojs-opt)))))
 127       ;; We do not want to use the script
 128       exp-plist
 129     ;; We do want to use the script, set it up
 130     (let ((template org-infojs-template)
 131         (ptoc (plist-get exp-plist :table-of-contents))
 132         (hlevels (plist-get exp-plist :headline-levels))
 133         tdepth sdepth s v e opt var val table default)
 134     (setq sdepth hlevels
 135           tdepth hlevels)
 136     (if (integerp ptoc) (setq tdepth (min ptoc tdepth)))
 137     (setq v (plist-get exp-plist :infojs-opt)
 138           table org-infojs-opts-table)
 139     (while (setq e (pop table))
 140       (setq opt (car e) var (nth 1 e)
 141             default (cdr (assoc opt org-infojs-options)))
 142       (and (symbolp default) (not (memq default '(t nil)))
 143            (setq default (plist-get exp-plist default)))
 144       (if (and v (string-match (format " %s:\\(\\S-+\\)" opt) v))
 145           (setq val (match-string 1 v))
 146         (setq val default))
 147       (cond
 148        ((eq opt 'path)
 149         (and (string-match "%SCRIPT_PATH" template)
 150              (setq template (replace-match val t t template))))
 151        ((eq opt 'sdepth)
 152         (if (integerp (read val))
 153             (setq sdepth (min (read val) hlevels))))
 154        ((eq opt 'tdepth)
 155         (if (integerp (read val))
 156             (setq tdepth (min (read val) hlevels))))
 157        (t
 158         (setq val
 159               (cond
 160                ((or (eq val t) (equal val "t")) "1")
 161                ((or (eq val nil) (equal val "nil")) "0")
 162                ((stringp val) val)
 163                (t (format "%s" val))))
 164         (push (cons var val) s))))
 165
 166     ;; Now we set the depth of the *generated* TOC to SDEPTH, because the
 167     ;; toc will actually determine the splitting.  How much of the toc will
 168     ;; actually be displayed is governed by the TDEPTH option.
 169     (setq exp-plist (plist-put exp-plist :table-of-contents sdepth))
 170
 171     ;; The table of contents should not show more sections then we generate
 172     (setq tdepth (min tdepth sdepth))
 173     (push (cons "TOC_DEPTH" tdepth) s)
 174
 175     (setq s (mapconcat
 176              (lambda (x) (format "org_html_manager.set(\"%s\", \"%s\");"
 177                                  (car x) (cdr x)))
 178              s "\n"))
 179     (when (and s (> (length s) 0))
 180       (and (string-match "%MANAGER_OPTIONS" template)
 181            (setq s (replace-match s t t template))
 182            (setq exp-plist
 183                  (plist-put
 184                   exp-plist :style-extra
 185                   (concat (or (plist-get exp-plist :style-extra) "") "\n" s)))))
 186     ;; This script absolutely needs the table of contents, to we change that
 187     ;; setting
 188     (if (not (plist-get exp-plist :table-of-contents))
 189         (setq exp-plist (plist-put exp-plist :table-of-contents t)))
 190     ;; Return the modified property list
 191     exp-plist)))
 192
 193 (defun org-infojs-options-inbuffer-template ()
 194   (format "#+INFOJS_OPT: view:%s toc:%s ltoc:%s mouse:%s buttons:%s path:%s"
 195           (if (eq t org-export-html-use-infojs) (cdr (assoc 'view org-infojs-options)) nil)
 196           (let ((a (cdr (assoc 'toc org-infojs-options))))
 197             (cond ((memq a '(nil t)) a)
 198                   (t (plist-get (org-infile-export-plist) :table-of-contents))))
 199           (if (equal (cdr (assoc 'ltoc org-infojs-options)) "1") t nil)
 200           (cdr (assoc 'mouse org-infojs-options))
 201           (cdr (assoc 'buttons org-infojs-options))
 202           (cdr (assoc 'path org-infojs-options))))
 203
 204 (provide 'org-infojs)
 205 (provide 'org-jsinfo)
 206
 207 ;; arch-tag: c71d1d85-3337-4817-a066-725e74ac9eac
 208
 209 ;;; org-jsinfo.el ends here