lisp/org-archive.el

   1 ;;; org-archive.el --- Archiving for Org             -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2004-2016 Free Software Foundation, Inc.
   4
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: http://orgmode.org
   8 ;;
   9 ;; This file is part of GNU Emacs.
  10 ;;
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  24 ;;
  25 ;;; Commentary:
  26
  27 ;; This file contains the face definitions for Org.
  28
  29 ;;; Code:
  30
  31 (require 'org)
  32
  33 (declare-function org-element-type "org-element" (element))
  34 (declare-function org-datetree-find-date-create "org-datetree" (date &optional keep-restriction))
  35 (declare-function org-inlinetask-remove-END-maybe "org-inlinetask" ())
  36
  37 (defcustom org-archive-default-command 'org-archive-subtree
  38   "The default archiving command."
  39   :group 'org-archive
  40   :type '(choice
  41           (const org-archive-subtree)
  42           (const org-archive-to-archive-sibling)
  43           (const org-archive-set-tag)))
  44
  45 (defcustom org-archive-reversed-order nil
  46   "Non-nil means make the tree first child under the archive heading, not last."
  47   :group 'org-archive
  48   :version "24.1"
  49   :type 'boolean)
  50
  51 (defcustom org-archive-sibling-heading "Archive"
  52   "Name of the local archive sibling that is used to archive entries locally.
  53 Locally means: in the tree, under a sibling.
  54 See `org-archive-to-archive-sibling' for more information."
  55   :group 'org-archive
  56   :type 'string)
  57
  58 (defcustom org-archive-mark-done nil
  59   "Non-nil means mark entries as DONE when they are moved to the archive file.
  60 This can be a string to set the keyword to use.  When non-nil, Org will
  61 use the first keyword in its list that means done."
  62   :group 'org-archive
  63   :type '(choice
  64           (const :tag "No" nil)
  65           (const :tag "Yes" t)
  66           (string :tag "Use this keyword")))
  67
  68 (defcustom org-archive-stamp-time t
  69   "Non-nil means add a time stamp to entries moved to an archive file.
  70 This variable is obsolete and has no effect anymore, instead add or remove
  71 `time' from the variable `org-archive-save-context-info'."
  72   :group 'org-archive
  73   :type 'boolean)
  74
  75 (defcustom org-archive-file-header-format "\nArchived entries from file %s\n\n"
  76   "The header format string for newly created archive files.
  77 When nil, no header will be inserted.
  78 When a string, a %s formatter will be replaced by the file name."
  79   :group 'org-archive
  80   :version "24.4"
  81   :package-version '(Org . "8.0")
  82   :type 'string)
  83
  84 (defcustom org-archive-subtree-add-inherited-tags 'infile
  85   "Non-nil means append inherited tags when archiving a subtree."
  86   :group 'org-archive
  87   :version "24.1"
  88   :type '(choice
  89           (const :tag "Never" nil)
  90           (const :tag "When archiving a subtree to the same file" infile)
  91           (const :tag "Always" t)))
  92
  93 (defcustom org-archive-save-context-info '(time file olpath category todo itags)
  94   "Parts of context info that should be stored as properties when archiving.
  95 When a subtree is moved to an archive file, it loses information given by
  96 context, like inherited tags, the category, and possibly also the TODO
  97 state (depending on the variable `org-archive-mark-done').
  98 This variable can be a list of any of the following symbols:
  99
 100 time       The time of archiving.
 101 file       The file where the entry originates.
 102 ltags      The local tags, in the headline of the subtree.
 103 itags      The tags the subtree inherits from further up the hierarchy.
 104 todo       The pre-archive TODO state.
 105 category   The category, taken from file name or #+CATEGORY lines.
 106 olpath     The outline path to the item.  These are all headlines above
 107            the current item, separated by /, like a file path.
 108
 109 For each symbol present in the list, a property will be created in
 110 the archived entry, with a prefix \"ARCHIVE_\", to remember this
 111 information."
 112   :group 'org-archive
 113   :type '(set :greedy t
 114               (const :tag "Time" time)
 115               (const :tag "File" file)
 116               (const :tag "Category" category)
 117               (const :tag "TODO state" todo)
 118               (const :tag "Priority" priority)
 119               (const :tag "Inherited tags" itags)
 120               (const :tag "Outline path" olpath)
 121               (const :tag "Local tags" ltags)))
 122
 123 (defvar org-archive-hook nil
 124   "Hook run after successfully archiving a subtree.
 125 Hook functions are called with point on the subtree in the
 126 original file.  At this stage, the subtree has been added to the
 127 archive location, but not yet deleted from the original file.")
 128
 129 (defun org-get-local-archive-location ()
 130   "Get the archive location applicable at point."
 131   (let ((re "^[ \t]*#\\+ARCHIVE:[ \t]+\\(\\S-.*\\S-\\)[ \t]*$")
 132         prop)
 133     (save-excursion
 134       (save-restriction
 135         (widen)
 136         (setq prop (org-entry-get nil "ARCHIVE" 'inherit))
 137         (cond
 138          ((and prop (string-match "\\S-" prop))
 139           prop)
 140          ((or (re-search-backward re nil t)
 141               (re-search-forward re nil t))
 142           (match-string 1))
 143          (t org-archive-location))))))
 144
 145 ;;;###autoload
 146 (defun org-add-archive-files (files)
 147   "Splice the archive files into the list of files.
 148 This implies visiting all these files and finding out what the
 149 archive file is."
 150   (org-uniquify
 151    (apply
 152     'append
 153     (mapcar
 154      (lambda (f)
 155        (if (not (file-exists-p f))
 156            nil
 157          (with-current-buffer (org-get-agenda-file-buffer f)
 158            (cons f (org-all-archive-files)))))
 159      files))))
 160
 161 (defun org-all-archive-files ()
 162   "Get a list of all archive files used in the current buffer."
 163   (let ((case-fold-search t)
 164         files)
 165     (org-with-wide-buffer
 166      (goto-char (point-min))
 167      (while (re-search-forward
 168              "^[ \t]*\\(#\\+\\|:\\)ARCHIVE:[ \t]+\\(.*\\)"
 169              nil t)
 170        (when (save-match-data
 171                (if (eq (match-string 1) ":") (org-at-property-p)
 172                  (eq (org-element-type (org-element-at-point)) 'keyword)))
 173          (let ((file (org-extract-archive-file
 174                       (match-string-no-properties 2))))
 175            (when (and (org-string-nw-p file) (file-exists-p file))
 176              (push file files))))))
 177     (setq files (nreverse files))
 178     (let ((file (org-extract-archive-file)))
 179       (when (and (org-string-nw-p file) (file-exists-p file))
 180         (push file files)))
 181     files))
 182
 183 (defun org-extract-archive-file (&optional location)
 184   "Extract and expand the file name from archive LOCATION.
 185 if LOCATION is not given, the value of `org-archive-location' is used."
 186   (setq location (or location org-archive-location))
 187   (if (string-match "\\(.*\\)::\\(.*\\)" location)
 188       (if (= (match-beginning 1) (match-end 1))
 189           (buffer-file-name (buffer-base-buffer))
 190         (expand-file-name
 191          (format (match-string 1 location)
 192                  (file-name-nondirectory
 193                   (buffer-file-name (buffer-base-buffer))))))))
 194
 195 (defun org-extract-archive-heading (&optional location)
 196   "Extract the heading from archive LOCATION.
 197 if LOCATION is not given, the value of `org-archive-location' is used."
 198   (setq location (or location org-archive-location))
 199   (if (string-match "\\(.*\\)::\\(.*\\)" location)
 200       (format (match-string 2 location)
 201               (file-name-nondirectory
 202                (buffer-file-name (buffer-base-buffer))))))
 203
 204 ;;;###autoload
 205 (defun org-archive-subtree (&optional find-done)
 206   "Move the current subtree to the archive.
 207 The archive can be a certain top-level heading in the current file, or in
 208 a different file.  The tree will be moved to that location, the subtree
 209 heading be marked DONE, and the current time will be added.
 210
 211 When called with a single prefix argument FIND-DONE, find whole trees without any
 212 open TODO items and archive them (after getting confirmation from the user).
 213 When called with a double prefix argument, find whole trees with timestamps before
 214 today and archive them (after getting confirmation from the user).
 215 If the cursor is not at a headline when these commands are called, try all level
 216 1 trees.  If the cursor is on a headline, only try the direct children of
 217 this heading."
 218   (interactive "P")
 219   (if (and (org-region-active-p) org-loop-over-headlines-in-active-region)
 220       (let ((cl (if (eq org-loop-over-headlines-in-active-region 'start-level)
 221                     'region-start-level 'region))
 222             org-loop-over-headlines-in-active-region)
 223         (org-map-entries
 224          `(progn (setq org-map-continue-from (progn (org-back-to-heading) (point)))
 225                  (org-archive-subtree ,find-done))
 226          org-loop-over-headlines-in-active-region
 227          cl (if (outline-invisible-p) (org-end-of-subtree nil t))))
 228     (cond
 229      ((equal find-done '(4))  (org-archive-all-done))
 230      ((equal find-done '(16)) (org-archive-all-old))
 231      (t
 232       ;; Save all relevant TODO keyword-relatex variables
 233       (let* ((tr-org-todo-keywords-1 org-todo-keywords-1)
 234              (tr-org-todo-kwd-alist org-todo-kwd-alist)
 235              (tr-org-done-keywords org-done-keywords)
 236              (tr-org-todo-regexp org-todo-regexp)
 237              (tr-org-todo-line-regexp org-todo-line-regexp)
 238              (tr-org-odd-levels-only org-odd-levels-only)
 239              (this-buffer (current-buffer))
 240              (time (format-time-string
 241                     (substring (cdr org-time-stamp-formats) 1 -1)))
 242              (file (abbreviate-file-name
 243                     (or (buffer-file-name (buffer-base-buffer))
 244                         (error "No file associated to buffer"))))
 245              (location (org-get-local-archive-location))
 246              (afile (or (org-extract-archive-file location)
 247                         (error "Invalid `org-archive-location'")))
 248              (heading (org-extract-archive-heading location))
 249              (infile-p (equal file (abbreviate-file-name (or afile ""))))
 250              (newfile-p (and (org-string-nw-p afile)
 251                              (not (file-exists-p afile))))
 252              (buffer (cond ((not (org-string-nw-p afile)) this-buffer)
 253                            ((find-buffer-visiting afile))
 254                            ((find-file-noselect afile))
 255                            (t (error "Cannot access file \"%s\"" afile))))
 256              level datetree-date datetree-subheading-p)
 257         (when (string-match "\\`datetree/" heading)
 258           ;; Replace with ***, to represent the 3 levels of headings the
 259           ;; datetree has.
 260           (setq heading (replace-regexp-in-string "\\`datetree/" "***" heading))
 261           (setq datetree-subheading-p (> (length heading) 3))
 262           (setq datetree-date (org-date-to-gregorian
 263                                (or (org-entry-get nil "CLOSED" t) time))))
 264         (if (and (> (length heading) 0)
 265                  (string-match "^\\*+" heading))
 266             (setq level (match-end 0))
 267           (setq heading nil level 0))
 268         (save-excursion
 269           (org-back-to-heading t)
 270           ;; Get context information that will be lost by moving the
 271           ;; tree.  See `org-archive-save-context-info'.
 272           (let* ((all-tags (org-get-tags-at))
 273                  (local-tags (org-get-tags))
 274                  (inherited-tags (org-delete-all local-tags all-tags))
 275                  (context
 276                   `((category . ,(org-get-category nil 'force-refresh))
 277                     (file . ,file)
 278                     (itags . ,(mapconcat #'identity inherited-tags " "))
 279                     (ltags . ,(mapconcat #'identity local-tags " "))
 280                     (olpath . ,(mapconcat #'identity
 281                                           (org-get-outline-path)
 282                                           "/"))
 283                     (time . ,time)
 284                     (todo . ,(org-entry-get (point) "TODO")))))
 285             ;; We first only copy, in case something goes wrong
 286             ;; we need to protect `this-command', to avoid kill-region sets it,
 287             ;; which would lead to duplication of subtrees
 288             (let (this-command) (org-copy-subtree 1 nil t))
 289             (set-buffer buffer)
 290             ;; Enforce Org mode for the archive buffer
 291             (if (not (derived-mode-p 'org-mode))
 292                 ;; Force the mode for future visits.
 293                 (let ((org-insert-mode-line-in-empty-file t)
 294                       (org-inhibit-startup t))
 295                   (call-interactively 'org-mode)))
 296             (when (and newfile-p org-archive-file-header-format)
 297               (goto-char (point-max))
 298               (insert (format org-archive-file-header-format
 299                               (buffer-file-name this-buffer))))
 300             (when datetree-date
 301               (require 'org-datetree)
 302               (org-datetree-find-date-create datetree-date)
 303               (org-narrow-to-subtree))
 304             ;; Force the TODO keywords of the original buffer
 305             (let ((org-todo-line-regexp tr-org-todo-line-regexp)
 306                   (org-todo-keywords-1 tr-org-todo-keywords-1)
 307                   (org-todo-kwd-alist tr-org-todo-kwd-alist)
 308                   (org-done-keywords tr-org-done-keywords)
 309                   (org-todo-regexp tr-org-todo-regexp)
 310                   (org-todo-line-regexp tr-org-todo-line-regexp)
 311                   (org-odd-levels-only
 312                    (if (local-variable-p 'org-odd-levels-only (current-buffer))
 313                        org-odd-levels-only
 314                      tr-org-odd-levels-only)))
 315               (goto-char (point-min))
 316               (outline-show-all)
 317               (if (and heading (not (and datetree-date (not datetree-subheading-p))))
 318                   (progn
 319                     (if (re-search-forward
 320                          (concat "^" (regexp-quote heading)
 321                                  "[ \t]*\\(:[[:alnum:]_@#%:]+:\\)?[ \t]*\\($\\|\r\\)")
 322                          nil t)
 323                         (goto-char (match-end 0))
 324                       ;; Heading not found, just insert it at the end
 325                       (goto-char (point-max))
 326                       (or (bolp) (insert "\n"))
 327                       ;; datetrees don't need too much spacing
 328                       (insert (if datetree-date "" "\n") heading "\n")
 329                       (end-of-line 0))
 330                     ;; Make the subtree visible
 331                     (outline-show-subtree)
 332                     (if org-archive-reversed-order
 333                         (progn
 334                           (org-back-to-heading t)
 335                           (outline-next-heading))
 336                       (org-end-of-subtree t))
 337                     (skip-chars-backward " \t\r\n")
 338                     (and (looking-at "[ \t\r\n]*")
 339                          ;; datetree archives don't need so much spacing.
 340                          (replace-match (if datetree-date "\n" "\n\n"))))
 341                 ;; No specific heading, just go to end of file.
 342                 (goto-char (point-max)) (unless datetree-date (insert "\n")))
 343               ;; Paste
 344               (org-paste-subtree (org-get-valid-level level (and heading 1)))
 345               ;; Shall we append inherited tags?
 346               (and inherited-tags
 347                    (or (and (eq org-archive-subtree-add-inherited-tags 'infile)
 348                             infile-p)
 349                        (eq org-archive-subtree-add-inherited-tags t))
 350                    (org-set-tags-to all-tags))
 351               ;; Mark the entry as done
 352               (when (and org-archive-mark-done
 353                          (looking-at org-todo-line-regexp)
 354                          (or (not (match-end 2))
 355                              (not (member (match-string 2) org-done-keywords))))
 356                 (let (org-log-done org-todo-log-states)
 357                   (org-todo
 358                    (car (or (member org-archive-mark-done org-done-keywords)
 359                             org-done-keywords)))))
 360
 361               ;; Add the context info.
 362               (dolist (item org-archive-save-context-info)
 363                 (let ((value (cdr (assq item context))))
 364                   (when (org-string-nw-p value)
 365                     (org-entry-put
 366                      (point)
 367                      (concat "ARCHIVE_" (upcase (symbol-name item)))
 368                      value))))
 369               (widen)
 370               ;; Save and kill the buffer, if it is not the same
 371               ;; buffer.
 372               (unless (eq this-buffer buffer) (save-buffer)))))
 373         ;; Here we are back in the original buffer.  Everything seems
 374         ;; to have worked.  So now run hooks, cut the tree and finish
 375         ;; up.
 376         (run-hooks 'org-archive-hook)
 377         (let (this-command) (org-cut-subtree))
 378         (when (featurep 'org-inlinetask)
 379           (org-inlinetask-remove-END-maybe))
 380         (setq org-markers-to-move nil)
 381         (message "Subtree archived %s"
 382                  (if (eq this-buffer buffer)
 383                      (concat "under heading: " heading)
 384                    (concat "in file: " (abbreviate-file-name afile)))))))
 385     (org-reveal)
 386     (if (looking-at "^[ \t]*$")
 387         (outline-next-visible-heading 1))))
 388
 389 ;;;###autoload
 390 (defun org-archive-to-archive-sibling ()
 391   "Archive the current heading by moving it under the archive sibling.
 392 The archive sibling is a sibling of the heading with the heading name
 393 `org-archive-sibling-heading' and an `org-archive-tag' tag.  If this
 394 sibling does not exist, it will be created at the end of the subtree."
 395   (interactive)
 396   (if (and (org-region-active-p) org-loop-over-headlines-in-active-region)
 397       (let ((cl (when (eq org-loop-over-headlines-in-active-region 'start-level)
 398                   'region-start-level 'region))
 399             org-loop-over-headlines-in-active-region)
 400         (org-map-entries
 401          '(progn (setq org-map-continue-from
 402                        (progn (org-back-to-heading)
 403                               (if (looking-at (concat "^.*:" org-archive-tag ":.*$"))
 404                                   (org-end-of-subtree t)
 405                                 (point))))
 406                  (when (org-at-heading-p)
 407                    (org-archive-to-archive-sibling)))
 408          org-loop-over-headlines-in-active-region
 409          cl (if (outline-invisible-p) (org-end-of-subtree nil t))))
 410     (save-restriction
 411       (widen)
 412       (let (b e pos leader level)
 413         (org-back-to-heading t)
 414         (looking-at org-outline-regexp)
 415         (setq leader (match-string 0)
 416               level (funcall outline-level))
 417         (setq pos (point))
 418         (condition-case nil
 419             (outline-up-heading 1 t)
 420           (error (setq e (point-max)) (goto-char (point-min))))
 421         (setq b (point))
 422         (unless e
 423           (condition-case nil
 424               (org-end-of-subtree t t)
 425             (error (goto-char (point-max))))
 426           (setq e (point)))
 427         (goto-char b)
 428         (unless (re-search-forward
 429                  (concat "^" (regexp-quote leader)
 430                          "[ \t]*"
 431                          org-archive-sibling-heading
 432                          "[ \t]*:"
 433                          org-archive-tag ":") e t)
 434           (goto-char e)
 435           (or (bolp) (newline))
 436           (insert leader org-archive-sibling-heading "\n")
 437           (beginning-of-line 0)
 438           (org-toggle-tag org-archive-tag 'on))
 439         (beginning-of-line 1)
 440         (if org-archive-reversed-order
 441             (outline-next-heading)
 442           (org-end-of-subtree t t))
 443         (save-excursion
 444           (goto-char pos)
 445           (let ((this-command this-command)) (org-cut-subtree)))
 446         (org-paste-subtree (org-get-valid-level level 1))
 447         (org-set-property
 448          "ARCHIVE_TIME"
 449          (format-time-string
 450           (substring (cdr org-time-stamp-formats) 1 -1)))
 451         (outline-up-heading 1 t)
 452         (outline-hide-subtree)
 453         (org-cycle-show-empty-lines 'folded)
 454         (goto-char pos)))
 455     (org-reveal)
 456     (if (looking-at "^[ \t]*$")
 457         (outline-next-visible-heading 1))))
 458
 459 (defun org-archive-all-done (&optional tag)
 460   "Archive sublevels of the current tree without open TODO items.
 461 If the cursor is not on a headline, try all level 1 trees.  If
 462 it is on a headline, try all direct children.
 463 When TAG is non-nil, don't move trees, but mark them with the ARCHIVE tag."
 464   (org-archive-all-matches
 465    (lambda (_beg end)
 466      (unless (re-search-forward org-not-done-heading-regexp end t)
 467        "no open TODO items"))
 468    tag))
 469
 470 (defun org-archive-all-old (&optional tag)
 471   "Archive sublevels of the current tree with timestamps prior to today.
 472 If the cursor is not on a headline, try all level 1 trees.  If
 473 it is on a headline, try all direct children.
 474 When TAG is non-nil, don't move trees, but mark them with the ARCHIVE tag."
 475   (org-archive-all-matches
 476    (lambda (_beg end)
 477      (let (ts)
 478        (and (re-search-forward org-ts-regexp end t)
 479             (setq ts (match-string 0))
 480             (< (org-time-stamp-to-now ts) 0)
 481             (if (not (looking-at
 482                       (concat "--\\(" org-ts-regexp "\\)")))
 483                 (concat "old timestamp " ts)
 484               (setq ts (concat "old timestamp " ts (match-string 0)))
 485               (and (< (org-time-stamp-to-now (match-string 1)) 0)
 486                    ts)))))
 487    tag))
 488
 489 (defun org-archive-all-matches (predicate &optional tag)
 490   "Archive sublevels of the current tree that match PREDICATE.
 491
 492 PREDICATE is a function of two arguments, BEG and END, which
 493 specify the beginning and end of the headline being considered.
 494 It is called with point positioned at BEG.  The headline will be
 495 archived if PREDICATE returns non-nil.  If the return value of
 496 PREDICATE is a string, it should describe the reason for
 497 archiving the heading.
 498
 499 If the cursor is not on a headline, try all level 1 trees.  If it
 500 is on a headline, try all direct children.  When TAG is non-nil,
 501 don't move trees, but mark them with the ARCHIVE tag."
 502   (let ((rea (concat ".*:" org-archive-tag ":")) re1
 503         (begm (make-marker))
 504         (endm (make-marker))
 505         (question (if tag "Set ARCHIVE tag? "
 506                     "Move subtree to archive? "))
 507         reason beg end (cntarch 0))
 508     (if (org-at-heading-p)
 509         (progn
 510           (setq re1 (concat "^" (regexp-quote
 511                                  (make-string
 512                                   (+ (- (match-end 0) (match-beginning 0) 1)
 513                                      (if org-odd-levels-only 2 1))
 514                                   ?*))
 515                             " "))
 516           (move-marker begm (point))
 517           (move-marker endm (org-end-of-subtree t)))
 518       (setq re1 "^* ")
 519       (move-marker begm (point-min))
 520       (move-marker endm (point-max)))
 521     (save-excursion
 522       (goto-char begm)
 523       (while (re-search-forward re1 endm t)
 524         (setq beg (match-beginning 0)
 525               end (save-excursion (org-end-of-subtree t) (point)))
 526         (goto-char beg)
 527         (if (not (setq reason (funcall predicate beg end)))
 528             (goto-char end)
 529           (goto-char beg)
 530           (if (and (or (not tag) (not (looking-at rea)))
 531                    (y-or-n-p
 532                     (if (stringp reason)
 533                         (concat question "(" reason ")")
 534                       question)))
 535               (progn
 536                 (if tag
 537                     (org-toggle-tag org-archive-tag 'on)
 538                   (org-archive-subtree))
 539                 (setq cntarch (1+ cntarch)))
 540             (goto-char end)))))
 541     (message "%d trees archived" cntarch)))
 542
 543 ;;;###autoload
 544 (defun org-toggle-archive-tag (&optional find-done)
 545   "Toggle the archive tag for the current headline.
 546 With prefix ARG, check all children of current headline and offer tagging
 547 the children that do not contain any open TODO items."
 548   (interactive "P")
 549   (if (and (org-region-active-p) org-loop-over-headlines-in-active-region)
 550       (let ((cl (if (eq org-loop-over-headlines-in-active-region 'start-level)
 551                     'region-start-level 'region))
 552             org-loop-over-headlines-in-active-region)
 553         (org-map-entries
 554          `(org-toggle-archive-tag ,find-done)
 555          org-loop-over-headlines-in-active-region
 556          cl (if (outline-invisible-p) (org-end-of-subtree nil t))))
 557     (if find-done
 558         (org-archive-all-done 'tag)
 559       (let (set)
 560         (save-excursion
 561           (org-back-to-heading t)
 562           (setq set (org-toggle-tag org-archive-tag))
 563           (when set (org-flag-subtree t)))
 564         (and set (beginning-of-line 1))
 565         (message "Subtree %s" (if set "archived" "unarchived"))))))
 566
 567 (defun org-archive-set-tag ()
 568   "Set the ARCHIVE tag."
 569   (interactive)
 570   (if (and (org-region-active-p) org-loop-over-headlines-in-active-region)
 571       (let ((cl (if (eq org-loop-over-headlines-in-active-region 'start-level)
 572                     'region-start-level 'region))
 573             org-loop-over-headlines-in-active-region)
 574         (org-map-entries
 575          'org-archive-set-tag
 576          org-loop-over-headlines-in-active-region
 577          cl (if (outline-invisible-p) (org-end-of-subtree nil t))))
 578     (org-toggle-tag org-archive-tag 'on)))
 579
 580 ;;;###autoload
 581 (defun org-archive-subtree-default ()
 582   "Archive the current subtree with the default command.
 583 This command is set with the variable `org-archive-default-command'."
 584   (interactive)
 585   (call-interactively org-archive-default-command))
 586
 587 ;;;###autoload
 588 (defun org-archive-subtree-default-with-confirmation ()
 589   "Archive the current subtree with the default command.
 590 This command is set with the variable `org-archive-default-command'."
 591   (interactive)
 592   (if (y-or-n-p "Archive this subtree or entry? ")
 593       (call-interactively org-archive-default-command)
 594     (error "Abort")))
 595
 596 (provide 'org-archive)
 597
 598 ;; Local variables:
 599 ;; generated-autoload-file: "org-loaddefs.el"
 600 ;; End:
 601
 602 ;;; org-archive.el ends here