lisp/ob-core.el

   1 ;;; ob-core.el --- working with code blocks in org-mode
   2
   3 ;; Copyright (C) 2009-2013  Free Software Foundation, Inc.
   4
   5 ;; Authors: Eric Schulte
   6 ;;      Dan Davison
   7 ;; Keywords: literate programming, reproducible research
   8 ;; Homepage: http://orgmode.org
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Code:
  26 (eval-when-compile
  27   (require 'cl))
  28 (require 'ob-eval)
  29 (require 'org-macs)
  30 (require 'org-compat)
  31
  32 (defconst org-babel-exeext
  33   (if (memq system-type '(windows-nt cygwin))
  34       ".exe"
  35     nil))
  36 ;; dynamically scoped for tramp
  37 (defvar org-babel-call-process-region-original nil)
  38 (defvar org-src-lang-modes)
  39 (defvar org-babel-library-of-babel)
  40 (declare-function show-all "outline" ())
  41 (declare-function org-reduce "org" (CL-FUNC CL-SEQ &rest CL-KEYS))
  42 (declare-function org-mark-ring-push "org" (&optional pos buffer))
  43 (declare-function tramp-compat-make-temp-file "tramp-compat"
  44                   (filename &optional dir-flag))
  45 (declare-function tramp-dissect-file-name "tramp" (name &optional nodefault))
  46 (declare-function tramp-file-name-user "tramp" (vec))
  47 (declare-function tramp-file-name-host "tramp" (vec))
  48 (declare-function with-parsed-tramp-file-name "tramp" (filename var &rest body))
  49 (declare-function org-icompleting-read "org" (&rest args))
  50 (declare-function org-edit-src-code "org-src"
  51                   (&optional context code edit-buffer-name quietp))
  52 (declare-function org-edit-src-exit "org-src"  (&optional context))
  53 (declare-function org-open-at-point "org" (&optional in-emacs reference-buffer))
  54 (declare-function org-save-outline-visibility "org-macs" (use-markers &rest body))
  55 (declare-function org-outline-overlay-data "org" (&optional use-markers))
  56 (declare-function org-set-outline-overlay-data "org" (data))
  57 (declare-function org-narrow-to-subtree "org" ())
  58 (declare-function org-split-string "org" (string &optional separators))
  59 (declare-function org-entry-get "org"
  60                   (pom property &optional inherit literal-nil))
  61 (declare-function org-make-options-regexp "org" (kwds &optional extra))
  62 (declare-function org-do-remove-indentation "org" (&optional n))
  63 (declare-function org-next-block "org" (arg &optional backward block-regexp))
  64 (declare-function org-previous-block "org" (arg &optional block-regexp))
  65 (declare-function org-show-context "org" (&optional key))
  66 (declare-function org-at-table-p "org" (&optional table-type))
  67 (declare-function org-cycle "org" (&optional arg))
  68 (declare-function org-uniquify "org" (list))
  69 (declare-function org-current-level "org" ())
  70 (declare-function org-table-import "org-table" (file arg))
  71 (declare-function org-add-hook "org-compat"
  72                   (hook function &optional append local))
  73 (declare-function org-table-align "org-table" ())
  74 (declare-function org-table-end "org-table" (&optional table-type))
  75 (declare-function orgtbl-to-generic "org-table" (table params))
  76 (declare-function orgtbl-to-orgtbl "org-table" (table params))
  77 (declare-function org-babel-tangle-comment-links "ob-tangle" (&optional info))
  78 (declare-function org-babel-lob-get-info "ob-lob" nil)
  79 (declare-function org-babel-ref-split-args "ob-ref" (arg-string))
  80 (declare-function org-babel-ref-parse "ob-ref" (assignment))
  81 (declare-function org-babel-ref-resolve "ob-ref" (ref))
  82 (declare-function org-babel-ref-goto-headline-id "ob-ref" (id))
  83 (declare-function org-babel-ref-headline-body "ob-ref" ())
  84 (declare-function org-babel-lob-execute-maybe "ob-lob" ())
  85 (declare-function org-number-sequence "org-compat" (from &optional to inc))
  86 (declare-function org-at-item-p "org-list" ())
  87 (declare-function org-list-parse-list "org-list" (&optional delete))
  88 (declare-function org-list-to-generic "org-list" (LIST PARAMS))
  89 (declare-function org-list-struct "org-list" ())
  90 (declare-function org-list-prevs-alist "org-list" (struct))
  91 (declare-function org-list-get-list-end "org-list" (item struct prevs))
  92 (declare-function org-remove-if "org" (predicate seq))
  93 (declare-function org-completing-read "org" (&rest args))
  94 (declare-function org-escape-code-in-region "org-src" (beg end))
  95 (declare-function org-unescape-code-in-string "org-src" (s))
  96 (declare-function org-table-to-lisp "org-table" (&optional txt))
  97 (declare-function org-reverse-string "org" (string))
  98 (declare-function org-element-context "org-element" (&optional ELEMENT))
  99
 100 (defgroup org-babel nil
 101   "Code block evaluation and management in `org-mode' documents."
 102   :tag "Babel"
 103   :group 'org)
 104
 105 (defcustom org-confirm-babel-evaluate t
 106   "Confirm before evaluation.
 107 Require confirmation before interactively evaluating code
 108 blocks in Org-mode buffers.  The default value of this variable
 109 is t, meaning confirmation is required for any code block
 110 evaluation.  This variable can be set to nil to inhibit any
 111 future confirmation requests.  This variable can also be set to a
 112 function which takes two arguments the language of the code block
 113 and the body of the code block.  Such a function should then
 114 return a non-nil value if the user should be prompted for
 115 execution or nil if no prompt is required.
 116
 117 Warning: Disabling confirmation may result in accidental
 118 evaluation of potentially harmful code.  It may be advisable
 119 remove code block execution from C-c C-c as further protection
 120 against accidental code block evaluation.  The
 121 `org-babel-no-eval-on-ctrl-c-ctrl-c' variable can be used to
 122 remove code block execution from the C-c C-c keybinding."
 123   :group 'org-babel
 124   :version "24.1"
 125   :type '(choice boolean function))
 126 ;; don't allow this variable to be changed through file settings
 127 (put 'org-confirm-babel-evaluate 'safe-local-variable (lambda (x) (eq x t)))
 128
 129 (defcustom org-babel-no-eval-on-ctrl-c-ctrl-c nil
 130   "Remove code block evaluation from the C-c C-c key binding."
 131   :group 'org-babel
 132   :version "24.1"
 133   :type 'boolean)
 134
 135 (defcustom org-babel-results-keyword "RESULTS"
 136   "Keyword used to name results generated by code blocks.
 137 Should be either RESULTS or NAME however any capitalization may
 138 be used."
 139   :group 'org-babel
 140   :version "24.4"
 141   :package-version '(Org . "8.0")
 142   :type 'string)
 143
 144 (defcustom org-babel-noweb-wrap-start "<<"
 145   "String used to begin a noweb reference in a code block.
 146 See also `org-babel-noweb-wrap-end'."
 147   :group 'org-babel
 148   :type 'string)
 149
 150 (defcustom org-babel-noweb-wrap-end ">>"
 151   "String used to end a noweb reference in a code block.
 152 See also `org-babel-noweb-wrap-start'."
 153   :group 'org-babel
 154   :type 'string)
 155
 156 (defcustom org-babel-inline-result-wrap "=%s="
 157   "Format string used to wrap inline results.
 158 This string must include a \"%s\" which will be replaced by the results."
 159   :group 'org-babel
 160   :type 'string)
 161
 162 (defun org-babel-noweb-wrap (&optional regexp)
 163   (concat org-babel-noweb-wrap-start
 164           (or regexp "\\([^ \t\n].+?[^ \t]\\|[^ \t\n]\\)")
 165           org-babel-noweb-wrap-end))
 166
 167 (defvar org-babel-src-name-regexp
 168   "^[ \t]*#\\+name:[ \t]*"
 169   "Regular expression used to match a source name line.")
 170
 171 (defvar org-babel-multi-line-header-regexp
 172   "^[ \t]*#\\+headers?:[ \t]*\\([^\n]*\\)$"
 173   "Regular expression used to match multi-line header arguments.")
 174
 175 (defvar org-babel-src-name-w-name-regexp
 176   (concat org-babel-src-name-regexp
 177           "\\("
 178           org-babel-multi-line-header-regexp
 179           "\\)*"
 180           "\\([^ ()\f\t\n\r\v]+\\)")
 181   "Regular expression matching source name lines with a name.")
 182
 183 (defvar org-babel-src-block-regexp
 184   (concat
 185    ;; (1) indentation                 (2) lang
 186    "^\\([ \t]*\\)#\\+begin_src[ \t]+\\([^ \f\t\n\r\v]+\\)[ \t]*"
 187    ;; (3) switches
 188    "\\([^\":\n]*\"[^\"\n*]*\"[^\":\n]*\\|[^\":\n]*\\)"
 189    ;; (4) header arguments
 190    "\\([^\n]*\\)\n"
 191    ;; (5) body
 192    "\\([^\000]*?\n\\)??[ \t]*#\\+end_src")
 193   "Regexp used to identify code blocks.")
 194
 195 (defvar org-babel-inline-src-block-regexp
 196   (concat
 197    ;; (1) replacement target (2) lang
 198    "\\(?:^\\|[^-[:alnum:]]\\)\\(src_\\([^ \f\t\n\r\v]+\\)"
 199    ;; (3,4) (unused, headers)
 200    "\\(\\|\\[\\(.*?\\)\\]\\)"
 201    ;; (5) body
 202    "{\\([^\f\n\r\v]+?\\)}\\)")
 203   "Regexp used to identify inline src-blocks.")
 204
 205 (defun org-babel-get-header (params key &optional others)
 206   "Select only header argument of type KEY from a list.
 207 Optional argument OTHERS indicates that only the header that do
 208 not match KEY should be returned."
 209   (delq nil
 210         (mapcar
 211          (lambda (p) (when (funcall (if others #'not #'identity) (eq (car p) key)) p))
 212          params)))
 213
 214 (defun org-babel-get-inline-src-block-matches()
 215   "Set match data if within body of an inline source block.
 216 Returns non-nil if match-data set"
 217   (let ((src-at-0-p (save-excursion
 218                       (beginning-of-line 1)
 219                       (string= "src" (thing-at-point 'word))))
 220         (first-line-p (= 1 (line-number-at-pos)))
 221         (orig (point)))
 222     (let ((search-for (cond ((and src-at-0-p first-line-p  "src_"))
 223                             (first-line-p "[[:punct:] \t]src_")
 224                             (t "[[:punct:] \f\t\n\r\v]src_")))
 225           (lower-limit (if first-line-p
 226                            nil
 227                          (- (point-at-bol) 1))))
 228       (save-excursion
 229         (when (or (and src-at-0-p (bobp))
 230                   (and (re-search-forward "}" (point-at-eol) t)
 231                        (re-search-backward search-for lower-limit t)
 232                        (> orig (point))))
 233           (when (looking-at org-babel-inline-src-block-regexp)
 234             t ))))))
 235
 236 (defvar org-babel-inline-lob-one-liner-regexp)
 237 (defun org-babel-get-lob-one-liner-matches()
 238   "Set match data if on line of an lob one liner.
 239 Returns non-nil if match-data set"
 240   (save-excursion
 241     (unless (= (point) (point-at-bol)) ;; move before inline block
 242       (re-search-backward "[ \f\t\n\r\v]" nil t))
 243     (if (looking-at org-babel-inline-lob-one-liner-regexp)
 244         t
 245       nil)))
 246
 247 (defun org-babel-get-src-block-info (&optional light)
 248   "Get information on the current source block.
 249
 250 Optional argument LIGHT does not resolve remote variable
 251 references; a process which could likely result in the execution
 252 of other code blocks.
 253
 254 Returns a list
 255  (language body header-arguments-alist switches name indent block-head)."
 256   (let ((case-fold-search t) head info name indent)
 257     ;; full code block
 258     (if (setq head (org-babel-where-is-src-block-head))
 259         (save-excursion
 260           (goto-char head)
 261           (setq info (org-babel-parse-src-block-match))
 262           (setq indent (car (last info)))
 263           (setq info (butlast info))
 264           (while (and (forward-line -1)
 265                       (looking-at org-babel-multi-line-header-regexp))
 266             (setf (nth 2 info)
 267                   (org-babel-merge-params
 268                    (nth 2 info)
 269                    (org-babel-parse-header-arguments (match-string 1)))))
 270           (when (looking-at org-babel-src-name-w-name-regexp)
 271             (setq name (org-no-properties (match-string 3)))))
 272       ;; inline source block
 273       (when (org-babel-get-inline-src-block-matches)
 274         (setq info (org-babel-parse-inline-src-block-match))))
 275     ;; resolve variable references and add summary parameters
 276     (when (and info (not light))
 277       (setf (nth 2 info) (org-babel-process-params (nth 2 info))))
 278     (when info (append info (list name indent head)))))
 279
 280 (defvar org-current-export-file) ; dynamically bound
 281 (defmacro org-babel-check-confirm-evaluate (info &rest body)
 282   "Evaluate BODY with special execution confirmation variables set.
 283
 284 Specifically; NOEVAL will indicate if evaluation is allowed,
 285 QUERY will indicate if a user query is required, CODE-BLOCK will
 286 hold the language of the code block, and BLOCK-NAME will hold the
 287 name of the code block."
 288   (declare (indent defun))
 289   (org-with-gensyms
 290       (lang block-body headers name eval eval-no export eval-no-export)
 291     `(let* ((,lang           (nth 0 ,info))
 292             (,block-body     (nth 1 ,info))
 293             (,headers        (nth 2 ,info))
 294             (,name           (nth 4 ,info))
 295             (,eval           (or (cdr  (assoc :eval   ,headers))
 296                                  (when (assoc :noeval ,headers) "no")))
 297             (,eval-no        (or (equal ,eval "no")
 298                                  (equal ,eval "never")))
 299             (,export         (org-bound-and-true-p org-current-export-file))
 300             (,eval-no-export (and ,export (or (equal ,eval "no-export")
 301                                               (equal ,eval "never-export"))))
 302             (noeval          (or ,eval-no ,eval-no-export))
 303             (query           (or (equal ,eval "query")
 304                                  (and ,export (equal ,eval "query-export"))
 305                                  (if (functionp org-confirm-babel-evaluate)
 306                                      (funcall org-confirm-babel-evaluate
 307                                               ,lang ,block-body)
 308                                    org-confirm-babel-evaluate)))
 309             (code-block      (if ,info (format  " %s "  ,lang) " "))
 310             (block-name      (if ,name (format " (%s) " ,name) " ")))
 311        ,@body)))
 312
 313 (defsubst org-babel-check-evaluate (info)
 314   "Check if code block INFO should be evaluated.
 315 Do not query the user."
 316   (org-babel-check-confirm-evaluate info
 317     (not (when noeval
 318            (message (format "Evaluation of this%scode-block%sis disabled."
 319                             code-block block-name))))))
 320
 321  ;; dynamically scoped for asynchroneous export
 322 (defvar org-babel-confirm-evaluate-answer-no)
 323
 324 (defsubst org-babel-confirm-evaluate (info)
 325   "Confirm evaluation of the code block INFO.
 326
 327 If the variable `org-babel-confirm-evaluate-answer-no' is bound
 328 to a non-nil value, auto-answer with \"no\".
 329
 330 This query can also be suppressed by setting the value of
 331 `org-confirm-babel-evaluate' to nil, in which case all future
 332 interactive code block evaluations will proceed without any
 333 confirmation from the user.
 334
 335 Note disabling confirmation may result in accidental evaluation
 336 of potentially harmful code."
 337   (org-babel-check-confirm-evaluate info
 338     (not (when query
 339            (unless
 340                (and (not (org-bound-and-true-p
 341                           org-babel-confirm-evaluate-answer-no))
 342                     (yes-or-no-p
 343                      (format "Evaluate this%scode block%son your system? "
 344                              code-block block-name)))
 345              (message (format "Evaluation of this%scode-block%sis aborted."
 346                               code-block block-name)))))))
 347
 348 ;;;###autoload
 349 (defun org-babel-execute-safely-maybe ()
 350   (unless org-babel-no-eval-on-ctrl-c-ctrl-c
 351     (org-babel-execute-maybe)))
 352
 353 (add-hook 'org-ctrl-c-ctrl-c-hook 'org-babel-execute-safely-maybe)
 354
 355 ;;;###autoload
 356 (defun org-babel-execute-maybe ()
 357   (interactive)
 358   (or (org-babel-execute-src-block-maybe)
 359       (org-babel-lob-execute-maybe)))
 360
 361 (defmacro org-babel-when-in-src-block (&rest body)
 362   "Execute BODY if point is in a source block and return t.
 363
 364 Otherwise do nothing and return nil."
 365   `(if (or (org-babel-where-is-src-block-head)
 366            (org-babel-get-inline-src-block-matches))
 367        (progn
 368          ,@body
 369          t)
 370      nil))
 371
 372 (defun org-babel-execute-src-block-maybe ()
 373   "Conditionally execute a source block.
 374 Detect if this is context for a Babel src-block and if so
 375 then run `org-babel-execute-src-block'."
 376   (interactive)
 377   (org-babel-when-in-src-block
 378    (org-babel-eval-wipe-error-buffer)
 379    (org-babel-execute-src-block current-prefix-arg)))
 380
 381 ;;;###autoload
 382 (defun org-babel-view-src-block-info ()
 383   "Display information on the current source block.
 384 This includes header arguments, language and name, and is largely
 385 a window into the `org-babel-get-src-block-info' function."
 386   (interactive)
 387   (let ((info (org-babel-get-src-block-info 'light))
 388         (full (lambda (it) (> (length it) 0)))
 389         (printf (lambda (fmt &rest args) (princ (apply #'format fmt args)))))
 390     (when info
 391       (with-help-window (help-buffer)
 392         (let ((name        (nth 4 info))
 393               (lang        (nth 0 info))
 394               (switches    (nth 3 info))
 395               (header-args (nth 2 info)))
 396           (when name            (funcall printf "Name: %s\n"     name))
 397           (when lang            (funcall printf "Lang: %s\n"     lang))
 398           (when (funcall full switches) (funcall printf "Switches: %s\n" switches))
 399           (funcall printf "Header Arguments:\n")
 400           (dolist (pair (sort header-args
 401                               (lambda (a b) (string< (symbol-name (car a))
 402                                                      (symbol-name (car b))))))
 403             (when (funcall full (cdr pair))
 404               (funcall printf "\t%S%s\t%s\n"
 405                        (car pair)
 406                        (if (> (length (format "%S" (car pair))) 7) "" "\t")
 407                        (cdr pair)))))))))
 408
 409 ;;;###autoload
 410 (defun org-babel-expand-src-block-maybe ()
 411   "Conditionally expand a source block.
 412 Detect if this is context for a org-babel src-block and if so
 413 then run `org-babel-expand-src-block'."
 414   (interactive)
 415   (org-babel-when-in-src-block
 416    (org-babel-expand-src-block current-prefix-arg)))
 417
 418 ;;;###autoload
 419 (defun org-babel-load-in-session-maybe ()
 420   "Conditionally load a source block in a session.
 421 Detect if this is context for a org-babel src-block and if so
 422 then run `org-babel-load-in-session'."
 423   (interactive)
 424   (org-babel-when-in-src-block
 425    (org-babel-load-in-session current-prefix-arg)))
 426
 427 (add-hook 'org-metaup-hook 'org-babel-load-in-session-maybe)
 428
 429 ;;;###autoload
 430 (defun org-babel-pop-to-session-maybe ()
 431   "Conditionally pop to a session.
 432 Detect if this is context for a org-babel src-block and if so
 433 then run `org-babel-switch-to-session'."
 434   (interactive)
 435   (org-babel-when-in-src-block
 436    (org-babel-switch-to-session current-prefix-arg)))
 437
 438 (add-hook 'org-metadown-hook 'org-babel-pop-to-session-maybe)
 439
 440 (defconst org-babel-common-header-args-w-values
 441   '((cache      . ((no yes)))
 442     (cmdline    . :any)
 443     (colnames   . ((nil no yes)))
 444     (comments   . ((no link yes org both noweb)))
 445     (dir        . :any)
 446     (eval       . ((never query)))
 447     (exports    . ((code results both none)))
 448     (epilogue   . :any)
 449     (file       . :any)
 450     (file-desc  . :any)
 451     (hlines     . ((no yes)))
 452     (mkdirp     . ((yes no)))
 453     (no-expand)
 454     (noeval)
 455     (noweb      . ((yes no tangle no-export strip-export)))
 456     (noweb-ref  . :any)
 457     (noweb-sep  . :any)
 458     (padline    . ((yes no)))
 459     (post       . :any)
 460     (prologue   . :any)
 461     (results    . ((file list vector table scalar verbatim)
 462                    (raw html latex org code pp drawer)
 463                    (replace silent none append prepend)
 464                    (output value)))
 465     (rownames   . ((no yes)))
 466     (sep        . :any)
 467     (session    . :any)
 468     (shebang    . :any)
 469     (tangle     . ((tangle yes no :any)))
 470     (tangle-mode . ((#o755 #o555 #o444 :any)))
 471     (var        . :any)
 472     (wrap       . :any)))
 473
 474 (defconst org-babel-header-arg-names
 475   (mapcar #'car org-babel-common-header-args-w-values)
 476   "Common header arguments used by org-babel.
 477 Note that individual languages may define their own language
 478 specific header arguments as well.")
 479
 480 (defvar org-babel-default-header-args
 481   '((:session . "none") (:results . "replace") (:exports . "code")
 482     (:cache . "no") (:noweb . "no") (:hlines . "no") (:tangle . "no"))
 483   "Default arguments to use when evaluating a source block.")
 484
 485 (defvar org-babel-default-inline-header-args
 486   '((:session . "none") (:results . "replace") (:exports . "results"))
 487   "Default arguments to use when evaluating an inline source block.")
 488
 489 (defvar org-babel-data-names '("tblname" "results" "name"))
 490
 491 (defvar org-babel-result-regexp
 492   (concat "^[ \t]*#\\+"
 493           (regexp-opt org-babel-data-names t)
 494           "\\(\\[\\("
 495           ;; FIXME The string below is `org-ts-regexp'
 496           "<\\([0-9]\\{4\\}-[0-9]\\{2\\}-[0-9]\\{2\\} ?[^\r\n>]*?\\)>"
 497           " \\)?\\([[:alnum:]]+\\)\\]\\)?\\:[ \t]*")
 498   "Regular expression used to match result lines.
 499 If the results are associated with a hash key then the hash will
 500 be saved in the second match data.")
 501
 502 (defvar org-babel-result-w-name-regexp
 503   (concat org-babel-result-regexp
 504           "\\([^ ()\f\t\n\r\v]+\\)\\(\(\\(.*\\)\)\\|\\)"))
 505
 506 (defvar org-babel-min-lines-for-block-output 10
 507   "The minimum number of lines for block output.
 508 If number of lines of output is equal to or exceeds this
 509 value, the output is placed in a #+begin_example...#+end_example
 510 block.  Otherwise the output is marked as literal by inserting
 511 colons at the starts of the lines.  This variable only takes
 512 effect if the :results output option is in effect.")
 513
 514 (defvar org-babel-noweb-error-langs nil
 515   "Languages for which Babel will raise literate programming errors.
 516 List of languages for which errors should be raised when the
 517 source code block satisfying a noweb reference in this language
 518 can not be resolved.")
 519
 520 (defvar org-babel-hash-show 4
 521   "Number of initial characters to show of a hidden results hash.")
 522
 523 (defvar org-babel-hash-show-time nil
 524   "Non-nil means show the time the code block was evaluated in the result hash.")
 525
 526 (defvar org-babel-after-execute-hook nil
 527   "Hook for functions to be called after `org-babel-execute-src-block'")
 528
 529 (defun org-babel-named-src-block-regexp-for-name (name)
 530   "This generates a regexp used to match a src block named NAME."
 531   (concat org-babel-src-name-regexp (regexp-quote name)
 532           "[ \t(]*[\r\n]\\(?:^#.*[\r\n]\\)*"
 533           (substring org-babel-src-block-regexp 1)))
 534
 535 (defun org-babel-named-data-regexp-for-name (name)
 536   "This generates a regexp used to match data named NAME."
 537   (concat org-babel-result-regexp (regexp-quote name) "\\([ \t]\\|$\\)"))
 538
 539 ;;; functions
 540 (defvar call-process-region)
 541 (defvar org-babel-current-src-block-location nil
 542   "Marker pointing to the src block currently being executed.
 543 This may also point to a call line or an inline code block.  If
 544 multiple blocks are being executed (e.g., in chained execution
 545 through use of the :var header argument) this marker points to
 546 the outer-most code block.")
 547
 548 ;;;###autoload
 549 (defun org-babel-execute-src-block (&optional arg info params)
 550   "Execute the current source code block.
 551 Insert the results of execution into the buffer.  Source code
 552 execution and the collection and formatting of results can be
 553 controlled through a variety of header arguments.
 554
 555 With prefix argument ARG, force re-execution even if an existing
 556 result cached in the buffer would otherwise have been returned.
 557
 558 Optionally supply a value for INFO in the form returned by
 559 `org-babel-get-src-block-info'.
 560
 561 Optionally supply a value for PARAMS which will be merged with
 562 the header arguments specified at the front of the source code
 563 block."
 564   (interactive)
 565   (let* ((org-babel-current-src-block-location
 566           (or org-babel-current-src-block-location
 567               (nth 6 info)
 568               (org-babel-where-is-src-block-head)))
 569          (info (if info
 570                    (copy-tree info)
 571                  (org-babel-get-src-block-info)))
 572          (merged-params (org-babel-merge-params (nth 2 info) params)))
 573     (when (org-babel-check-evaluate
 574            (let ((i info)) (setf (nth 2 i) merged-params) i))
 575       (let* ((params (if params
 576                          (org-babel-process-params merged-params)
 577                        (nth 2 info)))
 578              (cachep (and (not arg) (cdr (assoc :cache params))
 579                            (string= "yes" (cdr (assoc :cache params)))))
 580              (new-hash (when cachep (org-babel-sha1-hash info)))
 581              (old-hash (when cachep (org-babel-current-result-hash)))
 582              (cache-current-p (and (not arg) new-hash
 583                                    (equal new-hash old-hash))))
 584         (cond
 585          (cache-current-p
 586           (save-excursion ;; return cached result
 587             (goto-char (org-babel-where-is-src-block-result nil info))
 588             (end-of-line 1) (forward-char 1)
 589             (let ((result (org-babel-read-result)))
 590               (message (replace-regexp-in-string
 591                         "%" "%%" (format "%S" result))) result)))
 592          ((org-babel-confirm-evaluate
 593            (let ((i info)) (setf (nth 2 i) merged-params) i))
 594           (let* ((lang (nth 0 info))
 595                  (result-params (cdr (assoc :result-params params)))
 596                  (body (setf (nth 1 info)
 597                              (if (org-babel-noweb-p params :eval)
 598                                  (org-babel-expand-noweb-references info)
 599                                (nth 1 info))))
 600                  (dir (cdr (assoc :dir params)))
 601                  (default-directory
 602                    (or (and dir (file-name-as-directory (expand-file-name dir)))
 603                        default-directory))
 604                  (org-babel-call-process-region-original ;; for tramp handler
 605                   (or (org-bound-and-true-p
 606                        org-babel-call-process-region-original)
 607                       (symbol-function 'call-process-region)))
 608                  (indent (nth 5 info))
 609                  result cmd)
 610             (unwind-protect
 611                 (let ((call-process-region
 612                        (lambda (&rest args)
 613                          (apply 'org-babel-tramp-handle-call-process-region
 614                                 args))))
 615                   (let ((lang-check
 616                          (lambda (f)
 617                            (let ((f (intern (concat "org-babel-execute:" f))))
 618                              (when (fboundp f) f)))))
 619                     (setq cmd
 620                           (or (funcall lang-check lang)
 621                               (funcall lang-check
 622                                        (symbol-name
 623                                         (cdr (assoc lang org-src-lang-modes))))
 624                               (error "No org-babel-execute function for %s!"
 625                                      lang))))
 626                   (message "executing %s code block%s..."
 627                            (capitalize lang)
 628                            (if (nth 4 info) (format " (%s)" (nth 4 info)) ""))
 629                   (if (member "none" result-params)
 630                       (progn
 631                         (funcall cmd body params)
 632                         (message "result silenced")
 633                         (setq result nil))
 634                     (setq result
 635                           ((lambda (result)
 636                              (if (and (eq (cdr (assoc :result-type params))
 637                                           'value)
 638                                       (or (member "vector" result-params)
 639                                           (member "table" result-params))
 640                                       (not (listp result)))
 641                                  (list (list result)) result))
 642                            (funcall cmd body params)))
 643                     ;; if non-empty result and :file then write to :file
 644                     (when (cdr (assoc :file params))
 645                       (when result
 646                         (with-temp-file (cdr (assoc :file params))
 647                           (insert
 648                            (org-babel-format-result
 649                             result (cdr (assoc :sep (nth 2 info)))))))
 650                       (setq result (cdr (assoc :file params))))
 651                     ;; possibly perform post process provided its appropriate
 652                     (when (cdr (assoc :post params))
 653                       (let ((*this* (if (cdr (assoc :file params))
 654                                         (org-babel-result-to-file
 655                                          (cdr (assoc :file params))
 656                                          (when (assoc :file-desc params)
 657                                            (or (cdr (assoc :file-desc params))
 658                                                result)))
 659                                       result)))
 660                         (setq result (org-babel-ref-resolve
 661                                       (cdr (assoc :post params))))
 662                         (when (cdr (assoc :file params))
 663                           (setq result-params
 664                                 (remove "file" result-params)))))
 665                     (org-babel-insert-result
 666                      result result-params info new-hash indent lang))
 667                   (run-hooks 'org-babel-after-execute-hook)
 668                   result)
 669               (setq call-process-region
 670                     'org-babel-call-process-region-original)))))))))
 671
 672 (defun org-babel-expand-body:generic (body params &optional var-lines)
 673   "Expand BODY with PARAMS.
 674 Expand a block of code with org-babel according to its header
 675 arguments.  This generic implementation of body expansion is
 676 called for languages which have not defined their own specific
 677 org-babel-expand-body:lang function."
 678   (let ((pro (cdr (assoc :prologue params)))
 679         (epi (cdr (assoc :epilogue params))))
 680     (mapconcat #'identity
 681                (append (when pro (list pro))
 682                        var-lines
 683                        (list body)
 684                        (when epi (list epi)))
 685                "\n")))
 686
 687 ;;;###autoload
 688 (defun org-babel-expand-src-block (&optional arg info params)
 689   "Expand the current source code block.
 690 Expand according to the source code block's header
 691 arguments and pop open the results in a preview buffer."
 692   (interactive)
 693   (let* ((info (or info (org-babel-get-src-block-info)))
 694          (lang (nth 0 info))
 695          (params (setf (nth 2 info)
 696                        (sort (org-babel-merge-params (nth 2 info) params)
 697                              (lambda (el1 el2) (string< (symbol-name (car el1))
 698                                                         (symbol-name (car el2)))))))
 699          (body (setf (nth 1 info)
 700                      (if (org-babel-noweb-p params :eval)
 701                          (org-babel-expand-noweb-references info) (nth 1 info))))
 702          (expand-cmd (intern (concat "org-babel-expand-body:" lang)))
 703          (assignments-cmd (intern (concat "org-babel-variable-assignments:"
 704                                           lang)))
 705          (expanded
 706           (if (fboundp expand-cmd) (funcall expand-cmd body params)
 707             (org-babel-expand-body:generic
 708              body params (and (fboundp assignments-cmd)
 709                               (funcall assignments-cmd params))))))
 710     (if (org-called-interactively-p 'any)
 711         (org-edit-src-code
 712          nil expanded
 713          (concat "*Org-Babel Preview " (buffer-name) "[ " lang " ]*"))
 714       expanded)))
 715
 716 (defun org-babel-edit-distance (s1 s2)
 717   "Return the edit (levenshtein) distance between strings S1 S2."
 718   (let* ((l1 (length s1))
 719          (l2 (length s2))
 720          (dist (vconcat (mapcar (lambda (_) (make-vector (1+ l2) nil))
 721                                 (number-sequence 1 (1+ l1)))))
 722          (in (lambda (i j) (aref (aref dist i) j))))
 723     (setf (aref (aref dist 0) 0) 0)
 724     (dolist (j (number-sequence 1 l2))
 725       (setf (aref (aref dist 0) j) j))
 726     (dolist (i (number-sequence 1 l1))
 727       (setf (aref (aref dist i) 0) i)
 728       (dolist (j (number-sequence 1 l2))
 729         (setf (aref (aref dist i) j)
 730               (min
 731                (1+ (funcall in (1- i) j))
 732                (1+ (funcall in i (1- j)))
 733                (+ (if (equal (aref s1 (1- i)) (aref s2 (1- j))) 0 1)
 734                   (funcall in (1- i) (1- j)))))))
 735     (funcall in l1 l2)))
 736
 737 (defun org-babel-combine-header-arg-lists (original &rest others)
 738   "Combine a number of lists of header argument names and arguments."
 739   (let ((results (copy-sequence original)))
 740     (dolist (new-list others)
 741       (dolist (arg-pair new-list)
 742         (let ((header (car arg-pair))
 743               (args (cdr arg-pair)))
 744           (setq results
 745                 (cons arg-pair (org-remove-if
 746                                 (lambda (pair) (equal header (car pair)))
 747                                 results))))))
 748     results))
 749
 750 ;;;###autoload
 751 (defun org-babel-check-src-block ()
 752   "Check for misspelled header arguments in the current code block."
 753   (interactive)
 754   ;; TODO: report malformed code block
 755   ;; TODO: report incompatible combinations of header arguments
 756   ;; TODO: report uninitialized variables
 757   (let ((too-close 2) ;; <- control closeness to report potential match
 758         (names (mapcar #'symbol-name org-babel-header-arg-names)))
 759     (dolist (header (mapcar (lambda (arg) (substring (symbol-name (car arg)) 1))
 760                             (and (org-babel-where-is-src-block-head)
 761                                  (org-babel-parse-header-arguments
 762                                   (org-no-properties
 763                                    (match-string 4))))))
 764       (dolist (name names)
 765         (when (and (not (string= header name))
 766                    (<= (org-babel-edit-distance header name) too-close)
 767                    (not (member header names)))
 768           (error "Supplied header \"%S\" is suspiciously close to \"%S\""
 769                  header name))))
 770     (message "No suspicious header arguments found.")))
 771
 772 ;;;###autoload
 773 (defun org-babel-insert-header-arg ()
 774   "Insert a header argument selecting from lists of common args and values."
 775   (interactive)
 776   (let* ((lang (car (org-babel-get-src-block-info 'light)))
 777          (lang-headers (intern (concat "org-babel-header-args:" lang)))
 778          (headers (org-babel-combine-header-arg-lists
 779                    org-babel-common-header-args-w-values
 780                    (when (boundp lang-headers) (eval lang-headers))))
 781          (arg (org-icompleting-read
 782                "Header Arg: "
 783                (mapcar
 784                 (lambda (header-spec) (symbol-name (car header-spec)))
 785                 headers))))
 786     (insert ":" arg)
 787     (let ((vals (cdr (assoc (intern arg) headers))))
 788       (when vals
 789         (insert
 790          " "
 791          (cond
 792           ((eq vals :any)
 793            (read-from-minibuffer "value: "))
 794           ((listp vals)
 795            (mapconcat
 796             (lambda (group)
 797               (let ((arg (org-icompleting-read
 798                           "value: "
 799                           (cons "default" (mapcar #'symbol-name group)))))
 800                 (if (and arg (not (string= "default" arg)))
 801                     (concat arg " ")
 802                   "")))
 803             vals ""))))))))
 804
 805 ;; Add support for completing-read insertion of header arguments after ":"
 806 (defun org-babel-header-arg-expand ()
 807   "Call `org-babel-enter-header-arg-w-completion' in appropriate contexts."
 808   (when (and (equal (char-before) ?\:) (org-babel-where-is-src-block-head))
 809     (org-babel-enter-header-arg-w-completion (match-string 2))))
 810
 811 (defun org-babel-enter-header-arg-w-completion (&optional lang)
 812   "Insert header argument appropriate for LANG with completion."
 813   (let* ((lang-headers-var (intern (concat "org-babel-header-args:" lang)))
 814          (lang-headers (when (boundp lang-headers-var) (eval lang-headers-var)))
 815          (headers-w-values (org-babel-combine-header-arg-lists
 816                             org-babel-common-header-args-w-values lang-headers))
 817          (headers (mapcar #'symbol-name (mapcar #'car headers-w-values)))
 818          (header (org-completing-read "Header Arg: " headers))
 819          (args (cdr (assoc (intern header) headers-w-values)))
 820          (arg (when (and args (listp args))
 821                 (org-completing-read
 822                  (format "%s: " header)
 823                  (mapcar #'symbol-name (apply #'append args))))))
 824     (insert (concat header " " (or arg "")))
 825     (cons header arg)))
 826
 827 (add-hook 'org-tab-first-hook 'org-babel-header-arg-expand)
 828
 829 ;;;###autoload
 830 (defun org-babel-load-in-session (&optional arg info)
 831   "Load the body of the current source-code block.
 832 Evaluate the header arguments for the source block before
 833 entering the session.  After loading the body this pops open the
 834 session."
 835   (interactive)
 836   (let* ((info (or info (org-babel-get-src-block-info)))
 837          (lang (nth 0 info))
 838          (params (nth 2 info))
 839          (body (if (not info)
 840                    (user-error "No src code block at point")
 841                  (setf (nth 1 info)
 842                        (if (org-babel-noweb-p params :eval)
 843                            (org-babel-expand-noweb-references info)
 844                          (nth 1 info)))))
 845          (session (cdr (assoc :session params)))
 846          (dir (cdr (assoc :dir params)))
 847          (default-directory
 848            (or (and dir (file-name-as-directory dir)) default-directory))
 849          (cmd (intern (concat "org-babel-load-session:" lang))))
 850     (unless (fboundp cmd)
 851       (error "No org-babel-load-session function for %s!" lang))
 852     (pop-to-buffer (funcall cmd session body params))
 853     (end-of-line 1)))
 854
 855 ;;;###autoload
 856 (defun org-babel-initiate-session (&optional arg info)
 857   "Initiate session for current code block.
 858 If called with a prefix argument then resolve any variable
 859 references in the header arguments and assign these variables in
 860 the session.  Copy the body of the code block to the kill ring."
 861   (interactive "P")
 862   (let* ((info (or info (org-babel-get-src-block-info (not arg))))
 863          (lang (nth 0 info))
 864          (body (nth 1 info))
 865          (params (nth 2 info))
 866          (session (cdr (assoc :session params)))
 867          (dir (cdr (assoc :dir params)))
 868          (default-directory
 869            (or (and dir (file-name-as-directory dir)) default-directory))
 870          (init-cmd (intern (format "org-babel-%s-initiate-session" lang)))
 871          (prep-cmd (intern (concat "org-babel-prep-session:" lang))))
 872     (if (and (stringp session) (string= session "none"))
 873         (error "This block is not using a session!"))
 874     (unless (fboundp init-cmd)
 875       (error "No org-babel-initiate-session function for %s!" lang))
 876     (with-temp-buffer (insert (org-babel-trim body))
 877                       (copy-region-as-kill (point-min) (point-max)))
 878     (when arg
 879       (unless (fboundp prep-cmd)
 880         (error "No org-babel-prep-session function for %s!" lang))
 881       (funcall prep-cmd session params))
 882     (funcall init-cmd session params)))
 883
 884 ;;;###autoload
 885 (defun org-babel-switch-to-session (&optional arg info)
 886   "Switch to the session of the current code block.
 887 Uses `org-babel-initiate-session' to start the session.  If called
 888 with a prefix argument then this is passed on to
 889 `org-babel-initiate-session'."
 890   (interactive "P")
 891   (pop-to-buffer (org-babel-initiate-session arg info))
 892   (end-of-line 1))
 893
 894 (defalias 'org-babel-pop-to-session 'org-babel-switch-to-session)
 895
 896 ;;;###autoload
 897 (defun org-babel-switch-to-session-with-code (&optional arg info)
 898   "Switch to code buffer and display session."
 899   (interactive "P")
 900   (let ((swap-windows
 901          (lambda ()
 902            (let ((other-window-buffer (window-buffer (next-window))))
 903              (set-window-buffer (next-window) (current-buffer))
 904              (set-window-buffer (selected-window) other-window-buffer))
 905            (other-window 1)))
 906         (info (org-babel-get-src-block-info))
 907         (org-src-window-setup 'reorganize-frame))
 908     (save-excursion
 909       (org-babel-switch-to-session arg info))
 910     (org-edit-src-code)
 911     (funcall swap-windows)))
 912
 913 (defmacro org-babel-do-in-edit-buffer (&rest body)
 914   "Evaluate BODY in edit buffer if there is a code block at point.
 915 Return t if a code block was found at point, nil otherwise."
 916   `(let ((org-src-window-setup 'switch-invisibly))
 917      (when (and (org-babel-where-is-src-block-head)
 918                 (org-edit-src-code nil nil nil))
 919        (unwind-protect (progn ,@body)
 920          (if (org-bound-and-true-p org-edit-src-from-org-mode)
 921              (org-edit-src-exit)))
 922        t)))
 923 (def-edebug-spec org-babel-do-in-edit-buffer (body))
 924
 925 (defun org-babel-do-key-sequence-in-edit-buffer (key)
 926   "Read key sequence and execute the command in edit buffer.
 927 Enter a key sequence to be executed in the language major-mode
 928 edit buffer.  For example, TAB will alter the contents of the
 929 Org-mode code block according to the effect of TAB in the
 930 language major-mode buffer.  For languages that support
 931 interactive sessions, this can be used to send code from the Org
 932 buffer to the session for evaluation using the native major-mode
 933 evaluation mechanisms."
 934   (interactive "kEnter key-sequence to execute in edit buffer: ")
 935   (org-babel-do-in-edit-buffer
 936    (call-interactively
 937     (key-binding (or key (read-key-sequence nil))))))
 938
 939 (defvar org-bracket-link-regexp)
 940
 941 (defun org-babel-active-location-p ()
 942   (memq (car (save-match-data (org-element-context)))
 943         '(babel-call inline-babel-call inline-src-block src-block)))
 944
 945 ;;;###autoload
 946 (defun org-babel-open-src-block-result (&optional re-run)
 947   "If `point' is on a src block then open the results of the
 948 source code block, otherwise return nil.  With optional prefix
 949 argument RE-RUN the source-code block is evaluated even if
 950 results already exist."
 951   (interactive "P")
 952   (let ((info (org-babel-get-src-block-info 'light)))
 953     (when info
 954       (save-excursion
 955         ;; go to the results, if there aren't any then run the block
 956         (goto-char (or (and (not re-run) (org-babel-where-is-src-block-result))
 957                        (progn (org-babel-execute-src-block)
 958                               (org-babel-where-is-src-block-result))))
 959         (end-of-line 1)
 960         (while (looking-at "[\n\r\t\f ]") (forward-char 1))
 961         ;; open the results
 962         (if (looking-at org-bracket-link-regexp)
 963             ;; file results
 964             (org-open-at-point)
 965           (let ((r (org-babel-format-result
 966                     (org-babel-read-result) (cdr (assoc :sep (nth 2 info))))))
 967             (pop-to-buffer (get-buffer-create "*Org-Babel Results*"))
 968             (delete-region (point-min) (point-max))
 969             (insert r)))
 970         t))))
 971
 972 ;;;###autoload
 973 (defmacro org-babel-map-src-blocks (file &rest body)
 974   "Evaluate BODY forms on each source-block in FILE.
 975 If FILE is nil evaluate BODY forms on source blocks in current
 976 buffer.  During evaluation of BODY the following local variables
 977 are set relative to the currently matched code block.
 978
 979 full-block ------- string holding the entirety of the code block
 980 beg-block -------- point at the beginning of the code block
 981 end-block -------- point at the end of the matched code block
 982 lang ------------- string holding the language of the code block
 983 beg-lang --------- point at the beginning of the lang
 984 end-lang --------- point at the end of the lang
 985 switches --------- string holding the switches
 986 beg-switches ----- point at the beginning of the switches
 987 end-switches ----- point at the end of the switches
 988 header-args ------ string holding the header-args
 989 beg-header-args -- point at the beginning of the header-args
 990 end-header-args -- point at the end of the header-args
 991 body ------------- string holding the body of the code block
 992 beg-body --------- point at the beginning of the body
 993 end-body --------- point at the end of the body"
 994   (declare (indent 1))
 995   (let ((tempvar (make-symbol "file")))
 996     `(let* ((,tempvar ,file)
 997             (visited-p (or (null ,tempvar)
 998                            (get-file-buffer (expand-file-name ,tempvar))))
 999             (point (point)) to-be-removed)
1000        (save-window-excursion
1001          (when ,tempvar (find-file ,tempvar))
1002          (setq to-be-removed (current-buffer))
1003          (goto-char (point-min))
1004          (while (re-search-forward org-babel-src-block-regexp nil t)
1005            (when (org-babel-active-location-p)
1006              (goto-char (match-beginning 0))
1007              (let ((full-block (match-string 0))
1008                    (beg-block (match-beginning 0))
1009                    (end-block (match-end 0))
1010                    (lang (match-string 2))
1011                    (beg-lang (match-beginning 2))
1012                    (end-lang (match-end 2))
1013                    (switches (match-string 3))
1014                    (beg-switches (match-beginning 3))
1015                    (end-switches (match-end 3))
1016                    (header-args (match-string 4))
1017                    (beg-header-args (match-beginning 4))
1018                    (end-header-args (match-end 4))
1019                    (body (match-string 5))
1020                    (beg-body (match-beginning 5))
1021                    (end-body (match-end 5)))
1022                ,@body
1023                (goto-char end-block)))))
1024        (unless visited-p (kill-buffer to-be-removed))
1025        (goto-char point))))
1026 (def-edebug-spec org-babel-map-src-blocks (form body))
1027
1028 ;;;###autoload
1029 (defmacro org-babel-map-inline-src-blocks (file &rest body)
1030   "Evaluate BODY forms on each inline source-block in FILE.
1031 If FILE is nil evaluate BODY forms on source blocks in current
1032 buffer."
1033   (declare (indent 1))
1034   (let ((tempvar (make-symbol "file")))
1035     `(let* ((,tempvar ,file)
1036             (visited-p (or (null ,tempvar)
1037                            (get-file-buffer (expand-file-name ,tempvar))))
1038             (point (point)) to-be-removed)
1039        (save-window-excursion
1040          (when ,tempvar (find-file ,tempvar))
1041          (setq to-be-removed (current-buffer))
1042          (goto-char (point-min))
1043          (while (re-search-forward org-babel-inline-src-block-regexp nil t)
1044            (when (org-babel-active-location-p)
1045              (goto-char (match-beginning 1))
1046              (save-match-data ,@body))
1047            (goto-char (match-end 0))))
1048        (unless visited-p (kill-buffer to-be-removed))
1049        (goto-char point))))
1050 (def-edebug-spec org-babel-map-inline-src-blocks (form body))
1051
1052 (defvar org-babel-lob-one-liner-regexp)
1053
1054 ;;;###autoload
1055 (defmacro org-babel-map-call-lines (file &rest body)
1056   "Evaluate BODY forms on each call line in FILE.
1057 If FILE is nil evaluate BODY forms on source blocks in current
1058 buffer."
1059   (declare (indent 1))
1060   (let ((tempvar (make-symbol "file")))
1061     `(let* ((,tempvar ,file)
1062             (visited-p (or (null ,tempvar)
1063                            (get-file-buffer (expand-file-name ,tempvar))))
1064             (point (point)) to-be-removed)
1065        (save-window-excursion
1066          (when ,tempvar (find-file ,tempvar))
1067          (setq to-be-removed (current-buffer))
1068          (goto-char (point-min))
1069          (while (re-search-forward org-babel-lob-one-liner-regexp nil t)
1070            (when (org-babel-active-location-p)
1071              (goto-char (match-beginning 1))
1072              (save-match-data ,@body))
1073            (goto-char (match-end 0))))
1074        (unless visited-p (kill-buffer to-be-removed))
1075        (goto-char point))))
1076 (def-edebug-spec org-babel-map-call-lines (form body))
1077
1078 ;;;###autoload
1079 (defmacro org-babel-map-executables (file &rest body)
1080   (declare (indent 1))
1081   (let ((tempvar (make-symbol "file"))
1082         (rx (make-symbol "rx")))
1083     `(let* ((,tempvar ,file)
1084             (,rx (concat "\\(" org-babel-src-block-regexp
1085                          "\\|" org-babel-inline-src-block-regexp
1086                          "\\|" org-babel-lob-one-liner-regexp "\\)"))
1087             (visited-p (or (null ,tempvar)
1088                            (get-file-buffer (expand-file-name ,tempvar))))
1089             (point (point)) to-be-removed)
1090        (save-window-excursion
1091          (when ,tempvar (find-file ,tempvar))
1092          (setq to-be-removed (current-buffer))
1093          (goto-char (point-min))
1094          (while (re-search-forward ,rx nil t)
1095            (when (org-babel-active-location-p)
1096              (goto-char (match-beginning 1))
1097              (when (looking-at org-babel-inline-src-block-regexp)
1098                (forward-char 1))
1099              (save-match-data ,@body))
1100            (goto-char (match-end 0))))
1101        (unless visited-p (kill-buffer to-be-removed))
1102        (goto-char point))))
1103 (def-edebug-spec org-babel-map-executables (form body))
1104
1105 ;;;###autoload
1106 (defun org-babel-execute-buffer (&optional arg)
1107   "Execute source code blocks in a buffer.
1108 Call `org-babel-execute-src-block' on every source block in
1109 the current buffer."
1110   (interactive "P")
1111   (org-babel-eval-wipe-error-buffer)
1112   (org-save-outline-visibility t
1113     (org-babel-map-executables nil
1114       (if (looking-at org-babel-lob-one-liner-regexp)
1115           (org-babel-lob-execute-maybe)
1116         (org-babel-execute-src-block arg)))))
1117
1118 ;;;###autoload
1119 (defun org-babel-execute-subtree (&optional arg)
1120   "Execute source code blocks in a subtree.
1121 Call `org-babel-execute-src-block' on every source block in
1122 the current subtree."
1123   (interactive "P")
1124   (save-restriction
1125     (save-excursion
1126       (org-narrow-to-subtree)
1127       (org-babel-execute-buffer arg)
1128       (widen))))
1129
1130 ;;;###autoload
1131 (defun org-babel-sha1-hash (&optional info)
1132   "Generate an sha1 hash based on the value of info."
1133   (interactive)
1134   (let ((print-level nil)
1135         (info (or info (org-babel-get-src-block-info))))
1136     (setf (nth 2 info)
1137           (sort (copy-sequence (nth 2 info))
1138                 (lambda (a b) (string< (car a) (car b)))))
1139     (let* ((rm (lambda (lst)
1140                  (dolist (p '("replace" "silent" "none"
1141                               "append" "prepend"))
1142                    (setq lst (remove p lst)))
1143                  lst))
1144            (norm (lambda (arg)
1145                    (let ((v (if (and (listp (cdr arg)) (null (cddr arg)))
1146                                 (copy-sequence (cdr arg))
1147                               (cdr arg))))
1148                      (when (and v (not (and (sequencep v)
1149                                             (not (consp v))
1150                                             (= (length v) 0))))
1151                        (cond
1152                         ((and (listp v) ; lists are sorted
1153                               (member (car arg) '(:result-params)))
1154                          (sort (funcall rm v) #'string<))
1155                         ((and (stringp v) ; strings are sorted
1156                               (member (car arg) '(:results :exports)))
1157                          (mapconcat #'identity (sort (funcall rm (split-string v))
1158                                                      #'string<) " "))
1159                         (t v)))))))
1160       ((lambda (hash)
1161          (when (org-called-interactively-p 'interactive) (message hash)) hash)
1162        (let ((it (format "%s-%s"
1163                          (mapconcat
1164                           #'identity
1165                           (delq nil (mapcar (lambda (arg)
1166                                               (let ((normalized (funcall norm arg)))
1167                                                 (when normalized
1168                                                   (format "%S" normalized))))
1169                                             (nth 2 info))) ":")
1170                          (nth 1 info))))
1171          (sha1 it))))))
1172
1173 (defun org-babel-current-result-hash ()
1174   "Return the current in-buffer hash."
1175   (org-babel-where-is-src-block-result)
1176   (org-no-properties (match-string 5)))
1177
1178 (defun org-babel-set-current-result-hash (hash)
1179   "Set the current in-buffer hash to HASH."
1180   (org-babel-where-is-src-block-result)
1181   (save-excursion (goto-char (match-beginning 5))
1182                   (mapc #'delete-overlay (overlays-at (point)))
1183                   (forward-char org-babel-hash-show)
1184                   (mapc #'delete-overlay (overlays-at (point)))
1185                   (replace-match hash nil nil nil 5)
1186                   (goto-char (point-at-bol))
1187                   (org-babel-hide-hash)))
1188
1189 (defun org-babel-hide-hash ()
1190   "Hide the hash in the current results line.
1191 Only the initial `org-babel-hash-show' characters of the hash
1192 will remain visible."
1193   (add-to-invisibility-spec '(org-babel-hide-hash . t))
1194   (save-excursion
1195     (when (and (re-search-forward org-babel-result-regexp nil t)
1196                (match-string 5))
1197       (let* ((start (match-beginning 5))
1198              (hide-start (+ org-babel-hash-show start))
1199              (end (match-end 5))
1200              (hash (match-string 5))
1201              ov1 ov2)
1202         (setq ov1 (make-overlay start hide-start))
1203         (setq ov2 (make-overlay hide-start end))
1204         (overlay-put ov2 'invisible 'org-babel-hide-hash)
1205         (overlay-put ov1 'babel-hash hash)))))
1206
1207 (defun org-babel-hide-all-hashes ()
1208   "Hide the hash in the current buffer.
1209 Only the initial `org-babel-hash-show' characters of each hash
1210 will remain visible.  This function should be called as part of
1211 the `org-mode-hook'."
1212   (save-excursion
1213     (while (and (not org-babel-hash-show-time)
1214                 (re-search-forward org-babel-result-regexp nil t))
1215       (goto-char (match-beginning 0))
1216       (org-babel-hide-hash)
1217       (goto-char (match-end 0)))))
1218 (add-hook 'org-mode-hook 'org-babel-hide-all-hashes)
1219
1220 (defun org-babel-hash-at-point (&optional point)
1221   "Return the value of the hash at POINT.
1222 The hash is also added as the last element of the kill ring.
1223 This can be called with C-c C-c."
1224   (interactive)
1225   (let ((hash (car (delq nil (mapcar
1226                               (lambda (ol) (overlay-get ol 'babel-hash))
1227                               (overlays-at (or point (point))))))))
1228     (when hash (kill-new hash) (message hash))))
1229 (add-hook 'org-ctrl-c-ctrl-c-hook 'org-babel-hash-at-point)
1230
1231 (defun org-babel-result-hide-spec ()
1232   "Hide portions of results lines.
1233 Add `org-babel-hide-result' as an invisibility spec for hiding
1234 portions of results lines."
1235   (add-to-invisibility-spec '(org-babel-hide-result . t)))
1236 (add-hook 'org-mode-hook 'org-babel-result-hide-spec)
1237
1238 (defvar org-babel-hide-result-overlays nil
1239   "Overlays hiding results.")
1240
1241 (defun org-babel-result-hide-all ()
1242   "Fold all results in the current buffer."
1243   (interactive)
1244   (org-babel-show-result-all)
1245   (save-excursion
1246     (while (re-search-forward org-babel-result-regexp nil t)
1247       (save-excursion (goto-char (match-beginning 0))
1248                       (org-babel-hide-result-toggle-maybe)))))
1249
1250 (defun org-babel-show-result-all ()
1251   "Unfold all results in the current buffer."
1252   (mapc 'delete-overlay org-babel-hide-result-overlays)
1253   (setq org-babel-hide-result-overlays nil))
1254
1255 ;;;###autoload
1256 (defun org-babel-hide-result-toggle-maybe ()
1257   "Toggle visibility of result at point."
1258   (interactive)
1259   (let ((case-fold-search t))
1260     (if (save-excursion
1261           (beginning-of-line 1)
1262           (looking-at org-babel-result-regexp))
1263         (progn (org-babel-hide-result-toggle)
1264                t) ;; to signal that we took action
1265       nil))) ;; to signal that we did not
1266
1267 (defun org-babel-hide-result-toggle (&optional force)
1268   "Toggle the visibility of the current result."
1269   (interactive)
1270   (save-excursion
1271     (beginning-of-line)
1272     (if (re-search-forward org-babel-result-regexp nil t)
1273         (let ((start (progn (beginning-of-line 2) (- (point) 1)))
1274               (end (progn
1275                      (while (looking-at org-babel-multi-line-header-regexp)
1276                        (forward-line 1))
1277                      (goto-char (- (org-babel-result-end) 1)) (point)))
1278               ov)
1279           (if (memq t (mapcar (lambda (overlay)
1280                                 (eq (overlay-get overlay 'invisible)
1281                                     'org-babel-hide-result))
1282                               (overlays-at start)))
1283               (if (or (not force) (eq force 'off))
1284                   (mapc (lambda (ov)
1285                           (when (member ov org-babel-hide-result-overlays)
1286                             (setq org-babel-hide-result-overlays
1287                                   (delq ov org-babel-hide-result-overlays)))
1288                           (when (eq (overlay-get ov 'invisible)
1289                                     'org-babel-hide-result)
1290                             (delete-overlay ov)))
1291                         (overlays-at start)))
1292             (setq ov (make-overlay start end))
1293             (overlay-put ov 'invisible 'org-babel-hide-result)
1294             ;; make the block accessible to isearch
1295             (overlay-put
1296              ov 'isearch-open-invisible
1297              (lambda (ov)
1298                (when (member ov org-babel-hide-result-overlays)
1299                  (setq org-babel-hide-result-overlays
1300                        (delq ov org-babel-hide-result-overlays)))
1301                (when (eq (overlay-get ov 'invisible)
1302                          'org-babel-hide-result)
1303                  (delete-overlay ov))))
1304             (push ov org-babel-hide-result-overlays)))
1305       (error "Not looking at a result line"))))
1306
1307 ;; org-tab-after-check-for-cycling-hook
1308 (add-hook 'org-tab-first-hook 'org-babel-hide-result-toggle-maybe)
1309 ;; Remove overlays when changing major mode
1310 (add-hook 'org-mode-hook
1311           (lambda () (org-add-hook 'change-major-mode-hook
1312                                    'org-babel-show-result-all 'append 'local)))
1313
1314 (defvar org-file-properties)
1315 (defun org-babel-params-from-properties (&optional lang)
1316   "Retrieve parameters specified as properties.
1317 Return a list of association lists of source block params
1318 specified in the properties of the current outline entry."
1319   (save-match-data
1320     (list
1321      ;; DEPRECATED header arguments specified as separate property at
1322      ;; point of definition
1323      (let (val sym)
1324        (org-babel-parse-multiple-vars
1325         (delq nil
1326               (mapcar
1327                (lambda (header-arg)
1328                  (and (setq val (org-entry-get (point) header-arg t))
1329                       (cons (intern (concat ":" header-arg))
1330                             (org-babel-read val))))
1331                (mapcar
1332                 #'symbol-name
1333                 (mapcar
1334                  #'car
1335                  (org-babel-combine-header-arg-lists
1336                   org-babel-common-header-args-w-values
1337                   (progn
1338                     (setq sym (intern (concat "org-babel-header-args:" lang)))
1339                     (and (boundp sym) (eval sym))))))))))
1340      ;; header arguments specified with the header-args property at
1341      ;; point of call
1342      (org-babel-parse-header-arguments
1343       (org-entry-get org-babel-current-src-block-location
1344                      "header-args" 'inherit))
1345      (when lang ;; language-specific header arguments at point of call
1346          (org-babel-parse-header-arguments
1347           (org-entry-get org-babel-current-src-block-location
1348                          (concat "header-args:" lang) 'inherit))))))
1349
1350 (defvar org-src-preserve-indentation)
1351 (defun org-babel-parse-src-block-match ()
1352   "Parse the results from a match of the `org-babel-src-block-regexp'."
1353   (let* ((block-indentation (length (match-string 1)))
1354          (lang (org-no-properties (match-string 2)))
1355          (lang-headers (intern (concat "org-babel-default-header-args:" lang)))
1356          (switches (match-string 3))
1357          (body (org-no-properties
1358                 (let* ((body (match-string 5))
1359                        (sub-length (- (length body) 1)))
1360                   (if (and (> sub-length 0)
1361                            (string= "\n" (substring body sub-length)))
1362                       (substring body 0 sub-length)
1363                     (or body "")))))
1364          (preserve-indentation (or org-src-preserve-indentation
1365                                    (save-match-data
1366                                      (string-match "-i\\>" switches)))))
1367     (list lang
1368           ;; get block body less properties, protective commas, and indentation
1369           (with-temp-buffer
1370             (save-match-data
1371               (insert (org-unescape-code-in-string body))
1372               (unless preserve-indentation (org-do-remove-indentation))
1373               (buffer-string)))
1374           (apply #'org-babel-merge-params
1375                  org-babel-default-header-args
1376                  (when (boundp lang-headers) (eval lang-headers))
1377                  (append
1378                   (org-babel-params-from-properties lang)
1379                   (list (org-babel-parse-header-arguments
1380                          (org-no-properties (or (match-string 4) ""))))))
1381           switches
1382           block-indentation)))
1383
1384 (defun org-babel-parse-inline-src-block-match ()
1385   "Parse the results from a match of the `org-babel-inline-src-block-regexp'."
1386   (let* ((lang (org-no-properties (match-string 2)))
1387          (lang-headers (intern (concat "org-babel-default-header-args:" lang))))
1388     (list lang
1389           (org-unescape-code-in-string (org-no-properties (match-string 5)))
1390           (apply #'org-babel-merge-params
1391                  org-babel-default-inline-header-args
1392                  (if (boundp lang-headers) (eval lang-headers) nil)
1393                  (append
1394                   (org-babel-params-from-properties lang)
1395                   (list (org-babel-parse-header-arguments
1396                          (org-no-properties (or (match-string 4) "")))))))))
1397
1398 (defun org-babel-balanced-split (string alts)
1399   "Split STRING on instances of ALTS.
1400 ALTS is a cons of two character options where each option may be
1401 either the numeric code of a single character or a list of
1402 character alternatives.  For example to split on balanced
1403 instances of \"[ \t]:\" set ALTS to '((32 9) . 58)."
1404   (let* ((matches (lambda (ch spec) (if (listp spec) (member ch spec) (equal spec ch))))
1405          (matched (lambda (ch last)
1406                     (if (consp alts)
1407                         (and (funcall matches ch (cdr alts))
1408                              (funcall matches last (car alts)))
1409                       (funcall matches ch alts))))
1410          (balance 0) (last 0)
1411          quote partial lst)
1412     (mapc (lambda (ch)  ; split on [], (), "" balanced instances of [ \t]:
1413             (setq balance (+ balance
1414                              (cond ((or (equal 91 ch) (equal 40 ch)) 1)
1415                                    ((or (equal 93 ch) (equal 41 ch)) -1)
1416                                    (t 0))))
1417             (when (and (equal 34 ch) (not (equal 92 last)))
1418               (setq quote (not quote)))
1419             (setq partial (cons ch partial))
1420             (when (and (= balance 0) (not quote) (funcall matched ch last))
1421               (setq lst (cons (apply #'string (nreverse
1422                                                (if (consp alts)
1423                                                    (cddr partial)
1424                                                  (cdr partial))))
1425                               lst))
1426               (setq partial nil))
1427             (setq last ch))
1428           (string-to-list string))
1429     (nreverse (cons (apply #'string (nreverse partial)) lst))))
1430
1431 (defun org-babel-join-splits-near-ch (ch list)
1432   "Join splits where \"=\" is on either end of the split."
1433   (let ((last= (lambda (str) (= ch (aref str (1- (length str))))))
1434         (first= (lambda (str) (= ch (aref str 0)))))
1435     (reverse
1436      (org-reduce (lambda (acc el)
1437                    (let ((head (car acc)))
1438                      (if (and head (or (funcall last= head) (funcall first= el)))
1439                          (cons (concat head el) (cdr acc))
1440                        (cons el acc))))
1441                  list :initial-value nil))))
1442
1443 (defun org-babel-parse-header-arguments (arg-string)
1444   "Parse a string of header arguments returning an alist."
1445   (when (> (length arg-string) 0)
1446     (org-babel-parse-multiple-vars
1447      (delq nil
1448            (mapcar
1449             (lambda (arg)
1450               (if (string-match
1451                    "\\([^ \f\t\n\r\v]+\\)[ \f\t\n\r\v]+\\([^ \f\t\n\r\v]+.*\\)"
1452                    arg)
1453                   (cons (intern (match-string 1 arg))
1454                         (org-babel-read (org-babel-chomp (match-string 2 arg))))
1455                 (cons (intern (org-babel-chomp arg)) nil)))
1456             ((lambda (raw)
1457                (cons (car raw) (mapcar (lambda (r) (concat ":" r)) (cdr raw))))
1458              (org-babel-balanced-split arg-string '((32 9) . 58))))))))
1459
1460 (defun org-babel-parse-multiple-vars (header-arguments)
1461   "Expand multiple variable assignments behind a single :var keyword.
1462
1463 This allows expression of multiple variables with one :var as
1464 shown below.
1465
1466 #+PROPERTY: var foo=1, bar=2"
1467   (let (results)
1468     (mapc (lambda (pair)
1469             (if (eq (car pair) :var)
1470                 (mapcar (lambda (v) (push (cons :var (org-babel-trim v)) results))
1471                         (org-babel-join-splits-near-ch
1472                          61 (org-babel-balanced-split (cdr pair) 32)))
1473               (push pair results)))
1474           header-arguments)
1475     (nreverse results)))
1476
1477 (defun org-babel-process-params (params)
1478   "Expand variables in PARAMS and add summary parameters."
1479   (let* ((processed-vars (mapcar (lambda (el)
1480                                    (if (consp (cdr el))
1481                                        (cdr el)
1482                                      (org-babel-ref-parse (cdr el))))
1483                                  (org-babel-get-header params :var)))
1484          (vars-and-names (if (and (assoc :colname-names params)
1485                                   (assoc :rowname-names params))
1486                              (list processed-vars)
1487                            (org-babel-disassemble-tables
1488                             processed-vars
1489                             (cdr (assoc :hlines params))
1490                             (cdr (assoc :colnames params))
1491                             (cdr (assoc :rownames params)))))
1492          (raw-result (or (cdr (assoc :results params)) ""))
1493          (result-params (append
1494                          (split-string (if (stringp raw-result)
1495                                            raw-result
1496                                          (eval raw-result)))
1497                          (cdr (assoc :result-params params)))))
1498     (append
1499      (mapcar (lambda (var) (cons :var var)) (car vars-and-names))
1500      (list
1501       (cons :colname-names (or (cdr (assoc :colname-names params))
1502                                (cadr  vars-and-names)))
1503       (cons :rowname-names (or (cdr (assoc :rowname-names params))
1504                                (caddr vars-and-names)))
1505       (cons :result-params result-params)
1506       (cons :result-type  (cond ((member "output" result-params) 'output)
1507                                 ((member "value" result-params) 'value)
1508                                 (t 'value))))
1509      (org-babel-get-header params :var 'other))))
1510
1511 ;; row and column names
1512 (defun org-babel-del-hlines (table)
1513   "Remove all 'hlines from TABLE."
1514   (remove 'hline table))
1515
1516 (defun org-babel-get-colnames (table)
1517   "Return the column names of TABLE.
1518 Return a cons cell, the `car' of which contains the TABLE less
1519 colnames, and the `cdr' of which contains a list of the column
1520 names."
1521   (if (equal 'hline (nth 1 table))
1522       (cons (cddr table) (car table))
1523     (cons (cdr table) (car table))))
1524
1525 (defun org-babel-get-rownames (table)
1526   "Return the row names of TABLE.
1527 Return a cons cell, the `car' of which contains the TABLE less
1528 rownames, and the `cdr' of which contains a list of the rownames.
1529 Note: this function removes any hlines in TABLE."
1530   (let* ((table (org-babel-del-hlines table))
1531          (rownames (funcall (lambda ()
1532                               (let ((tp table))
1533                                 (mapcar
1534                                  (lambda (row)
1535                                    (prog1
1536                                        (pop (car tp))
1537                                      (setq tp (cdr tp))))
1538                                  table))))))
1539     (cons table rownames)))
1540
1541 (defun org-babel-put-colnames (table colnames)
1542   "Add COLNAMES to TABLE if they exist."
1543   (if colnames (apply 'list colnames 'hline table) table))
1544
1545 (defun org-babel-put-rownames (table rownames)
1546   "Add ROWNAMES to TABLE if they exist."
1547   (if rownames
1548       (mapcar (lambda (row)
1549                 (if (listp row)
1550                     (cons (or (pop rownames) "") row)
1551                   row)) table)
1552     table))
1553
1554 (defun org-babel-pick-name (names selector)
1555   "Select one out of an alist of row or column names.
1556 SELECTOR can be either a list of names in which case those names
1557 will be returned directly, or an index into the list NAMES in
1558 which case the indexed names will be return."
1559   (if (listp selector)
1560       selector
1561     (when names
1562       (if (and selector (symbolp selector) (not (equal t selector)))
1563           (cdr (assoc selector names))
1564         (if (integerp selector)
1565             (nth (- selector 1) names)
1566           (cdr (car (last names))))))))
1567
1568 (defun org-babel-disassemble-tables (vars hlines colnames rownames)
1569   "Parse tables for further processing.
1570 Process the variables in VARS according to the HLINES,
1571 ROWNAMES and COLNAMES header arguments.  Return a list consisting
1572 of the vars, cnames and rnames."
1573   (let (cnames rnames)
1574     (list
1575      (mapcar
1576       (lambda (var)
1577         (when (listp (cdr var))
1578           (when (and (not (equal colnames "no"))
1579                      (or colnames (and (equal (nth 1 (cdr var)) 'hline)
1580                                        (not (member 'hline (cddr (cdr var)))))))
1581             (let ((both (org-babel-get-colnames (cdr var))))
1582               (setq cnames (cons (cons (car var) (cdr both))
1583                                  cnames))
1584               (setq var (cons (car var) (car both)))))
1585           (when (and rownames (not (equal rownames "no")))
1586             (let ((both (org-babel-get-rownames (cdr var))))
1587               (setq rnames (cons (cons (car var) (cdr both))
1588                                  rnames))
1589               (setq var (cons (car var) (car both)))))
1590           (when (and hlines (not (equal hlines "yes")))
1591             (setq var (cons (car var) (org-babel-del-hlines (cdr var))))))
1592         var)
1593       vars)
1594      (reverse cnames) (reverse rnames))))
1595
1596 (defun org-babel-reassemble-table (table colnames rownames)
1597   "Add column and row names to a table.
1598 Given a TABLE and set of COLNAMES and ROWNAMES add the names
1599 to the table for reinsertion to org-mode."
1600   (if (listp table)
1601       ((lambda (table)
1602          (if (and colnames (listp (car table)) (= (length (car table))
1603                                                   (length colnames)))
1604              (org-babel-put-colnames table colnames) table))
1605        (if (and rownames (= (length table) (length rownames)))
1606            (org-babel-put-rownames table rownames) table))
1607     table))
1608
1609 (defun org-babel-where-is-src-block-head ()
1610   "Find where the current source block begins.
1611 Return the point at the beginning of the current source
1612 block.  Specifically at the beginning of the #+BEGIN_SRC line.
1613 If the point is not on a source block then return nil."
1614   (let ((initial (point)) (case-fold-search t) top bottom)
1615     (or
1616      (save-excursion ;; on a source name line or a #+header line
1617        (beginning-of-line 1)
1618        (and (or (looking-at org-babel-src-name-regexp)
1619                 (looking-at org-babel-multi-line-header-regexp))
1620             (progn
1621               (while (and (forward-line 1)
1622                           (or (looking-at org-babel-src-name-regexp)
1623                               (looking-at org-babel-multi-line-header-regexp))))
1624               (looking-at org-babel-src-block-regexp))
1625             (point)))
1626      (save-excursion ;; on a #+begin_src line
1627        (beginning-of-line 1)
1628        (and (looking-at org-babel-src-block-regexp)
1629             (point)))
1630      (save-excursion ;; inside a src block
1631        (and
1632         (re-search-backward "^[ \t]*#\\+begin_src" nil t) (setq top (point))
1633         (re-search-forward "^[ \t]*#\\+end_src" nil t) (setq bottom (point))
1634         (< top initial) (< initial bottom)
1635         (progn (goto-char top) (beginning-of-line 1)
1636                (looking-at org-babel-src-block-regexp))
1637         (point-marker))))))
1638
1639 ;;;###autoload
1640 (defun org-babel-goto-src-block-head ()
1641   "Go to the beginning of the current code block."
1642   (interactive)
1643   ((lambda (head)
1644      (if head (goto-char head) (error "Not currently in a code block")))
1645    (org-babel-where-is-src-block-head)))
1646
1647 ;;;###autoload
1648 (defun org-babel-goto-named-src-block (name)
1649   "Go to a named source-code block."
1650   (interactive
1651    (let ((completion-ignore-case t)
1652          (case-fold-search t)
1653          (under-point (thing-at-point 'line)))
1654      (list (org-icompleting-read
1655             "source-block name: " (org-babel-src-block-names) nil t
1656             (cond
1657              ;; noweb
1658              ((string-match (org-babel-noweb-wrap) under-point)
1659               (let ((block-name (match-string 1 under-point)))
1660                 (string-match "[^(]*" block-name)
1661                 (match-string 0 block-name)))
1662              ;; #+call:
1663              ((string-match org-babel-lob-one-liner-regexp under-point)
1664               (let ((source-info (car (org-babel-lob-get-info))))
1665                 (if (string-match "^\\([^\\[]+?\\)\\(\\[.*\\]\\)?(" source-info)
1666                     (let ((source-name (match-string 1 source-info)))
1667                       source-name))))
1668              ;; #+results:
1669              ((string-match (concat "#\\+" org-babel-results-keyword
1670                                     "\\:\s+\\([^\\(]*\\)") under-point)
1671               (match-string 1 under-point))
1672              ;; symbol-at-point
1673              ((and (thing-at-point 'symbol))
1674               (org-babel-find-named-block (thing-at-point 'symbol))
1675               (thing-at-point 'symbol))
1676              (""))))))
1677   (let ((point (org-babel-find-named-block name)))
1678     (if point
1679         ;; taken from `org-open-at-point'
1680         (progn (org-mark-ring-push) (goto-char point) (org-show-context))
1681       (message "source-code block '%s' not found in this buffer" name))))
1682
1683 (defun org-babel-find-named-block (name)
1684   "Find a named source-code block.
1685 Return the location of the source block identified by source
1686 NAME, or nil if no such block exists.  Set match data according to
1687 org-babel-named-src-block-regexp."
1688   (save-excursion
1689     (let ((case-fold-search t)
1690           (regexp (org-babel-named-src-block-regexp-for-name name)) msg)
1691       (goto-char (point-min))
1692       (when (or (re-search-forward regexp nil t)
1693                 (re-search-backward regexp nil t))
1694         (match-beginning 0)))))
1695
1696 (defun org-babel-src-block-names (&optional file)
1697   "Returns the names of source blocks in FILE or the current buffer."
1698   (save-excursion
1699     (when file (find-file file)) (goto-char (point-min))
1700     (let ((case-fold-search t) names)
1701       (while (re-search-forward org-babel-src-name-w-name-regexp nil t)
1702         (setq names (cons (match-string 3) names)))
1703       names)))
1704
1705 ;;;###autoload
1706 (defun org-babel-goto-named-result (name)
1707   "Go to a named result."
1708   (interactive
1709    (let ((completion-ignore-case t))
1710      (list (org-icompleting-read "source-block name: "
1711                                  (org-babel-result-names) nil t))))
1712   (let ((point (org-babel-find-named-result name)))
1713     (if point
1714         ;; taken from `org-open-at-point'
1715         (progn (goto-char point) (org-show-context))
1716       (message "result '%s' not found in this buffer" name))))
1717
1718 (defun org-babel-find-named-result (name &optional point)
1719   "Find a named result.
1720 Return the location of the result named NAME in the current
1721 buffer or nil if no such result exists."
1722   (save-excursion
1723     (let ((case-fold-search t))
1724       (goto-char (or point (point-min)))
1725       (catch 'is-a-code-block
1726         (when (re-search-forward
1727                (concat org-babel-result-regexp
1728                        "[ \t]" (regexp-quote name) "[ \t]*[\n\f\v\r]") nil t)
1729           (when (and (string= "name" (downcase (match-string 1)))
1730                      (or (beginning-of-line 1)
1731                          (looking-at org-babel-src-block-regexp)
1732                          (looking-at org-babel-multi-line-header-regexp)
1733                          (looking-at org-babel-lob-one-liner-regexp)))
1734             (throw 'is-a-code-block (org-babel-find-named-result name (point))))
1735           (beginning-of-line 0) (point))))))
1736
1737 (defun org-babel-result-names (&optional file)
1738   "Returns the names of results in FILE or the current buffer."
1739   (save-excursion
1740     (when file (find-file file)) (goto-char (point-min))
1741     (let ((case-fold-search t) names)
1742       (while (re-search-forward org-babel-result-w-name-regexp nil t)
1743         (setq names (cons (match-string 4) names)))
1744       names)))
1745
1746 ;;;###autoload
1747 (defun org-babel-next-src-block (&optional arg)
1748   "Jump to the next source block.
1749 With optional prefix argument ARG, jump forward ARG many source blocks."
1750   (interactive "p")
1751   (org-next-block arg nil org-babel-src-block-regexp))
1752
1753 ;;;###autoload
1754 (defun org-babel-previous-src-block (&optional arg)
1755   "Jump to the previous source block.
1756 With optional prefix argument ARG, jump backward ARG many source blocks."
1757   (interactive "p")
1758   (org-previous-block arg org-babel-src-block-regexp))
1759
1760 (defvar org-babel-load-languages)
1761
1762 ;;;###autoload
1763 (defun org-babel-mark-block ()
1764   "Mark current src block."
1765   (interactive)
1766   ((lambda (head)
1767      (when head
1768        (save-excursion
1769          (goto-char head)
1770          (looking-at org-babel-src-block-regexp))
1771        (push-mark (match-end 5) nil t)
1772        (goto-char (match-beginning 5))))
1773    (org-babel-where-is-src-block-head)))
1774
1775 (defun org-babel-demarcate-block (&optional arg)
1776   "Wrap or split the code in the region or on the point.
1777 When called from inside of a code block the current block is
1778 split.  When called from outside of a code block a new code block
1779 is created.  In both cases if the region is demarcated and if the
1780 region is not active then the point is demarcated."
1781   (interactive "P")
1782   (let ((info (org-babel-get-src-block-info 'light))
1783         (headers (progn (org-babel-where-is-src-block-head)
1784                         (match-string 4)))
1785         (stars (concat (make-string (or (org-current-level) 1) ?*) " ")))
1786     (if info
1787         (mapc
1788          (lambda (place)
1789            (save-excursion
1790              (goto-char place)
1791              (let ((lang (nth 0 info))
1792                    (indent (make-string (nth 5 info) ? )))
1793                (when (string-match "^[[:space:]]*$"
1794                                    (buffer-substring (point-at-bol)
1795                                                      (point-at-eol)))
1796                  (delete-region (point-at-bol) (point-at-eol)))
1797                (insert (concat
1798                         (if (looking-at "^") "" "\n")
1799                         indent "#+end_src\n"
1800                         (if arg stars indent) "\n"
1801                         indent "#+begin_src " lang
1802                         (if (> (length headers) 1)
1803                             (concat " " headers) headers)
1804                         (if (looking-at "[\n\r]")
1805                             ""
1806                           (concat "\n" (make-string (current-column) ? )))))))
1807            (move-end-of-line 2))
1808          (sort (if (org-region-active-p) (list (mark) (point)) (list (point))) #'>))
1809       (let ((start (point))
1810             (lang (org-icompleting-read
1811                    "Lang: "
1812                    (mapcar #'symbol-name
1813                            (delete-dups
1814                             (append (mapcar #'car org-babel-load-languages)
1815                                     (mapcar (lambda (el) (intern (car el)))
1816                                             org-src-lang-modes))))))
1817             (body (delete-and-extract-region
1818                    (if (org-region-active-p) (mark) (point)) (point))))
1819         (insert (concat (if (looking-at "^") "" "\n")
1820                         (if arg (concat stars "\n") "")
1821                         "#+begin_src " lang "\n"
1822                         body
1823                         (if (or (= (length body) 0)
1824                                 (string-match "[\r\n]$" body)) "" "\n")
1825                         "#+end_src\n"))
1826         (goto-char start) (move-end-of-line 1)))))
1827
1828 (defvar org-babel-lob-one-liner-regexp)
1829 (defun org-babel-where-is-src-block-result (&optional insert info hash indent)
1830   "Find where the current source block results begin.
1831 Return the point at the beginning of the result of the current
1832 source block.  Specifically at the beginning of the results line.
1833 If no result exists for this block then create a results line
1834 following the source block."
1835   (save-excursion
1836     (let* ((case-fold-search t)
1837            (on-lob-line (save-excursion
1838                           (beginning-of-line 1)
1839                           (looking-at org-babel-lob-one-liner-regexp)))
1840            (inlinep (when (org-babel-get-inline-src-block-matches)
1841                       (match-end 0)))
1842            (name (nth 4 (or info (org-babel-get-src-block-info 'light))))
1843            (head (unless on-lob-line (org-babel-where-is-src-block-head)))
1844            found beg end)
1845       (when head (goto-char head))
1846       (org-with-wide-buffer
1847        (setq
1848         found ;; was there a result (before we potentially insert one)
1849         (or
1850          inlinep
1851          (and
1852           ;; named results:
1853           ;; - return t if it is found, else return nil
1854           ;; - if it does not need to be rebuilt, then don't set end
1855           ;; - if it does need to be rebuilt then do set end
1856           name (setq beg (org-babel-find-named-result name))
1857           (prog1 beg
1858             (when (and hash (not (string= hash (match-string 5))))
1859               (goto-char beg) (setq end beg) ;; beginning of result
1860               (forward-line 1)
1861               (delete-region end (org-babel-result-end)) nil)))
1862          (and
1863           ;; unnamed results:
1864           ;; - return t if it is found, else return nil
1865           ;; - if it is found, and the hash doesn't match, delete and set end
1866           (or on-lob-line (re-search-forward "^[ \t]*#\\+end_src" nil t))
1867           (progn (end-of-line 1)
1868                  (if (eobp) (insert "\n") (forward-char 1))
1869                  (setq end (point))
1870                  (or (and
1871                       (not name)
1872                       (progn ;; unnamed results line already exists
1873                         (catch 'non-comment
1874                           (while (re-search-forward "[^ \f\t\n\r\v]" nil t)
1875                             (beginning-of-line 1)
1876                             (cond
1877                              ((looking-at (concat org-babel-result-regexp "\n"))
1878                               (throw 'non-comment t))
1879                              ((looking-at "^[ \t]*#") (end-of-line 1))
1880                              (t (throw 'non-comment nil))))))
1881                       (let ((this-hash (match-string 5)))
1882                         (prog1 (point)
1883                           ;; must remove and rebuild if hash!=old-hash
1884                           (if (and hash (not (string= hash this-hash)))
1885                               (prog1 nil
1886                                 (forward-line 1)
1887                                 (delete-region
1888                                  end (org-babel-result-end)))
1889                             (setq end nil)))))))))))
1890       (if (not (and insert end)) found
1891         (goto-char end)
1892         (unless beg
1893           (if (looking-at "[\n\r]") (forward-char 1) (insert "\n")))
1894         (insert (concat
1895                  (when (wholenump indent) (make-string indent ? ))
1896                  "#+" org-babel-results-keyword
1897                  (when hash
1898                    (if org-babel-hash-show-time
1899                        (concat
1900                         "["(format-time-string "<%Y-%m-%d %H:%M:%S>")" "hash"]")
1901                      (concat "["hash"]")))
1902                  ":"
1903                  (when name (concat " " name)) "\n"))
1904         (unless beg (insert "\n") (backward-char))
1905         (beginning-of-line 0)
1906         (if hash (org-babel-hide-hash))
1907         (point)))))
1908
1909 (defvar org-block-regexp)
1910 (defun org-babel-read-result ()
1911   "Read the result at `point' into emacs-lisp."
1912   (let ((case-fold-search t) result-string)
1913     (cond
1914      ((org-at-table-p) (org-babel-read-table))
1915      ((org-at-item-p) (org-babel-read-list))
1916      ((looking-at org-bracket-link-regexp) (org-babel-read-link))
1917      ((looking-at org-block-regexp) (org-babel-trim (match-string 4)))
1918      ((or (looking-at "^[ \t]*: ") (looking-at "^[ \t]*:$"))
1919       (setq result-string
1920             (org-babel-trim
1921              (mapconcat (lambda (line)
1922                           (or (and (> (length line) 1)
1923                                    (string-match "^[ \t]*: ?\\(.+\\)" line)
1924                                    (match-string 1 line))
1925                               ""))
1926                         (split-string
1927                          (buffer-substring
1928                           (point) (org-babel-result-end)) "[\r\n]+")
1929                         "\n")))
1930       (or (org-babel-number-p result-string) result-string))
1931      ((looking-at org-babel-result-regexp)
1932       (save-excursion (forward-line 1) (org-babel-read-result))))))
1933
1934 (defun org-babel-read-table ()
1935   "Read the table at `point' into emacs-lisp."
1936   (mapcar (lambda (row)
1937             (if (and (symbolp row) (equal row 'hline)) row
1938               (mapcar (lambda (el) (org-babel-read el 'inhibit-lisp-eval)) row)))
1939           (org-table-to-lisp)))
1940
1941 (defun org-babel-read-list ()
1942   "Read the list at `point' into emacs-lisp."
1943   (mapcar (lambda (el) (org-babel-read el 'inhibit-lisp-eval))
1944           (mapcar #'cadr (cdr (org-list-parse-list)))))
1945
1946 (defvar org-link-types-re)
1947 (defun org-babel-read-link ()
1948   "Read the link at `point' into emacs-lisp.
1949 If the path of the link is a file path it is expanded using
1950 `expand-file-name'."
1951   (let* ((case-fold-search t)
1952          (raw (and (looking-at org-bracket-link-regexp)
1953                    (org-no-properties (match-string 1))))
1954          (type (and (string-match org-link-types-re raw)
1955                     (match-string 1 raw))))
1956     (cond
1957      ((not type) (expand-file-name raw))
1958      ((string= type "file")
1959       (and (string-match "file\\(.*\\):\\(.+\\)" raw)
1960            (expand-file-name (match-string 2 raw))))
1961      (t raw))))
1962
1963 (defun org-babel-format-result (result &optional sep)
1964   "Format RESULT for writing to file."
1965   (let ((echo-res (lambda (r) (if (stringp r) r (format "%S" r)))))
1966     (if (listp result)
1967         ;; table result
1968         (orgtbl-to-generic
1969          result (list :sep (or sep "\t") :fmt echo-res))
1970       ;; scalar result
1971       (funcall echo-res result))))
1972
1973 (defun org-babel-insert-result
1974   (result &optional result-params info hash indent lang)
1975   "Insert RESULT into the current buffer.
1976 By default RESULT is inserted after the end of the
1977 current source block.  With optional argument RESULT-PARAMS
1978 controls insertion of results in the org-mode file.
1979 RESULT-PARAMS can take the following values:
1980
1981 replace - (default option) insert results after the source block
1982           replacing any previously inserted results
1983
1984 silent -- no results are inserted into the Org-mode buffer but
1985           the results are echoed to the minibuffer and are
1986           ingested by Emacs (a potentially time consuming
1987           process)
1988
1989 file ---- the results are interpreted as a file path, and are
1990           inserted into the buffer using the Org-mode file syntax
1991
1992 list ---- the results are interpreted as an Org-mode list.
1993
1994 raw ----- results are added directly to the Org-mode file.  This
1995           is a good option if you code block will output org-mode
1996           formatted text.
1997
1998 drawer -- results are added directly to the Org-mode file as with
1999           \"raw\", but are wrapped in a RESULTS drawer, allowing
2000           them to later be replaced or removed automatically.
2001
2002 org ----- results are added inside of a \"#+BEGIN_SRC org\" block.
2003           They are not comma-escaped when inserted, but Org syntax
2004           here will be discarded when exporting the file.
2005
2006 html ---- results are added inside of a #+BEGIN_HTML block.  This
2007           is a good option if you code block will output html
2008           formatted text.
2009
2010 latex --- results are added inside of a #+BEGIN_LATEX block.
2011           This is a good option if you code block will output
2012           latex formatted text.
2013
2014 code ---- the results are extracted in the syntax of the source
2015           code of the language being evaluated and are added
2016           inside of a #+BEGIN_SRC block with the source-code
2017           language set appropriately.  Note this relies on the
2018           optional LANG argument."
2019   (if (stringp result)
2020       (progn
2021         (setq result (org-no-properties result))
2022         (when (member "file" result-params)
2023           (setq result (org-babel-result-to-file
2024                         result (when (assoc :file-desc (nth 2 info))
2025                                  (or (cdr (assoc :file-desc (nth 2 info)))
2026                                      result))))))
2027     (unless (listp result) (setq result (format "%S" result))))
2028   (if (and result-params (member "silent" result-params))
2029       (progn
2030         (message (replace-regexp-in-string "%" "%%" (format "%S" result)))
2031         result)
2032     (save-excursion
2033       (let* ((inlinep
2034               (save-excursion
2035                 (when (or (org-babel-get-inline-src-block-matches)
2036                           (org-babel-get-lob-one-liner-matches))
2037                   (goto-char (match-end 0))
2038                   (insert (if (listp result) "\n" " "))
2039                   (point))))
2040              (existing-result (unless inlinep
2041                                 (org-babel-where-is-src-block-result
2042                                  t info hash indent)))
2043              (results-switches
2044               (cdr (assoc :results_switches (nth 2 info))))
2045              (visible-beg (copy-marker (point-min)))
2046              (visible-end (copy-marker (point-max)))
2047              ;; When results exist outside of the current visible
2048              ;; region of the buffer, be sure to widen buffer to
2049              ;; update them.
2050              (outside-scope-p (and existing-result
2051                                    (or (> visible-beg existing-result)
2052                                        (<= visible-end existing-result))))
2053              beg end)
2054         (when (and (stringp result)  ; ensure results end in a newline
2055                    (not inlinep)
2056                    (> (length result) 0)
2057                    (not (or (string-equal (substring result -1) "\n")
2058                             (string-equal (substring result -1) "\r"))))
2059           (setq result (concat result "\n")))
2060         (unwind-protect
2061             (progn
2062               (when outside-scope-p (widen))
2063               (if (not existing-result)
2064                   (setq beg (or inlinep (point)))
2065                 (goto-char existing-result)
2066                 (save-excursion
2067                   (re-search-forward "#" nil t)
2068                   (setq indent (- (current-column) 1)))
2069                 (forward-line 1)
2070                 (setq beg (point))
2071                 (cond
2072                  ((member "replace" result-params)
2073                   (delete-region (point) (org-babel-result-end)))
2074                  ((member "append" result-params)
2075                   (goto-char (org-babel-result-end)) (setq beg (point-marker)))
2076                  ((member "prepend" result-params)))) ; already there
2077               (setq results-switches
2078                     (if results-switches (concat " " results-switches) ""))
2079               (let ((wrap (lambda (start finish &optional no-escape)
2080                             (goto-char end) (insert (concat finish "\n"))
2081                             (goto-char beg) (insert (concat start "\n"))
2082                             (unless no-escape
2083                               (org-escape-code-in-region (min (point) end) end))
2084                             (goto-char end) (goto-char (point-at-eol))
2085                             (setq end (point-marker))))
2086                     (proper-list-p (lambda (it) (and (listp it) (null (cdr (last it)))))))
2087                 ;; insert results based on type
2088                 (cond
2089                  ;; do nothing for an empty result
2090                  ((null result))
2091                  ;; insert a list if preferred
2092                  ((member "list" result-params)
2093                   (insert
2094                    (org-babel-trim
2095                     (org-list-to-generic
2096                      (cons 'unordered
2097                            (mapcar
2098                             (lambda (el) (list nil (if (stringp el) el (format "%S" el))))
2099                             (if (listp result) result (split-string result "\n" t))))
2100                      '(:splicep nil :istart "- " :iend "\n")))
2101                    "\n"))
2102                  ;; assume the result is a table if it's not a string
2103                  ((funcall proper-list-p result)
2104                   (goto-char beg)
2105                   (insert (concat (orgtbl-to-orgtbl
2106                                    (if (or (eq 'hline (car result))
2107                                            (and (listp (car result))
2108                                                 (listp (cdr (car result)))))
2109                                        result (list result))
2110                                    '(:fmt (lambda (cell) (format "%s" cell)))) "\n"))
2111                   (goto-char beg) (when (org-at-table-p) (org-table-align)))
2112                  ((and (listp result) (not (funcall proper-list-p result)))
2113                   (insert (format "%s\n" result)))
2114                  ((member "file" result-params)
2115                   (when inlinep (goto-char inlinep))
2116                   (insert result))
2117                  (t (goto-char beg) (insert result)))
2118                 (when (funcall proper-list-p result) (goto-char (org-table-end)))
2119                 (setq end (point-marker))
2120                 ;; possibly wrap result
2121                 (cond
2122                  ((assoc :wrap (nth 2 info))
2123                   (let ((name (or (cdr (assoc :wrap (nth 2 info))) "RESULTS")))
2124                     (funcall wrap (concat "#+BEGIN_" name)
2125                              (concat "#+END_" (car (org-split-string name))))))
2126                  ((member "html" result-params)
2127                   (funcall wrap "#+BEGIN_HTML" "#+END_HTML"))
2128                  ((member "latex" result-params)
2129                   (funcall wrap "#+BEGIN_LaTeX" "#+END_LaTeX"))
2130                  ((member "org" result-params)
2131                   (goto-char beg) (if (org-at-table-p) (org-cycle))
2132                   (funcall wrap "#+BEGIN_SRC org" "#+END_SRC"))
2133                  ((member "code" result-params)
2134                   (funcall wrap (format "#+BEGIN_SRC %s%s" (or lang "none") results-switches)
2135                            "#+END_SRC"))
2136                  ((member "raw" result-params)
2137                   (goto-char beg) (if (org-at-table-p) (org-cycle)))
2138                  ((or (member "drawer" result-params)
2139                       ;; Stay backward compatible with <7.9.2
2140                       (member "wrap" result-params))
2141                   (goto-char beg) (if (org-at-table-p) (org-cycle))
2142                   (funcall wrap ":RESULTS:" ":END:" 'no-escape))
2143                  ((and (not (funcall proper-list-p result))
2144                        (not (member "file" result-params)))
2145                   (org-babel-examplize-region beg end results-switches)
2146                   (setq end (point)))))
2147               ;; possibly indent the results to match the #+results line
2148               (when (and (not inlinep) (numberp indent) indent (> indent 0)
2149                          ;; in this case `table-align' does the work for us
2150                          (not (and (listp result)
2151                                    (member "append" result-params))))
2152                 (indent-rigidly beg end indent))
2153               (if (null result)
2154                   (if (member "value" result-params)
2155                       (message "Code block returned no value.")
2156                     (message "Code block produced no output."))
2157                 (message "Code block evaluation complete.")))
2158           (when outside-scope-p (narrow-to-region visible-beg visible-end))
2159           (set-marker visible-beg nil)
2160           (set-marker visible-end nil))))))
2161
2162 (defun org-babel-remove-result (&optional info)
2163   "Remove the result of the current source block."
2164   (interactive)
2165   (let ((location (org-babel-where-is-src-block-result nil info)) start)
2166     (when location
2167       (setq start (- location 1))
2168       (save-excursion
2169         (goto-char location) (forward-line 1)
2170         (delete-region start (org-babel-result-end))))))
2171
2172 (defun org-babel-result-end ()
2173   "Return the point at the end of the current set of results."
2174   (save-excursion
2175     (cond
2176      ((org-at-table-p) (progn (goto-char (org-table-end)) (point)))
2177      ((org-at-item-p) (let* ((struct (org-list-struct))
2178                              (prvs (org-list-prevs-alist struct)))
2179                         (org-list-get-list-end (point-at-bol) struct prvs)))
2180      ((let ((case-fold-search t)) (looking-at "^\\([ \t]*\\):results:"))
2181       (progn (re-search-forward (concat "^" (match-string 1) ":END:"))
2182              (forward-char 1) (point)))
2183      (t
2184       (let ((case-fold-search t))
2185         (if (looking-at (concat "[ \t]*#\\+begin_\\([^ \t\n\r]+\\)"))
2186             (progn (re-search-forward (concat "[ \t]*#\\+end_" (match-string 1))
2187                                       nil t)
2188                    (forward-char 1))
2189           (while (looking-at "[ \t]*\\(: \\|:$\\|\\[\\[\\)")
2190             (forward-line 1))))
2191       (point)))))
2192
2193 (defun org-babel-result-to-file (result &optional description)
2194   "Convert RESULT into an `org-mode' link with optional DESCRIPTION.
2195 If the `default-directory' is different from the containing
2196 file's directory then expand relative links."
2197   (when (stringp result)
2198     (format "[[file:%s]%s]"
2199             (if (and default-directory
2200                      buffer-file-name
2201                      (not (string= (expand-file-name default-directory)
2202                                    (expand-file-name
2203                                     (file-name-directory buffer-file-name)))))
2204                 (expand-file-name result default-directory)
2205               result)
2206             (if description (concat "[" description "]") ""))))
2207
2208 (defvar org-babel-capitalize-examplize-region-markers nil
2209   "Make true to capitalize begin/end example markers inserted by code blocks.")
2210
2211 (defun org-babel-examplize-region (beg end &optional results-switches)
2212   "Comment out region using the inline '==' or ': ' org example quote."
2213   (interactive "*r")
2214   (let ((chars-between (lambda (b e)
2215                          (not (string-match "^[\\s]*$" (buffer-substring b e)))))
2216         (maybe-cap (lambda (str) (if org-babel-capitalize-examplize-region-markers
2217                                      (upcase str) str))))
2218     (if (or (funcall chars-between (save-excursion (goto-char beg) (point-at-bol)) beg)
2219             (funcall chars-between end (save-excursion (goto-char end) (point-at-eol))))
2220         (save-excursion
2221           (goto-char beg)
2222           (insert (format org-babel-inline-result-wrap
2223                           (prog1 (buffer-substring beg end)
2224                             (delete-region beg end)))))
2225       (let ((size (count-lines beg end)))
2226         (save-excursion
2227           (cond ((= size 0))          ; do nothing for an empty result
2228                 ((< size org-babel-min-lines-for-block-output)
2229                  (goto-char beg)
2230                  (dotimes (n size)
2231                    (beginning-of-line 1) (insert ": ") (forward-line 1)))
2232                 (t
2233                  (goto-char beg)
2234                  (insert (if results-switches
2235                              (format "%s%s\n"
2236                                      (funcall maybe-cap "#+begin_example")
2237                                      results-switches)
2238                            (funcall maybe-cap "#+begin_example\n")))
2239                  (if (markerp end) (goto-char end) (forward-char (- end beg)))
2240                  (insert (funcall maybe-cap "#+end_example\n")))))))))
2241
2242 (defun org-babel-update-block-body (new-body)
2243   "Update the body of the current code block to NEW-BODY."
2244   (if (not (org-babel-where-is-src-block-head))
2245       (error "Not in a source block")
2246     (save-match-data
2247       (replace-match (concat (org-babel-trim new-body) "\n") nil t nil 5))
2248     (indent-rigidly (match-beginning 5) (match-end 5) 2)))
2249
2250 (defun org-babel-merge-params (&rest plists)
2251   "Combine all parameter association lists in PLISTS.
2252 Later elements of PLISTS override the values of previous elements.
2253 This takes into account some special considerations for certain
2254 parameters when merging lists."
2255   (let* ((results-exclusive-groups
2256           (mapcar (lambda (group) (mapcar #'symbol-name group))
2257                   (cdr (assoc 'results org-babel-common-header-args-w-values))))
2258          (exports-exclusive-groups
2259           (mapcar (lambda (group) (mapcar #'symbol-name group))
2260                   (cdr (assoc 'exports org-babel-common-header-args-w-values))))
2261          (variable-index 0)
2262          (e-merge (lambda (exclusive-groups &rest result-params)
2263                     ;; maintain exclusivity of mutually exclusive parameters
2264                     (let (output)
2265                       (mapc (lambda (new-params)
2266                               (mapc (lambda (new-param)
2267                                       (mapc (lambda (exclusive-group)
2268                                               (when (member new-param exclusive-group)
2269                                                 (mapcar (lambda (excluded-param)
2270                                                           (setq output
2271                                                                 (delete
2272                                                                  excluded-param
2273                                                                  output)))
2274                                                         exclusive-group)))
2275                                             exclusive-groups)
2276                                       (setq output (org-uniquify
2277                                                     (cons new-param output))))
2278                                     new-params))
2279                             result-params)
2280                       output)))
2281          params results exports tangle noweb cache vars shebang comments padline
2282          clearnames)
2283
2284     (mapc
2285      (lambda (plist)
2286        (mapc
2287         (lambda (pair)
2288           (case (car pair)
2289             (:var
2290              (let ((name (if (listp (cdr pair))
2291                              (cadr pair)
2292                            (and (string-match "^\\([^= \f\t\n\r\v]+\\)[ \t]*="
2293                                               (cdr pair))
2294                                 (intern (match-string 1 (cdr pair)))))))
2295                (if name
2296                    (setq vars
2297                          (append
2298                           (if (member name (mapcar #'car vars))
2299                               (progn
2300                                 (push name clearnames)
2301                                 (delq nil
2302                                       (mapcar
2303                                        (lambda (p)
2304                                          (unless (equal (car p) name) p))
2305                                        vars)))
2306                             vars)
2307                           (list (cons name pair))))
2308                  ;; if no name is given and we already have named variables
2309                  ;; then assign to named variables in order
2310                  (if (and vars (nth variable-index vars))
2311                      (let ((name (car (nth variable-index vars))))
2312                        (push name clearnames) ; clear out colnames
2313                                               ; and rownames
2314                                               ; for replace vars
2315                        (prog1 (setf (cddr (nth variable-index vars))
2316                                     (concat (symbol-name name) "=" (cdr pair)))
2317                          (incf variable-index)))
2318                    (error "Variable \"%s\" must be assigned a default value"
2319                           (cdr pair))))))
2320             (:results
2321              (setq results (funcall e-merge results-exclusive-groups
2322                                     results
2323                                     (split-string
2324                                      (let ((r (cdr pair)))
2325                                        (if (stringp r) r (eval r)))))))
2326             (:file
2327              (when (cdr pair)
2328                (setq results (funcall e-merge results-exclusive-groups
2329                                       results '("file")))
2330                (unless (or (member "both" exports)
2331                            (member "none" exports)
2332                            (member "code" exports))
2333                  (setq exports (funcall e-merge exports-exclusive-groups
2334                                         exports '("results"))))
2335                (setq params (cons pair (assq-delete-all (car pair) params)))))
2336             (:exports
2337              (setq exports (funcall e-merge exports-exclusive-groups
2338                                     exports (split-string (cdr pair)))))
2339             (:tangle ;; take the latest -- always overwrite
2340              (setq tangle (or (list (cdr pair)) tangle)))
2341             (:noweb
2342              (setq noweb (funcall e-merge
2343                                   '(("yes" "no" "tangle" "no-export"
2344                                      "strip-export" "eval"))
2345                                   noweb
2346                                   (split-string (or (cdr pair) "")))))
2347             (:cache
2348              (setq cache (funcall e-merge '(("yes" "no")) cache
2349                                   (split-string (or (cdr pair) "")))))
2350             (:padline
2351              (setq padline (funcall e-merge '(("yes" "no")) padline
2352                                     (split-string (or (cdr pair) "")))))
2353             (:shebang ;; take the latest -- always overwrite
2354              (setq shebang (or (list (cdr pair)) shebang)))
2355             (:comments
2356              (setq comments (funcall e-merge '(("yes" "no")) comments
2357                                      (split-string (or (cdr pair) "")))))
2358             (t ;; replace: this covers e.g. :session
2359              (setq params (cons pair (assq-delete-all (car pair) params))))))
2360         plist))
2361      plists)
2362     (setq vars (reverse vars))
2363     (while vars (setq params (cons (cons :var (cddr (pop vars))) params)))
2364     ;; clear out col-names and row-names for replaced variables
2365     (mapc
2366      (lambda (name)
2367        (mapc
2368         (lambda (param)
2369           (when (assoc param params)
2370             (setf (cdr (assoc param params))
2371                   (org-remove-if (lambda (pair) (equal (car pair) name))
2372                                  (cdr (assoc param params))))
2373             (setf params (org-remove-if (lambda (pair) (and (equal (car pair) param)
2374                                                        (null (cdr pair))))
2375                                         params))))
2376         (list :colname-names :rowname-names)))
2377      clearnames)
2378     (mapc
2379      (lambda (hd)
2380        (let ((key (intern (concat ":" (symbol-name hd))))
2381              (val (eval hd)))
2382          (setf params (cons (cons key (mapconcat 'identity val " ")) params))))
2383      '(results exports tangle noweb padline cache shebang comments))
2384     params))
2385
2386 (defvar org-babel-use-quick-and-dirty-noweb-expansion nil
2387   "Set to true to use regular expressions to expand noweb references.
2388 This results in much faster noweb reference expansion but does
2389 not properly allow code blocks to inherit the \":noweb-ref\"
2390 header argument from buffer or subtree wide properties.")
2391
2392 (defun org-babel-noweb-p (params context)
2393   "Check if PARAMS require expansion in CONTEXT.
2394 CONTEXT may be one of :tangle, :export or :eval."
2395   (let* (intersect
2396          (intersect (lambda (as bs)
2397                       (when as
2398                         (if (member (car as) bs)
2399                             (car as)
2400                           (funcall intersect (cdr as) bs))))))
2401     (funcall intersect (case context
2402                          (:tangle '("yes" "tangle" "no-export" "strip-export"))
2403                          (:eval   '("yes" "no-export" "strip-export" "eval"))
2404                          (:export '("yes")))
2405              (split-string (or (cdr (assoc :noweb params)) "")))))
2406
2407 (defun org-babel-expand-noweb-references (&optional info parent-buffer)
2408   "Expand Noweb references in the body of the current source code block.
2409
2410 For example the following reference would be replaced with the
2411 body of the source-code block named 'example-block'.
2412
2413 <<example-block>>
2414
2415 Note that any text preceding the <<foo>> construct on a line will
2416 be interposed between the lines of the replacement text.  So for
2417 example if <<foo>> is placed behind a comment, then the entire
2418 replacement text will also be commented.
2419
2420 This function must be called from inside of the buffer containing
2421 the source-code block which holds BODY.
2422
2423 In addition the following syntax can be used to insert the
2424 results of evaluating the source-code block named 'example-block'.
2425
2426 <<example-block()>>
2427
2428 Any optional arguments can be passed to example-block by placing
2429 the arguments inside the parenthesis following the convention
2430 defined by `org-babel-lob'.  For example
2431
2432 <<example-block(a=9)>>
2433
2434 would set the value of argument \"a\" equal to \"9\".  Note that
2435 these arguments are not evaluated in the current source-code
2436 block but are passed literally to the \"example-block\"."
2437   (let* ((parent-buffer (or parent-buffer (current-buffer)))
2438          (info (or info (org-babel-get-src-block-info 'light)))
2439          (lang (nth 0 info))
2440          (body (nth 1 info))
2441          (ob-nww-start org-babel-noweb-wrap-start)
2442          (ob-nww-end org-babel-noweb-wrap-end)
2443          (comment (string= "noweb" (cdr (assoc :comments (nth 2 info)))))
2444          (rx-prefix (concat "\\(" org-babel-src-name-regexp "\\|"
2445                             ":noweb-ref[ \t]+" "\\)"))
2446          (new-body "")
2447          (nb-add (lambda (text) (setq new-body (concat new-body text))))
2448          (c-wrap (lambda (text)
2449                    (with-temp-buffer
2450                      (funcall (intern (concat lang "-mode")))
2451                      (comment-region (point) (progn (insert text) (point)))
2452                      (org-babel-trim (buffer-string)))))
2453          index source-name evaluate prefix blocks-in-buffer)
2454     (with-temp-buffer
2455       (org-set-local 'org-babel-noweb-wrap-start ob-nww-start)
2456       (org-set-local 'org-babel-noweb-wrap-end ob-nww-end)
2457       (insert body) (goto-char (point-min))
2458       (setq index (point))
2459       (while (and (re-search-forward (org-babel-noweb-wrap) nil t))
2460         (save-match-data (setf source-name (match-string 1)))
2461         (save-match-data (setq evaluate (string-match "\(.*\)" source-name)))
2462         (save-match-data
2463           (setq prefix
2464                 (buffer-substring (match-beginning 0)
2465                                   (save-excursion
2466                                     (beginning-of-line 1) (point)))))
2467         ;; add interval to new-body (removing noweb reference)
2468         (goto-char (match-beginning 0))
2469         (funcall nb-add (buffer-substring index (point)))
2470         (goto-char (match-end 0))
2471         (setq index (point))
2472         (funcall nb-add
2473                  (with-current-buffer parent-buffer
2474                    (save-restriction
2475                      (widen)
2476                      (mapconcat ;; interpose PREFIX between every line
2477                       #'identity
2478                       (split-string
2479                        (if evaluate
2480                            (let ((raw (org-babel-ref-resolve source-name)))
2481                              (if (stringp raw) raw (format "%S" raw)))
2482                          (or
2483                           ;; retrieve from the library of babel
2484                           (nth 2 (assoc (intern source-name)
2485                                         org-babel-library-of-babel))
2486                           ;; return the contents of headlines literally
2487                           (save-excursion
2488                             (when (org-babel-ref-goto-headline-id source-name)
2489                               (org-babel-ref-headline-body)))
2490                           ;; find the expansion of reference in this buffer
2491                           (let ((rx (concat rx-prefix source-name "[ \t\n]"))
2492                                 expansion)
2493                             (save-excursion
2494                               (goto-char (point-min))
2495                               (if org-babel-use-quick-and-dirty-noweb-expansion
2496                                   (while (re-search-forward rx nil t)
2497                                     (let* ((i (org-babel-get-src-block-info 'light))
2498                                            (body (org-babel-expand-noweb-references i))
2499                                            (sep (or (cdr (assoc :noweb-sep (nth 2 i)))
2500                                                     "\n"))
2501                                            (full (if comment
2502                                                      ((lambda (cs)
2503                                                         (concat (funcall c-wrap (car cs)) "\n"
2504                                                                 body "\n"
2505                                                                 (funcall c-wrap (cadr cs))))
2506                                                       (org-babel-tangle-comment-links i))
2507                                                    body)))
2508                                       (setq expansion (cons sep (cons full expansion)))))
2509                                 (org-babel-map-src-blocks nil
2510                                   (let ((i (org-babel-get-src-block-info 'light)))
2511                                     (when (equal (or (cdr (assoc :noweb-ref (nth 2 i)))
2512                                                      (nth 4 i))
2513                                                  source-name)
2514                                       (let* ((body (org-babel-expand-noweb-references i))
2515                                              (sep (or (cdr (assoc :noweb-sep (nth 2 i)))
2516                                                       "\n"))
2517                                              (full (if comment
2518                                                        ((lambda (cs)
2519                                                           (concat (funcall c-wrap (car cs)) "\n"
2520                                                                   body "\n"
2521                                                                   (funcall c-wrap (cadr cs))))
2522                                                         (org-babel-tangle-comment-links i))
2523                                                      body)))
2524                                         (setq expansion
2525                                               (cons sep (cons full expansion)))))))))
2526                             (and expansion
2527                                  (mapconcat #'identity (nreverse (cdr expansion)) "")))
2528                           ;; possibly raise an error if named block doesn't exist
2529                           (if (member lang org-babel-noweb-error-langs)
2530                               (error "%s" (concat
2531                                            (org-babel-noweb-wrap source-name)
2532                                            "could not be resolved (see "
2533                                            "`org-babel-noweb-error-langs')"))
2534                             "")))
2535                        "[\n\r]") (concat "\n" prefix))))))
2536       (funcall nb-add (buffer-substring index (point-max))))
2537     new-body))
2538
2539 (defun org-babel-script-escape (str &optional force)
2540   "Safely convert tables into elisp lists."
2541   (let (in-single in-double out)
2542     ((lambda (escaped) (condition-case nil (org-babel-read escaped) (error escaped)))
2543      (if (or force
2544              (and (stringp str)
2545                   (> (length str) 2)
2546                   (or (and (string-equal "[" (substring str 0 1))
2547                            (string-equal "]" (substring str -1)))
2548                       (and (string-equal "{" (substring str 0 1))
2549                            (string-equal "}" (substring str -1)))
2550                       (and (string-equal "(" (substring str 0 1))
2551                            (string-equal ")" (substring str -1))))))
2552          (org-babel-read
2553           (concat
2554            "'"
2555            (progn
2556              (mapc
2557               (lambda (ch)
2558                 (setq
2559                  out
2560                  (case ch
2561                    (91 (if (or in-double in-single) ; [
2562                            (cons 91 out)
2563                          (cons 40 out)))
2564                    (93 (if (or in-double in-single) ; ]
2565                            (cons 93 out)
2566                          (cons 41 out)))
2567                    (123 (if (or in-double in-single) ; {
2568                             (cons 123 out)
2569                           (cons 40 out)))
2570                    (125 (if (or in-double in-single) ; }
2571                             (cons 125 out)
2572                           (cons 41 out)))
2573                    (44 (if (or in-double in-single) ; ,
2574                            (cons 44 out) (cons 32 out)))
2575                    (39 (if in-double    ; '
2576                            (cons 39 out)
2577                          (setq in-single (not in-single)) (cons 34 out)))
2578                    (34 (if in-single    ; "
2579                            (append (list 34 32) out)
2580                          (setq in-double (not in-double)) (cons 34 out)))
2581                    (t  (cons ch out)))))
2582               (string-to-list str))
2583              (apply #'string (reverse out)))))
2584        str))))
2585
2586 (defun org-babel-read (cell &optional inhibit-lisp-eval)
2587   "Convert the string value of CELL to a number if appropriate.
2588 Otherwise if cell looks like lisp (meaning it starts with a
2589 \"(\", \"'\", \"`\" or a \"[\") then read it as lisp,
2590 otherwise return it unmodified as a string.  Optional argument
2591 NO-LISP-EVAL inhibits lisp evaluation for situations in which is
2592 it not appropriate."
2593   (if (and (stringp cell) (not (equal cell "")))
2594       (or (org-babel-number-p cell)
2595           (if (and (not inhibit-lisp-eval)
2596                    (or (member (substring cell 0 1) '("(" "'" "`" "["))
2597                        (string= cell "*this*")))
2598               (eval (read cell))
2599             (if (string= (substring cell 0 1) "\"")
2600                 (read cell)
2601               (progn (set-text-properties 0 (length cell) nil cell) cell))))
2602     cell))
2603
2604 (defun org-babel-number-p (string)
2605   "If STRING represents a number return its value."
2606   (if (and (string-match "[0-9]+" string)
2607            (string-match "^-?[0-9]*\\.?[0-9]*$" string)
2608            (= (length (substring string (match-beginning 0)
2609                                  (match-end 0)))
2610               (length string)))
2611       (string-to-number string)))
2612
2613 (defun org-babel-import-elisp-from-file (file-name &optional separator)
2614   "Read the results located at FILE-NAME into an elisp table.
2615 If the table is trivial, then return it as a scalar."
2616   (let (result)
2617     (save-window-excursion
2618       (with-temp-buffer
2619         (condition-case err
2620             (progn
2621               (org-table-import file-name separator)
2622               (delete-file file-name)
2623               (setq result (mapcar (lambda (row)
2624                                      (mapcar #'org-babel-string-read row))
2625                                    (org-table-to-lisp))))
2626           (error (message "Error reading results: %s" err) nil)))
2627       (if (null (cdr result)) ;; if result is trivial vector, then scalarize it
2628           (if (consp (car result))
2629               (if (null (cdr (car result)))
2630                   (caar result)
2631                 result)
2632             (car result))
2633         result))))
2634
2635 (defun org-babel-string-read (cell)
2636   "Strip nested \"s from around strings."
2637   (org-babel-read (or (and (stringp cell)
2638                            (string-match "\\\"\\(.+\\)\\\"" cell)
2639                            (match-string 1 cell))
2640                       cell) t))
2641
2642 (defun org-babel-chomp (string &optional regexp)
2643   "Strip trailing spaces and carriage returns from STRING.
2644 Default regexp used is \"[ \f\t\n\r\v]\" but can be
2645 overwritten by specifying a regexp as a second argument."
2646   (let ((regexp (or regexp "[ \f\t\n\r\v]")))
2647     (while (and (> (length string) 0)
2648                 (string-match regexp (substring string -1)))
2649       (setq string (substring string 0 -1)))
2650     string))
2651
2652 (defun org-babel-trim (string &optional regexp)
2653   "Strip leading and trailing spaces and carriage returns from STRING.
2654 Like `org-babel-chomp' only it runs on both the front and back
2655 of the string."
2656   (org-babel-chomp (org-reverse-string
2657                     (org-babel-chomp (org-reverse-string string) regexp))
2658                    regexp))
2659
2660 (defun org-babel-tramp-handle-call-process-region
2661   (start end program &optional delete buffer display &rest args)
2662   "Use Tramp to handle `call-process-region'.
2663 Fixes a bug in `tramp-handle-call-process-region'."
2664   (if (and (featurep 'tramp) (file-remote-p default-directory))
2665       (let ((tmpfile (tramp-compat-make-temp-file "")))
2666         (write-region start end tmpfile)
2667         (when delete (delete-region start end))
2668         (unwind-protect
2669             ;;  (apply 'call-process program tmpfile buffer display args)
2670             ;; bug in tramp
2671             (apply 'process-file program tmpfile buffer display args)
2672           (delete-file tmpfile)))
2673     ;; org-babel-call-process-region-original is the original emacs
2674     ;; definition.  It is in scope from the let binding in
2675     ;; org-babel-execute-src-block
2676     (apply org-babel-call-process-region-original
2677            start end program delete buffer display args)))
2678
2679 (defun org-babel-local-file-name (file)
2680   "Return the local name component of FILE."
2681   (if (file-remote-p file)
2682       (let (localname)
2683         (with-parsed-tramp-file-name file nil
2684                                      localname))
2685     file))
2686
2687 (defun org-babel-process-file-name (name &optional no-quote-p)
2688   "Prepare NAME to be used in an external process.
2689 If NAME specifies a remote location, the remote portion of the
2690 name is removed, since in that case the process will be executing
2691 remotely.  The file name is then processed by `expand-file-name'.
2692 Unless second argument NO-QUOTE-P is non-nil, the file name is
2693 additionally processed by `shell-quote-argument'"
2694   ((lambda (f) (if no-quote-p f (shell-quote-argument f)))
2695    (expand-file-name (org-babel-local-file-name name))))
2696
2697 (defvar org-babel-temporary-directory)
2698 (unless (or noninteractive (boundp 'org-babel-temporary-directory))
2699   (defvar org-babel-temporary-directory
2700     (or (and (boundp 'org-babel-temporary-directory)
2701              (file-exists-p org-babel-temporary-directory)
2702              org-babel-temporary-directory)
2703         (make-temp-file "babel-" t))
2704     "Directory to hold temporary files created to execute code blocks.
2705 Used by `org-babel-temp-file'.  This directory will be removed on
2706 Emacs shutdown."))
2707
2708 (defmacro org-babel-result-cond (result-params scalar-form &rest table-forms)
2709   "Call the code to parse raw string results according to RESULT-PARAMS."
2710   (declare (indent 1)
2711            (debug (form form &rest form)))
2712   (org-with-gensyms (params)
2713     `(let ((,params ,result-params))
2714        (unless (member "none" ,params)
2715          (if (or (member "scalar" ,params)
2716                  (member "verbatim" ,params)
2717                  (member "html" ,params)
2718                  (member "code" ,params)
2719                  (member "pp" ,params)
2720                  (and (or (member "output" ,params)
2721                           (member "raw"    ,params)
2722                           (member "org"    ,params)
2723                           (member "drawer" ,params))
2724                       (not (member "table" ,params))))
2725              ,scalar-form
2726            ,@table-forms)))))
2727 (def-edebug-spec org-babel-result-cond (form form body))
2728
2729 (defun org-babel-temp-file (prefix &optional suffix)
2730   "Create a temporary file in the `org-babel-temporary-directory'.
2731 Passes PREFIX and SUFFIX directly to `make-temp-file' with the
2732 value of `temporary-file-directory' temporarily set to the value
2733 of `org-babel-temporary-directory'."
2734   (if (file-remote-p default-directory)
2735       (let ((prefix
2736              (concat (file-remote-p default-directory)
2737                      (expand-file-name prefix temporary-file-directory))))
2738         (make-temp-file prefix nil suffix))
2739     (let ((temporary-file-directory
2740            (or (and (boundp 'org-babel-temporary-directory)
2741                     (file-exists-p org-babel-temporary-directory)
2742                     org-babel-temporary-directory)
2743                temporary-file-directory)))
2744       (make-temp-file prefix nil suffix))))
2745
2746 (defun org-babel-remove-temporary-directory ()
2747   "Remove `org-babel-temporary-directory' on Emacs shutdown."
2748   (when (and (boundp 'org-babel-temporary-directory)
2749              (file-exists-p org-babel-temporary-directory))
2750     ;; taken from `delete-directory' in files.el
2751     (condition-case nil
2752         (progn
2753           (mapc (lambda (file)
2754                   ;; This test is equivalent to
2755                   ;; (and (file-directory-p fn) (not (file-symlink-p fn)))
2756                   ;; but more efficient
2757                   (if (eq t (car (file-attributes file)))
2758                       (delete-directory file)
2759                     (delete-file file)))
2760                 ;; We do not want to delete "." and "..".
2761                 (directory-files org-babel-temporary-directory 'full
2762                                  "^\\([^.]\\|\\.\\([^.]\\|\\..\\)\\).*"))
2763           (delete-directory org-babel-temporary-directory))
2764       (error
2765        (message "Failed to remove temporary Org-babel directory %s"
2766                 (if (boundp 'org-babel-temporary-directory)
2767                     org-babel-temporary-directory
2768                   "[directory not defined]"))))))
2769
2770 (add-hook 'kill-emacs-hook 'org-babel-remove-temporary-directory)
2771
2772 (provide 'ob-core)
2773
2774 ;; Local variables:
2775 ;; generated-autoload-file: "org-loaddefs.el"
2776 ;; End:
2777
2778 ;;; ob-core.el ends here