lisp/org-protocol.el

   1 ;;; org-protocol.el --- Intercept calls from emacsclient to trigger custom actions.
   2 ;;
   3 ;; Copyright (c) 2008, 2009
   4 ;;          Bastien Guerry <bzg AT altern DOT org>,
   5 ;;          Daniel German <dmg AT uvic DOT org>,
   6 ;;          Sebastian Rose <sebastian_rose AT gmx DOT de>,
   7 ;;          Ross Patterson <me AT rpatterson DOT net>
   8 ;;          David Moffat
   9 ;;          (will be FSF when done)
  10 ;;
  11 ;;
  12 ;; Filename: org-protocol.el
  13 ;; Version: 6.29a
  14 ;; Author: Bastien Guerry <bzg AT altern DOT org>
  15 ;; Author: Daniel M German <dmg AT uvic DOT org>
  16 ;; Author: Sebastian Rose <sebastian_rose AT gmx DOT de>
  17 ;; Author: Ross Patterson <me AT rpatterson DOT net>
  18 ;; Maintainer: Sebastian Rose <sebastian_rose AT gmx DOT de>
  19 ;; Keywords: org, emacsclient, wp
  20
  21 ;; This file is not part of GNU Emacs.
  22
  23 ;; This program is free software: you can redistribute it and/or modify
  24 ;; it under the terms of the GNU General Public License as published by
  25 ;; the Free Software Foundation, either version 3 of the License, or
  26 ;; (at your option) any later version.
  27
  28 ;; This program is distributed in the hope that it will be useful,
  29 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  30 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  31 ;; GNU General Public License for more details.
  32
  33 ;; See <http://www.gnu.org/licenses/>.
  34
  35 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  36 ;;; Commentary:
  37 ;;
  38 ;; Intercept calls from emacsclient to trigger custom actions.
  39 ;;
  40 ;; This is done by advising `server-visit-files' to scann the list of filenames
  41 ;; for `org-protocol-the-protocol' and sub-procols defined in
  42 ;; `org-protocol-protocol-alist' and `org-protocol-protocol-alist-default'.
  43 ;;
  44 ;; Any application that supports calling external programs with an URL
  45 ;; as argument may be used with this functionality.
  46 ;;
  47 ;;
  48 ;; Usage:
  49 ;; ------
  50 ;;
  51 ;;   1.) Add this to your init file (.emacs probably):
  52 ;;
  53 ;;       (add-to-list 'load-path "/path/to/org-protocol/")
  54 ;;       (require 'org-protocol)
  55 ;;
  56 ;;   3.) Ensure emacs-server is up and running.
  57 ;;   4.) Try this from the command line (adjust the URL as needed):
  58 ;;
  59 ;;       $ emacsclient \
  60 ;;         org-protocol://store-link://http:%2F%2Flocalhost%2Findex.html/The%20title
  61 ;;
  62 ;;   5.) Optionally add custom sub-protocols and handlers:
  63 ;;
  64 ;;       (setq org-protocol-protocol-alist
  65 ;;             '(("my-protocol"
  66 ;;                :protocol "my-protocol"
  67 ;;                :function my-protocol-handler-fuction)))
  68 ;;
  69 ;;       A "sub-protocol" will be found in URLs like this:
  70 ;;
  71 ;;           org-protocol://sub-protocol://data
  72 ;;
  73 ;; If it works, you can now setup other applications for using this feature.
  74 ;;
  75 ;;
  76 ;; As of March 2009 Firefox users follow the steps documented on
  77 ;; http://kb.mozillazine.org/Register_protocol, Opera setup is described here:
  78 ;; http://www.opera.com/support/kb/view/535/
  79 ;;
  80 ;;
  81 ;; Documentation
  82 ;; -------------
  83 ;;
  84 ;; org-protocol.el comes with and installs handlers to open sources of published
  85 ;; online content, store and insert the browser's URLs and cite online content
  86 ;; by clicking on a bookmark in Firefox, Opera and probably other browsers and
  87 ;; applications:
  88 ;;
  89 ;;   * `org-protocol-open-source' uses the sub-protocol \"open-source\" and maps
  90 ;;     URLs to local filenames defined in `org-protocol-project-alist'.
  91 ;;
  92 ;;   * `org-protocol-store-link' stores an Org-link (if Org-mode is present) and
  93 ;;     pushes the browsers URL to the `kill-ring' for yanking. This handler is
  94 ;;     triggered through the sub-protocol \"store-link\".
  95 ;;
  96 ;;   * Call `org-protocol-remember' by using the sub-protocol \"remember\".  If
  97 ;;     Org-mode is loaded, emacs will popup a remember buffer and fill the
  98 ;;     template with the data provided. I.e. the browser's URL is inserted as an
  99 ;;     Org-link of which the page title will be the description part. If text
 100 ;;     was select in the browser, that text will be the body of the entry.
 101 ;;
 102 ;; You may use the same bookmark URL for all those standard handlers and just
 103 ;; adjust the sub-protocol used:
 104 ;;
 105 ;;     location.href='org-protocol://sub-protocol://'+
 106 ;;           encodeURIComponent(location.href)+'/'+
 107 ;;           encodeURIComponent(document.title)+'/'+
 108 ;;           encodeURIComponent(window.getSelection())
 109 ;;
 110 ;; The handler for the sub-protocol \"remember\" detects an optional template
 111 ;; char that, if present, triggers the use of a special template.
 112 ;; Example:
 113 ;;
 114 ;;     location.href='org-protocol://sub-protocol://x/'+ ...
 115 ;;
 116 ;;  use template ?x.
 117 ;;
 118 ;; Note, that using double shlashes is optional from org-protocol.el's point of
 119 ;; view because emacsclient sqashes the slashes to one.
 120 ;;
 121 ;;
 122 ;; provides: 'org-protocol
 123 ;;
 124 ;;; Code:
 125
 126 (require 'org)
 127 (eval-when-compile
 128   (require 'cl))
 129
 130 (declare-function org-publish-initialize-files-alist "org-publish"
 131                   (&optional refresh))
 132 (declare-function org-publish-get-project-from-filename "org-publish"
 133                   (filename &optional up))
 134 (declare-function server-edit "server" ())
 135
 136
 137 (defgroup org-protocol nil
 138   "Intercept calls from emacsclient to trigger custom actions.
 139
 140 This is done by advising `server-visit-files' to scann the list of filenames
 141 for `org-protocol-the-protocol' and sub-procols defined in
 142 `org-protocol-protocol-alist' and `org-protocol-protocol-alist-default'."
 143   :version "22.1"
 144   :group 'convenience
 145   :group 'org)
 146
 147
 148 ;;; Variables:
 149
 150 (defconst org-protocol-protocol-alist-default
 151   '(("org-remember"    :protocol "remember"    :function org-protocol-remember :kill-client t)
 152     ("org-store-link"  :protocol "store-link"  :function org-protocol-store-link)
 153     ("org-open-source" :protocol "open-source" :function org-protocol-open-source))
 154   "Default protocols to use.
 155 See `org-protocol-protocol-alist' for a description of this variable.")
 156
 157
 158 (defconst org-protocol-the-protocol "org-protocol"
 159   "This is the protocol to detect if org-protocol.el is loaded.
 160 `org-protocol-protocol-alist-default' and `org-protocol-protocol-alist' hold the
 161 sub-protocols that trigger the required action. You will have to define just one
 162 protocol handler OS-wide (MS-Windows) or per application (Linux). That protocol
 163 handler should call emacsclient.")
 164
 165
 166 ;;; User variables:
 167
 168 (defcustom org-protocol-reverse-list-of-files t
 169   "* The filenames passed on the commandline are passed to the emacs-server in
 170 reversed order. Set to `t' (default) to re-reverse the list, i.e. use the
 171 sequence on the command line. If nil, the sequence of the filenames is
 172 unchanged."
 173   :group 'org-protocol
 174   :type 'boolean)
 175
 176
 177 (defcustom org-protocol-project-alist nil
 178   "* Map URLs to local filenames for `org-protocol-open-source' (open-source).
 179
 180 Each element of this list must be of the form:
 181
 182   (module-name :property value property: value ...)
 183
 184 where module-name is an arbitrary name. All the values are strings.
 185
 186 Possible properties are:
 187
 188   :online-suffix     - the suffix to strip from the published URLs
 189   :working-suffix    - the replacement for online-suffix
 190   :base-url          - the base URL, e.g. http://www.example.com/project/
 191                        Last slash required.
 192   :working-directory - the local working directory. This is, what base-url will
 193                        be replaced with.
 194
 195 Example:
 196
 197    (setq org-protocol-project-alist
 198        '((\"http://orgmode.org/worg/\"
 199           :online-suffix \".php\"
 200           :working-suffix \".org\"
 201           :base-url \"http://orgmode.org/worg/\"
 202           :working-directory \"/home/user/org/Worg/\")
 203          (\"http://localhost/org-notes/\"
 204           :online-suffix \".html\"
 205           :working-suffix \".org\"
 206           :base-url \"http://localhost/org/\"
 207           :working-directory \"/home/user/org/\")))
 208
 209 Consider using the interactive functions `org-protocol-create' and
 210 `org-protocol-create-for-org' to help you filling this variable with valid contents."
 211   :group 'org-protocol
 212   :type 'alist)
 213
 214
 215 (defcustom org-protocol-protocol-alist nil
 216   "* Register custom handlers for org-protocol.
 217
 218 Each element of this list must be of the form:
 219
 220   (module-name :protocol protocol :function func :kill-client nil)
 221
 222 protocol - protocol to detect in a filename without trailing colon and slashes.
 223            See rfc1738 section 2.1 for more on this.
 224            If you define a protocol \"my-protocol\", `org-protocol-check-filename-for-protocol'
 225            will search filenames for \"org-protocol:/my-protocol:/\"
 226            and trigger your action for every match. `org-protocol' is defined in
 227            `org-protocol-the-protocol'. Double and tripple slashes are compressed
 228            to one by emacsclient.
 229
 230 function - function that handles requests with protocol and takes exactly one
 231            argument: the filename with all protocols stripped. If the function
 232            returns nil, emacsclient and -server do nothing. Any non-nil return
 233            value is considered a valid filename and thus passed to the server.
 234
 235            `org-protocol.el provides some support for handling those filenames,
 236            if you stay with the conventions used for the standard handlers in
 237            `org-protocol-protocol-alist-default'. See `org-protocol-split-data'.
 238
 239 kill-client - If t, kill the client immediately, once the sub-protocol is
 240            detected. This is neccessary for actions that can be interupted by
 241            `C-g' to avoid dangeling emacsclients. Note, that all other command
 242            line arguments but the this one will be discarded, greedy handlers
 243            still receive the whole list of arguments though.
 244
 245 Here is an example:
 246
 247   (setq org-protocol-protocol-alist
 248       '((\"my-protocol\"
 249          :protocol \"my-protocol\"
 250          :function my-protocol-handler-fuction)
 251         (\"your-protocol\"
 252          :protocol \"your-protocol\"
 253          :function your-protocol-handler-fuction)))"
 254   :group 'org-protocol
 255   :type '(alist))
 256
 257 (defcustom org-protocol-default-template-key "w"
 258   "The default org-remember-templates key to use."
 259   :group 'org-protocol
 260   :type 'string)
 261
 262
 263 ;;; Helper functions:
 264
 265 (defun org-protocol-sanitize-uri (uri)
 266   "emacsclient compresses double and tripple slashes.
 267 Slashes are sanitized to double slashes here."
 268   (when (string-match "^\\([a-z]+\\):/" uri)
 269     (let* ((splitparts (split-string uri "/+")))
 270       (setq uri (concat (car splitparts) "//" (mapconcat 'identity (cdr splitparts) "/")))))
 271   uri)
 272
 273
 274 (defun org-protocol-split-data(data &optional unhexify separator)
 275   "Split, what a org-protocol handler function gets as only argument.
 276 data is that one argument. Data is splitted at each occurrence of separator
 277  (regexp). If no separator is specified or separator is nil, assume \"/+\".
 278 The results of that splitting are return as a list. If unhexify is non-nil,
 279 hex-decode each split part. If unhexify is a function, use that function to
 280 decode each split part."
 281   (let* ((sep (or separator "/+"))
 282          (split-parts (split-string data sep)))
 283     (if unhexify
 284         (if (fboundp unhexify)
 285             (mapcar unhexify split-parts)
 286           (mapcar 'org-protocol-unhex-string split-parts))
 287       split-parts)))
 288
 289 (defun org-protocol-unhex-string(str)
 290   "Unhex hexified unicode strings as returned from the JavaScript function
 291 encodeURIComponent. E.g. `%C3%B6' is the german Umlaut `ü'."
 292   (setq str (or str ""))
 293   (let ((tmp "")
 294         (case-fold-search t))
 295     (while (string-match "\\(%[0-9a-f][0-9a-f]\\)+" str)
 296       (let* ((start (match-beginning 0))
 297              (end (match-end 0))
 298              (hex (match-string 0 str))
 299              (replacement (org-protocol-unhex-compound hex)))
 300         (setq tmp (concat tmp (substring str 0 start) replacement))
 301         (setq str (substring str end))))
 302     (setq tmp (concat tmp str))
 303     tmp))
 304
 305
 306 (defun org-protocol-unhex-compound (hex)
 307   "Unhexify unicode hex-chars. E.g. `%C3%B6' is the german Umlaut `ü'."
 308   (let* ((bytes (remove "" (split-string hex "%")))
 309          (ret "")
 310          (eat 0)
 311          (sum 0))
 312     (while bytes
 313       (let* ((b (pop bytes))
 314              (a (elt b 0))
 315              (b (elt b 1))
 316              (c1 (if (> a ?9) (+ 10 (- a ?A)) (- a ?0)))
 317              (c2 (if (> b ?9) (+ 10 (- b ?A)) (- b ?0)))
 318              (val (+ (lsh c1 4) c2))
 319              (shift
 320               (if (= 0 eat) ;; new byte
 321                   (if (>= val 252) 6
 322                     (if (>= val 248) 5
 323                       (if (>= val 240) 4
 324                         (if (>= val 224) 3
 325                           (if (>= val 192) 2 0)))))
 326                 6))
 327              (xor
 328               (if (= 0 eat) ;; new byte
 329                   (if (>= val 252) 252
 330                     (if (>= val 248) 248
 331                       (if (>= val 240) 240
 332                         (if (>= val 224) 224
 333                           (if (>= val 192) 192 0)))))
 334                 128)))
 335         (if (>= val 192) (setq eat shift))
 336         (setq val (logxor val xor))
 337         (setq sum (+ (lsh sum shift) val))
 338         (if (> eat 0) (setq eat (- eat 1)))
 339         (when (= 0 eat)
 340           (setq ret (concat ret (char-to-string sum)))
 341           (setq sum 0))
 342         )) ;; end (while bytes
 343     ret ))
 344
 345 (defun org-protocol-flatten-greedy (param-list &optional strip-path replacement)
 346   "Greedy handlers might recieve a list like this from emacsclient:
 347  '( (\"/dir/org-protocol:/greedy:/~/path1\" (23 . 12)) (\"/dir/param\")
 348 where \"/dir/\" is the absolute path to emacsclients working directory. This
 349 function transforms it into a flat list utilizing `org-protocol-flatten' and
 350 transforms the elements of that list as follows:
 351
 352 If strip-path is non-nil, remove the \"/dir/\" prefix from all members of
 353 param-list.
 354
 355 If replacement is string, replace the \"/dir/\" prefix with it.
 356
 357 The first parameter, the one that contains the protocols, is always changed.
 358 Everything up to the end of the protocols is stripped.
 359
 360 Note, that this function will always behave as if
 361 `org-protocol-reverse-list-of-files' was set to t and the returned list will
 362 reflect that. I.e. emacsclients first parameter will be the first one in the
 363 returned list."
 364 (let* ((l (org-protocol-flatten (if org-protocol-reverse-list-of-files
 365                                     param-list
 366                                   (reverse param-list))))
 367       (trigger (car l))
 368       (len 0)
 369       dir
 370       ret)
 371   (when (string-match "^\\(.*\\)\\(org-protocol:/+[a-zA-z0-9][-_a-zA-z0-9]*:/+\\)\\(.*\\)" trigger)
 372     (setq dir (match-string 1 trigger))
 373     (setq len (length dir))
 374     (setcar l (concat dir (match-string 3 trigger))))
 375   (if strip-path
 376       (progn
 377        (dolist (e l ret)
 378          (setq ret
 379                (append ret
 380                        (list
 381                         (if (stringp e)
 382                             (if (stringp replacement)
 383                                 (setq e (concat replacement (substring e len)))
 384                               (setq e (substring e len)))
 385                           e)))))
 386        ret)
 387     l)))
 388
 389
 390 (defun org-protocol-flatten (l)
 391   "Greedy handlers might recieve a list like this from emacsclient:
 392  '( (\"/dir/org-protocol:/greedy:/~/path1\" (23 . 12)) (\"/dir/param\")
 393 where \"/dir/\" is the absolute path to emacsclients working directory. This
 394 function transforms it into a flat list."
 395   (if (null l) ()
 396     (if (listp l)
 397        (append (org-protocol-flatten (car l)) (org-protocol-flatten (cdr l)))
 398       (list l))))
 399
 400 ;;; Standard protocol handlers:
 401
 402 (defun org-protocol-store-link (fname)
 403   "Process an org-protocol://store-link:// style url
 404 and store a browser URL as an org link. Also pushes the links URL to the
 405 `kill-ring'.
 406
 407 The location for a browser's bookmark has to look like this:
 408
 409   javascript:location.href='org-protocol://store-link://'+ \\
 410         encodeURIComponent(location.href)
 411         encodeURIComponent(document.title)+'/'+ \\
 412
 413 Don't use `escape()'! Use `encodeURIComponent()' instead. The title of the page
 414 could contain slashes and the location definitely will.
 415
 416 The sub-protocol used to reach this function is set in
 417 `org-protocol-protocol-alist'."
 418   (let* ((splitparts (org-protocol-split-data fname t))
 419          (uri (org-protocol-sanitize-uri (car splitparts)))
 420          (title (cadr splitparts))
 421          orglink)
 422     (if (boundp 'org-stored-links)
 423       (setq org-stored-links (cons (list uri title) org-stored-links)))
 424     (kill-new uri)
 425     (message "`%s' to insert new org-link, `%s' to insert `%s'"
 426              (substitute-command-keys"\\[org-insert-link]")
 427              (substitute-command-keys"\\[yank]")
 428              uri))
 429   nil)
 430
 431
 432 (defun org-protocol-remember  (info)
 433   "Process an org-protocol://remember:// style url.
 434
 435 The sub-protocol used to reach this function is set in
 436 `org-protocol-protocol-alist'.
 437
 438 This function detects an URL, title and optinal text, separated by '/'
 439 The location for a browser's bookmark has to look like this:
 440
 441   javascript:location.href='org-protocol://remember://'+ \\
 442         encodeURIComponent(location.href)+'/' \\
 443         encodeURIComponent(document.title)+'/'+ \\
 444         encodeURIComponent(window.getSelection())
 445
 446 By default, it uses the character `org-protocol-default-template-key',
 447 which should be associated with a template in `org-remember-templates'.
 448 But you may prepend the encoded URL with a character and a slash like so:
 449
 450   javascript:location.href='org-protocol://org-store-link://b/'+ ...
 451
 452 Now template ?b will be used."
 453
 454   (if (and (boundp 'org-stored-links)
 455            (fboundp 'org-remember))
 456       (let* ((parts (org-protocol-split-data info t))
 457              (template (or (and (= 1 (length (car parts))) (pop parts))
 458                            org-protocol-default-template-key))
 459              (url (org-protocol-sanitize-uri (car parts)))
 460              (type (if (string-match "^\\([a-z]+\\):" url)
 461                        (match-string 1 url)))
 462              (title (cadr parts))
 463              (region (caddr parts))
 464              (orglink (org-make-link-string url title))
 465              remember-annotation-functions)
 466         (setq org-stored-links
 467               (cons (list url title) org-stored-links))
 468         (kill-new orglink)
 469         (org-store-link-props :type type
 470                               :link url
 471                               :description title
 472                               :initial region)
 473         (raise-frame)
 474         (org-remember nil (string-to-char template)))
 475
 476     (message "Org-mode not loaded."))
 477   nil)
 478
 479
 480 (defun org-protocol-open-source (fname)
 481   "Process an org-protocol://open-source:// style url.
 482
 483 Change a filename by mapping URLs to local filenames as set
 484 in `org-protocol-project-alist'.
 485
 486 The location for a browser's bookmark should look like this:
 487
 488   javascript:location.href='org-protocol://open-source://'+ \\
 489         encodeURIComponent(location.href)"
 490
 491   ;; As we enter this function for a match on our protocol, the return value
 492   ;; defaults to nil.
 493   (let ((result nil)
 494         (f (org-protocol-unhex-string fname)))
 495     (catch 'result
 496       (dolist (prolist org-protocol-project-alist)
 497         (let* ((base-url (plist-get (cdr prolist) :base-url))
 498                (wsearch (regexp-quote base-url)))
 499
 500           (when (string-match wsearch f)
 501             (let* ((wdir (plist-get (cdr prolist) :working-directory))
 502                    (strip-suffix (plist-get (cdr prolist) :online-suffix))
 503                    (add-suffix (plist-get (cdr prolist) :working-suffix))
 504                    (start-pos (+ (string-match wsearch f) (length base-url)))
 505                    (end-pos (string-match
 506                              (concat (regexp-quote strip-suffix) "\\([?#].*\\)?$") f))
 507                    (the-file (concat wdir (substring f start-pos end-pos) add-suffix)))
 508               (if (file-readable-p the-file)
 509                   (throw 'result the-file))
 510               (if (file-exists-p the-file)
 511                   (message "%s: permission denied!" the-file)
 512                 (message "%s: no such file or directory." the-file))))))
 513       result)))
 514
 515
 516 ;;; Core functions:
 517
 518 (defun org-protocol-check-filename-for-protocol (fname restoffiles client)
 519   "Detect if `org-protocol-the-protocol' and a known sub-protocol is used in fname.
 520 Sub-protocols are registered in `org-protocol-protocol-alist' and
 521 `org-protocol-protocol-alist-default'.
 522 This is, how the matching is done:
 523
 524   (string-match \"protocol:/+sub-protocol:/+\" ...)
 525
 526 protocol and sub-protocol are regexp-quoted.
 527
 528 If a matching protcol is found, the protcol is stripped from fname and the
 529 result is passed to the protocols function as the only parameter. If the
 530 function returns nil, the filename is removed from the list of filenames
 531 passed from emacsclient to the server.
 532 If the function returns a non nil value, that value is passed to the server
 533 as filename."
 534   (let ((sub-protocols (append org-protocol-protocol-alist org-protocol-protocol-alist-default)))
 535     (catch 'fname
 536       (let ((the-protocol (concat (regexp-quote org-protocol-the-protocol) ":/+")))
 537         (when (string-match the-protocol fname)
 538           (dolist (prolist sub-protocols)
 539             (let ((proto (concat the-protocol (regexp-quote (plist-get (cdr prolist) :protocol)) ":/+")))
 540               (when (string-match proto fname)
 541                 (let* ((func (plist-get (cdr prolist) :function))
 542                        (greedy (plist-get (cdr prolist) :greedy))
 543                        (splitted (split-string fname proto))
 544                        (result (if greedy restoffiles (cadr splitted))))
 545                   (when (plist-get (cdr prolist) :kill-client)
 546                     (message "Greedy org-protocol handler. Killing client.")
 547                     (server-edit))
 548                   (when (fboundp func)
 549                     (unless greedy
 550                       (throw 'fname (funcall func result)))
 551                     (funcall func result)
 552                     (throw 'fname t))))))))
 553       ;; (message "fname: %s" fname)
 554       fname)))
 555
 556
 557 (defadvice server-visit-files (before org-protocol-detect-protocol-server activate)
 558   "Advice server-visit-flist to call `org-protocol-modify-filename-for-protocol'."
 559   (let ((flist (if org-protocol-reverse-list-of-files
 560                    (reverse  (ad-get-arg 0))
 561                  (ad-get-arg 0)))
 562         (client (ad-get-arg 1)))
 563     (catch 'greedy
 564       (dolist (var flist)
 565         (let ((fname  (expand-file-name (car var)))) ;; `\' to `/' on windows. FIXME: could this be done any better?
 566           (setq fname (org-protocol-check-filename-for-protocol fname (member var flist)  client))
 567           (if (eq fname t) ;; greedy? We need the `t' return value.
 568               (progn
 569                 (ad-set-arg 0 nil)
 570                 (throw 'greedy t))
 571             (if (stringp fname) ;; probably filename
 572                 (setcar var fname)
 573               (ad-set-arg 0 (delq var (ad-get-arg 0))))))
 574         ))))
 575
 576 ;;; Org specific functions:
 577
 578 (defun org-protocol-create-for-org ()
 579   "Create a org-protocol project for the current file's Org-mode project.
 580 This works, if the file visited is part of a publishing project in
 581 `org-publish-project-alist'. This functions calls `org-protocol-create' to do
 582 most of the work."
 583   (interactive)
 584   (require 'org-publish)
 585   (org-publish-initialize-files-alist)
 586   (let ((all (or (org-publish-get-project-from-filename buffer-file-name))))
 587     (if all (org-protocol-create (cdr all))
 588       (message "Not in an org-project. Did mean %s?"
 589                (substitute-command-keys"\\[org-protocol-create]")))))
 590
 591
 592 (defun org-protocol-create(&optional project-plist)
 593   "Create a new org-protocol project interactively.
 594 An org-protocol project is an entry in `org-protocol-project-alist'
 595 which is used by `org-protocol-open-source'.
 596 Optionally use project-plist to initialize the defaults for this worglet. If
 597 project-plist is the CDR of an element in `org-publish-project-alist', reuse
 598 :base-directory, :html-extension and :base-extension."
 599   (interactive)
 600   (let ((working-dir (expand-file-name(or (plist-get project-plist :base-directory) default-directory)))
 601         (base-url "http://orgmode.org/worg/")
 602         (strip-suffix (or (plist-get project-plist :html-extension) ".html"))
 603         (working-suffix (if (plist-get project-plist :base-extension)
 604                             (concat "." (plist-get project-plist :base-extension))
 605                           ".org"))
 606
 607         (worglet-buffer nil)
 608
 609         (insert-default-directory t)
 610         (minibuffer-allow-text-properties nil))
 611
 612     (setq base-url (read-string "Base URL of published content: " base-url nil base-url t))
 613     (if (not (string-match "\\/$" base-url))
 614         (setq base-url (concat base-url "/")))
 615
 616     (setq working-dir
 617           (expand-file-name
 618            (read-directory-name "Local working directory: " working-dir working-dir t)))
 619     (if (not (string-match "\\/$" working-dir))
 620         (setq working-dir (concat working-dir "/")))
 621
 622     (setq strip-suffix
 623           (read-string
 624            (concat "Extension to strip from published URLs ("strip-suffix"): ")
 625                    strip-suffix nil strip-suffix t))
 626
 627     (setq working-suffix
 628           (read-string
 629            (concat "Extension of editable files ("working-suffix"): ")
 630                    working-suffix nil working-suffix t))
 631
 632     (when (yes-or-no-p "Save the new worglet to your init file? ")
 633       (setq org-protocol-project-alist
 634             (cons `(,base-url . (:base-url ,base-url
 635                                  :working-directory ,working-dir
 636                                  :online-suffix ,strip-suffix
 637                                  :working-suffix ,working-suffix))
 638                   org-protocol-project-alist))
 639       (customize-save-variable 'org-protocol-project-alist org-protocol-project-alist))))
 640
 641 (provide 'org-protocol)
 642 ;;; org-protocol.el ends here