testing/lisp/test-org.el

   1 ;;; test-org.el --- tests for org.el
   2
   3 ;; Copyright (c)  David Maus
   4 ;; Authors: David Maus
   5
   6 ;; This file is not part of GNU Emacs.
   7
   8 ;; This program is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation, either version 3 of the License, or
  11 ;; (at your option) any later version.
  12
  13 ;; This program is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 ;;; Comments:
  22
  23 ;; Template test file for Org-mode tests
  24
  25 ;;; Code:
  26
  27 \f
  28 ;;; Comments
  29
  30 (ert-deftest test-org/comment-dwim ()
  31   "Test `comment-dwim' behaviour in an Org buffer."
  32   ;; No region selected, no comment on current line and line not
  33   ;; empty: insert comment on line above.
  34   (should
  35    (equal "# \nComment"
  36           (org-test-with-temp-text "Comment"
  37             (progn (call-interactively 'comment-dwim)
  38                    (buffer-string)))))
  39   ;; No region selected, no comment on current line and line empty:
  40   ;; insert comment on this line.
  41   (should
  42    (equal "# \nParagraph"
  43           (org-test-with-temp-text "\nParagraph"
  44             (progn (call-interactively 'comment-dwim)
  45                    (buffer-string)))))
  46   ;; No region selected, and a comment on this line: indent it.
  47   (should
  48    (equal "* Headline\n  # Comment"
  49           (org-test-with-temp-text "* Headline\n# Comment"
  50             (progn (forward-line)
  51                    (let ((org-adapt-indentation t))
  52                      (call-interactively 'comment-dwim))
  53                    (buffer-string)))))
  54   ;; Also recognize single # at column 0 as comments.
  55   (should
  56    (equal "# Comment"
  57           (org-test-with-temp-text "# Comment"
  58             (progn (forward-line)
  59                    (call-interactively 'comment-dwim)
  60                    (buffer-string)))))
  61   ;; Region selected and only comments and blank lines within it:
  62   ;; un-comment all commented lines.
  63   (should
  64    (equal "Comment 1\n\nComment 2"
  65           (org-test-with-temp-text "# Comment 1\n\n# Comment 2"
  66             (progn
  67               (transient-mark-mode 1)
  68               (push-mark (point) t t)
  69               (goto-char (point-max))
  70               (call-interactively 'comment-dwim)
  71               (buffer-string)))))
  72   ;; Region selected without comments: comment all lines if
  73   ;; `comment-empty-lines' is non-nil, only non-blank lines otherwise.
  74   (should
  75    (equal "# Comment 1\n\n# Comment 2"
  76           (org-test-with-temp-text "Comment 1\n\nComment 2"
  77             (progn
  78               (transient-mark-mode 1)
  79               (push-mark (point) t t)
  80               (goto-char (point-max))
  81               (let ((comment-empty-lines nil))
  82                 (call-interactively 'comment-dwim))
  83               (buffer-string)))))
  84   (should
  85    (equal "# Comment 1\n# \n# Comment 2"
  86           (org-test-with-temp-text "Comment 1\n\nComment 2"
  87             (progn
  88               (transient-mark-mode 1)
  89               (push-mark (point) t t)
  90               (goto-char (point-max))
  91               (let ((comment-empty-lines t))
  92                 (call-interactively 'comment-dwim))
  93               (buffer-string)))))
  94   ;; In front of a keyword without region, insert a new comment.
  95   (should
  96    (equal "# \n#+KEYWORD: value"
  97           (org-test-with-temp-text "#+KEYWORD: value"
  98             (progn (call-interactively 'comment-dwim)
  99                    (buffer-string))))))
 100
 101
 102 \f
 103 ;;; Date and time analysis
 104
 105 (ert-deftest test-org/org-read-date ()
 106   "Test `org-read-date' specifications."
 107   ;; Parse ISO date with abbreviated year and month.
 108   (should (equal "2012-03-29 16:40"
 109                  (let ((org-time-was-given t))
 110                    (org-read-date t nil "12-3-29 16:40"))))
 111   ;; Parse Europeans dates.
 112   (should (equal "2012-03-29 16:40"
 113                  (let ((org-time-was-given t))
 114                    (org-read-date t nil "29.03.2012 16:40"))))
 115   ;; Parse Europeans dates without year.
 116   (should (string-match "2[0-9]\\{3\\}-03-29 16:40"
 117                         (let ((org-time-was-given t))
 118                           (org-read-date t nil "29.03. 16:40")))))
 119
 120 (ert-deftest test-org/org-parse-time-string ()
 121   "Test `org-parse-time-string'."
 122   (should (equal (org-parse-time-string "2012-03-29 16:40")
 123                  '(0 40 16 29 3 2012 nil nil nil)))
 124   (should (equal (org-parse-time-string "[2012-03-29 16:40]")
 125                  '(0 40 16 29 3 2012 nil nil nil)))
 126   (should (equal (org-parse-time-string "<2012-03-29 16:40>")
 127                  '(0 40 16 29 3 2012 nil nil nil)))
 128   (should (equal (org-parse-time-string "<2012-03-29>")
 129                  '(0 0 0 29 3 2012 nil nil nil)))
 130   (should (equal (org-parse-time-string "<2012-03-29>" t)
 131                  '(0 nil nil 29 3 2012 nil nil nil))))
 132
 133 \f
 134 ;;; Filling
 135
 136 (ert-deftest test-org/fill-paragraph ()
 137   "Test `org-fill-paragraph' specifications."
 138   ;; At an Org table, align it.
 139   (should
 140    (equal "| a |\n"
 141           (org-test-with-temp-text "|a|"
 142             (org-fill-paragraph)
 143             (buffer-string))))
 144   (should
 145    (equal "#+name: table\n| a |\n"
 146           (org-test-with-temp-text "#+name: table\n| a |"
 147             (org-fill-paragraph)
 148             (buffer-string))))
 149   ;; At a paragraph, preserve line breaks.
 150   (org-test-with-temp-text "some \\\\\nlong\ntext"
 151     (let ((fill-column 20))
 152       (org-fill-paragraph)
 153       (should (equal (buffer-string) "some \\\\\nlong text"))))
 154   ;; Correctly fill a paragraph when point is at its very end.
 155   (should
 156    (equal "A B"
 157           (org-test-with-temp-text "A\nB"
 158             (let ((fill-column 20))
 159               (goto-char (point-max))
 160               (org-fill-paragraph)
 161               (buffer-string)))))
 162   ;; Correctly fill the last paragraph of a greater element.
 163   (should
 164    (equal "#+BEGIN_CENTER\n- 012345\n  789\n#+END_CENTER"
 165           (org-test-with-temp-text "#+BEGIN_CENTER\n- 012345 789\n#+END_CENTER"
 166             (let ((fill-column 8))
 167               (forward-line)
 168               (end-of-line)
 169               (org-fill-paragraph)
 170               (buffer-string)))))
 171   ;; Correctly fill an element in a narrowed buffer.
 172   (should
 173    (equal "01234\n6"
 174           (org-test-with-temp-text "01234 6789"
 175             (let ((fill-column 5))
 176               (narrow-to-region 1 8)
 177               (org-fill-paragraph)
 178               (buffer-string)))))
 179   ;; Special case: Fill first paragraph when point is at an item or
 180   ;; a plain-list or a footnote reference.
 181   (should
 182    (equal "- A B"
 183           (org-test-with-temp-text "- A\n  B"
 184             (let ((fill-column 20))
 185               (org-fill-paragraph)
 186               (buffer-string)))))
 187   (should
 188    (equal "[fn:1] A B"
 189           (org-test-with-temp-text "[fn:1] A\nB"
 190             (let ((fill-column 20))
 191               (org-fill-paragraph)
 192               (buffer-string)))))
 193   (org-test-with-temp-text "#+BEGIN_VERSE\nSome \\\\\nlong\ntext\n#+END_VERSE"
 194     (let ((fill-column 20))
 195       (org-fill-paragraph)
 196       (should (equal (buffer-string)
 197                      "#+BEGIN_VERSE\nSome \\\\\nlong\ntext\n#+END_VERSE"))))
 198   ;; Fill contents of `comment-block' elements.
 199   (should
 200    (equal
 201     (org-test-with-temp-text "#+BEGIN_COMMENT\nSome\ntext\n#+END_COMMENT"
 202       (let ((fill-column 20))
 203         (forward-line)
 204         (org-fill-paragraph)
 205         (buffer-string)))
 206     "#+BEGIN_COMMENT\nSome text\n#+END_COMMENT"))
 207   ;; Fill `comment' elements.
 208   (should
 209    (equal "  # A B"
 210           (org-test-with-temp-text "  # A\n  # B"
 211             (let ((fill-column 20))
 212               (org-fill-paragraph)
 213               (buffer-string)))))
 214   ;; Do not mix consecutive comments when filling one of them.
 215   (should
 216    (equal "# A B\n\n# C"
 217           (org-test-with-temp-text "# A\n# B\n\n# C"
 218             (let ((fill-column 20))
 219               (org-fill-paragraph)
 220               (buffer-string)))))
 221   ;; Use commented empty lines as separators when filling comments.
 222   (should
 223    (equal "# A B\n#\n# C"
 224           (org-test-with-temp-text "# A\n# B\n#\n# C"
 225             (let ((fill-column 20))
 226               (org-fill-paragraph)
 227               (buffer-string)))))
 228   ;; Do nothing at affiliated keywords.
 229   (org-test-with-temp-text "#+NAME: para\nSome\ntext."
 230     (let ((fill-column 20))
 231       (org-fill-paragraph)
 232       (should (equal (buffer-string) "#+NAME: para\nSome\ntext."))))
 233   ;; Do not move point after table when filling a table.
 234   (should-not
 235    (org-test-with-temp-text "| a | b |\n| c | d |\n"
 236      (forward-char)
 237      (org-fill-paragraph)
 238      (eobp))))
 239
 240 (ert-deftest test-org/auto-fill-function ()
 241   "Test auto-filling features."
 242   ;; Auto fill paragraph.
 243   (should
 244    (equal "12345\n7890"
 245           (org-test-with-temp-text "12345 7890"
 246             (let ((fill-column 5))
 247               (end-of-line)
 248               (org-auto-fill-function)
 249               (buffer-string)))))
 250   ;; Auto fill first paragraph in an item.
 251   (should
 252    (equal "- 12345\n  7890"
 253           (org-test-with-temp-text "- 12345 7890"
 254             (let ((fill-column 7))
 255               (end-of-line)
 256               (org-auto-fill-function)
 257               (buffer-string)))))
 258   ;; Auto fill comments.
 259   (should
 260    (equal "  # 12345\n  # 7890"
 261           (org-test-with-temp-text "  # 12345 7890"
 262             (let ((fill-column 10))
 263               (end-of-line)
 264               (org-auto-fill-function)
 265               (buffer-string)))))
 266   ;; A hash within a line isn't a comment.
 267   (should-not
 268    (equal "12345 # 7890\n# 1"
 269           (org-test-with-temp-text "12345 # 7890 1"
 270             (let ((fill-column 12))
 271               (end-of-line)
 272               (org-auto-fill-function)
 273               (buffer-string)))))
 274   ;; Correctly interpret empty prefix.
 275   (should-not
 276    (equal "# a\n# b\nRegular\n# paragraph"
 277           (org-test-with-temp-text "# a\n# b\nRegular paragraph"
 278             (let ((fill-column 12))
 279               (end-of-line 3)
 280               (org-auto-fill-function)
 281               (buffer-string)))))
 282   ;; Comment block: auto fill contents.
 283   (should
 284    (equal "#+BEGIN_COMMENT\n12345\n7890\n#+END_COMMENT"
 285           (org-test-with-temp-text "#+BEGIN_COMMENT\n12345 7890\n#+END_COMMENT"
 286             (let ((fill-column 5))
 287               (forward-line)
 288               (end-of-line)
 289               (org-auto-fill-function)
 290               (buffer-string)))))
 291   (should
 292    (equal "#+BEGIN_COMMENT\n12345\n7890\n#+END_COMMENT"
 293           (org-test-with-temp-text "#+BEGIN_COMMENT\n12345 7890\n#+END_COMMENT"
 294             (let ((fill-column 5))
 295               (forward-line)
 296               (end-of-line)
 297               (org-auto-fill-function)
 298               (buffer-string)))))
 299   ;; Do not fill if a new item could be created.
 300   (should-not
 301    (equal "12345\n- 90"
 302           (org-test-with-temp-text "12345 - 90"
 303             (let ((fill-column 5))
 304               (end-of-line)
 305               (org-auto-fill-function)
 306               (buffer-string)))))
 307   ;; Do not fill if a line break could be introduced.
 308   (should-not
 309    (equal "123\\\\\n7890"
 310           (org-test-with-temp-text "123\\\\ 7890"
 311             (let ((fill-column 6))
 312               (end-of-line)
 313               (org-auto-fill-function)
 314               (buffer-string)))))
 315   ;; Do not fill affiliated keywords.
 316   (should-not
 317    (equal "#+ATTR_LATEX: ABC\nDEFGHIJKL"
 318           (org-test-with-temp-text "#+ATTR_LATEX: ABC DEFGHIJKL"
 319             (let ((fill-column 20))
 320               (end-of-line)
 321               (org-auto-fill-function)
 322               (buffer-string))))))
 323
 324
 325 \f
 326 ;;; Links
 327
 328 ;;;; Fuzzy Links
 329
 330 ;; Fuzzy links [[text]] encompass links to a target (<<text>>), to
 331 ;; a named element (#+name: text) and to headlines (* Text).
 332
 333 (ert-deftest test-org/fuzzy-links ()
 334   "Test fuzzy links specifications."
 335   ;; 1. Fuzzy link goes in priority to a matching target.
 336   (should
 337    (org-test-with-temp-text "#+NAME: Test\n|a|b|\n<<Test>>\n* Test\n[[Test]]"
 338      (goto-line 5)
 339      (org-open-at-point)
 340      (looking-at "<<Test>>")))
 341   ;; 2. Then fuzzy link points to an element with a given name.
 342   (should
 343    (org-test-with-temp-text "Test\n#+NAME: Test\n|a|b|\n* Test\n[[Test]]"
 344      (goto-line 5)
 345      (org-open-at-point)
 346      (looking-at "#\\+NAME: Test")))
 347   ;; 3. A target still lead to a matching headline otherwise.
 348   (should
 349    (org-test-with-temp-text "* Head1\n* Head2\n*Head3\n[[Head2]]"
 350      (goto-line 4)
 351      (org-open-at-point)
 352      (looking-at "\\* Head2")))
 353   ;; 4. With a leading star in link, enforce heading match.
 354   (should
 355    (org-test-with-temp-text "* Test\n<<Test>>\n[[*Test]]"
 356      (goto-line 3)
 357      (org-open-at-point)
 358      (looking-at "\\* Test"))))
 359
 360
 361 ;;;; Link Escaping
 362
 363 (ert-deftest test-org/org-link-escape-ascii-character ()
 364   "Escape an ascii character."
 365   (should
 366    (string=
 367     "%5B"
 368     (org-link-escape "["))))
 369
 370 (ert-deftest test-org/org-link-escape-ascii-ctrl-character ()
 371   "Escape an ascii control character."
 372   (should
 373    (string=
 374     "%09"
 375     (org-link-escape "\t"))))
 376
 377 (ert-deftest test-org/org-link-escape-multibyte-character ()
 378   "Escape an unicode multibyte character."
 379   (should
 380    (string=
 381     "%E2%82%AC"
 382     (org-link-escape "€"))))
 383
 384 (ert-deftest test-org/org-link-escape-custom-table ()
 385   "Escape string with custom character table."
 386   (should
 387    (string=
 388     "Foo%3A%42ar%0A"
 389     (org-link-escape "Foo:Bar\n" '(?\: ?\B)))))
 390
 391 (ert-deftest test-org/org-link-escape-custom-table-merge ()
 392   "Escape string with custom table merged with default table."
 393   (should
 394    (string=
 395     "%5BF%6F%6F%3A%42ar%0A%5D"
 396     (org-link-escape "[Foo:Bar\n]" '(?\: ?\B ?\o) t))))
 397
 398 (ert-deftest test-org/org-link-unescape-ascii-character ()
 399   "Unescape an ascii character."
 400   (should
 401    (string=
 402     "["
 403     (org-link-unescape "%5B"))))
 404
 405 (ert-deftest test-org/org-link-unescape-ascii-ctrl-character ()
 406   "Unescpae an ascii control character."
 407   (should
 408    (string=
 409     "\n"
 410     (org-link-unescape "%0A"))))
 411
 412 (ert-deftest test-org/org-link-unescape-multibyte-character ()
 413   "Unescape unicode multibyte character."
 414   (should
 415    (string=
 416     "€"
 417     (org-link-unescape "%E2%82%AC"))))
 418
 419 (ert-deftest test-org/org-link-unescape-ascii-extended-char ()
 420   "Unescape old style percent escaped character."
 421   (should
 422    (string=
 423     "àâçèéêîôùû"
 424         (decode-coding-string (org-link-unescape "%E0%E2%E7%E8%E9%EA%EE%F4%F9%FB") 'latin-1))))
 425
 426 (ert-deftest test-org/org-link-escape-url-with-escaped-char ()
 427   "Escape and unscape a URL that includes an escaped char.
 428 http://article.gmane.org/gmane.emacs.orgmode/21459/"
 429   (should
 430    (string=
 431     "http://some.host.com/form?&id=blah%2Bblah25"
 432     (org-link-unescape (org-link-escape "http://some.host.com/form?&id=blah%2Bblah25")))))
 433
 434
 435 \f
 436 ;;; Node Properties
 437
 438 (ert-deftest test-org/accumulated-properties-in-drawers ()
 439   "Ensure properties accumulate in subtree drawers."
 440   (org-test-at-id "75282ba2-f77a-4309-a970-e87c149fe125"
 441     (org-babel-next-src-block)
 442     (should (equal '(2 1) (org-babel-execute-src-block)))))
 443
 444
 445 \f
 446 ;;; Mark Region
 447
 448 (ert-deftest test-org/mark-subtree ()
 449   "Test `org-mark-subtree' specifications."
 450   ;; Error when point is before first headline.
 451   (should-error
 452    (org-test-with-temp-text "Paragraph\n* Headline\nBody"
 453      (progn (transient-mark-mode 1)
 454             (org-mark-subtree))))
 455   ;; Without argument, mark current subtree.
 456   (should
 457    (equal
 458     '(12 32)
 459     (org-test-with-temp-text "* Headline\n** Sub-headline\nBody"
 460       (progn (transient-mark-mode 1)
 461              (forward-line 2)
 462              (org-mark-subtree)
 463              (list (region-beginning) (region-end))))))
 464   ;; With an argument, move ARG up.
 465   (should
 466    (equal
 467     '(1 32)
 468     (org-test-with-temp-text "* Headline\n** Sub-headline\nBody"
 469       (progn (transient-mark-mode 1)
 470              (forward-line 2)
 471              (org-mark-subtree 1)
 472              (list (region-beginning) (region-end))))))
 473   ;; Do not get fooled by inlinetasks.
 474   (when (featurep 'org-inlinetask)
 475     (should
 476      (= 1
 477         (org-test-with-temp-text "* Headline\n*************** Task\nContents"
 478           (progn (transient-mark-mode 1)
 479                  (forward-line 1)
 480                  (let ((org-inlinetask-min-level 15)) (org-mark-subtree))
 481                  (region-beginning)))))))
 482
 483
 484  \f
 485 ;;; Navigation
 486
 487 (ert-deftest test-org/beginning-of-line ()
 488   "Test `org-beginning-of-line' specifications."
 489   ;; Standard test.
 490   (should
 491    (org-test-with-temp-text "Some text\nSome other text"
 492      (progn (org-beginning-of-line) (bolp))))
 493   ;; Standard test with `visual-line-mode'.
 494   (should-not
 495    (org-test-with-temp-text "A long line of text\nSome other text"
 496      (progn (visual-line-mode)
 497             (forward-char 2)
 498             (dotimes (i 1000) (insert "very "))
 499             (org-beginning-of-line)
 500             (bolp))))
 501   ;; At an headline with special movement.
 502   (should
 503    (org-test-with-temp-text "* TODO Headline"
 504      (let ((org-special-ctrl-a/e t))
 505        (org-end-of-line)
 506        (and (progn (org-beginning-of-line) (looking-at "Headline"))
 507             (progn (org-beginning-of-line) (bolp))
 508             (progn (org-beginning-of-line) (looking-at "Headline")))))))
 509
 510 (ert-deftest test-org/end-of-line ()
 511   "Test `org-end-of-line' specifications."
 512   ;; Standard test.
 513   (should
 514    (org-test-with-temp-text "Some text\nSome other text"
 515      (progn (org-end-of-line) (eolp))))
 516   ;; Standard test with `visual-line-mode'.
 517   (should-not
 518    (org-test-with-temp-text "A long line of text\nSome other text"
 519      (progn (visual-line-mode)
 520             (forward-char 2)
 521             (dotimes (i 1000) (insert "very "))
 522             (goto-char (point-min))
 523             (org-end-of-line)
 524             (eolp))))
 525   ;; At an headline with special movement.
 526   (should
 527    (org-test-with-temp-text "* Headline1 :tag:\n"
 528      (let ((org-special-ctrl-a/e t))
 529        (and (progn (org-end-of-line) (looking-at " :tag:"))
 530             (progn (org-end-of-line) (eolp))
 531             (progn (org-end-of-line) (looking-at " :tag:"))))))
 532   ;; At an headline without special movement.
 533   (should
 534    (org-test-with-temp-text "* Headline2 :tag:\n"
 535      (let ((org-special-ctrl-a/e nil))
 536        (and (progn (org-end-of-line) (eolp))
 537             (progn (org-end-of-line) (eolp))))))
 538   ;; At an headline, with reversed movement.
 539   (should
 540    (org-test-with-temp-text "* Headline3 :tag:\n"
 541      (let ((org-special-ctrl-a/e 'reversed)
 542            (this-command last-command))
 543        (and (progn (org-end-of-line) (eolp))
 544             (progn (org-end-of-line) (looking-at " :tag:"))))))
 545   ;; At a block without hidden contents.
 546   (should
 547    (org-test-with-temp-text "#+BEGIN_CENTER\nContents\n#+END_CENTER"
 548      (progn (org-end-of-line) (eolp))))
 549   ;; At a block with hidden contents.
 550   (should-not
 551    (org-test-with-temp-text "#+BEGIN_CENTER\nContents\n#+END_CENTER"
 552      (let ((org-special-ctrl-a/e t))
 553        (org-hide-block-toggle)
 554        (org-end-of-line)
 555        (eobp)))))
 556
 557 (ert-deftest test-org/forward-element ()
 558   "Test `org-forward-element' specifications."
 559   ;; 1. At EOB: should error.
 560   (org-test-with-temp-text "Some text\n"
 561     (goto-char (point-max))
 562     (should-error (org-forward-element)))
 563   ;; 2. Standard move: expected to ignore blank lines.
 564   (org-test-with-temp-text "First paragraph.\n\n\nSecond paragraph."
 565     (org-forward-element)
 566     (should (looking-at (regexp-quote "Second paragraph."))))
 567   ;; 3. Headline tests.
 568   (org-test-with-temp-text "
 569 * Head 1
 570 ** Head 1.1
 571 *** Head 1.1.1
 572 ** Head 1.2"
 573     ;; 3.1. At an headline beginning: move to next headline at the
 574     ;;      same level.
 575     (goto-line 3)
 576     (org-forward-element)
 577     (should (looking-at (regexp-quote "** Head 1.2")))
 578     ;; 3.2. At an headline beginning: move to parent headline if no
 579     ;;      headline at the same level.
 580     (goto-line 3)
 581     (org-forward-element)
 582     (should (looking-at (regexp-quote "** Head 1.2"))))
 583   ;; 4. Greater element tests.
 584   (org-test-with-temp-text
 585       "#+BEGIN_CENTER\nInside.\n#+END_CENTER\n\nOutside."
 586     ;; 4.1. At a greater element: expected to skip contents.
 587     (org-forward-element)
 588     (should (looking-at (regexp-quote "Outside.")))
 589     ;; 4.2. At the end of greater element contents: expected to skip
 590     ;;      to the end of the greater element.
 591     (goto-line 2)
 592     (org-forward-element)
 593     (should (looking-at (regexp-quote "Outside."))))
 594   ;; 5. List tests.
 595   (org-test-with-temp-text "
 596 - item1
 597
 598   - sub1
 599
 600   - sub2
 601
 602   - sub3
 603
 604   Inner paragraph.
 605
 606 - item2
 607
 608 Outside."
 609     ;; 5.1. At list top point: expected to move to the element after
 610     ;;      the list.
 611     (goto-line 2)
 612     (org-forward-element)
 613     (should (looking-at (regexp-quote "Outside.")))
 614     ;; 5.2. Special case: at the first line of a sub-list, but not at
 615     ;;      beginning of line, move to next item.
 616     (goto-line 2)
 617     (forward-char)
 618     (org-forward-element)
 619     (should (looking-at "- item2"))
 620     (goto-line 4)
 621     (forward-char)
 622     (org-forward-element)
 623     (should (looking-at "  - sub2"))
 624     ;; 5.3 At sub-list beginning: expected to move after the sub-list.
 625     (goto-line 4)
 626     (org-forward-element)
 627     (should (looking-at (regexp-quote "  Inner paragraph.")))
 628     ;; 5.4. At sub-list end: expected to move outside the sub-list.
 629     (goto-line 8)
 630     (org-forward-element)
 631     (should (looking-at (regexp-quote "  Inner paragraph.")))
 632     ;; 5.5. At an item: expected to move to next item, if any.
 633     (goto-line 6)
 634     (org-forward-element)
 635     (should (looking-at "  - sub3"))))
 636
 637 (ert-deftest test-org/backward-element ()
 638   "Test `org-backward-element' specifications."
 639   ;; 1. Should error at BOB.
 640   (org-test-with-temp-text "    \nParagraph."
 641     (should-error (org-backward-element)))
 642   ;; 2. Should move at BOB when called on the first element in buffer.
 643   (should
 644    (org-test-with-temp-text "\n#+TITLE: test"
 645      (progn (forward-line)
 646             (org-backward-element)
 647             (bobp))))
 648   ;; 3. Not at the beginning of an element: move at its beginning.
 649   (org-test-with-temp-text "Paragraph1.\n\nParagraph2."
 650     (goto-line 3)
 651     (end-of-line)
 652     (org-backward-element)
 653     (should (looking-at (regexp-quote "Paragraph2."))))
 654   ;; 4. Headline tests.
 655   (org-test-with-temp-text "
 656 * Head 1
 657 ** Head 1.1
 658 *** Head 1.1.1
 659 ** Head 1.2"
 660     ;; 4.1. At an headline beginning: move to previous headline at the
 661     ;;      same level.
 662     (goto-line 5)
 663     (org-backward-element)
 664     (should (looking-at (regexp-quote "** Head 1.1")))
 665     ;; 4.2. At an headline beginning: move to parent headline if no
 666     ;;      headline at the same level.
 667     (goto-line 3)
 668     (org-backward-element)
 669     (should (looking-at (regexp-quote "* Head 1")))
 670     ;; 4.3. At the first top-level headline: should error.
 671     (goto-line 2)
 672     (should-error (org-backward-element)))
 673   ;; 5. At beginning of first element inside a greater element:
 674   ;;    expected to move to greater element's beginning.
 675   (org-test-with-temp-text "Before.\n#+BEGIN_CENTER\nInside.\n#+END_CENTER"
 676     (goto-line 3)
 677     (org-backward-element)
 678     (should (looking-at "#\\+BEGIN_CENTER")))
 679   ;; 6. At the beginning of the first element in a section: should
 680   ;;    move back to headline, if any.
 681   (should
 682    (org-test-with-temp-text "#+TITLE: test\n* Headline\n\nParagraph"
 683      (progn (goto-char (point-max))
 684             (beginning-of-line)
 685             (org-backward-element)
 686             (org-at-heading-p))))
 687   ;; 7. List tests.
 688   (org-test-with-temp-text "
 689 - item1
 690
 691   - sub1
 692
 693   - sub2
 694
 695   - sub3
 696
 697   Inner paragraph.
 698
 699 - item2
 700
 701
 702 Outside."
 703     ;; 7.1. At beginning of sub-list: expected to move to the
 704     ;;      paragraph before it.
 705     (goto-line 4)
 706     (org-backward-element)
 707     (should (looking-at "item1"))
 708     ;; 7.2. At an item in a list: expected to move at previous item.
 709     (goto-line 8)
 710     (org-backward-element)
 711     (should (looking-at "  - sub2"))
 712     (goto-line 12)
 713     (org-backward-element)
 714     (should (looking-at "- item1"))
 715     ;; 7.3. At end of list/sub-list: expected to move to list/sub-list
 716     ;;      beginning.
 717     (goto-line 10)
 718     (org-backward-element)
 719     (should (looking-at "  - sub1"))
 720     (goto-line 15)
 721     (org-backward-element)
 722     (should (looking-at "- item1"))
 723     ;; 7.4. At blank-lines before list end: expected to move to top
 724     ;; item.
 725     (goto-line 14)
 726     (org-backward-element)
 727     (should (looking-at "- item1"))))
 728
 729 (ert-deftest test-org/up-element ()
 730   "Test `org-up-element' specifications."
 731   ;; 1. At BOB or with no surrounding element: should error.
 732   (org-test-with-temp-text "Paragraph."
 733     (should-error (org-up-element)))
 734   (org-test-with-temp-text "* Head1\n* Head2"
 735     (goto-line 2)
 736     (should-error (org-up-element)))
 737   (org-test-with-temp-text "Paragraph1.\n\nParagraph2."
 738     (goto-line 3)
 739     (should-error (org-up-element)))
 740   ;; 2. At an headline: move to parent headline.
 741   (org-test-with-temp-text "* Head1\n** Sub-Head1\n** Sub-Head2"
 742     (goto-line 3)
 743     (org-up-element)
 744     (should (looking-at "\\* Head1")))
 745   ;; 3. Inside a greater element: move to greater element beginning.
 746   (org-test-with-temp-text
 747       "Before.\n#+BEGIN_CENTER\nParagraph1\nParagraph2\n#+END_CENTER\n"
 748     (goto-line 3)
 749     (org-up-element)
 750     (should (looking-at "#\\+BEGIN_CENTER")))
 751   ;; 4. List tests.
 752   (org-test-with-temp-text "* Top
 753 - item1
 754
 755   - sub1
 756
 757   - sub2
 758
 759     Paragraph within sub2.
 760
 761 - item2"
 762     ;; 4.1. Within an item: move to the item beginning.
 763     (goto-line 8)
 764     (org-up-element)
 765     (should (looking-at "  - sub2"))
 766     ;; 4.2. At an item in a sub-list: move to parent item.
 767     (goto-line 4)
 768     (org-up-element)
 769     (should (looking-at "- item1"))
 770     ;; 4.3. At an item in top list: move to beginning of whole list.
 771     (goto-line 10)
 772     (org-up-element)
 773     (should (looking-at "- item1"))
 774     ;; 4.4. Special case.  At very top point: should move to parent of
 775     ;;      list.
 776     (goto-line 2)
 777     (org-up-element)
 778     (should (looking-at "\\* Top"))))
 779
 780 (ert-deftest test-org/down-element ()
 781   "Test `org-down-element' specifications."
 782   ;; Error when the element hasn't got a recursive type.
 783   (org-test-with-temp-text "Paragraph."
 784     (should-error (org-down-element)))
 785   ;; Error when the element has no contents
 786   (org-test-with-temp-text "* Headline"
 787     (should-error (org-down-element)))
 788   ;; When at a plain-list, move to first item.
 789   (org-test-with-temp-text "- Item 1\n  - Item 1.1\n  - Item 2.2"
 790     (goto-line 2)
 791     (org-down-element)
 792     (should (looking-at " - Item 1.1")))
 793   (org-test-with-temp-text "#+NAME: list\n- Item 1"
 794     (org-down-element)
 795     (should (looking-at " Item 1")))
 796   ;; When at a table, move to first row
 797   (org-test-with-temp-text "#+NAME: table\n| a | b |"
 798     (org-down-element)
 799     (should (looking-at " a | b |")))
 800   ;; Otherwise, move inside the greater element.
 801   (org-test-with-temp-text "#+BEGIN_CENTER\nParagraph.\n#+END_CENTER"
 802     (org-down-element)
 803     (should (looking-at "Paragraph"))))
 804
 805 (ert-deftest test-org/drag-element-backward ()
 806   "Test `org-drag-element-backward' specifications."
 807   ;; 1. Error when trying to move first element of buffer.
 808   (org-test-with-temp-text "Paragraph 1.\n\nParagraph 2."
 809     (should-error (org-drag-element-backward)))
 810   ;; 2. Error when trying to swap nested elements.
 811   (org-test-with-temp-text "#+BEGIN_CENTER\nTest.\n#+END_CENTER"
 812     (forward-line)
 813     (should-error (org-drag-element-backward)))
 814   ;; 3. Error when trying to swap an headline element and
 815   ;;    a non-headline element.
 816   (org-test-with-temp-text "Test.\n* Head 1"
 817     (forward-line)
 818     (should-error (org-drag-element-backward)))
 819   ;; 4. Otherwise, swap elements, preserving column and blank lines
 820   ;;    between elements.
 821   (org-test-with-temp-text "Para1\n\n\nParagraph 2\n\nPara3"
 822     (search-forward "graph")
 823     (org-drag-element-backward)
 824     (should (equal (buffer-string) "Paragraph 2\n\n\nPara1\n\nPara3"))
 825     (should (looking-at " 2")))
 826   ;; 5. Preserve visibility of elements and their contents.
 827   (org-test-with-temp-text "
 828 #+BEGIN_CENTER
 829 Text.
 830 #+END_CENTER
 831 - item 1
 832   #+BEGIN_QUOTE
 833   Text.
 834   #+END_QUOTE"
 835     (while (search-forward "BEGIN_" nil t) (org-cycle))
 836     (search-backward "- item 1")
 837     (org-drag-element-backward)
 838     (should
 839      (equal
 840       '((63 . 82) (26 . 48))
 841       (mapcar (lambda (ov) (cons (overlay-start ov) (overlay-end ov)))
 842               (overlays-in (point-min) (point-max)))))))
 843
 844 (ert-deftest test-org/drag-element-forward ()
 845   "Test `org-drag-element-forward' specifications."
 846   ;; 1. Error when trying to move first element of buffer.
 847   (org-test-with-temp-text "Paragraph 1.\n\nParagraph 2."
 848     (goto-line 3)
 849     (should-error (org-drag-element-forward)))
 850   ;; 2. Error when trying to swap nested elements.
 851   (org-test-with-temp-text "#+BEGIN_CENTER\nTest.\n#+END_CENTER"
 852     (forward-line)
 853     (should-error (org-drag-element-forward)))
 854   ;; 3. Error when trying to swap a non-headline element and an
 855   ;;    headline.
 856   (org-test-with-temp-text "Test.\n* Head 1"
 857     (should-error (org-drag-element-forward)))
 858   ;; 4. Otherwise, swap elements, preserving column and blank lines
 859   ;;    between elements.
 860   (org-test-with-temp-text "Paragraph 1\n\n\nPara2\n\nPara3"
 861     (search-forward "graph")
 862     (org-drag-element-forward)
 863     (should (equal (buffer-string) "Para2\n\n\nParagraph 1\n\nPara3"))
 864     (should (looking-at " 1")))
 865   ;; 5. Preserve visibility of elements and their contents.
 866   (org-test-with-temp-text "
 867 #+BEGIN_CENTER
 868 Text.
 869 #+END_CENTER
 870 - item 1
 871   #+BEGIN_QUOTE
 872   Text.
 873   #+END_QUOTE"
 874     (while (search-forward "BEGIN_" nil t) (org-cycle))
 875     (search-backward "#+BEGIN_CENTER")
 876     (org-drag-element-forward)
 877     (should
 878      (equal
 879       '((63 . 82) (26 . 48))
 880       (mapcar (lambda (ov) (cons (overlay-start ov) (overlay-end ov)))
 881               (overlays-in (point-min) (point-max)))))))
 882
 883
 884 \f
 885 ;;; Planning
 886
 887 (ert-deftest test-org/timestamp-has-time-p ()
 888   "Test `org-timestamp-has-time-p' specifications."
 889   ;; With time.
 890   (should
 891    (org-test-with-temp-text "<2012-03-29 Thu 16:40>"
 892      (org-timestamp-has-time-p (org-element-context))))
 893   ;; Without time.
 894   (should-not
 895    (org-test-with-temp-text "<2012-03-29 Thu>"
 896      (org-timestamp-has-time-p (org-element-context)))))
 897
 898 (ert-deftest test-org/timestamp-format ()
 899   "Test `org-timestamp-format' specifications."
 900   ;; Regular test.
 901   (should
 902    (equal
 903     "2012-03-29 16:40"
 904     (org-test-with-temp-text "<2012-03-29 Thu 16:40>"
 905       (org-timestamp-format (org-element-context) "%Y-%m-%d %R"))))
 906   ;; Range end.
 907   (should
 908    (equal
 909     "2012-03-29"
 910     (org-test-with-temp-text "[2011-07-14 Thu]--[2012-03-29 Thu]"
 911       (org-timestamp-format (org-element-context) "%Y-%m-%d" t)))))
 912
 913 (ert-deftest test-org/timestamp-split-range ()
 914   "Test `org-timestamp-split-range' specifications."
 915   ;; Extract range start (active).
 916   (should
 917    (equal '(2012 3 29)
 918           (org-test-with-temp-text "<2012-03-29 Thu>--<2012-03-30 Fri>"
 919             (let ((ts (org-timestamp-split-range (org-element-context))))
 920               (mapcar (lambda (p) (org-element-property p ts))
 921                       '(:year-end :month-end :day-end))))))
 922   ;; Extract range start (inactive)
 923   (should
 924    (equal '(2012 3 29)
 925           (org-test-with-temp-text "[2012-03-29 Thu]--[2012-03-30 Fri]"
 926             (let ((ts (org-timestamp-split-range (org-element-context))))
 927               (mapcar (lambda (p) (org-element-property p ts))
 928                       '(:year-end :month-end :day-end))))))
 929   ;; Extract range end (active).
 930   (should
 931    (equal '(2012 3 30)
 932           (org-test-with-temp-text "<2012-03-29 Thu>--<2012-03-30 Fri>"
 933             (let ((ts (org-timestamp-split-range
 934                        (org-element-context) t)))
 935               (mapcar (lambda (p) (org-element-property p ts))
 936                       '(:year-end :month-end :day-end))))))
 937   ;; Extract range end (inactive)
 938   (should
 939    (equal '(2012 3 30)
 940           (org-test-with-temp-text "[2012-03-29 Thu]--[2012-03-30 Fri]"
 941             (let ((ts (org-timestamp-split-range
 942                        (org-element-context) t)))
 943               (mapcar (lambda (p) (org-element-property p ts))
 944                       '(:year-end :month-end :day-end))))))
 945   ;; Return the timestamp if not a range.
 946   (should
 947    (org-test-with-temp-text "[2012-03-29 Thu]"
 948      (let* ((ts-orig (org-element-context))
 949             (ts-copy (org-timestamp-split-range ts-orig)))
 950        (eq ts-orig ts-copy))))
 951   (should
 952    (org-test-with-temp-text "<%%(org-float t 4 2)>"
 953      (let* ((ts-orig (org-element-context))
 954             (ts-copy (org-timestamp-split-range ts-orig)))
 955        (eq ts-orig ts-copy))))
 956   ;; Check that parent is the same when a range was split.
 957   (should
 958    (org-test-with-temp-text "[2012-03-29 Thu]--[2012-03-30 Fri]"
 959      (let* ((ts-orig (org-element-context))
 960             (ts-copy (org-timestamp-split-range ts-orig)))
 961        (eq (org-element-property :parent ts-orig)
 962            (org-element-property :parent ts-copy))))))
 963
 964 (ert-deftest test-org/timestamp-translate ()
 965   "Test `org-timestamp-translate' specifications."
 966   ;; Translate whole date range.
 967   (should
 968    (equal "<29>--<30>"
 969           (org-test-with-temp-text "<2012-03-29 Thu>--<2012-03-30 Fri>"
 970             (let ((org-display-custom-times t)
 971                   (org-time-stamp-custom-formats '("<%d>" . "<%d>")))
 972               (org-timestamp-translate (org-element-context))))))
 973   ;; Translate date range start.
 974   (should
 975    (equal "<29>"
 976           (org-test-with-temp-text "<2012-03-29 Thu>--<2012-03-30 Fri>"
 977             (let ((org-display-custom-times t)
 978                   (org-time-stamp-custom-formats '("<%d>" . "<%d>")))
 979               (org-timestamp-translate (org-element-context) 'start)))))
 980   ;; Translate date range end.
 981   (should
 982    (equal "<30>"
 983           (org-test-with-temp-text "<2012-03-29 Thu>--<2012-03-30 Fri>"
 984             (let ((org-display-custom-times t)
 985                   (org-time-stamp-custom-formats '("<%d>" . "<%d>")))
 986               (org-timestamp-translate (org-element-context) 'end)))))
 987   ;; Translate time range.
 988   (should
 989    (equal "<08>--<16>"
 990           (org-test-with-temp-text "<2012-03-29 Thu 8:30-16:40>"
 991             (let ((org-display-custom-times t)
 992                   (org-time-stamp-custom-formats '("<%d>" . "<%H>")))
 993               (org-timestamp-translate (org-element-context))))))
 994   ;; Translate non-range timestamp.
 995   (should
 996    (equal "<29>"
 997           (org-test-with-temp-text "<2012-03-29 Thu>"
 998             (let ((org-display-custom-times t)
 999                   (org-time-stamp-custom-formats '("<%d>" . "<%d>")))
1000               (org-timestamp-translate (org-element-context))))))
1001   ;; Do not change `diary' timestamps.
1002   (should
1003    (equal "<%%(org-float t 4 2)>"
1004           (org-test-with-temp-text "<%%(org-float t 4 2)>"
1005             (let ((org-display-custom-times t)
1006                   (org-time-stamp-custom-formats '("<%d>" . "<%d>")))
1007               (org-timestamp-translate (org-element-context)))))))
1008
1009
1010 \f
1011 ;;; Targets and Radio Targets
1012
1013 (ert-deftest test-org/all-targets ()
1014   "Test `org-all-targets' specifications."
1015   ;; Without an argument.
1016   (should
1017    (equal '("radio-target" "target")
1018           (org-test-with-temp-text "<<target>> <<<radio-target>>>\n: <<verb>>"
1019             (org-all-targets))))
1020   (should
1021    (equal '("radio-target")
1022           (org-test-with-temp-text "<<<radio-target>>>!" (org-all-targets))))
1023   ;; With argument.
1024   (should
1025    (equal '("radio-target")
1026           (org-test-with-temp-text "<<target>> <<<radio-target>>>"
1027             (org-all-targets t)))))
1028
1029
1030 (provide 'test-org)
1031
1032 ;;; test-org.el ends here