lisp/org-compat.el

   1 ;;; org-compat.el --- Compatibility code for Org-mode
   2
   3 ;; Copyright (C) 2004-2011 Free Software Foundation, Inc.
   4
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: http://orgmode.org
   8 ;;
   9 ;; This file is part of GNU Emacs.
  10 ;;
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  24 ;;
  25 ;;; Commentary:
  26
  27 ;; This file contains code needed for compatibility with XEmacs and older
  28 ;; versions of GNU Emacs.
  29
  30 ;;; Code:
  31
  32 (eval-when-compile
  33   (require 'cl))
  34
  35 (require 'org-macs)
  36
  37 (declare-function find-library-name "find-func"  (library))
  38 (declare-function w32-focus-frame "term/w32-win" (frame))
  39
  40 ;; The following constant is for backward compatibility.  We do not use
  41 ;; it in org-mode, because the Byte compiler evaluates (featurep 'xemacs)
  42 ;; at compilation time and can therefore optimize code better.
  43 (defconst org-xemacs-p (featurep 'xemacs))
  44 (defconst org-format-transports-properties-p
  45   (let ((x "a"))
  46     (add-text-properties 0 1 '(test t) x)
  47     (get-text-property 0 'test (format "%s" x)))
  48   "Does format transport text properties?")
  49
  50 (defun org-compatible-face (inherits specs)
  51   "Make a compatible face specification.
  52 If INHERITS is an existing face and if the Emacs version supports it,
  53 just inherit the face.  If INHERITS is set and the Emacs version does
  54 not support it, copy the face specification from the inheritance face.
  55 If INHERITS is not given and SPECS is, use SPECS to define the face.
  56 XEmacs and Emacs 21 do not know about the `min-colors' attribute.
  57 For them we convert a (min-colors 8) entry to a `tty' entry and move it
  58 to the top of the list.  The `min-colors' attribute will be removed from
  59 any other entries, and any resulting duplicates will be removed entirely."
  60   (when (and inherits (facep inherits) (not specs))
  61     (setq specs (or specs
  62                     (get inherits 'saved-face)
  63                     (get inherits 'face-defface-spec))))
  64   (cond
  65    ((and inherits (facep inherits)
  66          (not (featurep 'xemacs))
  67          (>= emacs-major-version 22)
  68          ;; do not inherit outline faces before Emacs 23
  69          (or (>= emacs-major-version 23)
  70              (not (string-match "\\`outline-[0-9]+"
  71                                 (symbol-name inherits)))))
  72     (list (list t :inherit inherits)))
  73    ((or (featurep 'xemacs) (< emacs-major-version 22))
  74     ;; These do not understand the `min-colors' attribute.
  75     (let (r e a)
  76       (while (setq e (pop specs))
  77         (cond
  78          ((memq (car e) '(t default)) (push e r))
  79          ((setq a (member '(min-colors 8) (car e)))
  80           (nconc r (list (cons (cons '(type tty) (delq (car a) (car e)))
  81                                (cdr e)))))
  82          ((setq a (assq 'min-colors (car e)))
  83           (setq e (cons (delq a (car e)) (cdr e)))
  84           (or (assoc (car e) r) (push e r)))
  85          (t (or (assoc (car e) r) (push e r)))))
  86       (nreverse r)))
  87    (t specs)))
  88 (put 'org-compatible-face 'lisp-indent-function 1)
  89
  90 (defun org-version-check (version feature level)
  91   (let* ((v1 (mapcar 'string-to-number (split-string version "[.]")))
  92          (v2 (mapcar 'string-to-number (split-string emacs-version "[.]")))
  93          (rmaj (or (nth 0 v1) 99))
  94          (rmin (or (nth 1 v1) 99))
  95          (rbld (or (nth 2 v1) 99))
  96          (maj (or (nth 0 v2) 0))
  97          (min (or (nth 1 v2) 0))
  98          (bld (or (nth 2 v2) 0)))
  99     (if (or (< maj rmaj)
 100             (and (= maj rmaj)
 101                  (< min rmin))
 102             (and (= maj rmaj)
 103                  (= min rmin)
 104                  (< bld rbld)))
 105         (if (eq level :predicate)
 106             ;; just return if we have the version
 107             nil
 108           (let ((msg (format "Emacs %s or greater is recommended for %s"
 109                              version feature)))
 110             (display-warning 'org msg level)
 111             t))
 112       t)))
 113
 114 ;;;; Emacs/XEmacs compatibility
 115
 116 ;; Keys
 117 (defconst org-xemacs-key-equivalents
 118   '(([mouse-1] . [button1])
 119     ([mouse-2] . [button2])
 120     ([mouse-3] . [button3])
 121     ([C-mouse-4] . [(control mouse-4)])
 122     ([C-mouse-5] . [(control mouse-5)]))
 123   "Translation alist for a couple of keys.")
 124
 125 ;; Overlay compatibility functions
 126 (defun org-detach-overlay (ovl)
 127   (if (featurep 'xemacs) (detach-extent ovl) (delete-overlay ovl)))
 128 (defun org-overlay-display (ovl text &optional face evap)
 129   "Make overlay OVL display TEXT with face FACE."
 130   (if (featurep 'xemacs)
 131       (let ((gl (make-glyph text)))
 132         (and face (set-glyph-face gl face))
 133         (set-extent-property ovl 'invisible t)
 134         (set-extent-property ovl 'end-glyph gl))
 135     (overlay-put ovl 'display text)
 136     (if face (overlay-put ovl 'face face))
 137     (if evap (overlay-put ovl 'evaporate t))))
 138 (defun org-overlay-before-string (ovl text &optional face evap)
 139   "Make overlay OVL display TEXT with face FACE."
 140   (if (featurep 'xemacs)
 141       (let ((gl (make-glyph text)))
 142         (and face (set-glyph-face gl face))
 143         (set-extent-property ovl 'begin-glyph gl))
 144     (if face (org-add-props text nil 'face face))
 145     (overlay-put ovl 'before-string text)
 146     (if evap (overlay-put ovl 'evaporate t))))
 147 (defun org-find-overlays (prop &optional pos delete)
 148   "Find all overlays specifying PROP at POS or point.
 149 If DELETE is non-nil, delete all those overlays."
 150   (let ((overlays (overlays-at (or pos (point))))
 151         ov found)
 152     (while (setq ov (pop overlays))
 153       (if (overlay-get ov prop)
 154           (if delete (delete-overlay ov) (push ov found))))
 155     found))
 156
 157 (defun org-get-x-clipboard (value)
 158   "Get the value of the x clipboard, compatible with XEmacs, and GNU Emacs 21."
 159   (if (eq window-system 'x)
 160       (let ((x (org-get-x-clipboard-compat value)))
 161         (if x (org-no-properties x)))))
 162
 163 (defsubst org-decompose-region (beg end)
 164   "Decompose from BEG to END."
 165   (if (featurep 'xemacs)
 166       (let ((modified-p (buffer-modified-p))
 167             (buffer-read-only nil))
 168         (remove-text-properties beg end '(composition nil))
 169         (set-buffer-modified-p modified-p))
 170     (decompose-region beg end)))
 171
 172 ;; Miscellaneous functions
 173
 174 (defun org-add-hook (hook function &optional append local)
 175   "Add-hook, compatible with both Emacsen."
 176   (if (and local (featurep 'xemacs))
 177       (add-local-hook hook function append)
 178     (add-hook hook function append local)))
 179
 180 (defun org-add-props (string plist &rest props)
 181   "Add text properties to entire string, from beginning to end.
 182 PLIST may be a list of properties, PROPS are individual properties and values
 183 that will be added to PLIST.  Returns the string that was modified."
 184   (add-text-properties
 185    0 (length string) (if props (append plist props) plist) string)
 186   string)
 187 (put 'org-add-props 'lisp-indent-function 2)
 188
 189 (defun org-fit-window-to-buffer (&optional window max-height min-height
 190                                            shrink-only)
 191   "Fit WINDOW to the buffer, but only if it is not a side-by-side window.
 192 WINDOW defaults to the selected window.  MAX-HEIGHT and MIN-HEIGHT are
 193 passed through to `fit-window-to-buffer'.  If SHRINK-ONLY is set, call
 194 `shrink-window-if-larger-than-buffer' instead, the height limit is
 195 ignored in this case."
 196   (cond ((if (fboundp 'window-full-width-p)
 197              (not (window-full-width-p window))
 198            (> (frame-width) (window-width window)))
 199          ;; do nothing if another window would suffer
 200          )
 201         ((and (fboundp 'fit-window-to-buffer) (not shrink-only))
 202          (fit-window-to-buffer window max-height min-height))
 203         ((fboundp 'shrink-window-if-larger-than-buffer)
 204          (shrink-window-if-larger-than-buffer window)))
 205   (or window (selected-window)))
 206
 207 (defun org-number-sequence (from &optional to inc)
 208   "Call `number-sequence or emulate it."
 209   (if (fboundp 'number-sequence)
 210       (number-sequence from to inc)
 211     (if (or (not to) (= from to))
 212         (list from)
 213       (or inc (setq inc 1))
 214       (when (zerop inc) (error "The increment can not be zero"))
 215       (let (seq (n 0) (next from))
 216         (if (> inc 0)
 217             (while (<= next to)
 218               (setq seq (cons next seq)
 219                     n (1+ n)
 220                     next (+ from (* n inc))))
 221           (while (>= next to)
 222             (setq seq (cons next seq)
 223                   n (1+ n)
 224                   next (+ from (* n inc)))))
 225         (nreverse seq)))))
 226
 227 ;; Region compatibility
 228
 229 (defvar org-ignore-region nil
 230   "To temporarily disable the active region.")
 231
 232 (defun org-region-active-p ()
 233   "Is `transient-mark-mode' on and the region active?
 234 Works on both Emacs and XEmacs."
 235   (if org-ignore-region
 236       nil
 237     (if (featurep 'xemacs)
 238         (and zmacs-regions (region-active-p))
 239       (if (fboundp 'use-region-p)
 240           (use-region-p)
 241         (and transient-mark-mode mark-active))))) ; Emacs 22 and before
 242
 243 (defun org-cursor-to-region-beginning ()
 244   (when (and (org-region-active-p)
 245              (> (point) (region-beginning)))
 246     (exchange-point-and-mark)))
 247
 248 ;; Emacs 22 misses `activate-mark'
 249 (if (fboundp 'activate-mark)
 250     (defalias 'org-activate-mark 'activate-mark)
 251   (defun org-activate-mark ()
 252     (when (mark t)
 253       (setq mark-active t)
 254       (unless transient-mark-mode
 255         (setq transient-mark-mode 'lambda)))))
 256
 257 ;; Invisibility compatibility
 258
 259 (defun org-remove-from-invisibility-spec (arg)
 260   "Remove elements from `buffer-invisibility-spec'."
 261   (if (fboundp 'remove-from-invisibility-spec)
 262       (remove-from-invisibility-spec arg)
 263     (if (consp buffer-invisibility-spec)
 264         (setq buffer-invisibility-spec
 265               (delete arg buffer-invisibility-spec)))))
 266
 267 (defun org-in-invisibility-spec-p (arg)
 268   "Is ARG a member of `buffer-invisibility-spec'?"
 269   (if (consp buffer-invisibility-spec)
 270       (member arg buffer-invisibility-spec)
 271     nil))
 272
 273 (defmacro org-xemacs-without-invisibility (&rest body)
 274   "Turn off exents with invisibility while executing BODY."
 275   `(let ((ext-inv (extent-list nil (point-at-bol) (point-at-eol)
 276                                'all-extents-closed-open 'invisible))
 277          ext-inv-specs)
 278      (dolist (ext ext-inv)
 279        (when (extent-property ext 'invisible)
 280          (add-to-list 'ext-inv-specs (list ext (extent-property
 281                                                 ext 'invisible)))
 282          (set-extent-property ext 'invisible nil)))
 283      ,@body
 284      (dolist (ext-inv-spec ext-inv-specs)
 285        (set-extent-property (car ext-inv-spec) 'invisible
 286                             (cadr ext-inv-spec)))))
 287 (def-edebug-spec org-xemacs-without-invisibility (body))
 288
 289 (defun org-indent-to-column (column &optional minimum buffer)
 290   "Work around a bug with extents with invisibility in XEmacs."
 291   (if (featurep 'xemacs)
 292       (org-xemacs-without-invisibility (indent-to-column column minimum buffer))
 293     (indent-to-column column minimum)))
 294
 295 (defun org-indent-line-to (column)
 296   "Work around a bug with extents with invisibility in XEmacs."
 297   (if (featurep 'xemacs)
 298       (org-xemacs-without-invisibility (indent-line-to column))
 299     (indent-line-to column)))
 300
 301 (defun org-move-to-column (column &optional force buffer)
 302   (if (featurep 'xemacs)
 303       (org-xemacs-without-invisibility (move-to-column column force buffer))
 304     (move-to-column column force)))
 305
 306 (defun org-get-x-clipboard-compat (value)
 307   "Get the clipboard value on XEmacs or Emacs 21."
 308   (cond ((featurep 'xemacs)
 309          (org-no-warnings (get-selection-no-error value)))
 310         ((fboundp 'x-get-selection)
 311          (condition-case nil
 312              (or (x-get-selection value 'UTF8_STRING)
 313                  (x-get-selection value 'COMPOUND_TEXT)
 314                  (x-get-selection value 'STRING)
 315                  (x-get-selection value 'TEXT))
 316            (error nil)))))
 317
 318 (defun org-propertize (string &rest properties)
 319   (if (featurep 'xemacs)
 320       (progn
 321         (add-text-properties 0 (length string) properties string)
 322         string)
 323     (apply 'propertize string properties)))
 324
 325 (defun org-substring-no-properties (string &optional from to)
 326   (if (featurep 'xemacs)
 327       (org-no-properties (substring string (or from 0) to))
 328     (substring-no-properties string from to)))
 329
 330 (defun org-find-library-name (library)
 331   (if (fboundp 'find-library-name)
 332       (file-name-directory (find-library-name library))
 333     ; XEmacs does not have `find-library-name'
 334     (flet ((find-library-name-helper (filename ignored-codesys)
 335                                      filename)
 336            (find-library-name (library)
 337             (find-library library nil 'find-library-name-helper)))
 338       (file-name-directory (find-library-name library)))))
 339
 340 (defun org-count-lines (s)
 341   "How many lines in string S?"
 342   (let ((start 0) (n 1))
 343     (while (string-match "\n" s start)
 344       (setq start (match-end 0) n (1+ n)))
 345     (if (and (> (length s) 0) (= (aref s (1- (length s))) ?\n))
 346         (setq n (1- n)))
 347     n))
 348
 349 (defun org-kill-new (string &rest args)
 350   (remove-text-properties 0 (length string) '(line-prefix t wrap-prefix t)
 351                           string)
 352   (apply 'kill-new string args))
 353
 354 (defun org-select-frame-set-input-focus (frame)
 355   "Select FRAME, raise it, and set input focus, if possible."
 356   (cond ((featurep 'xemacs)
 357          (if (fboundp 'select-frame-set-input-focus)
 358              (select-frame-set-input-focus frame)
 359            (raise-frame frame)
 360            (select-frame frame)
 361            (focus-frame frame)))
 362         ;; `select-frame-set-input-focus' defined in Emacs 21 will not
 363         ;; set the input focus.
 364         ((>= emacs-major-version 22)
 365          (select-frame-set-input-focus frame))
 366         (t
 367          (raise-frame frame)
 368          (select-frame frame)
 369          (cond ((memq window-system '(x ns mac))
 370                 (x-focus-frame frame))
 371                ((eq window-system 'w32)
 372                 (w32-focus-frame frame)))
 373          (when focus-follows-mouse
 374            (set-mouse-position frame (1- (frame-width frame)) 0)))))
 375
 376 (defun org-float-time (&optional time)
 377   "Convert time value TIME to a floating point number.
 378 TIME defaults to the current time."
 379   (if (featurep 'xemacs)
 380       (time-to-seconds (or time (current-time)))
 381     (float-time time)))
 382
 383 (if (fboundp 'string-match-p)
 384     (defalias 'org-string-match-p 'string-match-p)
 385   (defun org-string-match-p (regexp string &optional start)
 386     (save-match-data
 387       (funcall 'string-match regexp string start))))
 388
 389 (if (fboundp 'looking-at-p)
 390     (defalias 'org-looking-at-p 'looking-at-p)
 391   (defun org-looking-at-p (&rest args)
 392     (save-match-data
 393       (apply 'looking-at args))))
 394
 395 ; XEmacs does not have `looking-back'.
 396 (if (fboundp 'looking-back)
 397     (defalias 'org-looking-back 'looking-back)
 398   (defun org-looking-back (regexp &optional limit greedy)
 399     "Return non-nil if text before point matches regular expression REGEXP.
 400 Like `looking-at' except matches before point, and is slower.
 401 LIMIT if non-nil speeds up the search by specifying a minimum
 402 starting position, to avoid checking matches that would start
 403 before LIMIT.
 404
 405 If GREEDY is non-nil, extend the match backwards as far as
 406 possible, stopping when a single additional previous character
 407 cannot be part of a match for REGEXP.  When the match is
 408 extended, its starting position is allowed to occur before
 409 LIMIT."
 410     (let ((start (point))
 411           (pos
 412            (save-excursion
 413              (and (re-search-backward (concat "\\(?:" regexp "\\)\\=") limit t)
 414                   (point)))))
 415       (if (and greedy pos)
 416           (save-restriction
 417             (narrow-to-region (point-min) start)
 418             (while (and (> pos (point-min))
 419                         (save-excursion
 420                           (goto-char pos)
 421                           (backward-char 1)
 422                           (looking-at (concat "\\(?:"  regexp "\\)\\'"))))
 423               (setq pos (1- pos)))
 424             (save-excursion
 425               (goto-char pos)
 426               (looking-at (concat "\\(?:"  regexp "\\)\\'")))))
 427       (not (null pos)))))
 428
 429 (defun org-floor* (x &optional y)
 430   "Return a list of the floor of X and the fractional part of X.
 431 With two arguments, return floor and remainder of their quotient."
 432   (let ((q (floor x y)))
 433     (list q (- x (if y (* y q) q)))))
 434
 435 ;; `pop-to-buffer-same-window' has been introduced with Emacs 24.1.
 436 (defun org-pop-to-buffer-same-window
 437   (&optional buffer-or-name norecord label)
 438   "Pop to buffer specified by BUFFER-OR-NAME in the selected window."
 439   (if (fboundp 'pop-to-buffer-same-window)
 440       (funcall
 441        'pop-to-buffer-same-window buffer-or-name norecord label)
 442     (funcall 'switch-to-buffer buffer-or-name norecord)))
 443
 444 (provide 'org-compat)
 445
 446 ;;; org-compat.el ends here