lisp/ob-lob.el

   1 ;;; ob-lob.el --- functions supporting the Library of Babel
   2
   3 ;; Copyright (C) 2009-2012  Free Software Foundation, Inc.
   4
   5 ;; Authors: Eric Schulte
   6 ;;       Dan Davison
   7 ;; Keywords: literate programming, reproducible research
   8 ;; Homepage: http://orgmode.org
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Code:
  26 (eval-when-compile
  27   (require 'cl))
  28 (require 'ob)
  29 (require 'ob-table)
  30
  31 (declare-function org-babel-in-example-or-verbatim "ob-exp" nil)
  32
  33 (defvar org-babel-library-of-babel nil
  34   "Library of source-code blocks.
  35 This is an association list.  Populate the library by adding
  36 files to `org-babel-lob-files'.")
  37
  38 (defcustom org-babel-lob-files '()
  39   "Files used to populate the `org-babel-library-of-babel'.
  40 To add files to this list use the `org-babel-lob-ingest' command."
  41   :group 'org-babel
  42   :version "24.1"
  43   :type 'list)
  44
  45 (defvar org-babel-default-lob-header-args '((:exports . "results"))
  46   "Default header arguments to use when exporting #+lob/call lines.")
  47
  48 ;;;###autoload
  49 (defun org-babel-lob-ingest (&optional file)
  50   "Add all named source-blocks defined in FILE to
  51 `org-babel-library-of-babel'."
  52   (interactive "fFile: ")
  53   (let ((lob-ingest-count 0))
  54     (org-babel-map-src-blocks file
  55       (let* ((info (org-babel-get-src-block-info 'light))
  56              (source-name (nth 4 info)))
  57         (when source-name
  58           (setq source-name (intern source-name)
  59                 org-babel-library-of-babel
  60                 (cons (cons source-name info)
  61                       (assq-delete-all source-name org-babel-library-of-babel))
  62                 lob-ingest-count (1+ lob-ingest-count)))))
  63     (message "%d src block%s added to Library of Babel"
  64              lob-ingest-count (if (> lob-ingest-count 1) "s" ""))
  65     lob-ingest-count))
  66
  67 (defconst org-babel-block-lob-one-liner-regexp
  68   (concat
  69    "^\\([ \t]*?\\)#\\+call:[ \t]+\\([^\(\)\n]+?\\)\\(\\[\\(.*\\)\\]\\|\\(\\)\\)"
  70    "\(\\([^\n]*?\\)\)\\(\\[.+\\]\\|\\)[ \t]*\\(\\([^\n]*\\)\\)?")
  71   "Regexp to match non-inline calls to predefined source block functions.")
  72
  73 (defconst org-babel-inline-lob-one-liner-regexp
  74   (concat
  75    "\\([^\n]*?\\)call_\\([^\(\)\n]+?\\)\\(\\[\\(.*?\\)\\]\\|\\(\\)\\)"
  76    "\(\\([^\n]*?\\)\)\\(\\[\\(.*?\\)\\]\\)?")
  77   "Regexp to match inline calls to predefined source block functions.")
  78
  79 (defconst org-babel-lob-one-liner-regexp
  80   (concat "\\(" org-babel-block-lob-one-liner-regexp
  81           "\\|" org-babel-inline-lob-one-liner-regexp "\\)")
  82   "Regexp to match calls to predefined source block functions.")
  83
  84 ;; functions for executing lob one-liners
  85
  86 ;;;###autoload
  87 (defun org-babel-lob-execute-maybe ()
  88   "Execute a Library of Babel source block, if appropriate.
  89 Detect if this is context for a Library Of Babel source block and
  90 if so then run the appropriate source block from the Library."
  91   (interactive)
  92   (let ((info (org-babel-lob-get-info)))
  93     (if (and (nth 0 info) (not (org-babel-in-example-or-verbatim)))
  94         (progn (org-babel-lob-execute info) t)
  95       nil)))
  96
  97 ;;;###autoload
  98 (defun org-babel-lob-get-info ()
  99   "Return a Library of Babel function call as a string."
 100   (let ((case-fold-search t)
 101         (nonempty (lambda (a b)
 102                     (let ((it (match-string a)))
 103                       (if (= (length it) 0) (match-string b) it)))))
 104     (save-excursion
 105       (beginning-of-line 1)
 106       (when (looking-at org-babel-lob-one-liner-regexp)
 107         (append
 108          (mapcar #'org-babel-clean-text-properties
 109                  (list
 110                   (format "%s%s(%s)%s"
 111                           (funcall nonempty 3 12)
 112                           (if (not (= 0 (length (funcall nonempty 5 14))))
 113                               (concat "[" (funcall nonempty 5 14) "]") "")
 114                           (or (funcall nonempty 7 16) "")
 115                           (or (funcall nonempty 8 19) ""))
 116                   (funcall nonempty 9 18)))
 117          (list (length (if (= (length (match-string 12)) 0)
 118                            (match-string 2) (match-string 11)))))))))
 119
 120 (defun org-babel-lob-execute (info)
 121   "Execute the lob call specified by INFO."
 122   (let* ((mkinfo (lambda (p) (list "emacs-lisp" "results" p nil nil (nth 2 info))))
 123          (pre-params (org-babel-merge-params
 124                       org-babel-default-header-args
 125                       (org-babel-params-from-properties)
 126                       (org-babel-parse-header-arguments
 127                        (org-babel-clean-text-properties
 128                         (concat ":var results="
 129                                 (mapconcat #'identity (butlast info) " "))))))
 130          (pre-info (funcall mkinfo pre-params))
 131          (cache? (and (cdr (assoc :cache pre-params))
 132                       (string= "yes" (cdr (assoc :cache pre-params)))))
 133          (new-hash (when cache? (org-babel-sha1-hash pre-info)))
 134          (old-hash (when cache? (org-babel-current-result-hash))))
 135     (if (and cache? (equal new-hash old-hash))
 136         (save-excursion (goto-char (org-babel-where-is-src-block-result))
 137                         (forward-line 1)
 138                         (message "%S" (org-babel-read-result)))
 139       (prog1 (org-babel-execute-src-block
 140               nil (funcall mkinfo (org-babel-process-params pre-params)))
 141         ;; update the hash
 142         (when new-hash (org-babel-set-current-result-hash new-hash))))))
 143
 144 (provide 'ob-lob)
 145
 146
 147
 148 ;;; ob-lob.el ends here