lisp/org-vm.el

   1 ;;; org-vm.el --- Support for links to VM messages from within Org-mode
   2
   3 ;; Copyright (C) 2004, 2005, 2006, 2007, 2008, 2009 Free Software Foundation, Inc.
   4
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: http://orgmode.org
   8 ;; Version: 6.18trans
   9 ;;
  10 ;; This file is part of GNU Emacs.
  11 ;;
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  25 ;;
  26 ;;; Commentary:
  27 ;; This file implements links to VM messages and folders from within Org-mode.
  28 ;; Org-mode loads this module by default - if this is not what you want,
  29 ;; configure the variable `org-modules'.
  30
  31 ;;; Code:
  32
  33 (require 'org)
  34
  35 ;; Declare external functions and variables
  36 (declare-function vm-preview-current-message "ext:vm-page" ())
  37 (declare-function vm-follow-summary-cursor "ext:vm-motion" ())
  38 (declare-function vm-get-header-contents "ext:vm-summary"
  39                   (message header-name-regexp &optional clump-sep))
  40 (declare-function vm-isearch-narrow "ext:vm-search" ())
  41 (declare-function vm-isearch-update "ext:vm-search" ())
  42 (declare-function vm-select-folder-buffer "ext:vm-macro" ())
  43 (declare-function vm-su-message-id "ext:vm-summary" (m))
  44 (declare-function vm-su-subject "ext:vm-summary" (m))
  45 (declare-function vm-summarize "ext:vm-summary" (&optional display raise))
  46 (defvar vm-message-pointer)
  47 (defvar vm-folder-directory)
  48
  49 ;; Install the link type
  50 (org-add-link-type "vm" 'org-vm-open)
  51 (add-hook 'org-store-link-functions 'org-vm-store-link)
  52
  53 ;; Implementation
  54 (defun org-vm-store-link ()
  55   "Store a link to a VM folder or message."
  56   (when (or (eq major-mode 'vm-summary-mode)
  57             (eq major-mode 'vm-presentation-mode))
  58     (and (eq major-mode 'vm-presentation-mode) (vm-summarize))
  59     (vm-follow-summary-cursor)
  60     (save-excursion
  61       (vm-select-folder-buffer)
  62       (let* ((message (car vm-message-pointer))
  63              (folder buffer-file-name)
  64              (subject (vm-su-subject message))
  65              (to (vm-get-header-contents message "To"))
  66              (from (vm-get-header-contents message "From"))
  67              (message-id (vm-su-message-id message))
  68              desc link)
  69         (org-store-link-props :type "vm" :from from :to to :subject subject
  70                               :message-id message-id)
  71         (setq message-id (org-remove-angle-brackets message-id))
  72         (setq folder (abbreviate-file-name folder))
  73         (if (string-match (concat "^" (regexp-quote vm-folder-directory))
  74                           folder)
  75             (setq folder (replace-match "" t t folder)))
  76         (setq desc (org-email-link-description))
  77         (setq link (org-make-link "vm:" folder "#" message-id))
  78         (org-add-link-props :link link :description desc)
  79         link))))
  80
  81 (defun org-vm-open (path)
  82   "Follow a VM message link specified by PATH."
  83   (let (folder article)
  84     (if (not (string-match "\\`\\([^#]+\\)\\(#\\(.*\\)\\)?" path))
  85         (error "Error in VM link"))
  86     (setq folder (match-string 1 path)
  87           article (match-string 3 path))
  88     ;; The prefix argument will be interpreted as read-only
  89     (org-vm-follow-link folder article current-prefix-arg)))
  90
  91 (defun org-vm-follow-link (&optional folder article readonly)
  92   "Follow a VM link to FOLDER and ARTICLE."
  93   (require 'vm)
  94   (setq article (org-add-angle-brackets article))
  95   (if (string-match "^//\\([a-zA-Z]+@\\)?\\([^:]+\\):\\(.*\\)" folder)
  96       ;; ange-ftp or efs or tramp access
  97       (let ((user (or (match-string 1 folder) (user-login-name)))
  98             (host (match-string 2 folder))
  99             (file (match-string 3 folder)))
 100         (cond
 101          ((featurep 'tramp)
 102           ;; use tramp to access the file
 103           (if (featurep 'xemacs)
 104               (setq folder (format "[%s@%s]%s" user host file))
 105             (setq folder (format "/%s@%s:%s" user host file))))
 106          (t
 107           ;; use ange-ftp or efs
 108           (require (if (featurep 'xemacs) 'efs 'ange-ftp))
 109           (setq folder (format "/%s@%s:%s" user host file))))))
 110   (when folder
 111     (funcall (cdr (assq 'vm org-link-frame-setup)) folder readonly)
 112     (sit-for 0.1)
 113     (when article
 114       (require 'vm-search)
 115       (vm-select-folder-buffer)
 116       (widen)
 117       (let ((case-fold-search t))
 118         (goto-char (point-min))
 119         (if (not (re-search-forward
 120                   (concat "^" "message-id: *" (regexp-quote article))))
 121             (error "Could not find the specified message in this folder"))
 122         (vm-isearch-update)
 123         (vm-isearch-narrow)
 124         (vm-preview-current-message)
 125         (vm-summarize)))))
 126
 127 (provide 'org-vm)
 128
 129 ;; arch-tag: cbc3047b-935e-4d2a-96e7-c5b0117aaa6d
 130
 131 ;;; org-vm.el ends here