lisp/org-clock.el

   1 ;;; org-clock.el --- The time clocking code for Org-mode
   2
   3 ;; Copyright (C) 2004, 2005, 2006, 2007, 2008, 2009
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   7 ;; Keywords: outlines, hypermedia, calendar, wp
   8 ;; Homepage: http://orgmode.org
   9 ;; Version: 6.33trans
  10 ;;
  11 ;; This file is part of GNU Emacs.
  12 ;;
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  26 ;;
  27 ;;; Commentary:
  28
  29 ;; This file contains the time clocking code for Org-mode
  30
  31 (require 'org)
  32 (eval-when-compile
  33   (require 'cl)
  34   (require 'calendar))
  35
  36 (declare-function calendar-absolute-from-iso    "cal-iso"    (&optional date))
  37 (defvar org-time-stamp-formats)
  38
  39 (defgroup org-clock nil
  40   "Options concerning clocking working time in Org-mode."
  41   :tag "Org Clock"
  42   :group 'org-progress)
  43
  44 (defcustom org-clock-into-drawer org-log-into-drawer
  45   "Should clocking info be wrapped into a drawer?
  46 When t, clocking info will always be inserted into a :LOGBOOK: drawer.
  47 If necessary, the drawer will be created.
  48 When nil, the drawer will not be created, but used when present.
  49 When an integer and the number of clocking entries in an item
  50 reaches or exceeds this number, a drawer will be created.
  51 When a string, it names the drawer to be used.
  52
  53 The default for this variable is the value of `org-log-into-drawer',
  54 which see."
  55   :group 'org-todo
  56   :group 'org-clock
  57   :type '(choice
  58           (const :tag "Always" t)
  59           (const :tag "Only when drawer exists" nil)
  60           (integer :tag "When at least N clock entries")
  61           (const :tag "Into LOGBOOK drawer" "LOGBOOK")
  62           (string :tag "Into Drawer named...")))
  63
  64 (defcustom org-clock-out-when-done t
  65   "When non-nil, clock will be stopped when the clocked entry is marked DONE.
  66 A nil value means, clock will keep running until stopped explicitly with
  67 `C-c C-x C-o', or until the clock is started in a different item."
  68   :group 'org-clock
  69   :type 'boolean)
  70
  71 (defcustom org-clock-out-remove-zero-time-clocks nil
  72   "Non-nil means, remove the clock line when the resulting time is zero."
  73   :group 'org-clock
  74   :type 'boolean)
  75
  76 (defcustom org-clock-in-switch-to-state nil
  77   "Set task to a special todo state while clocking it.
  78 The value should be the state to which the entry should be
  79 switched. If the value is a function, it must take one
  80 parameter (the current TODO state of the item) and return the
  81 state to switch it to."
  82   :group 'org-clock
  83   :group 'org-todo
  84   :type '(choice
  85           (const :tag "Don't force a state" nil)
  86           (string :tag "State")
  87           (symbol :tag "Function")))
  88
  89 (defcustom org-clock-out-switch-to-state nil
  90   "Set task to a special todo state after clocking out.
  91 The value should be the state to which the entry should be
  92 switched. If the value is a function, it must take one
  93 parameter (the current TODO state of the item) and return the
  94 state to switch it to."
  95   :group 'org-clock
  96   :group 'org-todo
  97   :type '(choice
  98           (const :tag "Don't force a state" nil)
  99           (string :tag "State")
 100           (symbol :tag "Function")))
 101
 102 (defcustom org-clock-history-length 5
 103   "Number of clock tasks to remember in history."
 104   :group 'org-clock
 105   :type 'integer)
 106
 107 (defcustom org-clock-goto-may-find-recent-task t
 108   "Non-nil means, `org-clock-goto' can go to recent task if no active clock."
 109   :group 'org-clock
 110   :type 'boolean)
 111
 112 (defcustom org-clock-heading-function nil
 113   "When non-nil, should be a function to create `org-clock-heading'.
 114 This is the string shown in the mode line when a clock is running.
 115 The function is called with point at the beginning of the headline."
 116   :group 'org-clock
 117   :type 'function)
 118
 119 (defcustom org-clock-string-limit 0
 120   "Maximum length of clock strings in the modeline. 0 means no limit."
 121   :group 'org-clock
 122   :type 'integer)
 123
 124 (defcustom org-clock-in-resume nil
 125   "If non-nil, resume clock when clocking into task with open clock.
 126 When clocking into a task with a clock entry which has not been closed,
 127 the clock can be resumed from that point."
 128   :group 'org-clock
 129   :type 'boolean)
 130
 131 (defcustom org-clock-persist nil
 132   "When non-nil, save the running clock when emacs is closed.
 133 The clock is resumed when emacs restarts.
 134 When this is t, both the running clock, and the entire clock
 135 history are saved.  When this is the symbol `clock', only the
 136 running clock is saved.
 137
 138 When Emacs restarts with saved clock information, the file containing the
 139 running clock as well as all files mentioned in the clock history will
 140 be visited.
 141 All this depends on running `org-clock-persistence-insinuate' in .emacs"
 142   :group 'org-clock
 143   :type '(choice
 144           (const :tag "Just the running clock" clock)
 145           (const :tag "Just the history" history)
 146           (const :tag "Clock and history" t)
 147           (const :tag "No persistence" nil)))
 148
 149 (defcustom org-clock-persist-file (convert-standard-filename
 150                                    "~/.emacs.d/org-clock-save.el")
 151   "File to save clock data to."
 152   :group 'org-clock
 153   :type 'string)
 154
 155 (defcustom org-clock-persist-query-save nil
 156   "When non-nil, ask before saving the current clock on exit."
 157   :group 'org-clock
 158   :type 'boolean)
 159
 160 (defcustom org-clock-persist-query-resume t
 161   "When non-nil, ask before resuming any stored clock during load."
 162   :group 'org-clock
 163   :type 'boolean)
 164
 165 (defcustom org-clock-sound nil
 166   "Sound that will used for notifications.
 167 Possible values:
 168
 169 nil        no sound played.
 170 t          standard Emacs beep
 171 file name  play this sound file.  If not possible, fall back to beep"
 172   :group 'org-clock
 173   :type '(choice
 174           (const :tag "No sound" nil)
 175           (const :tag "Standard beep" t)
 176           (file :tag "Play sound file")))
 177
 178 (defcustom org-clock-modeline-total 'auto
 179   "Default setting for the time included for the modeline clock.
 180 This can be overruled locally using the CLOCK_MODELINE_TOTAL property.
 181 Allowed values are:
 182
 183 current  Only the time in the current instance of the clock
 184 today    All time clocked into this task today
 185 repeat   All time clocked into this task since last repeat
 186 all      All time ever recorded for this task
 187 auto     Automatically, either `all', or `repeat' for repeating tasks"
 188   :group 'org-clock
 189   :type '(choice
 190           (const :tag "Current clock" current)
 191           (const :tag "Today's task time" today)
 192           (const :tag "Since last repeat" repeat)
 193           (const :tag "All task time" all)
 194           (const :tag "Automatically, `all' or since `repeat'" auto)))
 195
 196 (defcustom org-show-notification-handler nil
 197   "Function or program to send notification with.
 198 The function or program will be called with the notification
 199 string as argument."
 200   :group 'org-clock
 201   :type '(choice
 202           (string :tag "Program")
 203           (function :tag "Function")))
 204
 205 (defcustom org-clock-clocktable-default-properties '(:maxlevel 2 :scope file)
 206   "Default properties for new clocktables."
 207   :group 'org-clock
 208   :type 'plist)
 209
 210 (defcustom org-clock-idle-time nil
 211   "When non-nil, resolve open clocks if the user is idle more than X minutes."
 212   :group 'org-clock
 213   :type '(choice
 214           (const :tag "Never" nil)
 215           (integer :tag "After N minutes")))
 216
 217 (defcustom org-clock-auto-clock-resolution 'when-no-clock-is-running
 218   "When to automatically resolve open clocks found in Org buffers."
 219   :group 'org-clock
 220   :type '(choice
 221           (const :tag "Never" nil)
 222           (const :tag "Always" t)
 223           (const :tag "When no clock is running" when-no-clock-is-running)))
 224
 225 (defvar org-clock-in-prepare-hook nil
 226   "Hook run when preparing the clock.
 227 This hook is run before anything happens to the task that
 228 you want to clock in.  For example, you can use this hook
 229 to add an effort property.")
 230 (defvar org-clock-in-hook nil
 231   "Hook run when starting the clock.")
 232 (defvar org-clock-out-hook nil
 233   "Hook run when stopping the current clock.")
 234
 235 (defvar org-clock-cancel-hook nil
 236   "Hook run when cancelling the current clock.")
 237 (defvar org-clock-goto-hook nil
 238   "Hook run when selecting the currently clocked-in entry.")
 239 (defvar org-clock-has-been-used nil
 240   "Has the clock been used during the current Emacs session?")
 241
 242 ;;; The clock for measuring work time.
 243
 244 (defvar org-mode-line-string "")
 245 (put 'org-mode-line-string 'risky-local-variable t)
 246
 247 (defvar org-clock-mode-line-timer nil)
 248 (defvar org-clock-idle-timer nil)
 249 (defvar org-clock-heading) ; defined in org.el
 250 (defvar org-clock-heading-for-remember "")
 251 (defvar org-clock-start-time "")
 252
 253 (defvar org-clock-left-over-time nil
 254   "If non-nil, user cancelled a clock; this is when leftover time started.")
 255
 256 (defvar org-clock-effort ""
 257   "Effort estimate of the currently clocking task")
 258
 259 (defvar org-clock-total-time nil
 260   "Holds total time, spent previously on currently clocked item.
 261 This does not include the time in the currently running clock.")
 262
 263 (defvar org-clock-history nil
 264   "List of marker pointing to recent clocked tasks.")
 265
 266 (defvar org-clock-default-task (make-marker)
 267   "Marker pointing to the default task that should clock time.
 268 The clock can be made to switch to this task after clocking out
 269 of a different task.")
 270
 271 (defvar org-clock-interrupted-task (make-marker)
 272   "Marker pointing to the task that has been interrupted by the current clock.")
 273
 274 (defvar org-clock-mode-line-map (make-sparse-keymap))
 275 (define-key org-clock-mode-line-map [mode-line mouse-2] 'org-clock-goto)
 276 (define-key org-clock-mode-line-map [mode-line mouse-1] 'org-clock-menu)
 277
 278 (defun org-clock-menu ()
 279   (interactive)
 280   (popup-menu
 281    '("Clock"
 282      ["Clock out" org-clock-out t]
 283      ["Change effort estimate" org-clock-modify-effort-estimate t]
 284      ["Go to clock entry" org-clock-goto t]
 285      ["Switch task" (lambda () (interactive) (org-clock-in '(4))) :active t :keys "C-u C-c C-x C-i"])))
 286
 287 (defun org-clock-history-push (&optional pos buffer)
 288   "Push a marker to the clock history."
 289   (setq org-clock-history-length (max 1 (min 35 org-clock-history-length)))
 290   (let ((m (move-marker (make-marker) (or pos (point)) buffer)) n l)
 291     (while (setq n (member m org-clock-history))
 292       (move-marker (car n) nil))
 293     (setq org-clock-history
 294           (delq nil
 295                 (mapcar (lambda (x) (if (marker-buffer x) x nil))
 296                         org-clock-history)))
 297     (when (>= (setq l (length org-clock-history)) org-clock-history-length)
 298       (setq org-clock-history
 299             (nreverse
 300              (nthcdr (- l org-clock-history-length -1)
 301                      (nreverse org-clock-history)))))
 302     (push m org-clock-history)))
 303
 304 (defun org-clock-save-markers-for-cut-and-paste (beg end)
 305   "Save relative positions of markers in region."
 306   (org-check-and-save-marker org-clock-marker beg end)
 307   (org-check-and-save-marker org-clock-hd-marker beg end)
 308   (org-check-and-save-marker org-clock-default-task beg end)
 309   (org-check-and-save-marker org-clock-interrupted-task beg end)
 310   (mapc (lambda (m) (org-check-and-save-marker m beg end))
 311         org-clock-history))
 312
 313 (defun org-clock-select-task (&optional prompt)
 314   "Select a task that recently was associated with clocking."
 315   (interactive)
 316   (let (sel-list rpl (i 0) s)
 317     (save-window-excursion
 318       (org-switch-to-buffer-other-window
 319        (get-buffer-create "*Clock Task Select*"))
 320       (erase-buffer)
 321       (when (marker-buffer org-clock-default-task)
 322         (insert (org-add-props "Default Task\n" nil 'face 'bold))
 323         (setq s (org-clock-insert-selection-line ?d org-clock-default-task))
 324         (push s sel-list))
 325       (when (marker-buffer org-clock-interrupted-task)
 326         (insert (org-add-props "The task interrupted by starting the last one\n" nil 'face 'bold))
 327         (setq s (org-clock-insert-selection-line ?i org-clock-interrupted-task))
 328         (push s sel-list))
 329       (when (marker-buffer org-clock-marker)
 330         (insert (org-add-props "Current Clocking Task\n" nil 'face 'bold))
 331         (setq s (org-clock-insert-selection-line ?c org-clock-marker))
 332         (push s sel-list))
 333       (insert (org-add-props "Recent Tasks\n" nil 'face 'bold))
 334       (mapc
 335        (lambda (m)
 336          (when (marker-buffer m)
 337            (setq i (1+ i)
 338                  s (org-clock-insert-selection-line
 339                     (if (< i 10)
 340                         (+ i ?0)
 341                       (+ i (- ?A 10))) m))
 342            (if (fboundp 'int-to-char) (setf (car s) (int-to-char (car s))))
 343            (push s sel-list)))
 344        org-clock-history)
 345       (org-fit-window-to-buffer)
 346       (message (or prompt "Select task for clocking:"))
 347       (setq rpl (read-char-exclusive))
 348       (cond
 349        ((eq rpl ?q) nil)
 350        ((eq rpl ?x) nil)
 351        ((assoc rpl sel-list) (cdr (assoc rpl sel-list)))
 352        (t (error "Invalid task choice %c" rpl))))))
 353
 354 (defun org-clock-insert-selection-line (i marker)
 355   "Insert a line for the clock selection menu.
 356 And return a cons cell with the selection character integer and the marker
 357 pointing to it."
 358   (when (marker-buffer marker)
 359     (let (file cat task heading prefix)
 360       (with-current-buffer (org-base-buffer (marker-buffer marker))
 361         (save-excursion
 362           (save-restriction
 363             (widen)
 364             (ignore-errors
 365               (goto-char marker)
 366               (setq file (buffer-file-name (marker-buffer marker))
 367                     cat (or (org-get-category)
 368                             (progn (org-refresh-category-properties)
 369                                    (org-get-category)))
 370                     heading (org-get-heading 'notags)
 371                     prefix (save-excursion
 372                              (org-back-to-heading t)
 373                              (looking-at "\\*+ ")
 374                              (match-string 0))
 375                     task (substring
 376                           (org-fontify-like-in-org-mode
 377                            (concat prefix heading)
 378                            org-odd-levels-only)
 379                           (length prefix)))))))
 380       (when (and cat task)
 381         (insert (format "[%c] %-15s %s\n" i cat task))
 382         (cons i marker)))))
 383
 384 (defun org-clock-get-clock-string ()
 385   "Form a clock-string, that will be show in the mode line.
 386 If an effort estimate was defined for current item, use
 387 01:30/01:50 format (clocked/estimated).
 388 If not, show simply the clocked time like 01:50."
 389   (let* ((clocked-time (org-clock-get-clocked-time))
 390          (h (floor clocked-time 60))
 391          (m (- clocked-time (* 60 h))))
 392     (if (and org-clock-effort)
 393         (let* ((effort-in-minutes (org-hh:mm-string-to-minutes org-clock-effort))
 394                (effort-h (floor effort-in-minutes 60))
 395                (effort-m (- effort-in-minutes (* effort-h 60))))
 396           (format (concat "-[" org-time-clocksum-format "/" org-time-clocksum-format " (%s)]")
 397                   h m effort-h effort-m  org-clock-heading))
 398       (format (concat "-[" org-time-clocksum-format " (%s)]")
 399               h m org-clock-heading))))
 400
 401 (defun org-clock-update-mode-line ()
 402   (setq org-mode-line-string
 403         (org-propertize
 404          (let ((clock-string (org-clock-get-clock-string))
 405                (help-text "Org-mode clock is running.\nmouse-1 shows a menu\nmouse-2 will jump to task"))
 406            (if (and (> org-clock-string-limit 0)
 407                     (> (length clock-string) org-clock-string-limit))
 408                (org-propertize (substring clock-string 0 org-clock-string-limit)
 409                                'help-echo (concat help-text ": " org-clock-heading))
 410              (org-propertize clock-string 'help-echo help-text)))
 411          'local-map org-clock-mode-line-map
 412          'mouse-face (if (featurep 'xemacs) 'highlight 'mode-line-highlight)
 413          'face 'org-mode-line-clock))
 414   (if org-clock-effort (org-clock-notify-once-if-expired))
 415   (force-mode-line-update))
 416
 417 (defun org-clock-get-clocked-time ()
 418   "Get the clocked time for the current item in minutes.
 419 The time returned includes the time spent on this task in
 420 previous clocking intervals."
 421   (let ((currently-clocked-time
 422          (floor (- (org-float-time)
 423                    (org-float-time org-clock-start-time)) 60)))
 424     (+ currently-clocked-time (or org-clock-total-time 0))))
 425
 426 (defun org-clock-modify-effort-estimate (&optional value)
 427  "Add to or set the effort estimate of the item currently being clocked.
 428 VALUE can be a number of minutes, or a string with format hh:mm or mm.
 429 When the string starts with a + or a - sign, the current value of the effort
 430 property will be changed by that amount.
 431 This will update the \"Effort\" property of currently clocked item, and
 432 the mode line."
 433  (interactive)
 434  (when (org-clock-is-active)
 435    (let ((current org-clock-effort) sign)
 436      (unless value
 437        ;; Prompt user for a value or a change
 438        (setq value
 439              (read-string
 440               (format "Set effort (hh:mm or mm%s): "
 441                       (if current
 442                           (format ", prefix + to add to %s" org-clock-effort)
 443                         "")))))
 444      (when (stringp value)
 445        ;; A string.  See if it is a delta
 446        (setq sign (string-to-char value))
 447        (if (member sign '(?- ?+))
 448            (setq current (org-hh:mm-string-to-minutes (substring current 1)))
 449          (setq current 0))
 450        (setq value (org-hh:mm-string-to-minutes value))
 451        (if (equal ?- sign)
 452            (setq value (- current value))
 453          (if (equal ?+ sign) (setq value (+ current value)))))
 454      (setq value (max 0 value)
 455            org-clock-effort (org-minutes-to-hh:mm-string value))
 456      (org-entry-put org-clock-marker "Effort" org-clock-effort)
 457      (org-clock-update-mode-line)
 458      (message "Effort is now %s" org-clock-effort))))
 459
 460 (defvar org-clock-notification-was-shown nil
 461   "Shows if we have shown notification already.")
 462
 463 (defun org-clock-notify-once-if-expired ()
 464   "Show notification if we spent more time than we estimated before.
 465 Notification is shown only once."
 466   (when (marker-buffer org-clock-marker)
 467     (let ((effort-in-minutes (org-hh:mm-string-to-minutes org-clock-effort))
 468           (clocked-time (org-clock-get-clocked-time)))
 469       (if (>= clocked-time effort-in-minutes)
 470           (unless org-clock-notification-was-shown
 471             (setq org-clock-notification-was-shown t)
 472             (org-notify
 473              (format "Task '%s' should be finished by now. (%s)"
 474                      org-clock-heading org-clock-effort) t))
 475         (setq org-clock-notification-was-shown nil)))))
 476
 477 (defun org-notify (notification &optional play-sound)
 478   "Send a NOTIFICATION and maybe PLAY-SOUND."
 479   (org-show-notification notification)
 480   (if play-sound (org-clock-play-sound)))
 481
 482 (defun org-show-notification (notification)
 483   "Show notification.
 484 Use `org-show-notification-handler' if defined,
 485 use libnotify if available, or fall back on a message."
 486   (cond ((functionp org-show-notification-handler)
 487          (funcall org-show-notification-handler notification))
 488         ((stringp org-show-notification-handler)
 489          (start-process "emacs-timer-notification" nil
 490                         org-show-notification-handler notification))
 491         ((org-program-exists "notify-send")
 492          (start-process "emacs-timer-notification" nil
 493                         "notify-send" notification))
 494         ;; Maybe the handler will send a message, so only use message as
 495         ;; a fall back option
 496         (t (message "%s" notification))))
 497
 498 (defun org-clock-play-sound ()
 499   "Play sound as configured by `org-clock-sound'.
 500 Use alsa's aplay tool if available."
 501   (cond
 502    ((not org-clock-sound))
 503    ((eq org-clock-sound t) (beep t) (beep t))
 504    ((stringp org-clock-sound)
 505     (let ((file (expand-file-name org-clock-sound)))
 506       (if (file-exists-p file)
 507           (if (org-program-exists "aplay")
 508               (start-process "org-clock-play-notification" nil
 509                              "aplay" file)
 510             (condition-case nil
 511                 (play-sound-file file)
 512               (error (beep t) (beep t)))))))))
 513
 514 (defun org-program-exists (program-name)
 515   "Checks whenever we can locate program and launch it."
 516   (if (eq system-type 'gnu/linux)
 517       (= 0 (call-process "which" nil nil nil program-name))))
 518
 519 (defvar org-clock-mode-line-entry nil
 520   "Information for the modeline about the running clock.")
 521
 522 (defun org-find-open-clocks (file)
 523   "Search through the given file and find all open clocks."
 524   (let ((buf (or (get-file-buffer file)
 525                  (find-file-noselect file)))
 526         clocks)
 527     (with-current-buffer buf
 528       (save-excursion
 529         (goto-char (point-min))
 530         (while (re-search-forward "CLOCK: \\(\\[.*?\\]\\)$" nil t)
 531           (push (cons (copy-marker (1- (match-end 1)) t)
 532                       (org-time-string-to-time (match-string 1))) clocks))))
 533     clocks))
 534
 535 (defsubst org-is-active-clock (clock)
 536   "Return t if CLOCK is the currently active clock."
 537   (and (org-clock-is-active)
 538        (= org-clock-marker (car clock))))
 539
 540 (defmacro org-with-clock-position (clock &rest forms)
 541   "Evaluate FORMS with CLOCK as the current active clock."
 542   `(with-current-buffer (marker-buffer (car ,clock))
 543      (save-excursion
 544        (save-restriction
 545          (widen)
 546          (goto-char (car ,clock))
 547          (beginning-of-line)
 548          ,@forms))))
 549
 550 (put 'org-with-clock-position 'lisp-indent-function 1)
 551
 552 (defmacro org-with-clock (clock &rest forms)
 553   "Evaluate FORMS with CLOCK as the current active clock.
 554 This macro also protects the current active clock from being altered."
 555   `(org-with-clock-position ,clock
 556      (let ((org-clock-start-time (cdr ,clock))
 557            (org-clock-total-time)
 558            (org-clock-history)
 559            (org-clock-effort)
 560            (org-clock-marker (car ,clock))
 561            (org-clock-hd-marker (save-excursion
 562                                   (outline-back-to-heading t)
 563                                   (point-marker))))
 564        ,@forms)))
 565
 566 (put 'org-with-clock 'lisp-indent-function 1)
 567
 568 (defsubst org-clock-clock-in (clock &optional resume)
 569   "Clock in to the clock located by CLOCK.
 570 If necessary, clock-out of the currently active clock."
 571   (org-with-clock-position clock
 572     (let ((org-clock-in-resume (or resume org-clock-in-resume)))
 573       (org-clock-in))))
 574
 575 (defsubst org-clock-clock-out (clock &optional fail-quietly at-time)
 576   "Clock out of the clock located by CLOCK."
 577   (let ((temp (copy-marker (car clock)
 578                            (marker-insertion-type (car clock)))))
 579     (if (org-is-active-clock clock)
 580         (org-clock-out fail-quietly at-time)
 581       (org-with-clock clock
 582         (org-clock-out fail-quietly at-time)))
 583     (setcar clock temp)))
 584
 585 (defsubst org-clock-clock-cancel (clock)
 586   "Cancel the clock located by CLOCK."
 587   (let ((temp (copy-marker (car clock)
 588                            (marker-insertion-type (car clock)))))
 589     (if (org-is-active-clock clock)
 590         (org-clock-cancel)
 591       (org-with-clock clock
 592         (org-clock-cancel)))
 593     (setcar clock temp)))
 594
 595 (defvar org-clock-clocking-in nil)
 596 (defvar org-clock-resolving-clocks nil)
 597 (defvar org-clock-resolving-clocks-due-to-idleness nil)
 598
 599 (defun org-clock-resolve-clock (clock resolve-to &optional close-p
 600                                       restart-p fail-quietly)
 601   "Resolve `CLOCK' given the time `RESOLVE-TO', and the present.
 602 `CLOCK' is a cons cell of the form (MARKER START-TIME).
 603 This routine can do one of many things:
 604
 605   if `RESOLVE-TO' is nil
 606     if `CLOSE-P' is non-nil, give an error
 607     if this clock is the active clock, cancel it
 608     else delete the clock line (as if it never happened)
 609     if `RESTART-P' is non-nil, start a new clock
 610
 611   else if `RESOLVE-TO' is the symbol `now'
 612     if `RESTART-P' is non-nil, give an error
 613     if `CLOSE-P' is non-nil, clock out the entry and
 614        if this clock is the active clock, stop it
 615     else if this clock is the active clock, do nothing
 616     else if there is no active clock, resume this clock
 617     else ask to cancel the active clock, and if so,
 618          resume this clock after cancelling it
 619
 620   else if `RESOLVE-TO' is some date in the future
 621     give an error about `RESOLVE-TO' being invalid
 622
 623   else if `RESOLVE-TO' is some date in the past
 624     if `RESTART-P' is non-nil, give an error
 625     if `CLOSE-P' is non-nil, enter a closing time and
 626        if this clock is the active clock, stop it
 627     else if this clock is the active clock, enter a
 628        closing time, stop the current clock, then
 629        start a new clock for the same item
 630     else just enter a closing time for this clock
 631        and then start a new clock for the same item"
 632   (let ((org-clock-resolving-clocks t))
 633     (cond
 634      ((null resolve-to)
 635       (org-clock-clock-cancel clock)
 636       (if (and restart-p (not org-clock-clocking-in))
 637           (org-clock-clock-in clock)))
 638
 639      ((eq resolve-to 'now)
 640       (if restart-p
 641           (error "RESTART-P is not valid here"))
 642       (if (or close-p org-clock-clocking-in)
 643           (org-clock-clock-out clock fail-quietly)
 644         (unless (org-is-active-clock clock)
 645           (org-clock-clock-in clock t))))
 646
 647      ((not (time-less-p resolve-to (current-time)))
 648       (error "RESOLVE-TO must refer to a time in the past"))
 649
 650      (t
 651       (if restart-p
 652           (error "RESTART-P is not valid here"))
 653       (org-clock-clock-out clock fail-quietly resolve-to)
 654       (unless org-clock-clocking-in
 655         (if close-p
 656             (setq org-clock-left-over-time resolve-to)
 657           (org-clock-clock-in clock)))))))
 658
 659 (defun org-clock-resolve (clock &optional prompt-fn last-valid fail-quietly)
 660   "Resolve an open org-mode clock.
 661 An open clock was found, with `dangling' possibly being non-nil.
 662 If this function was invoked with a prefix argument, non-dangling
 663 open clocks are ignored.  The given clock requires some sort of
 664 user intervention to resolve it, either because a clock was left
 665 dangling or due to an idle timeout.  The clock resolution can
 666 either be:
 667
 668   (a) deleted, the user doesn't care about the clock
 669   (b) restarted from the current time (if no other clock is open)
 670   (c) closed, giving the clock X minutes
 671   (d) closed and then restarted
 672   (e) resumed, as if the user had never left
 673
 674 The format of clock is (CONS MARKER START-TIME), where MARKER
 675 identifies the buffer and position the clock is open at (and
 676 thus, the heading it's under), and START-TIME is when the clock
 677 was started."
 678   (assert clock)
 679   (let* ((ch
 680           (save-window-excursion
 681             (save-excursion
 682               (unless org-clock-resolving-clocks-due-to-idleness
 683                 (org-with-clock clock (org-clock-goto))
 684                 (with-current-buffer (marker-buffer (car clock))
 685                   (goto-char (car clock))
 686                   (if org-clock-into-drawer
 687                       (let ((logbook
 688                              (if (stringp org-clock-into-drawer)
 689                                  (concat ":" org-clock-into-drawer ":")
 690                                ":LOGBOOK:")))
 691                         (ignore-errors
 692                           (outline-flag-region
 693                            (save-excursion
 694                              (outline-back-to-heading t)
 695                              (search-forward logbook)
 696                              (goto-char (match-beginning 0)))
 697                            (save-excursion
 698                              (outline-back-to-heading t)
 699                              (search-forward logbook)
 700                              (search-forward ":END:")
 701                              (goto-char (match-end 0)))
 702                            nil))))))
 703               (let (char-pressed)
 704                 (if (featurep 'xemacs)
 705                     (progn
 706                       (message (concat (funcall prompt-fn clock)
 707                                        " [(kK)eep (sS)ubtract (C)ancel]? "))
 708                       (setq char-pressed (read-char-exclusive)))
 709                   (while (null char-pressed)
 710                     (setq char-pressed
 711                           (read-char (concat (funcall prompt-fn clock)
 712                                              " [(kK)eep (sS)ubtract (C)ancel]? ")
 713                                      nil 45)))
 714                   char-pressed)))))
 715          (default (floor (/ (org-float-time
 716                              (time-subtract (current-time) last-valid)) 60)))
 717          (keep (and (memq ch '(?k ?K))
 718                     (read-number "Keep how many minutes? " default)))
 719          (subtractp (memq ch '(?s ?S)))
 720          (barely-started-p (< (- (org-float-time last-valid)
 721                                  (org-float-time (cdr clock))) 45))
 722          (start-over (and subtractp barely-started-p)))
 723     (if (or (null ch)
 724             (not (memq ch '(?k ?K ?s ?S ?C))))
 725         (message "")
 726       (org-clock-resolve-clock
 727        clock (cond
 728               ((or (eq ch ?C)
 729                    ;; If the time on the clock was less than a minute before
 730                    ;; the user went away, and they've ask to subtract all the
 731                    ;; time...
 732                    start-over)
 733                nil)
 734               (subtractp
 735                last-valid)
 736               ((= keep default)
 737                'now)
 738               (t
 739                (time-add last-valid (seconds-to-time (* 60 keep)))))
 740        (memq ch '(?K ?S))
 741        (and start-over
 742             (not (memq ch '(?K ?S ?C))))
 743        fail-quietly))))
 744
 745 (defun org-resolve-clocks (&optional also-non-dangling-p prompt-fn last-valid)
 746   "Resolve all currently open org-mode clocks.
 747 If `also-non-dangling-p' is non-nil, also ask to resolve
 748 non-dangling (i.e., currently open and valid) clocks."
 749   (interactive "P")
 750   (unless org-clock-resolving-clocks
 751     (let ((org-clock-resolving-clocks t))
 752       (dolist (file (org-files-list))
 753         (let ((clocks (org-find-open-clocks file)))
 754           (dolist (clock clocks)
 755             (let ((dangling (or (not (org-clock-is-active))
 756                                 (/= (car clock) org-clock-marker))))
 757               (unless (and (not dangling) (not also-non-dangling-p))
 758                 (org-clock-resolve
 759                  clock
 760                  (or prompt-fn
 761                      (function
 762                       (lambda (clock)
 763                         (format
 764                          "Dangling clock started %d mins ago"
 765                          (floor
 766                           (/ (- (org-float-time (current-time))
 767                                 (org-float-time (cdr clock))) 60))))))
 768                  (or last-valid
 769                      (cdr clock)))))))))))
 770
 771 (defun org-emacs-idle-seconds ()
 772   "Return the current Emacs idle time in seconds, or nil if not idle."
 773   (let ((idle-time (current-idle-time)))
 774     (if idle-time
 775         (org-float-time idle-time)
 776       0)))
 777
 778 (defun org-mac-idle-seconds ()
 779   "Return the current Mac idle time in seconds"
 780   (string-to-number (shell-command-to-string "ioreg -c IOHIDSystem | perl -ane 'if (/Idle/) {$idle=(pop @F)/1000000000; print $idle; last}'")))
 781
 782 (defun org-x11-idle-seconds ()
 783   "Return the current X11 idle time in seconds"
 784   (/ (string-to-number (shell-command-to-string "x11idle")) 1000))
 785
 786 (defun org-user-idle-seconds ()
 787   "Return the number of seconds the user has been idle for.
 788 This routine returns a floating point number."
 789   (if (or (eq system-type 'darwin) (eq window-system 'x))
 790       (let ((emacs-idle (org-emacs-idle-seconds)))
 791         ;; If Emacs has been idle for longer than the user's
 792         ;; `org-clock-idle-time' value, check whether the whole system has
 793         ;; really been idle for that long.
 794         (if (> emacs-idle (* 60 org-clock-idle-time))
 795             (min emacs-idle (if (eq system-type 'darwin)
 796                                 (org-mac-idle-seconds)
 797                               (org-x11-idle-seconds)))
 798           emacs-idle))
 799     (org-emacs-idle-seconds)))
 800
 801 (defvar org-clock-user-idle-seconds)
 802
 803 (defun org-resolve-clocks-if-idle ()
 804   "Resolve all currently open org-mode clocks.
 805 This is performed after `org-clock-idle-time' minutes, to check
 806 if the user really wants to stay clocked in after being idle for
 807 so long."
 808   (when (and org-clock-idle-time (not org-clock-resolving-clocks)
 809              org-clock-marker)
 810     (let ((org-clock-user-idle-seconds (org-user-idle-seconds))
 811           (org-clock-user-idle-start
 812            (time-subtract (current-time)
 813                           (seconds-to-time org-clock-user-idle-seconds)))
 814           (org-clock-resolving-clocks-due-to-idleness t))
 815       (if (> org-clock-user-idle-seconds (* 60 org-clock-idle-time))
 816           (org-clock-resolve
 817            (cons org-clock-marker
 818                  org-clock-start-time)
 819            (function
 820             (lambda (clock)
 821               (format "Clocked in & idle for %.1f mins"
 822                       (/ (org-float-time
 823                           (time-subtract (current-time)
 824                                          org-clock-user-idle-start))
 825                          60.0))))
 826            org-clock-user-idle-start)))))
 827
 828 (defun org-clock-in (&optional select)
 829   "Start the clock on the current item.
 830 If necessary, clock-out of the currently active clock.
 831 With prefix arg SELECT, offer a list of recently clocked tasks to
 832 clock into.  When SELECT is `C-u C-u', clock into the current task and mark
 833 is as the default task, a special task that will always be offered in
 834 the clocking selection, associated with the letter `d'."
 835   (interactive "P")
 836   (setq org-clock-notification-was-shown nil)
 837   (catch 'abort
 838     (let ((interrupting (and (not org-clock-resolving-clocks-due-to-idleness)
 839                              (marker-buffer org-clock-marker)))
 840           ts selected-task target-pos (msg-extra "")
 841           (left-over (and (not org-clock-resolving-clocks)
 842                           org-clock-left-over-time)))
 843       (when (and org-clock-auto-clock-resolution
 844                  (or (not interrupting)
 845                      (eq t org-clock-auto-clock-resolution))
 846                  (not org-clock-clocking-in)
 847                  (not org-clock-resolving-clocks))
 848         (setq org-clock-left-over-time nil)
 849         (let ((org-clock-clocking-in t))
 850           (org-resolve-clocks)))        ; check if any clocks are dangling
 851       (when (equal select '(4))
 852         (setq selected-task (org-clock-select-task "Clock-in on task: "))
 853         (if selected-task
 854             (setq selected-task (copy-marker selected-task))
 855           (error "Abort")))
 856       (when interrupting
 857         ;; We are interrupting the clocking of a different task.
 858         ;; Save a marker to this task, so that we can go back.
 859         (move-marker org-clock-interrupted-task
 860                      (marker-position org-clock-marker)
 861                      (marker-buffer org-clock-marker))
 862         (org-clock-out t))
 863
 864       (when (equal select '(16))
 865         ;; Mark as default clocking task
 866         (org-clock-mark-default-task))
 867
 868       ;; Clock in at which position?
 869       (setq target-pos
 870             (if (and (eobp) (not (org-on-heading-p)))
 871                 (point-at-bol 0)
 872               (point)))
 873       (run-hooks 'org-clock-in-prepare-hook)
 874       (save-excursion
 875         (when (and selected-task (marker-buffer selected-task))
 876           ;; There is a selected task, move to the correct buffer
 877           ;; and set the new target position.
 878           (set-buffer (org-base-buffer (marker-buffer selected-task)))
 879           (setq target-pos (marker-position selected-task))
 880           (move-marker selected-task nil))
 881         (save-excursion
 882           (save-restriction
 883             (widen)
 884             (goto-char target-pos)
 885             (org-back-to-heading t)
 886             (or interrupting (move-marker org-clock-interrupted-task nil))
 887             (org-clock-history-push)
 888             (cond ((functionp org-clock-in-switch-to-state)
 889                    (looking-at org-complex-heading-regexp)
 890                    (let ((newstate (funcall org-clock-in-switch-to-state
 891                                             (match-string 2))))
 892                      (if newstate (org-todo newstate))))
 893                   ((and org-clock-in-switch-to-state
 894                         (not (looking-at (concat outline-regexp "[ \t]*"
 895                                                  org-clock-in-switch-to-state
 896                                                  "\\>"))))
 897                    (org-todo org-clock-in-switch-to-state)))
 898             (setq org-clock-heading-for-remember
 899                   (and (looking-at org-complex-heading-regexp)
 900                        (match-end 4)
 901                        (org-trim (buffer-substring (match-end 1)
 902                                                    (match-end 4)))))
 903             (setq org-clock-heading
 904                   (cond ((and org-clock-heading-function
 905                               (functionp org-clock-heading-function))
 906                          (funcall org-clock-heading-function))
 907                         ((looking-at org-complex-heading-regexp)
 908                          (match-string 4))
 909                         (t "???")))
 910             (setq org-clock-heading (org-propertize org-clock-heading
 911                                                     'face nil))
 912             (org-clock-find-position org-clock-in-resume)
 913             (cond
 914              ((and org-clock-in-resume
 915                    (looking-at
 916                     (concat "^[ \t]* " org-clock-string
 917                             " \\[\\([0-9]\\{4\\}-[0-9]\\{2\\}-[0-9]\\{2\\}"
 918                             " +\\sw+\.? +[012][0-9]:[0-5][0-9]\\)\\][ \t]*$")))
 919               (message "Matched %s" (match-string 1))
 920               (setq ts (concat "[" (match-string 1) "]"))
 921               (goto-char (match-end 1))
 922               (setq org-clock-start-time
 923                     (apply 'encode-time
 924                            (org-parse-time-string (match-string 1))))
 925               (setq org-clock-effort (org-get-effort))
 926               (setq org-clock-total-time (org-clock-sum-current-item
 927                                           (org-clock-get-sum-start))))
 928              ((eq org-clock-in-resume 'auto-restart)
 929               ;; called from org-clock-load during startup,
 930               ;; do not interrupt, but warn!
 931               (message "Cannot restart clock because task does not contain unfinished clock")
 932               (ding)
 933               (sit-for 2)
 934               (throw 'abort nil))
 935              (t
 936               (insert-before-markers "\n")
 937               (backward-char 1)
 938               (org-indent-line-function)
 939               (when (and (save-excursion
 940                            (end-of-line 0)
 941                            (org-in-item-p)))
 942                 (beginning-of-line 1)
 943                 (org-indent-line-to (- (org-get-indentation) 2)))
 944               (insert org-clock-string " ")
 945               (setq org-clock-effort (org-get-effort))
 946               (setq org-clock-total-time (org-clock-sum-current-item
 947                                           (org-clock-get-sum-start)))
 948               (setq org-clock-start-time
 949                     (or (and left-over
 950                              (y-or-n-p
 951                               (format
 952                                "You stopped another clock %d mins ago; start this one from then? "
 953                                (/ (- (org-float-time (current-time))
 954                                      (org-float-time left-over)) 60)))
 955                              left-over)
 956                         (current-time)))
 957               (setq ts (org-insert-time-stamp org-clock-start-time
 958                                               'with-hm 'inactive))))
 959             (move-marker org-clock-marker (point) (buffer-base-buffer))
 960             (move-marker org-clock-hd-marker
 961                          (save-excursion (org-back-to-heading t) (point))
 962                          (buffer-base-buffer))
 963             (setq org-clock-has-been-used t)
 964             (or global-mode-string (setq global-mode-string '("")))
 965             (or (memq 'org-mode-line-string global-mode-string)
 966                 (setq global-mode-string
 967                       (append global-mode-string '(org-mode-line-string))))
 968             (org-clock-update-mode-line)
 969             (when org-clock-mode-line-timer
 970               (cancel-timer org-clock-mode-line-timer)
 971               (setq org-clock-mode-line-timer nil))
 972             (setq org-clock-mode-line-timer
 973                   (run-with-timer 60 60 'org-clock-update-mode-line))
 974             (when org-clock-idle-timer
 975               (cancel-timer org-clock-idle-timer)
 976               (setq org-clock-idle-timer nil))
 977             (setq org-clock-idle-timer
 978                   (run-with-timer 60 60 'org-resolve-clocks-if-idle))
 979             (message "Clock starts at %s - %s" ts msg-extra)
 980             (run-hooks 'org-clock-in-hook)))))))
 981
 982 (defun org-clock-mark-default-task ()
 983   "Mark current task as default task."
 984   (interactive)
 985   (save-excursion
 986     (org-back-to-heading t)
 987     (move-marker org-clock-default-task (point))))
 988
 989 (defvar msg-extra)
 990 (defun org-clock-get-sum-start ()
 991   "Return the time from which clock times should be counted.
 992 This is for the currently running clock as it is displayed
 993 in the mode line.  This function looks at the properties
 994 LAST_REPEAT and in particular CLOCK_MODELINE_TOTAL and the
 995 corresponding variable `org-clock-modeline-total' and then
 996 decides which time to use."
 997   (let ((cmt (or (org-entry-get nil "CLOCK_MODELINE_TOTAL")
 998                  (symbol-name org-clock-modeline-total)))
 999         (lr (org-entry-get nil "LAST_REPEAT")))
1000     (cond
1001      ((equal cmt "current")
1002       (setq msg-extra "showing time in current clock instance")
1003       (current-time))
1004      ((equal cmt "today")
1005       (setq msg-extra "showing today's task time.")
1006       (let* ((dt (decode-time (current-time))))
1007         (setq dt (append (list 0 0 0) (nthcdr 3 dt)))
1008         (if org-extend-today-until
1009             (setf (nth 2 dt) org-extend-today-until))
1010         (apply 'encode-time dt)))
1011      ((or (equal cmt "all")
1012           (and (or (not cmt) (equal cmt "auto"))
1013                (not lr)))
1014       (setq msg-extra "showing entire task time.")
1015       nil)
1016      ((or (equal cmt "repeat")
1017           (and (or (not cmt) (equal cmt "auto"))
1018                lr))
1019       (setq msg-extra "showing task time since last repeat.")
1020       (if (not lr)
1021           nil
1022         (org-time-string-to-time lr)))
1023      (t nil))))
1024
1025 (defun org-clock-find-position (find-unclosed)
1026   "Find the location where the next clock line should be inserted.
1027 When FIND-UNCLOSED is non-nil, first check if there is an unclosed clock
1028 line and position cursor in that line."
1029   (org-back-to-heading t)
1030   (catch 'exit
1031     (let ((beg (save-excursion
1032                  (beginning-of-line 2)
1033                  (or (bolp) (newline))
1034                  (point)))
1035           (end (progn (outline-next-heading) (point)))
1036           (re (concat "^[ \t]*" org-clock-string))
1037           (cnt 0)
1038           (drawer (if (stringp org-clock-into-drawer)
1039                       org-clock-into-drawer "LOGBOOK"))
1040           first last ind-last)
1041       (goto-char beg)
1042       (when (and find-unclosed
1043                  (re-search-forward
1044                   (concat "^[ \t]* " org-clock-string
1045                           " \\[\\([0-9]\\{4\\}-[0-9]\\{2\\}-[0-9]\\{2\\}"
1046                           " +\\sw+ +[012][0-9]:[0-5][0-9]\\)\\][ \t]*$")
1047                   end t))
1048         (beginning-of-line 1)
1049         (throw 'exit t))
1050       (when (eobp) (newline) (setq end (max (point) end)))
1051       (when (re-search-forward (concat "^[ \t]*:" drawer ":") end t)
1052         ;; we seem to have a CLOCK drawer, so go there.
1053         (beginning-of-line 2)
1054         (or org-log-states-order-reversed
1055             (and (re-search-forward org-property-end-re nil t)
1056                  (goto-char (match-beginning 0))))
1057         (throw 'exit t))
1058       ;; Lets count the CLOCK lines
1059       (goto-char beg)
1060       (while (re-search-forward re end t)
1061         (setq first (or first (match-beginning 0))
1062               last (match-beginning 0)
1063               cnt (1+ cnt)))
1064       (when (and (integerp org-clock-into-drawer)
1065                  last
1066                  (>= (1+ cnt) org-clock-into-drawer))
1067         ;; Wrap current entries into a new drawer
1068         (goto-char last)
1069         (setq ind-last (org-get-indentation))
1070         (beginning-of-line 2)
1071         (if (and (>= (org-get-indentation) ind-last)
1072                  (org-at-item-p))
1073             (org-end-of-item))
1074         (insert ":END:\n")
1075         (beginning-of-line 0)
1076         (org-indent-line-to ind-last)
1077         (goto-char first)
1078         (insert ":" drawer ":\n")
1079         (beginning-of-line 0)
1080         (org-indent-line-function)
1081         (org-flag-drawer t)
1082         (beginning-of-line 2)
1083         (or org-log-states-order-reversed
1084             (and (re-search-forward org-property-end-re nil t)
1085                  (goto-char (match-beginning 0))))
1086         (throw 'exit nil))
1087
1088       (goto-char beg)
1089       (while (and (looking-at (concat "[ \t]*" org-keyword-time-regexp))
1090                   (not (equal (match-string 1) org-clock-string)))
1091         ;; Planning info, skip to after it
1092         (beginning-of-line 2)
1093         (or (bolp) (newline)))
1094       (when (or (eq org-clock-into-drawer t)
1095                 (stringp org-clock-into-drawer)
1096                 (and (integerp org-clock-into-drawer)
1097                      (< org-clock-into-drawer 2)))
1098         (insert ":" drawer ":\n:END:\n")
1099         (beginning-of-line -1)
1100         (org-indent-line-function)
1101         (org-flag-drawer t)
1102         (beginning-of-line 2)
1103         (org-indent-line-function)
1104         (beginning-of-line)
1105         (or org-log-states-order-reversed
1106             (and (re-search-forward org-property-end-re nil t)
1107                  (goto-char (match-beginning 0))))))))
1108
1109 (defun org-clock-out (&optional fail-quietly at-time)
1110   "Stop the currently running clock.
1111 If there is no running clock, throw an error, unless FAIL-QUIETLY is set."
1112   (interactive)
1113   (catch 'exit
1114     (if (not (marker-buffer org-clock-marker))
1115         (if fail-quietly (throw 'exit t) (error "No active clock")))
1116     (let (ts te s h m remove)
1117       (save-excursion
1118         (set-buffer (marker-buffer org-clock-marker))
1119         (save-restriction
1120           (widen)
1121           (goto-char org-clock-marker)
1122           (beginning-of-line 1)
1123           (if (and (looking-at (concat "[ \t]*" org-keyword-time-regexp))
1124                    (equal (match-string 1) org-clock-string))
1125               (setq ts (match-string 2))
1126             (if fail-quietly (throw 'exit nil) (error "Clock start time is gone")))
1127           (goto-char (match-end 0))
1128           (delete-region (point) (point-at-eol))
1129           (insert "--")
1130           (setq te (org-insert-time-stamp (or at-time (current-time))
1131                                           'with-hm 'inactive))
1132           (setq s (- (org-float-time (apply 'encode-time (org-parse-time-string te)))
1133                      (org-float-time (apply 'encode-time (org-parse-time-string ts))))
1134                 h (floor (/ s 3600))
1135                 s (- s (* 3600 h))
1136                 m (floor (/ s 60))
1137                 s (- s (* 60 s)))
1138           (insert " => " (format "%2d:%02d" h m))
1139           (when (setq remove (and org-clock-out-remove-zero-time-clocks
1140                                   (= (+ h m) 0)))
1141             (beginning-of-line 1)
1142             (delete-region (point) (point-at-eol))
1143             (and (looking-at "\n") (> (point-max) (1+ (point)))
1144                  (delete-char 1)))
1145           (move-marker org-clock-marker nil)
1146           (move-marker org-clock-hd-marker nil)
1147           (when org-log-note-clock-out
1148             (org-add-log-setup 'clock-out nil nil nil nil
1149                                (concat "# Task: " (org-get-heading t) "\n\n")))
1150           (when org-clock-mode-line-timer
1151             (cancel-timer org-clock-mode-line-timer)
1152             (setq org-clock-mode-line-timer nil))
1153           (when org-clock-idle-timer
1154             (cancel-timer org-clock-idle-timer)
1155             (setq org-clock-idle-timer nil))
1156           (setq global-mode-string
1157                 (delq 'org-mode-line-string global-mode-string))
1158           (when org-clock-out-switch-to-state
1159             (save-excursion
1160               (org-back-to-heading t)
1161               (let ((org-inhibit-logging t))
1162                 (cond
1163                  ((functionp org-clock-out-switch-to-state)
1164                   (looking-at org-complex-heading-regexp)
1165                   (let ((newstate (funcall org-clock-out-switch-to-state
1166                                            (match-string 2))))
1167                     (if newstate (org-todo newstate))))
1168                  ((and org-clock-out-switch-to-state
1169                        (not (looking-at (concat outline-regexp "[ \t]*"
1170                                                 org-clock-out-switch-to-state
1171                                                 "\\>"))))
1172                   (org-todo org-clock-out-switch-to-state))))))
1173           (force-mode-line-update)
1174           (message (concat "Clock stopped at %s after HH:MM = " org-time-clocksum-format "%s") te h m
1175                    (if remove " => LINE REMOVED" ""))
1176           (run-hooks 'org-clock-out-hook))))))
1177
1178 (defun org-clock-cancel ()
1179   "Cancel the running clock be removing the start timestamp."
1180   (interactive)
1181   (if (not (marker-buffer org-clock-marker))
1182       (error "No active clock"))
1183   (save-excursion
1184     (set-buffer (marker-buffer org-clock-marker))
1185     (goto-char org-clock-marker)
1186     (delete-region (1- (point-at-bol)) (point-at-eol))
1187     ;; Just in case, remove any empty LOGBOOK left over
1188     (org-remove-empty-drawer-at "LOGBOOK" (point)))
1189   (move-marker org-clock-marker nil)
1190   (move-marker org-clock-hd-marker nil)
1191   (setq global-mode-string
1192         (delq 'org-mode-line-string global-mode-string))
1193   (force-mode-line-update)
1194   (message "Clock canceled")
1195   (run-hooks 'org-clock-cancel-hook))
1196
1197 (defun org-clock-goto (&optional select)
1198   "Go to the currently clocked-in entry, or to the most recently clocked one.
1199 With prefix arg SELECT, offer recently clocked tasks for selection."
1200   (interactive "@P")
1201   (let* ((recent nil)
1202          (m (cond
1203              (select
1204               (or (org-clock-select-task "Select task to go to: ")
1205                   (error "No task selected")))
1206              ((marker-buffer org-clock-marker) org-clock-marker)
1207              ((and org-clock-goto-may-find-recent-task
1208                    (car org-clock-history)
1209                    (marker-buffer (car org-clock-history)))
1210               (setq recent t)
1211               (car org-clock-history))
1212              (t (error "No active or recent clock task")))))
1213     (switch-to-buffer (marker-buffer m))
1214     (if (or (< m (point-min)) (> m (point-max))) (widen))
1215     (goto-char m)
1216     (org-show-entry)
1217     (org-back-to-heading t)
1218     (org-cycle-hide-drawers 'children)
1219     (recenter)
1220     (if recent
1221         (message "No running clock, this is the most recently clocked task"))
1222     (run-hooks 'org-clock-goto-hook)))
1223
1224 (defvar org-clock-file-total-minutes nil
1225   "Holds the file total time in minutes, after a call to `org-clock-sum'.")
1226 (make-variable-buffer-local 'org-clock-file-total-minutes)
1227
1228 (defun org-clock-sum (&optional tstart tend)
1229   "Sum the times for each subtree.
1230 Puts the resulting times in minutes as a text property on each headline.
1231 TSTART and TEND can mark a time range to be considered."
1232   (interactive)
1233   (let* ((bmp (buffer-modified-p))
1234          (re (concat "^\\(\\*+\\)[ \t]\\|^[ \t]*"
1235                      org-clock-string
1236                      "[ \t]*\\(?:\\(\\[.*?\\]\\)-+\\(\\[.*?\\]\\)\\|=>[ \t]+\\([0-9]+\\):\\([0-9]+\\)\\)"))
1237          (lmax 30)
1238          (ltimes (make-vector lmax 0))
1239          (t1 0)
1240          (level 0)
1241          ts te dt
1242          time)
1243     (if (stringp tstart) (setq tstart (org-time-string-to-seconds tstart)))
1244     (if (stringp tend) (setq tend (org-time-string-to-seconds tend)))
1245     (if (consp tstart) (setq tstart (org-float-time tstart)))
1246     (if (consp tend) (setq tend (org-float-time tend)))
1247     (remove-text-properties (point-min) (point-max) '(:org-clock-minutes t))
1248     (save-excursion
1249       (goto-char (point-max))
1250       (while (re-search-backward re nil t)
1251         (cond
1252          ((match-end 2)
1253           ;; Two time stamps
1254           (setq ts (match-string 2)
1255                 te (match-string 3)
1256                 ts (org-float-time
1257                     (apply 'encode-time (org-parse-time-string ts)))
1258                 te (org-float-time
1259                     (apply 'encode-time (org-parse-time-string te)))
1260                 ts (if tstart (max ts tstart) ts)
1261                 te (if tend (min te tend) te)
1262                 dt (- te ts)
1263                 t1 (if (> dt 0) (+ t1 (floor (/ dt 60))) t1)))
1264          ((match-end 4)
1265           ;; A naked time
1266           (setq t1 (+ t1 (string-to-number (match-string 5))
1267                       (* 60 (string-to-number (match-string 4))))))
1268          (t ;; A headline
1269           (setq level (- (match-end 1) (match-beginning 1)))
1270           (when (or (> t1 0) (> (aref ltimes level) 0))
1271             (loop for l from 0 to level do
1272                   (aset ltimes l (+ (aref ltimes l) t1)))
1273             (setq t1 0 time (aref ltimes level))
1274             (loop for l from level to (1- lmax) do
1275                   (aset ltimes l 0))
1276             (goto-char (match-beginning 0))
1277             (put-text-property (point) (point-at-eol) :org-clock-minutes time)))))
1278       (setq org-clock-file-total-minutes (aref ltimes 0)))
1279     (set-buffer-modified-p bmp)))
1280
1281 (defun org-clock-sum-current-item (&optional tstart)
1282   "Returns time, clocked on current item in total"
1283   (save-excursion
1284     (save-restriction
1285       (org-narrow-to-subtree)
1286       (org-clock-sum tstart)
1287       org-clock-file-total-minutes)))
1288
1289 (defun org-clock-display (&optional total-only)
1290   "Show subtree times in the entire buffer.
1291 If TOTAL-ONLY is non-nil, only show the total time for the entire file
1292 in the echo area."
1293   (interactive)
1294   (org-clock-remove-overlays)
1295   (let (time h m p)
1296     (org-clock-sum)
1297     (unless total-only
1298       (save-excursion
1299         (goto-char (point-min))
1300         (while (or (and (equal (setq p (point)) (point-min))
1301                         (get-text-property p :org-clock-minutes))
1302                    (setq p (next-single-property-change
1303                             (point) :org-clock-minutes)))
1304           (goto-char p)
1305           (when (setq time (get-text-property p :org-clock-minutes))
1306             (org-clock-put-overlay time (funcall outline-level))))
1307         (setq h (/ org-clock-file-total-minutes 60)
1308               m (- org-clock-file-total-minutes (* 60 h)))
1309         ;; Arrange to remove the overlays upon next change.
1310         (when org-remove-highlights-with-change
1311           (org-add-hook 'before-change-functions 'org-clock-remove-overlays
1312                         nil 'local))))
1313     (if org-time-clocksum-use-fractional
1314         (message (concat "Total file time: " org-time-clocksum-fractional-format
1315                          " (%d hours and %d minutes)")
1316                  (/ (+ (* h 60.0) m) 60.0) h m)
1317       (message (concat "Total file time: " org-time-clocksum-format
1318                        " (%d hours and %d minutes)") h m h m))))
1319
1320 (defvar org-clock-overlays nil)
1321 (make-variable-buffer-local 'org-clock-overlays)
1322
1323 (defun org-clock-put-overlay (time &optional level)
1324   "Put an overlays on the current line, displaying TIME.
1325 If LEVEL is given, prefix time with a corresponding number of stars.
1326 This creates a new overlay and stores it in `org-clock-overlays', so that it
1327 will be easy to remove."
1328   (let* ((c 60) (h (floor (/ time 60))) (m (- time (* 60 h)))
1329          (l (if level (org-get-valid-level level 0) 0))
1330          (fmt (concat "%s " (if org-time-clocksum-use-fractional
1331                                 org-time-clocksum-fractional-format
1332                               org-time-clocksum-format) "%s"))
1333          (off 0)
1334          ov tx)
1335     (org-move-to-column c)
1336     (unless (eolp) (skip-chars-backward "^ \t"))
1337     (skip-chars-backward " \t")
1338     (setq ov (org-make-overlay (1- (point)) (point-at-eol))
1339           tx (concat (buffer-substring (1- (point)) (point))
1340                      (make-string (+ off (max 0 (- c (current-column)))) ?.)
1341                      (org-add-props (if org-time-clocksum-use-fractional
1342                                         (format fmt
1343                                                 (make-string l ?*)
1344                                                 (/ (+ (* h 60.0) m) 60.0)
1345                                                 (make-string (- 16 l) ?\ ))
1346                                       (format fmt
1347                                               (make-string l ?*) h m
1348                                               (make-string (- 16 l) ?\ )))
1349                          (list 'face 'org-clock-overlay))
1350                      ""))
1351     (if (not (featurep 'xemacs))
1352         (org-overlay-put ov 'display tx)
1353       (org-overlay-put ov 'invisible t)
1354       (org-overlay-put ov 'end-glyph (make-glyph tx)))
1355     (push ov org-clock-overlays)))
1356
1357 (defun org-clock-remove-overlays (&optional beg end noremove)
1358   "Remove the occur highlights from the buffer.
1359 BEG and END are ignored.  If NOREMOVE is nil, remove this function
1360 from the `before-change-functions' in the current buffer."
1361   (interactive)
1362   (unless org-inhibit-highlight-removal
1363     (mapc 'org-delete-overlay org-clock-overlays)
1364     (setq org-clock-overlays nil)
1365     (unless noremove
1366       (remove-hook 'before-change-functions
1367                    'org-clock-remove-overlays 'local))))
1368
1369 (defvar state) ;; dynamically scoped into this function
1370 (defun org-clock-out-if-current ()
1371   "Clock out if the current entry contains the running clock.
1372 This is used to stop the clock after a TODO entry is marked DONE,
1373 and is only done if the variable `org-clock-out-when-done' is not nil."
1374   (when (and org-clock-out-when-done
1375              (member state org-done-keywords)
1376              (equal (or (buffer-base-buffer (marker-buffer org-clock-marker))
1377                         (marker-buffer org-clock-marker))
1378                     (or (buffer-base-buffer (current-buffer))
1379                         (current-buffer)))
1380              (< (point) org-clock-marker)
1381              (> (save-excursion (outline-next-heading) (point))
1382                 org-clock-marker))
1383     ;; Clock out, but don't accept a logging message for this.
1384     (let ((org-log-note-clock-out nil))
1385       (org-clock-out))))
1386
1387 (add-hook 'org-after-todo-state-change-hook
1388           'org-clock-out-if-current)
1389
1390 ;;;###autoload
1391 (defun org-get-clocktable (&rest props)
1392   "Get a formatted clocktable with parameters according to PROPS.
1393 The table is created in a temporary buffer, fully formatted and
1394 fontified, and then returned."
1395   ;; Set the defaults
1396   (setq props (plist-put props :name "clocktable"))
1397   (unless (plist-member props :maxlevel)
1398     (setq props (plist-put props :maxlevel 2)))
1399   (unless (plist-member props :scope)
1400     (setq props (plist-put props :scope 'agenda)))
1401   (with-temp-buffer
1402     (org-mode)
1403     (org-create-dblock props)
1404     (org-update-dblock)
1405     (font-lock-fontify-buffer)
1406     (forward-line 2)
1407     (buffer-substring (point) (progn
1408                                 (re-search-forward "^#\\+END" nil t)
1409                                 (point-at-bol)))))
1410
1411 (defun org-clock-report (&optional arg)
1412   "Create a table containing a report about clocked time.
1413 If the cursor is inside an existing clocktable block, then the table
1414 will be updated.  If not, a new clocktable will be inserted.
1415 When called with a prefix argument, move to the first clock table in the
1416 buffer and update it."
1417   (interactive "P")
1418   (org-clock-remove-overlays)
1419   (when arg
1420     (org-find-dblock "clocktable")
1421     (org-show-entry))
1422   (if (org-in-clocktable-p)
1423       (goto-char (org-in-clocktable-p))
1424     (org-create-dblock (append (list :name "clocktable")
1425                                org-clock-clocktable-default-properties)))
1426   (org-update-dblock))
1427
1428 (defun org-in-clocktable-p ()
1429   "Check if the cursor is in a clocktable."
1430   (let ((pos (point)) start)
1431     (save-excursion
1432       (end-of-line 1)
1433       (and (re-search-backward "^#\\+BEGIN:[ \t]+clocktable" nil t)
1434            (setq start (match-beginning 0))
1435            (re-search-forward "^#\\+END:.*" nil t)
1436            (>= (match-end 0) pos)
1437            start))))
1438
1439 (defun org-clock-special-range (key &optional time as-strings)
1440   "Return two times bordering a special time range.
1441 Key is a symbol specifying the range and can be one of `today', `yesterday',
1442 `thisweek', `lastweek', `thismonth', `lastmonth', `thisyear', `lastyear'.
1443 A week starts Monday 0:00 and ends Sunday 24:00.
1444 The range is determined relative to TIME.  TIME defaults to the current time.
1445 The return value is a cons cell with two internal times like the ones
1446 returned by `current time' or `encode-time'. if AS-STRINGS is non-nil,
1447 the returned times will be formatted strings."
1448   (if (integerp key) (setq key (intern (number-to-string key))))
1449   (let* ((tm (decode-time (or time (current-time))))
1450          (s 0) (m (nth 1 tm)) (h (nth 2 tm))
1451          (d (nth 3 tm)) (month (nth 4 tm)) (y (nth 5 tm))
1452          (dow (nth 6 tm))
1453          (skey (symbol-name key))
1454          (shift 0)
1455          s1 m1 h1 d1 month1 y1 diff ts te fm txt w date)
1456     (cond
1457      ((string-match "^[0-9]+$" skey)
1458       (setq y (string-to-number skey) m 1 d 1 key 'year))
1459      ((string-match "^\\([0-9]+\\)-\\([0-9]\\{1,2\\}\\)$" skey)
1460       (setq y (string-to-number (match-string 1 skey))
1461             month (string-to-number (match-string 2 skey))
1462             d 1 key 'month))
1463      ((string-match "^\\([0-9]+\\)-[wW]\\([0-9]\\{1,2\\}\\)$" skey)
1464       (require 'cal-iso)
1465       (setq y (string-to-number (match-string 1 skey))
1466             w (string-to-number (match-string 2 skey)))
1467       (setq date (calendar-gregorian-from-absolute
1468                   (calendar-absolute-from-iso (list w 1 y))))
1469       (setq d (nth 1 date) month (car date) y (nth 2 date)
1470             dow 1
1471             key 'week))
1472      ((string-match "^\\([0-9]+\\)-\\([0-9]\\{1,2\\}\\)-\\([0-9]\\{1,2\\}\\)$" skey)
1473       (setq y (string-to-number (match-string 1 skey))
1474             month (string-to-number (match-string 2 skey))
1475             d (string-to-number (match-string 3 skey))
1476             key 'day))
1477      ((string-match "\\([-+][0-9]+\\)$" skey)
1478       (setq shift (string-to-number (match-string 1 skey))
1479             key (intern (substring skey 0 (match-beginning 1))))))
1480     (when (= shift 0)
1481       (cond ((eq key 'yesterday) (setq key 'today shift -1))
1482             ((eq key 'lastweek)  (setq key 'week  shift -1))
1483             ((eq key 'lastmonth) (setq key 'month shift -1))
1484             ((eq key 'lastyear)  (setq key 'year  shift -1))))
1485     (cond
1486      ((memq key '(day today))
1487       (setq d (+ d shift) h 0 m 0 h1 24 m1 0))
1488      ((memq key '(week thisweek))
1489       (setq diff (+ (* -7 shift) (if (= dow 0) 6 (1- dow)))
1490             m 0 h 0 d (- d diff) d1 (+ 7 d)))
1491      ((memq key '(month thismonth))
1492       (setq d 1 h 0 m 0 d1 1 month (+ month shift) month1 (1+ month) h1 0 m1 0))
1493      ((memq key '(year thisyear))
1494       (setq m 0 h 0 d 1 month 1 y (+ y shift) y1 (1+ y)))
1495      (t (error "No such time block %s" key)))
1496     (setq ts (encode-time s m h d month y)
1497           te (encode-time (or s1 s) (or m1 m) (or h1 h)
1498                           (or d1 d) (or month1 month) (or y1 y)))
1499     (setq fm (cdr org-time-stamp-formats))
1500     (cond
1501      ((memq key '(day today))
1502       (setq txt (format-time-string "%A, %B %d, %Y" ts)))
1503      ((memq key '(week thisweek))
1504       (setq txt (format-time-string "week %G-W%V" ts)))
1505      ((memq key '(month thismonth))
1506       (setq txt (format-time-string "%B %Y" ts)))
1507      ((memq key '(year thisyear))
1508       (setq txt (format-time-string "the year %Y" ts))))
1509     (if as-strings
1510         (list (format-time-string fm ts) (format-time-string fm te) txt)
1511       (list ts te txt))))
1512
1513 (defun org-clocktable-shift (dir n)
1514   "Try to shift the :block date of the clocktable at point.
1515 Point must be in the #+BEGIN: line of a clocktable, or this function
1516 will throw an error.
1517 DIR is a direction, a symbol `left', `right', `up', or `down'.
1518 Both `left' and `down' shift the block toward the past, `up' and `right'
1519 push it toward the future.
1520 N is the number of shift steps to take.  The size of the step depends on
1521 the currently selected interval size."
1522   (setq n (prefix-numeric-value n))
1523   (and (memq dir '(left down)) (setq n (- n)))
1524   (save-excursion
1525     (goto-char (point-at-bol))
1526     (if (not (looking-at "#\\+BEGIN: clocktable\\>.*?:block[ \t]+\\(\\S-+\\)"))
1527         (error "Line needs a :block definition before this command works")
1528       (let* ((b (match-beginning 1)) (e (match-end 1))
1529              (s (match-string 1))
1530              block shift ins y mw d date wp m)
1531         (cond
1532          ((equal s "yesterday") (setq s "today-1"))
1533          ((equal s "lastweek") (setq s "thisweek-1"))
1534          ((equal s "lastmonth") (setq s "thismonth-1"))
1535          ((equal s "lastyear") (setq s "thisyear-1")))
1536         (cond
1537          ((string-match "^\\(today\\|thisweek\\|thismonth\\|thisyear\\)\\([-+][0-9]+\\)?$" s)
1538           (setq block (match-string 1 s)
1539                 shift (if (match-end 2)
1540                           (string-to-number (match-string 2 s))
1541                         0))
1542           (setq shift (+ shift n))
1543           (setq ins (if (= shift 0) block (format "%s%+d" block shift))))
1544          ((string-match "\\([0-9]+\\)\\(-\\([wW]?\\)\\([0-9]\\{1,2\\}\\)\\(-\\([0-9]\\{1,2\\}\\)\\)?\\)?" s)
1545           ;;               1        1  2   3       3  4                4  5   6                6  5   2
1546           (setq y (string-to-number (match-string 1 s))
1547                 wp (and (match-end 3) (match-string 3 s))
1548                 mw (and (match-end 4) (string-to-number (match-string 4 s)))
1549                 d (and (match-end 6) (string-to-number (match-string 6 s))))
1550           (cond
1551            (d (setq ins (format-time-string
1552                          "%Y-%m-%d"
1553                          (encode-time 0 0 0 (+ d n) m y))))
1554            ((and wp mw (> (length wp) 0))
1555             (require 'cal-iso)
1556             (setq date (calendar-gregorian-from-absolute (calendar-absolute-from-iso (list (+ mw n) 1 y))))
1557             (setq ins (format-time-string
1558                        "%G-W%V"
1559                        (encode-time 0 0 0 (nth 1 date) (car date) (nth 2 date)))))
1560            (mw
1561             (setq ins (format-time-string
1562                        "%Y-%m"
1563                        (encode-time 0 0 0 1 (+ mw n) y))))
1564            (y
1565             (setq ins (number-to-string (+ y n))))))
1566          (t (error "Cannot shift clocktable block")))
1567         (when ins
1568           (goto-char b)
1569           (insert ins)
1570           (delete-region (point) (+ (point) (- e b)))
1571           (beginning-of-line 1)
1572           (org-update-dblock)
1573           t)))))
1574
1575 (defun org-dblock-write:clocktable (params)
1576   "Write the standard clocktable."
1577   (catch 'exit
1578     (let* ((hlchars '((1 . "*") (2 . "/")))
1579            (ins (make-marker))
1580            (total-time nil)
1581            (scope (plist-get params :scope))
1582            (tostring (plist-get  params :tostring))
1583            (multifile (plist-get  params :multifile))
1584            (header (plist-get  params :header))
1585            (maxlevel (or (plist-get params :maxlevel) 3))
1586            (step (plist-get params :step))
1587            (emph (plist-get params :emphasize))
1588            (timestamp (plist-get params :timestamp))
1589            (ts (plist-get params :tstart))
1590            (te (plist-get params :tend))
1591            (block (plist-get params :block))
1592            (link (plist-get params :link))
1593            ipos time p level hlc hdl tsp props content recalc formula pcol
1594            cc beg end pos tbl tbl1 range-text rm-file-column scope-is-list st)
1595       (setq org-clock-file-total-minutes nil)
1596       (when step
1597         (unless (or block (and ts te))
1598           (error "Clocktable `:step' can only be used with `:block' or `:tstart,:end'"))
1599         (org-clocktable-steps params)
1600         (throw 'exit nil))
1601       (when block
1602         (setq cc (org-clock-special-range block nil t)
1603               ts (car cc) te (nth 1 cc) range-text (nth 2 cc)))
1604       (when (integerp ts) (setq ts (calendar-gregorian-from-absolute ts)))
1605       (when (integerp te) (setq te (calendar-gregorian-from-absolute te)))
1606       (when (and ts (listp ts))
1607         (setq ts (format "%4d-%02d-%02d" (nth 2 ts) (car ts) (nth 1 ts))))
1608       (when (and te (listp te))
1609         (setq te (format "%4d-%02d-%02d" (nth 2 te) (car te) (nth 1 te))))
1610       ;; Now the times are strings we can parse.
1611       (if ts (setq ts (org-float-time
1612                        (apply 'encode-time (org-parse-time-string ts)))))
1613       (if te (setq te (org-float-time
1614                        (apply 'encode-time (org-parse-time-string te)))))
1615       (move-marker ins (point))
1616       (setq ipos (point))
1617
1618       ;; Get the right scope
1619       (setq pos (point))
1620       (cond
1621        ((and scope (listp scope) (symbolp (car scope)))
1622         (setq scope (eval scope)))
1623        ((eq scope 'agenda)
1624         (setq scope (org-agenda-files t)))
1625        ((eq scope 'agenda-with-archives)
1626         (setq scope (org-agenda-files t))
1627         (setq scope (org-add-archive-files scope)))
1628        ((eq scope 'file-with-archives)
1629         (setq scope (org-add-archive-files (list (buffer-file-name)))
1630               rm-file-column t)))
1631       (setq scope-is-list (and scope (listp scope)))
1632       (save-restriction
1633         (cond
1634          ((not scope))
1635          ((eq scope 'file) (widen))
1636          ((eq scope 'subtree) (org-narrow-to-subtree))
1637          ((eq scope 'tree)
1638           (while (org-up-heading-safe))
1639           (org-narrow-to-subtree))
1640          ((and (symbolp scope) (string-match "^tree\\([0-9]+\\)$"
1641                                              (symbol-name scope)))
1642           (setq level (string-to-number (match-string 1 (symbol-name scope))))
1643           (catch 'exit
1644             (while (org-up-heading-safe)
1645               (looking-at outline-regexp)
1646               (if (<= (org-reduced-level (funcall outline-level)) level)
1647                   (throw 'exit nil))))
1648           (org-narrow-to-subtree))
1649          (scope-is-list
1650           (let* ((files scope)
1651                  (scope 'agenda)
1652                  (p1 (copy-sequence params))
1653                  file)
1654             (setq p1 (plist-put p1 :tostring t))
1655             (setq p1 (plist-put p1 :multifile t))
1656             (setq p1 (plist-put p1 :scope 'file))
1657             (org-prepare-agenda-buffers files)
1658             (while (setq file (pop files))
1659               (with-current-buffer (find-buffer-visiting file)
1660                 (setq tbl1 (org-dblock-write:clocktable p1))
1661                 (when tbl1
1662                   (push (org-clocktable-add-file
1663                          file
1664                          (concat "| |*File time*|*"
1665                                  (org-minutes-to-hh:mm-string
1666                                   org-clock-file-total-minutes)
1667                                  "*|\n"
1668                                  tbl1)) tbl)
1669                   (setq total-time (+ (or total-time 0)
1670                                       org-clock-file-total-minutes))))))))
1671         (goto-char pos)
1672
1673         (unless scope-is-list
1674           (org-clock-sum ts te)
1675           (goto-char (point-min))
1676           (setq st t)
1677           (while (or (and (bobp) (prog1 st (setq st nil))
1678                           (get-text-property (point) :org-clock-minutes)
1679                           (setq p (point-min)))
1680                      (setq p (next-single-property-change (point) :org-clock-minutes)))
1681             (goto-char p)
1682             (when (setq time (get-text-property p :org-clock-minutes))
1683               (save-excursion
1684                 (beginning-of-line 1)
1685                 (when (and (looking-at (org-re "\\(\\*+\\)[ \t]+\\(.*?\\)\\([ \t]+:[[:alnum:]_@:]+:\\)?[ \t]*$"))
1686                            (setq level (org-reduced-level
1687                                         (- (match-end 1) (match-beginning 1))))
1688                            (<= level maxlevel))
1689                   (setq hlc (if emph (or (cdr (assoc level hlchars)) "") "")
1690                         hdl (if (not link)
1691                                 (match-string 2)
1692                               (org-make-link-string
1693                                (format "file:%s::%s"
1694                                        (buffer-file-name)
1695                                        (save-match-data
1696                                          (org-make-org-heading-search-string
1697                                           (match-string 2))))
1698                                (match-string 2)))
1699                         tsp (when timestamp
1700                               (setq props (org-entry-properties (point)))
1701                               (or (cdr (assoc "SCHEDULED" props))
1702                                   (cdr (assoc "TIMESTAMP" props))
1703                                   (cdr (assoc "DEADLINE" props))
1704                                   (cdr (assoc "TIMESTAMP_IA" props)))))
1705                   (if (and (not multifile) (= level 1)) (push "|-" tbl))
1706                   (push (concat
1707                          "| " (int-to-string level) "|"
1708                          (if timestamp (concat tsp "|") "")
1709                          hlc hdl hlc " |"
1710                          (make-string (1- level) ?|)
1711                          hlc (org-minutes-to-hh:mm-string time) hlc
1712                          " |") tbl))))))
1713         (setq tbl (nreverse tbl))
1714         (if tostring
1715             (if tbl (mapconcat 'identity tbl "\n") nil)
1716           (goto-char ins)
1717           (insert-before-markers
1718            (or header
1719                (concat
1720                 "Clock summary at ["
1721                 (substring
1722                  (format-time-string (cdr org-time-stamp-formats))
1723                  1 -1)
1724                 "]"
1725                 (if block (concat ", for " range-text ".") "")
1726                 "\n\n"))
1727            (if scope-is-list "|File" "")
1728            "|L|" (if timestamp "Timestamp|" "") "Headline|Time|\n")
1729           (setq total-time (or total-time org-clock-file-total-minutes))
1730           (insert-before-markers
1731            "|-\n|"
1732            (if scope-is-list "|" "")
1733            (if timestamp "|Timestamp|" "|")
1734            "*Total time*| *"
1735            (org-minutes-to-hh:mm-string (or total-time 0))
1736            "*|\n|-\n")
1737           (setq tbl (delq nil tbl))
1738           (if (and (stringp (car tbl)) (> (length (car tbl)) 1)
1739                    (equal (substring (car tbl) 0 2) "|-"))
1740               (pop tbl))
1741           (insert-before-markers (mapconcat
1742                                   'identity (delq nil tbl)
1743                                   (if scope-is-list "\n|-\n" "\n")))
1744           (backward-delete-char 1)
1745           (if (setq formula (plist-get params :formula))
1746               (cond
1747                ((eq formula '%)
1748                 (setq pcol (+ (if scope-is-list 1 0) maxlevel 3))
1749                 (insert
1750                  (format
1751                   "\n#+TBLFM: $%d='(org-clock-time%% @%d$%d $%d..$%d);%%.1f"
1752                   pcol
1753                   2
1754                   (+ 3 (if scope-is-list 1 0))
1755                   (+ (if scope-is-list 1 0) 3)
1756                   (1- pcol)))
1757                 (setq recalc t))
1758                ((stringp formula)
1759                 (insert "\n#+TBLFM: " formula)
1760                 (setq recalc t))
1761                (t (error "invalid formula in clocktable")))
1762             ;; Should we rescue an old formula?
1763             (when (stringp (setq content (plist-get params :content)))
1764               (when (string-match "^\\([ \t]*#\\+TBLFM:.*\\)" content)
1765                 (setq recalc t)
1766                 (insert "\n" (match-string 1 (plist-get params :content)))
1767                 (beginning-of-line 0))))
1768           (goto-char ipos)
1769           (skip-chars-forward "^|")
1770           (org-table-align)
1771           (when recalc
1772             (if (eq formula '%)
1773                 (save-excursion (org-table-goto-column pcol nil 'force)
1774                                 (insert "%")))
1775             (org-table-recalculate 'all))
1776           (when rm-file-column
1777             (forward-char 1)
1778             (org-table-delete-column)))))))
1779
1780 (defun org-clocktable-steps (params)
1781   (let* ((p1 (copy-sequence params))
1782          (ts (plist-get p1 :tstart))
1783          (te (plist-get p1 :tend))
1784          (step0 (plist-get p1 :step))
1785          (step (cdr (assoc step0 '((day . 86400) (week . 604800)))))
1786          (block (plist-get p1 :block))
1787          cc range-text)
1788     (when block
1789       (setq cc (org-clock-special-range block nil t)
1790             ts (car cc) te (nth 1 cc) range-text (nth 2 cc)))
1791     (if ts (setq ts (org-float-time
1792                      (apply 'encode-time (org-parse-time-string ts)))))
1793     (if te (setq te (org-float-time
1794                      (apply 'encode-time (org-parse-time-string te)))))
1795     (setq p1 (plist-put p1 :header ""))
1796     (setq p1 (plist-put p1 :step nil))
1797     (setq p1 (plist-put p1 :block nil))
1798     (while (< ts te)
1799       (or (bolp) (insert "\n"))
1800       (setq p1 (plist-put p1 :tstart (format-time-string
1801                                       (org-time-stamp-format nil t)
1802                                       (seconds-to-time ts))))
1803       (setq p1 (plist-put p1 :tend (format-time-string
1804                                     (org-time-stamp-format nil t)
1805                                     (seconds-to-time (setq ts (+ ts step))))))
1806       (insert "\n" (if (eq step0 'day) "Daily report: " "Weekly report starting on: ")
1807               (plist-get p1 :tstart) "\n")
1808       (org-dblock-write:clocktable p1)
1809       (re-search-forward "#\\+END:")
1810       (end-of-line 0))))
1811
1812 (defun org-clocktable-add-file (file table)
1813   (if table
1814       (let ((lines (org-split-string table "\n"))
1815             (ff (file-name-nondirectory file)))
1816         (mapconcat 'identity
1817                    (mapcar (lambda (x)
1818                              (if (string-match org-table-dataline-regexp x)
1819                                  (concat "|" ff x)
1820                                x))
1821                            lines)
1822                    "\n"))))
1823
1824 (defun org-clock-time% (total &rest strings)
1825   "Compute a time fraction in percent.
1826 TOTAL s a time string like 10:21 specifying the total times.
1827 STRINGS is a list of strings that should be checked for a time.
1828 The first string that does have a time will be used.
1829 This function is made for clock tables."
1830   (let ((re "\\([0-9]+\\):\\([0-9]+\\)")
1831         tot s)
1832     (save-match-data
1833       (catch 'exit
1834         (if (not (string-match re total))
1835             (throw 'exit 0.)
1836           (setq tot (+ (string-to-number (match-string 2 total))
1837                        (* 60 (string-to-number (match-string 1 total)))))
1838           (if (= tot 0.) (throw 'exit 0.)))
1839         (while (setq s (pop strings))
1840           (if (string-match "\\([0-9]+\\):\\([0-9]+\\)" s)
1841               (throw 'exit
1842                      (/ (* 100.0 (+ (string-to-number (match-string 2 s))
1843                                     (* 60 (string-to-number (match-string 1 s)))))
1844                         tot))))
1845         0))))
1846
1847 (defvar org-clock-loaded nil
1848   "Was the clock file loaded?")
1849
1850 (defun org-clock-save ()
1851   "Persist various clock-related data to disk.
1852 The details of what will be saved are regulated by the variable
1853 `org-clock-persist'."
1854   (when (and org-clock-persist
1855              (or org-clock-loaded
1856                  org-clock-has-been-used
1857                  (not (file-exists-p org-clock-persist-file))))
1858     (let (b)
1859       (with-current-buffer (find-file (expand-file-name org-clock-persist-file))
1860         (progn
1861           (delete-region (point-min) (point-max))
1862           ;;Store clock
1863           (insert (format ";; org-persist.el - %s at %s\n"
1864                           system-name (format-time-string
1865                                        (cdr org-time-stamp-formats))))
1866           (if (and (memq org-clock-persist '(t clock))
1867                    (setq b (marker-buffer org-clock-marker))
1868                    (setq b (or (buffer-base-buffer b) b))
1869                    (buffer-live-p b)
1870                    (buffer-file-name b)
1871                    (or (not org-clock-persist-query-save)
1872                        (y-or-n-p (concat "Save current clock ("
1873                                          (substring-no-properties org-clock-heading)
1874                                          ") "))))
1875               (insert "(setq resume-clock '(\""
1876                       (buffer-file-name (marker-buffer org-clock-marker))
1877                       "\" . " (int-to-string (marker-position org-clock-marker))
1878                       "))\n"))
1879           ;; Store clocked task history. Tasks are stored reversed to make
1880           ;; reading simpler
1881           (when (and (memq org-clock-persist '(t history))
1882                      org-clock-history)
1883             (insert
1884              "(setq stored-clock-history '("
1885              (mapconcat
1886               (lambda (m)
1887                 (when (and (setq b (marker-buffer m))
1888                            (setq b (or (buffer-base-buffer b) b))
1889                            (buffer-live-p b)
1890                            (buffer-file-name b))
1891                   (concat "(\"" (buffer-file-name b)
1892                           "\" . " (int-to-string (marker-position m))
1893                           ")")))
1894               (reverse org-clock-history) " ") "))\n"))
1895           (save-buffer)
1896           (kill-buffer (current-buffer)))))))
1897
1898 (defun org-clock-load ()
1899   "Load clock-related data from disk, maybe resuming a stored clock."
1900   (when (and org-clock-persist (not org-clock-loaded))
1901     (let ((filename (expand-file-name org-clock-persist-file))
1902           (org-clock-in-resume 'auto-restart)
1903           resume-clock stored-clock-history)
1904       (if (not (file-readable-p filename))
1905           (message "Not restoring clock data; %s not found"
1906                    org-clock-persist-file)
1907         (message "%s" "Restoring clock data")
1908         (setq org-clock-loaded t)
1909         (load-file filename)
1910         ;; load history
1911         (when stored-clock-history
1912           (save-window-excursion
1913             (mapc (lambda (task)
1914                     (if (file-exists-p (car task))
1915                         (org-clock-history-push (cdr task)
1916                                                 (find-file (car task)))))
1917                   stored-clock-history)))
1918         ;; resume clock
1919         (when (and resume-clock org-clock-persist
1920                    (file-exists-p (car resume-clock))
1921                    (or (not org-clock-persist-query-resume)
1922                        (y-or-n-p
1923                         (concat
1924                          "Resume clock ("
1925                          (with-current-buffer (find-file (car resume-clock))
1926                            (save-excursion
1927                              (goto-char (cdr resume-clock))
1928                              (org-back-to-heading t)
1929                              (and (looking-at org-complex-heading-regexp)
1930                                   (match-string 4))))
1931                          ") "))))
1932           (when (file-exists-p (car resume-clock))
1933             (with-current-buffer (find-file (car resume-clock))
1934               (goto-char (cdr resume-clock))
1935               (let ((org-clock-auto-clock-resolution nil))
1936                 (org-clock-in)
1937                 (if (org-invisible-p)
1938                     (org-show-context))))))))))
1939
1940 ;;;###autoload
1941 (defun org-clock-persistence-insinuate ()
1942   "Set up hooks for clock persistence"
1943   (add-hook 'org-mode-hook 'org-clock-load)
1944   (add-hook 'kill-emacs-hook 'org-clock-save))
1945
1946 ;; Suggested bindings
1947 (org-defkey org-mode-map "\C-c\C-x\C-e" 'org-clock-modify-effort-estimate)
1948
1949 (provide 'org-clock)
1950
1951 ;; arch-tag: 7b42c5d4-9b36-48be-97c0-66a869daed4c
1952
1953 ;;; org-clock.el ends here