lisp/ob-ruby.el

   1 ;;; ob-ruby.el --- Babel Functions for Ruby          -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2009-2017 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Org-Babel support for evaluating ruby source code.
  27
  28 ;;; Requirements:
  29
  30 ;; - ruby and irb executables :: http://www.ruby-lang.org/
  31 ;;
  32 ;; - ruby-mode :: Can be installed through ELPA, or from
  33 ;;   http://github.com/eschulte/rinari/raw/master/util/ruby-mode.el
  34 ;;
  35 ;; - inf-ruby mode :: Can be installed through ELPA, or from
  36 ;;   http://github.com/eschulte/rinari/raw/master/util/inf-ruby.el
  37
  38 ;;; Code:
  39 (require 'ob)
  40
  41 (declare-function org-trim "org" (s &optional keep-lead))
  42 (declare-function run-ruby "ext:inf-ruby" (&optional command name))
  43 (declare-function xmp "ext:rcodetools" (&optional option))
  44
  45 (defvar org-babel-tangle-lang-exts)
  46 (add-to-list 'org-babel-tangle-lang-exts '("ruby" . "rb"))
  47
  48 (defvar org-babel-default-header-args:ruby '())
  49
  50 (defvar org-babel-ruby-command "ruby"
  51   "Name of command to use for executing ruby code.")
  52
  53 (defcustom org-babel-ruby-hline-to "nil"
  54   "Replace hlines in incoming tables with this when translating to ruby."
  55   :group 'org-babel
  56   :version "24.4"
  57   :package-version '(Org . "8.0")
  58   :type 'string)
  59
  60 (defcustom org-babel-ruby-nil-to 'hline
  61   "Replace nil in ruby tables with this before returning."
  62   :group 'org-babel
  63   :version "24.4"
  64   :package-version '(Org . "8.0")
  65   :type 'symbol)
  66
  67 (defun org-babel-execute:ruby (body params)
  68   "Execute a block of Ruby code with Babel.
  69 This function is called by `org-babel-execute-src-block'."
  70   (let* ((session (org-babel-ruby-initiate-session
  71                    (cdr (assq :session params))))
  72          (result-params (cdr (assq :result-params params)))
  73          (result-type (cdr (assq :result-type params)))
  74          (full-body (org-babel-expand-body:generic
  75                      body params (org-babel-variable-assignments:ruby params)))
  76          (result (if (member "xmp" result-params)
  77                      (with-temp-buffer
  78                        (require 'rcodetools)
  79                        (insert full-body)
  80                        (xmp (cdr (assq :xmp-option params)))
  81                        (buffer-string))
  82                    (org-babel-ruby-evaluate
  83                     session full-body result-type result-params))))
  84     (org-babel-reassemble-table
  85      (org-babel-result-cond result-params
  86        result
  87        (org-babel-ruby-table-or-string result))
  88      (org-babel-pick-name (cdr (assq :colname-names params))
  89                           (cdr (assq :colnames params)))
  90      (org-babel-pick-name (cdr (assq :rowname-names params))
  91                           (cdr (assq :rownames params))))))
  92
  93 (defun org-babel-prep-session:ruby (session params)
  94   "Prepare SESSION according to the header arguments specified in PARAMS."
  95   ;; (message "params=%S" params) ;; debugging
  96   (let* ((session (org-babel-ruby-initiate-session session))
  97          (var-lines (org-babel-variable-assignments:ruby params)))
  98     (org-babel-comint-in-buffer session
  99       (sit-for .5) (goto-char (point-max))
 100       (mapc (lambda (var)
 101               (insert var) (comint-send-input nil t)
 102               (org-babel-comint-wait-for-output session)
 103               (sit-for .1) (goto-char (point-max))) var-lines))
 104     session))
 105
 106 (defun org-babel-load-session:ruby (session body params)
 107   "Load BODY into SESSION."
 108   (save-window-excursion
 109     (let ((buffer (org-babel-prep-session:ruby session params)))
 110       (with-current-buffer buffer
 111         (goto-char (process-mark (get-buffer-process (current-buffer))))
 112         (insert (org-babel-chomp body)))
 113       buffer)))
 114
 115 ;; helper functions
 116
 117 (defun org-babel-variable-assignments:ruby (params)
 118   "Return list of ruby statements assigning the block's variables."
 119   (mapcar
 120    (lambda (pair)
 121      (format "%s=%s"
 122              (car pair)
 123              (org-babel-ruby-var-to-ruby (cdr pair))))
 124    (org-babel--get-vars params)))
 125
 126 (defun org-babel-ruby-var-to-ruby (var)
 127   "Convert VAR into a ruby variable.
 128 Convert an elisp value into a string of ruby source code
 129 specifying a variable of the same value."
 130   (if (listp var)
 131       (concat "[" (mapconcat #'org-babel-ruby-var-to-ruby var ", ") "]")
 132     (if (eq var 'hline)
 133         org-babel-ruby-hline-to
 134       (format "%S" var))))
 135
 136 (defun org-babel-ruby-table-or-string (results)
 137   "Convert RESULTS into an appropriate elisp value.
 138 If RESULTS look like a table, then convert them into an
 139 Emacs-lisp table, otherwise return the results as a string."
 140   (let ((res (org-babel-script-escape results)))
 141     (if (listp res)
 142         (mapcar (lambda (el) (if (not el)
 143                                  org-babel-ruby-nil-to el))
 144                 res)
 145       res)))
 146
 147 (defun org-babel-ruby-initiate-session (&optional session _params)
 148   "Initiate a ruby session.
 149 If there is not a current inferior-process-buffer in SESSION
 150 then create one.  Return the initialized session."
 151   (unless (string= session "none")
 152     (require 'inf-ruby)
 153     (let* ((cmd (cdr (assoc inf-ruby-default-implementation
 154                             inf-ruby-implementations)))
 155            (buffer (get-buffer (format "*%s*" session)))
 156            (session-buffer (or buffer (save-window-excursion
 157                                         (run-ruby cmd session)
 158                                         (current-buffer)))))
 159       (if (org-babel-comint-buffer-livep session-buffer)
 160           (progn (sit-for .25) session-buffer)
 161         (sit-for .5)
 162         (org-babel-ruby-initiate-session session)))))
 163
 164 (defvar org-babel-ruby-eoe-indicator ":org_babel_ruby_eoe"
 165   "String to indicate that evaluation has completed.")
 166 (defvar org-babel-ruby-f-write
 167   "File.open('%s','w'){|f| f.write((_.class == String) ? _ : _.inspect)}")
 168 (defvar org-babel-ruby-pp-f-write
 169   "File.open('%s','w'){|f| $stdout = f; pp(results); $stdout = orig_out}")
 170 (defvar org-babel-ruby-wrapper-method
 171   "
 172 def main()
 173 %s
 174 end
 175 results = main()
 176 File.open('%s', 'w'){ |f| f.write((results.class == String) ? results : results.inspect) }
 177 ")
 178 (defvar org-babel-ruby-pp-wrapper-method
 179   "
 180 require 'pp'
 181 def main()
 182 %s
 183 end
 184 results = main()
 185 File.open('%s', 'w') do |f|
 186   $stdout = f
 187   pp results
 188 end
 189 ")
 190
 191 (defun org-babel-ruby-evaluate
 192     (buffer body &optional result-type result-params)
 193   "Pass BODY to the Ruby process in BUFFER.
 194 If RESULT-TYPE equals `output' then return a list of the outputs
 195 of the statements in BODY, if RESULT-TYPE equals `value' then
 196 return the value of the last statement in BODY, as elisp."
 197   (if (not buffer)
 198       ;; external process evaluation
 199       (pcase result-type
 200         (`output (org-babel-eval org-babel-ruby-command body))
 201         (`value (let ((tmp-file (org-babel-temp-file "ruby-")))
 202                   (org-babel-eval
 203                    org-babel-ruby-command
 204                    (format (if (member "pp" result-params)
 205                                org-babel-ruby-pp-wrapper-method
 206                              org-babel-ruby-wrapper-method)
 207                            body (org-babel-process-file-name tmp-file 'noquote)))
 208                   (org-babel-eval-read-file tmp-file))))
 209     ;; comint session evaluation
 210     (pcase result-type
 211       (`output
 212        (let ((eoe-string (format "puts \"%s\"" org-babel-ruby-eoe-indicator)))
 213          ;; Force the session to be ready before the actual session
 214          ;; code is run.  There is some problem in comint that will
 215          ;; sometimes show the prompt after the the input has already
 216          ;; been inserted and that throws off the extraction of the
 217          ;; result for Babel.
 218          (org-babel-comint-with-output
 219              (buffer org-babel-ruby-eoe-indicator t eoe-string)
 220            (insert eoe-string) (comint-send-input nil t))
 221          ;; Now we can start the evaluation.
 222          (mapconcat
 223           #'identity
 224           (butlast
 225            (split-string
 226             (mapconcat
 227              #'org-trim
 228              (org-babel-comint-with-output
 229                  (buffer org-babel-ruby-eoe-indicator t body)
 230                (mapc
 231                 (lambda (line)
 232                   (insert (org-babel-chomp line)) (comint-send-input nil t))
 233                 (list "conf.echo=false;_org_prompt_mode=conf.prompt_mode;conf.prompt_mode=:NULL"
 234                       body
 235                       "conf.prompt_mode=_org_prompt_mode;conf.echo=true"
 236                       eoe-string)))
 237              "\n") "[\r\n]") 4) "\n")))
 238       (`value
 239        (let* ((tmp-file (org-babel-temp-file "ruby-"))
 240               (ppp (or (member "code" result-params)
 241                        (member "pp" result-params))))
 242          (org-babel-comint-with-output
 243              (buffer org-babel-ruby-eoe-indicator t body)
 244            (when ppp (insert "require 'pp';") (comint-send-input nil t))
 245            (mapc
 246             (lambda (line)
 247               (insert (org-babel-chomp line)) (comint-send-input nil t))
 248             (append
 249              (list body)
 250              (if (not ppp)
 251                  (list (format org-babel-ruby-f-write
 252                                (org-babel-process-file-name tmp-file 'noquote)))
 253                (list
 254                 "results=_" "require 'pp'" "orig_out = $stdout"
 255                 (format org-babel-ruby-pp-f-write
 256                         (org-babel-process-file-name tmp-file 'noquote))))
 257              (list org-babel-ruby-eoe-indicator)))
 258            (comint-send-input nil t))
 259          (org-babel-eval-read-file tmp-file))))))
 260
 261 (provide 'ob-ruby)
 262
 263
 264
 265 ;;; ob-ruby.el ends here