lisp/ob-tangle.el

   1 ;;; ob-tangle.el --- extract source code from org-mode files
   2
   3 ;; Copyright (C) 2009-2013 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Extract the code from source blocks out into raw source-code files.
  27
  28 ;;; Code:
  29 (require 'org-src)
  30 (eval-when-compile
  31   (require 'cl))
  32
  33 (declare-function org-edit-special "org" (&optional arg))
  34 (declare-function org-link-escape "org" (text &optional table))
  35 (declare-function org-store-link "org" (arg))
  36 (declare-function org-open-link-from-string "org" (s &optional arg reference-buffer))
  37 (declare-function org-heading-components "org" ())
  38 (declare-function org-back-to-heading "org" (invisible-ok))
  39 (declare-function org-fill-template "org" (template alist))
  40 (declare-function org-babel-update-block-body "org" (new-body))
  41 (declare-function make-directory "files" (dir &optional parents))
  42
  43 (defcustom org-babel-tangle-lang-exts
  44   '(("emacs-lisp" . "el"))
  45   "Alist mapping languages to their file extensions.
  46 The key is the language name, the value is the string that should
  47 be inserted as the extension commonly used to identify files
  48 written in this language.  If no entry is found in this list,
  49 then the name of the language is used."
  50   :group 'org-babel-tangle
  51   :version "24.1"
  52   :type '(repeat
  53           (cons
  54            (string "Language name")
  55            (string "File Extension"))))
  56
  57 (defcustom org-babel-post-tangle-hook nil
  58   "Hook run in code files tangled by `org-babel-tangle'."
  59   :group 'org-babel
  60   :version "24.1"
  61   :type 'hook)
  62
  63 (defcustom org-babel-pre-tangle-hook '(save-buffer)
  64   "Hook run at the beginning of `org-babel-tangle'."
  65   :group 'org-babel
  66   :version "24.1"
  67   :type 'hook)
  68
  69 (defcustom org-babel-tangle-body-hook nil
  70   "Hook run over the contents of each code block body."
  71   :group 'org-babel
  72   :version "24.1"
  73   :type 'hook)
  74
  75 (defcustom org-babel-tangle-comment-format-beg "[[%link][%source-name]]"
  76   "Format of inserted comments in tangled code files.
  77 The following format strings can be used to insert special
  78 information into the output using `org-fill-template'.
  79 %start-line --- the line number at the start of the code block
  80 %file --------- the file from which the code block was tangled
  81 %link --------- Org-mode style link to the code block
  82 %source-name -- name of the code block
  83
  84 Whether or not comments are inserted during tangling is
  85 controlled by the :comments header argument."
  86   :group 'org-babel
  87   :version "24.1"
  88   :type 'string)
  89
  90 (defcustom org-babel-tangle-comment-format-end "%source-name ends here"
  91   "Format of inserted comments in tangled code files.
  92 The following format strings can be used to insert special
  93 information into the output using `org-fill-template'.
  94 %start-line --- the line number at the start of the code block
  95 %file --------- the file from which the code block was tangled
  96 %link --------- Org-mode style link to the code block
  97 %source-name -- name of the code block
  98
  99 Whether or not comments are inserted during tangling is
 100 controlled by the :comments header argument."
 101   :group 'org-babel
 102   :version "24.1"
 103   :type 'string)
 104
 105 (defcustom org-babel-process-comment-text #'org-babel-trim
 106   "Function called to process raw Org-mode text collected to be
 107 inserted as comments in tangled source-code files.  The function
 108 should take a single string argument and return a string
 109 result.  The default value is `org-babel-trim'."
 110   :group 'org-babel
 111   :version "24.1"
 112   :type 'function)
 113
 114 (defun org-babel-find-file-noselect-refresh (file)
 115   "Find file ensuring that the latest changes on disk are
 116 represented in the file."
 117   (find-file-noselect file 'nowarn)
 118   (with-current-buffer (get-file-buffer file)
 119     (revert-buffer t t t)))
 120
 121 (defmacro org-babel-with-temp-filebuffer (file &rest body)
 122   "Open FILE into a temporary buffer execute BODY there like
 123 `progn', then kill the FILE buffer returning the result of
 124 evaluating BODY."
 125   (declare (indent 1))
 126   (let ((temp-path (make-symbol "temp-path"))
 127         (temp-result (make-symbol "temp-result"))
 128         (temp-file (make-symbol "temp-file"))
 129         (visited-p (make-symbol "visited-p")))
 130     `(let* ((,temp-path ,file)
 131             (,visited-p (get-file-buffer ,temp-path))
 132             ,temp-result ,temp-file)
 133        (org-babel-find-file-noselect-refresh ,temp-path)
 134        (setf ,temp-file (get-file-buffer ,temp-path))
 135        (with-current-buffer ,temp-file
 136          (setf ,temp-result (progn ,@body)))
 137        (unless ,visited-p (kill-buffer ,temp-file))
 138        ,temp-result)))
 139 (def-edebug-spec org-babel-with-temp-filebuffer (form body))
 140
 141 ;;;###autoload
 142 (defun org-babel-tangle-file (file &optional target-file lang)
 143   "Extract the bodies of source code blocks in FILE.
 144 Source code blocks are extracted with `org-babel-tangle'.
 145 Optional argument TARGET-FILE can be used to specify a default
 146 export file for all source blocks.  Optional argument LANG can be
 147 used to limit the exported source code blocks by language."
 148   (interactive "fFile to tangle: \nP")
 149   (let ((visited-p (get-file-buffer (expand-file-name file)))
 150         to-be-removed)
 151     (save-window-excursion
 152       (find-file file)
 153       (setq to-be-removed (current-buffer))
 154       (org-babel-tangle nil target-file lang))
 155     (unless visited-p
 156       (kill-buffer to-be-removed))))
 157
 158 (defun org-babel-tangle-publish (_ filename pub-dir)
 159   "Tangle FILENAME and place the results in PUB-DIR."
 160   (mapc (lambda (el) (copy-file el pub-dir t)) (org-babel-tangle-file filename)))
 161
 162 ;;;###autoload
 163 (defun org-babel-tangle (&optional arg target-file lang)
 164   "Write code blocks to source-specific files.
 165 Extract the bodies of all source code blocks from the current
 166 file into their own source-specific files.
 167 With one universal prefix argument, only tangle the block at point.
 168 When two universal prefix arguments, only tangle blocks for the
 169 tangle file of the block at point.
 170 Optional argument TARGET-FILE can be used to specify a default
 171 export file for all source blocks.  Optional argument LANG can be
 172 used to limit the exported source code blocks by language."
 173   (interactive "P")
 174   (run-hooks 'org-babel-pre-tangle-hook)
 175   ;; Possibly Restrict the buffer to the current code block
 176   (save-restriction
 177     (when (equal arg '(4))
 178       (let ((head (org-babel-where-is-src-block-head)))
 179           (if head
 180               (goto-char head)
 181             (user-error "Point is not in a source code block"))))
 182     (save-excursion
 183       (let ((block-counter 0)
 184             (org-babel-default-header-args
 185              (if target-file
 186                  (org-babel-merge-params org-babel-default-header-args
 187                                          (list (cons :tangle target-file)))
 188                org-babel-default-header-args))
 189             (tangle-file
 190              (when (equal arg '(16))
 191                (or (cdr (assoc :tangle (nth 2 (org-babel-get-src-block-info 'light))))
 192                    (user-error "Point is not in a source code block"))))
 193             path-collector)
 194         (mapc ;; map over all languages
 195          (lambda (by-lang)
 196            (let* ((lang (car by-lang))
 197                   (specs (cdr by-lang))
 198                   (ext (or (cdr (assoc lang org-babel-tangle-lang-exts)) lang))
 199                   (lang-f (intern
 200                            (concat
 201                             (or (and (cdr (assoc lang org-src-lang-modes))
 202                                      (symbol-name
 203                                       (cdr (assoc lang org-src-lang-modes))))
 204                                 lang)
 205                             "-mode")))
 206                   she-banged)
 207              (mapc
 208               (lambda (spec)
 209                 (let ((get-spec (lambda (name) (cdr (assoc name (nth 4 spec))))))
 210                   (let* ((tangle (funcall get-spec :tangle))
 211                          (she-bang ((lambda (sheb) (when (> (length sheb) 0) sheb))
 212                                     (funcall get-spec :shebang)))
 213                          (tangle-mode (funcall get-spec :tangle-mode))
 214                          (base-name (cond
 215                                      ((string= "yes" tangle)
 216                                       (file-name-sans-extension
 217                                        (buffer-file-name)))
 218                                      ((string= "no" tangle) nil)
 219                                      ((> (length tangle) 0) tangle)))
 220                          (file-name (when base-name
 221                                       ;; decide if we want to add ext to base-name
 222                                       (if (and ext (string= "yes" tangle))
 223                                           (concat base-name "." ext) base-name))))
 224                     (when file-name
 225                       ;; possibly create the parent directories for file
 226                       (when ((lambda (m) (and m (not (string= m "no"))))
 227                              (funcall get-spec :mkdirp))
 228                         (make-directory (file-name-directory file-name) 'parents))
 229                       ;; delete any old versions of file
 230                       (when (and (file-exists-p file-name)
 231                                  (not (member file-name (mapcar #'car path-collector))))
 232                         (delete-file file-name))
 233                       ;; drop source-block to file
 234                       (with-temp-buffer
 235                         (when (fboundp lang-f) (ignore-errors (funcall lang-f)))
 236                         (when (and she-bang (not (member file-name she-banged)))
 237                           (insert (concat she-bang "\n"))
 238                           (setq she-banged (cons file-name she-banged)))
 239                         (org-babel-spec-to-string spec)
 240                         ;; We avoid append-to-file as it does not work with tramp.
 241                         (let ((content (buffer-string)))
 242                           (with-temp-buffer
 243                             (if (file-exists-p file-name)
 244                                 (insert-file-contents file-name))
 245                             (goto-char (point-max))
 246                             (insert content)
 247                             (write-region nil nil file-name))))
 248                       ;; if files contain she-bangs, then make the executable
 249                       (when she-bang
 250                         (unless tangle-mode (setq tangle-mode #o755)))
 251                       ;; update counter
 252                       (setq block-counter (+ 1 block-counter))
 253                       (add-to-list 'path-collector
 254                                    (cons file-name tangle-mode)
 255                                    nil
 256                                    (lambda (a b) (equal (car a) (car b))))))))
 257               specs)))
 258          (if (equal arg '(4))
 259              (org-babel-tangle-single-block 1 t)
 260            (org-babel-tangle-collect-blocks lang tangle-file)))
 261         (message "Tangled %d code block%s from %s" block-counter
 262                  (if (= block-counter 1) "" "s")
 263                  (file-name-nondirectory
 264                   (buffer-file-name
 265                    (or (buffer-base-buffer) (current-buffer)))))
 266         ;; run `org-babel-post-tangle-hook' in all tangled files
 267         (when org-babel-post-tangle-hook
 268           (mapc
 269            (lambda (file)
 270              (org-babel-with-temp-filebuffer file
 271                (run-hooks 'org-babel-post-tangle-hook)))
 272            (mapcar #'car path-collector)))
 273         ;; set permissions on tangled files
 274         (mapc (lambda (pair)
 275                 (when (cdr pair) (set-file-modes (car pair) (cdr pair))))
 276               path-collector)
 277         (mapcar #'car path-collector)))))
 278
 279 (defun org-babel-tangle-clean ()
 280   "Remove comments inserted by `org-babel-tangle'.
 281 Call this function inside of a source-code file generated by
 282 `org-babel-tangle' to remove all comments inserted automatically
 283 by `org-babel-tangle'.  Warning, this comment removes any lines
 284 containing constructs which resemble org-mode file links or noweb
 285 references."
 286   (interactive)
 287   (goto-char (point-min))
 288   (while (or (re-search-forward "\\[\\[file:.*\\]\\[.*\\]\\]" nil t)
 289              (re-search-forward (org-babel-noweb-wrap) nil t))
 290     (delete-region (save-excursion (beginning-of-line 1) (point))
 291                    (save-excursion (end-of-line 1) (forward-char 1) (point)))))
 292
 293 (defvar org-stored-links)
 294 (defvar org-bracket-link-regexp)
 295 (defun org-babel-spec-to-string (spec)
 296   "Insert SPEC into the current file.
 297
 298 Insert the source-code specified by SPEC into the current source
 299 code file.  This function uses `comment-region' which assumes
 300 that the appropriate major-mode is set.  SPEC has the form:
 301
 302   \(start-line file link source-name params body comment)"
 303   (let* ((start-line (nth 0 spec))
 304          (file (nth 1 spec))
 305          (link (nth 2 spec))
 306          (source-name (nth 3 spec))
 307          (body (nth 5 spec))
 308          (comment (nth 6 spec))
 309          (comments (cdr (assoc :comments (nth 4 spec))))
 310          (padline (not (string= "no" (cdr (assoc :padline (nth 4 spec))))))
 311          (link-p (or (string= comments "both") (string= comments "link")
 312                      (string= comments "yes") (string= comments "noweb")))
 313          (link-data (mapcar (lambda (el)
 314                               (cons (symbol-name el)
 315                                     ((lambda (le)
 316                                        (if (stringp le) le (format "%S" le)))
 317                                      (eval el))))
 318                             '(start-line file link source-name)))
 319          (insert-comment (lambda (text)
 320                            (when (and comments (not (string= comments "no"))
 321                                       (> (length text) 0))
 322                              (when padline (insert "\n"))
 323                              (comment-region (point) (progn (insert text) (point)))
 324                              (end-of-line nil) (insert "\n")))))
 325     (when comment (funcall insert-comment comment))
 326     (when link-p
 327       (funcall
 328        insert-comment
 329        (org-fill-template org-babel-tangle-comment-format-beg link-data)))
 330     (when padline (insert "\n"))
 331     (insert
 332      (format
 333       "%s\n"
 334       (org-unescape-code-in-string
 335        (org-babel-trim body (if org-src-preserve-indentation "[\f\n\r\v]")))))
 336     (when link-p
 337       (funcall
 338        insert-comment
 339        (org-fill-template org-babel-tangle-comment-format-end link-data)))))
 340
 341 (defvar org-comment-string) ;; Defined in org.el
 342 (defun org-babel-tangle-collect-blocks (&optional language tangle-file)
 343   "Collect source blocks in the current Org-mode file.
 344 Return an association list of source-code block specifications of
 345 the form used by `org-babel-spec-to-string' grouped by language.
 346 Optional argument LANGUAGE can be used to limit the collected
 347 source code blocks by language.  Optional argument TANGLE-FILE
 348 can be used to limit the collected code blocks by target file."
 349   (let ((block-counter 1) (current-heading "") blocks by-lang)
 350     (org-babel-map-src-blocks (buffer-file-name)
 351       (lambda (new-heading)
 352         (if (not (string= new-heading current-heading))
 353             (progn
 354               (setq block-counter 1)
 355               (setq current-heading new-heading))
 356           (setq block-counter (+ 1 block-counter))))
 357       (replace-regexp-in-string "[ \t]" "-"
 358                                 (condition-case nil
 359                                     (or (nth 4 (org-heading-components))
 360                                         "(dummy for heading without text)")
 361                                   (error (buffer-file-name))))
 362       (let* ((info (org-babel-get-src-block-info 'light))
 363              (src-lang (nth 0 info))
 364              (src-tfile (cdr (assoc :tangle (nth 2 info)))))
 365         (unless (or (string-match (concat "^" org-comment-string) current-heading)
 366                     (string= (cdr (assoc :tangle (nth 2 info))) "no")
 367                     (and tangle-file (not (equal tangle-file src-tfile))))
 368           (unless (and language (not (string= language src-lang)))
 369             ;; Add the spec for this block to blocks under it's language
 370             (setq by-lang (cdr (assoc src-lang blocks)))
 371             (setq blocks (delq (assoc src-lang blocks) blocks))
 372             (setq blocks (cons
 373                           (cons src-lang
 374                                 (cons
 375                                  (org-babel-tangle-single-block
 376                                   block-counter)
 377                                  by-lang)) blocks))))))
 378     ;; Ensure blocks are in the correct order
 379     (setq blocks
 380           (mapcar
 381            (lambda (by-lang) (cons (car by-lang) (reverse (cdr by-lang))))
 382            blocks))
 383     blocks))
 384
 385 (defun org-babel-tangle-single-block
 386   (block-counter &optional only-this-block)
 387   "Collect the tangled source for current block.
 388 Return the list of block attributes needed by
 389 `org-babel-tangle-collect-blocks'.
 390 When ONLY-THIS-BLOCK is non-nil, return the full association
 391 list to be used by `org-babel-tangle' directly."
 392   (let* ((info (org-babel-get-src-block-info))
 393          (start-line
 394           (save-restriction (widen)
 395                             (+ 1 (line-number-at-pos (point)))))
 396          (file (buffer-file-name))
 397          (src-lang (nth 0 info))
 398          (params (nth 2 info))
 399          (extra (nth 3 info))
 400          (cref-fmt (or (and (string-match "-l \"\\(.+\\)\"" extra)
 401                             (match-string 1 extra))
 402                        org-coderef-label-format))
 403          (link ((lambda (link)
 404                   (and (string-match org-bracket-link-regexp link)
 405                        (match-string 1 link)))
 406                 (org-no-properties
 407                  (org-store-link nil))))
 408          (source-name
 409           (intern (or (nth 4 info)
 410                       (format "%s:%d"
 411                               (or (ignore-errors (nth 4 (org-heading-components)))
 412                                   "No heading")
 413                               block-counter))))
 414          (expand-cmd
 415           (intern (concat "org-babel-expand-body:" src-lang)))
 416          (assignments-cmd
 417           (intern (concat "org-babel-variable-assignments:" src-lang)))
 418          (body
 419           ((lambda (body) ;; Run the tangle-body-hook
 420              (with-temp-buffer
 421                (insert body)
 422                (when (string-match "-r" extra)
 423                  (goto-char (point-min))
 424                  (while (re-search-forward
 425                          (replace-regexp-in-string "%s" ".+" cref-fmt) nil t)
 426                    (replace-match "")))
 427                (run-hooks 'org-babel-tangle-body-hook)
 428                (buffer-string)))
 429            ((lambda (body) ;; Expand the body in language specific manner
 430               (if (assoc :no-expand params)
 431                   body
 432                 (if (fboundp expand-cmd)
 433                     (funcall expand-cmd body params)
 434                   (org-babel-expand-body:generic
 435                    body params
 436                    (and (fboundp assignments-cmd)
 437                         (funcall assignments-cmd params))))))
 438             (if (org-babel-noweb-p params :tangle)
 439                 (org-babel-expand-noweb-references info)
 440               (nth 1 info)))))
 441          (comment
 442           (when (or (string= "both" (cdr (assoc :comments params)))
 443                     (string= "org" (cdr (assoc :comments params))))
 444             ;; From the previous heading or code-block end
 445             (funcall
 446              org-babel-process-comment-text
 447              (buffer-substring
 448               (max (condition-case nil
 449                        (save-excursion
 450                          (org-back-to-heading t)  ; Sets match data
 451                          (match-end 0))
 452                      (error (point-min)))
 453                    (save-excursion
 454                      (if (re-search-backward
 455                           org-babel-src-block-regexp nil t)
 456                          (match-end 0)
 457                        (point-min))))
 458               (point)))))
 459          (result
 460           (list start-line file link source-name params body comment)))
 461     (if only-this-block
 462         (list (cons src-lang (list result)))
 463       result)))
 464
 465 (defun org-babel-tangle-comment-links ( &optional info)
 466   "Return a list of begin and end link comments for the code block at point."
 467   (let* ((start-line (org-babel-where-is-src-block-head))
 468          (file (buffer-file-name))
 469          (link (org-link-escape (progn (call-interactively 'org-store-link)
 470                                        (org-no-properties
 471                                         (car (pop org-stored-links))))))
 472          (source-name (nth 4 (or info (org-babel-get-src-block-info 'light))))
 473          (link-data (mapcar (lambda (el)
 474                               (cons (symbol-name el)
 475                                     ((lambda (le)
 476                                        (if (stringp le) le (format "%S" le)))
 477                                      (eval el))))
 478                             '(start-line file link source-name))))
 479     (list (org-fill-template org-babel-tangle-comment-format-beg link-data)
 480           (org-fill-template org-babel-tangle-comment-format-end link-data))))
 481
 482 ;; de-tangling functions
 483 (defvar org-bracket-link-analytic-regexp)
 484 (defun org-babel-detangle (&optional source-code-file)
 485   "Propagate changes in source file back original to Org-mode file.
 486 This requires that code blocks were tangled with link comments
 487 which enable the original code blocks to be found."
 488   (interactive)
 489   (save-excursion
 490     (when source-code-file (find-file source-code-file))
 491     (goto-char (point-min))
 492     (let ((counter 0) new-body end)
 493       (while (re-search-forward org-bracket-link-analytic-regexp nil t)
 494         (when (re-search-forward
 495                (concat " " (regexp-quote (match-string 5)) " ends here"))
 496           (setq end (match-end 0))
 497           (forward-line -1)
 498           (save-excursion
 499             (when (setq new-body (org-babel-tangle-jump-to-org))
 500               (org-babel-update-block-body new-body)))
 501           (setq counter (+ 1 counter)))
 502         (goto-char end))
 503       (prog1 counter (message "Detangled %d code blocks" counter)))))
 504
 505 (defun org-babel-tangle-jump-to-org ()
 506   "Jump from a tangled code file to the related Org-mode file."
 507   (interactive)
 508   (let ((mid (point))
 509         start body-start end done
 510         target-buffer target-char link path block-name body)
 511     (save-window-excursion
 512       (save-excursion
 513         (while (and (re-search-backward org-bracket-link-analytic-regexp nil t)
 514                     (not ; ever wider searches until matching block comments
 515                      (and (setq start (point-at-eol))
 516                           (setq body-start (save-excursion
 517                                              (forward-line 2) (point-at-bol)))
 518                           (setq link (match-string 0))
 519                           (setq path (match-string 3))
 520                           (setq block-name (match-string 5))
 521                           (save-excursion
 522                             (save-match-data
 523                               (re-search-forward
 524                                (concat " " (regexp-quote block-name)
 525                                        " ends here") nil t)
 526                               (setq end (point-at-bol))))))))
 527         (unless (and start (< start mid) (< mid end))
 528           (error "Not in tangled code"))
 529         (setq body (org-babel-trim (buffer-substring start end))))
 530       (when (string-match "::" path)
 531         (setq path (substring path 0 (match-beginning 0))))
 532       (find-file path) (setq target-buffer (current-buffer))
 533       (goto-char start) (org-open-link-from-string link)
 534       (if (string-match "[^ \t\n\r]:\\([[:digit:]]+\\)" block-name)
 535           (org-babel-next-src-block
 536            (string-to-number (match-string 1 block-name)))
 537         (org-babel-goto-named-src-block block-name))
 538       ;; position at the beginning of the code block body
 539       (goto-char (org-babel-where-is-src-block-head))
 540       (forward-line 1)
 541       ;; Use org-edit-special to isolate the code.
 542       (org-edit-special)
 543       ;; Then move forward the correct number of characters in the
 544       ;; code buffer.
 545       (forward-char (- mid body-start))
 546       ;; And return to the Org-mode buffer with the point in the right
 547       ;; place.
 548       (org-edit-src-exit)
 549       (setq target-char (point)))
 550     (org-src-switch-to-buffer target-buffer t)
 551     (prog1 body (goto-char target-char))))
 552
 553 (provide 'ob-tangle)
 554
 555 ;; Local variables:
 556 ;; generated-autoload-file: "org-loaddefs.el"
 557 ;; End:
 558
 559 ;;; ob-tangle.el ends here