lisp/org-src.el

   1 ;;; org-src.el --- Source code examples in Org
   2 ;;
   3 ;; Copyright (C) 2004-2015 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;;         Bastien Guerry <bzg@gnu.org>
   7 ;;         Dan Davison <davison at stats dot ox dot ac dot uk>
   8 ;; Keywords: outlines, hypermedia, calendar, wp
   9 ;; Homepage: http://orgmode.org
  10 ;;
  11 ;; This file is part of GNU Emacs.
  12 ;;
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  26 ;;
  27 ;;; Commentary:
  28
  29 ;; This file contains the code dealing with source code examples in Org-mode.
  30
  31 ;;; Code:
  32
  33 (require 'org-macs)
  34 (require 'org-compat)
  35 (require 'ob-keys)
  36 (require 'ob-comint)
  37 (eval-when-compile (require 'cl))
  38
  39 (declare-function org-base-buffer "org" (buffer))
  40 (declare-function org-do-remove-indentation "org" (&optional n))
  41 (declare-function org-element-at-point "org-element" ())
  42 (declare-function org-element-context "org-element" (&optional element))
  43 (declare-function org-element-lineage "org-element"
  44                   (blob &optional types with-self))
  45 (declare-function org-element-property "org-element" (property element))
  46 (declare-function org-element-type "org-element" (element))
  47 (declare-function org-footnote-goto-definition "org-footnote"
  48                   (label &optional location))
  49 (declare-function org-get-indentation "org" (&optional line))
  50 (declare-function org-pop-to-buffer-same-window "org-compat"
  51                   (&optional buffer-or-name norecord label))
  52 (declare-function org-some "org" (pred seq))
  53 (declare-function org-switch-to-buffer-other-window "org" (&rest args))
  54 (declare-function org-trim "org" (s))
  55
  56 (defvar org-element-all-elements)
  57
  58 (defcustom org-edit-src-turn-on-auto-save nil
  59   "Non-nil means turn `auto-save-mode' on when editing a source block.
  60 This will save the content of the source code editing buffer into
  61 a newly created file, not the base buffer for this source block.
  62
  63 If you want to regularly save the base buffer instead of the source
  64 code editing buffer, see `org-edit-src-auto-save-idle-delay' instead."
  65   :group 'org-edit-structure
  66   :version "24.4"
  67   :package-version '(Org . "8.0")
  68   :type 'boolean)
  69
  70 (defcustom org-edit-src-auto-save-idle-delay 0
  71   "Delay before saving a source code buffer back into its base buffer.
  72 When a positive integer N, save after N seconds of idle time.
  73 When 0 (the default), don't auto-save.
  74
  75 If you want to save the source code buffer itself, don't use this.
  76 Check `org-edit-src-turn-on-auto-save' instead."
  77   :group 'org-edit-structure
  78   :version "24.4"
  79   :package-version '(Org . "8.0")
  80   :type 'integer)
  81
  82 (defcustom org-coderef-label-format "(ref:%s)"
  83   "The default coderef format.
  84 This format string will be used to search for coderef labels in literal
  85 examples (EXAMPLE and SRC blocks).  The format can be overwritten in
  86 an individual literal example with the -l option, like
  87
  88 #+BEGIN_SRC pascal +n -r -l \"((%s))\"
  89 ...
  90 #+END_SRC
  91
  92 If you want to use this for HTML export, make sure that the format does
  93 not introduce special font-locking, and avoid the HTML special
  94 characters `<', `>', and `&'.  The reason for this restriction is that
  95 the labels are searched for only after htmlize has done its job."
  96   :group 'org-edit-structure ; FIXME this is not in the right group
  97   :type 'string)
  98
  99 (defcustom org-edit-fixed-width-region-mode 'artist-mode
 100   "The mode that should be used to edit fixed-width regions.
 101 These are the regions where each line starts with a colon."
 102   :group 'org-edit-structure
 103   :type '(choice
 104           (const artist-mode)
 105           (const picture-mode)
 106           (const fundamental-mode)
 107           (function :tag "Other (specify)")))
 108
 109 (defcustom org-src-preserve-indentation nil
 110   "If non-nil preserve leading whitespace characters on export.
 111 If non-nil leading whitespace characters in source code blocks
 112 are preserved on export, and when switching between the org
 113 buffer and the language mode edit buffer.
 114
 115 When this variable is nil, after editing with \\[org-edit-src-code],
 116 the minimum (across-lines) number of leading whitespace characters
 117 are removed from all lines, and the code block is uniformly indented
 118 according to the value of `org-edit-src-content-indentation'."
 119   :group 'org-edit-structure
 120   :type 'boolean)
 121
 122 (defcustom org-edit-src-content-indentation 2
 123   "Indentation for the content of a source code block.
 124 This should be the number of spaces added to the indentation of the #+begin
 125 line in order to compute the indentation of the block content after
 126 editing it with \\[org-edit-src-code].  Has no effect if
 127 `org-src-preserve-indentation' is non-nil."
 128   :group 'org-edit-structure
 129   :type 'integer)
 130
 131 (defcustom org-edit-src-persistent-message t
 132   "Non-nil means show persistent exit help message while editing src examples.
 133 The message is shown in the header-line, which will be created in the
 134 first line of the window showing the editing buffer."
 135   :group 'org-edit-structure
 136   :type 'boolean)
 137
 138 (defcustom org-src-ask-before-returning-to-edit-buffer t
 139   "Non-nil means ask before switching to an existing edit buffer.
 140 If nil, when `org-edit-src-code' is used on a block that already
 141 has an active edit buffer, it will switch to that edit buffer
 142 immediately; otherwise it will ask whether you want to return to
 143 the existing edit buffer."
 144   :group 'org-edit-structure
 145   :version "24.4"
 146   :package-version '(Org . "8.0")
 147   :type 'boolean)
 148
 149 (defcustom org-src-window-setup 'reorganize-frame
 150   "How the source code edit buffer should be displayed.
 151 Possible values for this option are:
 152
 153 current-window    Show edit buffer in the current window, keeping all other
 154                   windows.
 155 other-window      Use `switch-to-buffer-other-window' to display edit buffer.
 156 reorganize-frame  Show only two windows on the current frame, the current
 157                   window and the edit buffer.  When exiting the edit buffer,
 158                   return to one window.
 159 other-frame       Use `switch-to-buffer-other-frame' to display edit buffer.
 160                   Also, when exiting the edit buffer, kill that frame."
 161   :group 'org-edit-structure
 162   :type '(choice
 163           (const current-window)
 164           (const other-frame)
 165           (const other-window)
 166           (const reorganize-frame)))
 167
 168 (defvar org-src-mode-hook nil
 169   "Hook run after Org switched a source code snippet to its Emacs mode.
 170 \\<org-mode-map>
 171 This hook will run:
 172 - when editing a source code snippet with \\[org-edit-special]
 173 - when formatting a source code snippet for export with htmlize.
 174
 175 You may want to use this hook for example to turn off `outline-minor-mode'
 176 or similar things which you want to have when editing a source code file,
 177 but which mess up the display of a snippet in Org exported files.")
 178
 179 (defcustom org-src-lang-modes
 180   '(("ocaml" . tuareg) ("elisp" . emacs-lisp) ("ditaa" . artist)
 181     ("asymptote" . asy) ("dot" . fundamental) ("sqlite" . sql)
 182     ("calc" . fundamental) ("C" . c) ("cpp" . c++) ("C++" . c++)
 183     ("screen" . shell-script) ("shell" . sh) ("bash" . sh))
 184   "Alist mapping languages to their major mode.
 185 The key is the language name, the value is the string that should
 186 be inserted as the name of the major mode.  For many languages this is
 187 simple, but for language where this is not the case, this variable
 188 provides a way to simplify things on the user side.
 189 For example, there is no ocaml-mode in Emacs, but the mode to use is
 190 `tuareg-mode'."
 191   :group 'org-edit-structure
 192   :type '(repeat
 193           (cons
 194            (string "Language name")
 195            (symbol "Major mode"))))
 196
 197 (defcustom org-src-tab-acts-natively nil
 198   "If non-nil, the effect of TAB in a code block is as if it were
 199 issued in the language major mode buffer."
 200   :type 'boolean
 201   :version "24.1"
 202   :group 'org-babel)
 203
 204
 205 \f
 206 ;;; Internal functions and variables
 207
 208 (defvar org-src--allow-write-back t)
 209 (defvar org-src--auto-save-timer nil)
 210 (defvar org-src--babel-info nil)
 211 (defvar org-src--beg-marker nil)
 212 (defvar org-src--block-indentation nil)
 213 (defvar org-src--end-marker nil)
 214 (defvar org-src--from-org-mode nil)
 215 (defvar org-src--overlay nil)
 216 (defvar org-src--preserve-indentation nil)
 217 (defvar org-src--remote nil)
 218 (defvar org-src--saved-temp-window-config nil)
 219
 220 (defun org-src--construct-edit-buffer-name (org-buffer-name lang)
 221   "Construct the buffer name for a source editing buffer."
 222   (concat "*Org Src " org-buffer-name "[ " lang " ]*"))
 223
 224 (defun org-src--edit-buffer (beg end)
 225   "Return buffer editing area between BEG and END.
 226 Return nil if there is no such buffer."
 227   (catch 'exit
 228     (dolist (b (buffer-list))
 229       (with-current-buffer b
 230         (and (org-src-edit-buffer-p)
 231              (= beg org-src--beg-marker)
 232              (eq (marker-buffer beg) (marker-buffer org-src--beg-marker))
 233              (= end org-src--end-marker)
 234              (eq (marker-buffer end) (marker-buffer org-src--end-marker))
 235              (throw 'exit b))))))
 236
 237 (defun org-src--source-buffer ()
 238   "Return source buffer edited by current buffer."
 239   (unless (org-src-edit-buffer-p) (error "Not in a source buffer"))
 240   (or (marker-buffer org-src--beg-marker)
 241       (error "No source buffer available for current editing session")))
 242
 243 (defun org-src--get-lang-mode (lang)
 244   "Return major mode that should be used for LANG.
 245 LANG is a string, and the returned major mode is a symbol."
 246   (intern
 247    (concat
 248     (let ((l (or (cdr (assoc lang org-src-lang-modes)) lang)))
 249       (if (symbolp l) (symbol-name l) l))
 250     "-mode")))
 251
 252 (defun org-src--coordinates (pos beg end)
 253   "Return coordinates of POS relatively to BEG and END.
 254 POS, BEG and END are buffer positions.  Return value is either
 255 a cons cell (LINE . COLUMN) or symbol `end'.  See also
 256 `org-src--goto-coordinates'."
 257   (if (>= pos end) 'end
 258     (org-with-wide-buffer
 259      (goto-char (max beg pos))
 260      (cons (count-lines beg (line-beginning-position))
 261            ;; Column is relative to the end of line to avoid problems of
 262            ;; comma escaping or colons appended in front of the line.
 263            (- (current-column)
 264               (progn (end-of-line) (current-column)))))))
 265
 266 (defun org-src--goto-coordinates (coord beg end)
 267   "Move to coordinates COORD relatively to BEG and END.
 268 COORD are coordinates, as returned by `org-src--coordinates',
 269 which see.  BEG and END are buffer positions."
 270   (goto-char
 271    (if (eq coord 'end) (max (1- end) beg)
 272      ;; If BEG happens to be located outside of the narrowed part of
 273      ;; the buffer, widen it first.
 274      (org-with-wide-buffer
 275       (goto-char beg)
 276       (forward-line (car coord))
 277       (end-of-line)
 278       (org-move-to-column (max (+ (current-column) (cdr coord)) 0))
 279       (point)))))
 280
 281 (defun org-src--contents-area (datum)
 282   "Return contents boundaries of DATUM.
 283 DATUM is an element or object.  Return a list (BEG END CONTENTS)
 284 where BEG and END are buffer positions and CONTENTS is a string."
 285   (let ((type (org-element-type datum)))
 286     (cond
 287      ((eq type 'footnote-definition)
 288       (let* ((beg (org-with-wide-buffer
 289                    (goto-char (org-element-property :post-affiliated datum))
 290                    (search-forward "]")))
 291              (end (or (org-element-property :contents-end datum) beg)))
 292         (list beg end (buffer-substring-no-properties beg end))))
 293      ((org-element-property :contents-begin datum)
 294       (let ((beg (org-element-property :contents-begin datum))
 295             (end (org-element-property :contents-end datum)))
 296         (list beg end (buffer-substring-no-properties beg end))))
 297      ((memq type '(example-block export-block src-block))
 298       (list (org-with-wide-buffer
 299              (goto-char (org-element-property :post-affiliated datum))
 300              (line-beginning-position 2))
 301             (org-with-wide-buffer
 302              (goto-char (org-element-property :end datum))
 303              (skip-chars-backward " \r\t\n")
 304              (line-beginning-position 1))
 305             (org-element-property :value datum)))
 306      ((memq type '(fixed-width table))
 307       (let ((beg (org-element-property :post-affiliated datum))
 308             (end (org-with-wide-buffer
 309                   (goto-char (org-element-property :end datum))
 310                   (skip-chars-backward " \r\t\n")
 311                   (line-beginning-position 2))))
 312         (list beg
 313               end
 314               (if (eq type 'fixed-width) (org-element-property :value datum)
 315                 (buffer-substring-no-properties beg end)))))
 316      (t (error "Unsupported element or object: %s" type)))))
 317
 318 (defun org-src--make-source-overlay (beg end edit-buffer)
 319   "Create overlay between BEG and END positions and return it.
 320 EDIT-BUFFER is the buffer currently editing area between BEG and
 321 END."
 322   (let ((overlay (make-overlay beg end)))
 323     (overlay-put overlay 'face 'secondary-selection)
 324     (overlay-put overlay 'edit-buffer edit-buffer)
 325     (overlay-put overlay 'help-echo
 326                  "Click with mouse-1 to switch to buffer editing this segment")
 327     (overlay-put overlay 'face 'secondary-selection)
 328     (overlay-put overlay 'keymap
 329                  (let ((map (make-sparse-keymap)))
 330                    (define-key map [mouse-1] 'org-edit-src-continue)
 331                    map))
 332     (let ((read-only
 333            (list
 334             (lambda (&rest _)
 335               (user-error
 336                "Cannot modify an area being edited in a dedicated buffer")))))
 337       (overlay-put overlay 'modification-hooks read-only)
 338       (overlay-put overlay 'insert-in-front-hooks read-only)
 339       (overlay-put overlay 'insert-behind-hooks read-only))
 340     overlay))
 341
 342 (defun org-src--remove-overlay ()
 343   "Remove overlay from current source buffer."
 344   (when (overlayp org-src--overlay) (delete-overlay org-src--overlay)))
 345
 346 (defun org-src--on-datum-p (datum)
 347   "Non-nil when point is on DATUM.
 348 DATUM is an element or an object.  Consider blank lines or white
 349 spaces after it as being outside."
 350   (and (>= (point) (org-element-property :begin datum))
 351        (<= (point)
 352            (org-with-wide-buffer
 353             (goto-char (org-element-property :end datum))
 354             (skip-chars-backward " \r\t\n")
 355             (if (memq (org-element-type datum) org-element-all-elements)
 356                 (line-end-position)
 357               (point))))))
 358
 359 (defun org-src--contents-for-write-back ()
 360   "Return buffer contents in a format appropriate for write back.
 361 Assume point is in the corresponding edit buffer."
 362   (let ((indentation (or org-src--block-indentation 0))
 363         (preserve-indentation org-src--preserve-indentation)
 364         (contents (org-with-wide-buffer (buffer-string)))
 365         (write-back org-src--allow-write-back))
 366     (with-temp-buffer
 367       (insert (org-no-properties contents))
 368       (goto-char (point-min))
 369       (when (functionp write-back) (funcall write-back))
 370       (unless (or preserve-indentation (= indentation 0))
 371         (let ((ind (make-string indentation ?\s)))
 372           (goto-char (point-min))
 373           (while (not (eobp))
 374             (when (org-looking-at-p "[ \t]*\\S-") (insert ind))
 375             (forward-line))))
 376       (buffer-string))))
 377
 378 (defun org-src--edit-element
 379     (datum name &optional major write-back contents remote)
 380   "Edit DATUM contents in a dedicated buffer NAME.
 381
 382 MAJOR is the major mode used in the edit buffer.  A nil value is
 383 equivalent to `fundamental-mode'.
 384
 385 When WRITE-BACK is non-nil, assume contents will replace original
 386 region.  Moreover, if it is a function, apply it in the edit
 387 buffer, from point min, before returning the contents.
 388
 389 When CONTENTS is non-nil, display them in the edit buffer.
 390 Otherwise, show DATUM contents as specified by
 391 `org-src--contents-area'.
 392
 393 When REMOTE is non-nil, do not try to preserve point or mark when
 394 moving from the edit area to the source.
 395
 396 Leave point in edit buffer."
 397   (setq org-src--saved-temp-window-config (current-window-configuration))
 398   (let* ((area (org-src--contents-area datum))
 399          (beg (copy-marker (nth 0 area)))
 400          (end (copy-marker (nth 1 area) t))
 401          (old-edit-buffer (org-src--edit-buffer beg end))
 402          (contents (or contents (nth 2 area))))
 403     (if (and old-edit-buffer
 404              (or (not org-src-ask-before-returning-to-edit-buffer)
 405                  (y-or-n-p "Return to existing edit buffer ([n] will revert changes)? ")))
 406         ;; Move to existing buffer.
 407         (org-src-switch-to-buffer old-edit-buffer 'return)
 408       ;; Discard old edit buffer.
 409       (when old-edit-buffer
 410         (with-current-buffer old-edit-buffer (org-src--remove-overlay))
 411         (kill-buffer old-edit-buffer))
 412       (let* ((org-mode-p (derived-mode-p 'org-mode))
 413              (type (org-element-type datum))
 414              (ind (org-with-wide-buffer
 415                    (goto-char (org-element-property :begin datum))
 416                    (org-get-indentation)))
 417              (preserve-ind
 418               (and (memq type '(example-block src-block))
 419                    (or (org-element-property :preserve-indent datum)
 420                        org-src-preserve-indentation)))
 421              ;; Store relative positions of mark (if any) and point
 422              ;; within the edited area.
 423              (point-coordinates (and (not remote)
 424                                      (org-src--coordinates (point) beg end)))
 425              (mark-coordinates (and (not remote)
 426                                     (org-region-active-p)
 427                                     (let ((m (mark)))
 428                                       (and (>= m beg) (>= end m)
 429                                            (org-src--coordinates m beg end)))))
 430              ;; Generate a new edit buffer.
 431              (buffer (generate-new-buffer name))
 432              ;; Add an overlay on top of source.
 433              (overlay (org-src--make-source-overlay beg end buffer)))
 434         ;; Switch to edit buffer.
 435         (org-src-switch-to-buffer buffer 'edit)
 436         ;; Insert contents.
 437         (insert contents)
 438         (remove-text-properties (point-min) (point-max)
 439                                 '(display nil invisible nil intangible nil))
 440         (unless preserve-ind (org-do-remove-indentation))
 441         (set-buffer-modified-p nil)
 442         (setq buffer-file-name nil)
 443         ;; Start major mode.
 444         (if (not major) (fundamental-mode)
 445           (let ((org-inhibit-startup t))
 446             (condition-case e (funcall major)
 447               (error (message "Language mode `%s' fails with: %S"
 448                               major (nth 1 e))))))
 449         ;; Transmit buffer-local variables for exit function.  It must
 450         ;; be done after initializing major mode, as this operation
 451         ;; may reset them otherwise.
 452         (org-set-local 'org-src--from-org-mode org-mode-p)
 453         (org-set-local 'org-src--beg-marker beg)
 454         (org-set-local 'org-src--end-marker end)
 455         (org-set-local 'org-src--remote remote)
 456         (org-set-local 'org-src--block-indentation ind)
 457         (org-set-local 'org-src--preserve-indentation preserve-ind)
 458         (org-set-local 'org-src--overlay overlay)
 459         (org-set-local 'org-src--allow-write-back write-back)
 460         ;; Start minor mode.
 461         (org-src-mode)
 462         ;; Move mark and point in edit buffer to the corresponding
 463         ;; location.
 464         (if remote
 465             (progn
 466               ;; Put point at first non read-only character after
 467               ;; leading blank.
 468               (goto-char
 469                (or (text-property-any (point-min) (point-max) 'read-only nil)
 470                    (point-max)))
 471               (skip-chars-forward " \r\t\n"))
 472           ;; Set mark and point.
 473           (when mark-coordinates
 474             (org-src--goto-coordinates mark-coordinates (point-min) (point-max))
 475             (push-mark (point) 'no-message t)
 476             (setq deactivate-mark nil))
 477           (org-src--goto-coordinates
 478            point-coordinates (point-min) (point-max)))))))
 479
 480
 481 \f
 482 ;;; Fontification of source blocks
 483
 484 (defun org-src-font-lock-fontify-block (lang start end)
 485   "Fontify code block.
 486 This function is called by emacs automatic fontification, as long
 487 as `org-src-fontify-natively' is non-nil."
 488   (let ((lang-mode (org-src--get-lang-mode lang)))
 489     (when (fboundp lang-mode)
 490       (let ((string (buffer-substring-no-properties start end))
 491             (modified (buffer-modified-p))
 492             (org-buffer (current-buffer)) pos next)
 493         (remove-text-properties start end '(face nil))
 494         (with-current-buffer
 495             (get-buffer-create
 496              (concat " org-src-fontification:" (symbol-name lang-mode)))
 497           (delete-region (point-min) (point-max))
 498           (insert string " ") ;; so there's a final property change
 499           (unless (eq major-mode lang-mode) (funcall lang-mode))
 500           ;; Avoid `font-lock-ensure', which does not display fonts in
 501           ;; source block.
 502           (font-lock-fontify-buffer)
 503           (setq pos (point-min))
 504           (while (setq next (next-single-property-change pos 'face))
 505             (put-text-property
 506              (+ start (1- pos)) (1- (+ start next)) 'face
 507              (get-text-property pos 'face) org-buffer)
 508             (setq pos next)))
 509         (add-text-properties
 510          start end
 511          '(font-lock-fontified t fontified t font-lock-multiline t))
 512         (set-buffer-modified-p modified)))))
 513
 514
 515 \f
 516 ;;; Escape contents
 517
 518 (defun org-escape-code-in-region (beg end)
 519   "Escape lines between BEG and END.
 520 Escaping happens when a line starts with \"*\", \"#+\", \",*\" or
 521 \",#+\" by appending a comma to it."
 522   (interactive "r")
 523   (save-excursion
 524     (goto-char end)
 525     (while (re-search-backward "^[ \t]*,?\\(\\*\\|#\\+\\)" beg t)
 526       (save-excursion (replace-match ",\\1" nil nil nil 1)))))
 527
 528 (defun org-escape-code-in-string (s)
 529   "Escape lines in string S.
 530 Escaping happens when a line starts with \"*\", \"#+\", \",*\" or
 531 \",#+\" by appending a comma to it."
 532   (replace-regexp-in-string "^[ \t]*,?\\(\\*\\|#\\+\\)" ",\\1" s nil nil 1))
 533
 534 (defun org-unescape-code-in-region (beg end)
 535   "Un-escape lines between BEG and END.
 536 Un-escaping happens by removing the first comma on lines starting
 537 with \",*\", \",#+\", \",,*\" and \",,#+\"."
 538   (interactive "r")
 539   (save-excursion
 540     (goto-char end)
 541     (while (re-search-backward "^[ \t]*,?\\(,\\)\\(?:\\*\\|#\\+\\)" beg t)
 542       (save-excursion (replace-match "" nil nil nil 1)))))
 543
 544 (defun org-unescape-code-in-string (s)
 545   "Un-escape lines in string S.
 546 Un-escaping happens by removing the first comma on lines starting
 547 with \",*\", \",#+\", \",,*\" and \",,#+\"."
 548   (replace-regexp-in-string
 549    "^[ \t]*,?\\(,\\)\\(?:\\*\\|#\\+\\)" "" s nil nil 1))
 550
 551
 552 \f
 553 ;;; Org src minor mode
 554
 555 (defvar org-src-mode-map
 556   (let ((map (make-sparse-keymap)))
 557     (define-key map "\C-c'" 'org-edit-src-exit)
 558     (define-key map "\C-c\C-k" 'org-edit-src-abort)
 559     (define-key map "\C-x\C-s" 'org-edit-src-save)
 560     map))
 561
 562 (define-minor-mode org-src-mode
 563   "Minor mode for language major mode buffers generated by Org.
 564 \\<org-mode-map>
 565 This minor mode is turned on in two situations:
 566   - when editing a source code snippet with \\[org-edit-special]
 567   - when formatting a source code snippet for export with htmlize.
 568
 569 \\{org-src-mode-map}
 570
 571 See also `org-src-mode-hook'."
 572   nil " OrgSrc" nil
 573   (when org-edit-src-persistent-message
 574     (org-set-local
 575      'header-line-format
 576      (substitute-command-keys
 577       (if org-src--allow-write-back
 578           "Edit, then exit with \\[org-edit-src-exit] or abort with \
 579 \\[org-edit-src-abort]"
 580         "Exit with \\[org-edit-src-exit] or abort with \
 581 \\[org-edit-src-abort]"))))
 582   ;; Possibly activate various auto-save features (for the edit buffer
 583   ;; or the source buffer).
 584   (when org-edit-src-turn-on-auto-save
 585     (setq buffer-auto-save-file-name
 586           (concat (make-temp-name "org-src-")
 587                   (format-time-string "-%Y-%d-%m")
 588                   ".txt")))
 589   (unless (or org-src--auto-save-timer (zerop org-edit-src-auto-save-idle-delay))
 590     (setq org-src--auto-save-timer
 591           (run-with-idle-timer
 592            org-edit-src-auto-save-idle-delay t
 593            (lambda ()
 594              (save-excursion
 595                (let (edit-flag)
 596                  (dolist (b (buffer-list))
 597                    (with-current-buffer b
 598                      (when (org-src-edit-buffer-p)
 599                        (unless edit-flag (setq edit-flag t))
 600                        (when (buffer-modified-p) (org-edit-src-save)))))
 601                  (unless edit-flag
 602                    (cancel-timer org-src--auto-save-timer)
 603                    (setq org-src--auto-save-timer nil)))))))))
 604
 605 (defun org-src-mode-configure-edit-buffer ()
 606   (when (org-bound-and-true-p org-src--from-org-mode)
 607     (org-add-hook 'kill-buffer-hook #'org-src--remove-overlay nil 'local)
 608     (if (org-bound-and-true-p org-src--allow-write-back)
 609         (progn
 610           (setq buffer-offer-save t)
 611           (setq buffer-file-name
 612                 (concat (buffer-file-name (marker-buffer org-src--beg-marker))
 613                         "[" (buffer-name) "]"))
 614           (if (featurep 'xemacs)
 615               (progn
 616                 (make-variable-buffer-local 'write-contents-hooks) ; needed only for 21.4
 617                 (setq write-contents-hooks '(org-edit-src-save)))
 618             (setq write-contents-functions '(org-edit-src-save))))
 619       (setq buffer-read-only t))))
 620
 621 (org-add-hook 'org-src-mode-hook #'org-src-mode-configure-edit-buffer)
 622
 623
 624 \f
 625 ;;; Babel related functions
 626
 627 (defun org-src-associate-babel-session (info)
 628   "Associate edit buffer with comint session."
 629   (interactive)
 630   (let ((session (cdr (assoc :session (nth 2 info)))))
 631     (and session (not (string= session "none"))
 632          (org-babel-comint-buffer-livep session)
 633          (let ((f (intern (format "org-babel-%s-associate-session"
 634                                   (nth 0 info)))))
 635            (and (fboundp f) (funcall f session))))))
 636
 637 (defun org-src-babel-configure-edit-buffer ()
 638   (when org-src--babel-info
 639     (org-src-associate-babel-session org-src--babel-info)))
 640
 641 (org-add-hook 'org-src-mode-hook #'org-src-babel-configure-edit-buffer)
 642
 643 (defmacro org-src-do-at-code-block (&rest body)
 644   "Execute a command from an edit buffer in the Org mode buffer."
 645   `(let ((beg-marker org-src--beg-marker))
 646      (when beg-marker
 647        (with-current-buffer (marker-buffer beg-marker)
 648          (goto-char beg-marker)
 649          ,@body))))
 650 (def-edebug-spec org-src-do-at-code-block (body))
 651
 652 (defun org-src-do-key-sequence-at-code-block (&optional key)
 653   "Execute key sequence at code block in the source Org buffer.
 654 The command bound to KEY in the Org-babel key map is executed
 655 remotely with point temporarily at the start of the code block in
 656 the Org buffer.
 657
 658 This command is not bound to a key by default, to avoid conflicts
 659 with language major mode bindings.  To bind it to C-c @ in all
 660 language major modes, you could use
 661
 662   (add-hook 'org-src-mode-hook
 663             (lambda () (define-key org-src-mode-map \"\\C-c@\"
 664                     'org-src-do-key-sequence-at-code-block)))
 665
 666 In that case, for example, C-c @ t issued in code edit buffers
 667 would tangle the current Org code block, C-c @ e would execute
 668 the block and C-c @ h would display the other available
 669 Org-babel commands."
 670   (interactive "kOrg-babel key: ")
 671   (if (equal key (kbd "C-g")) (keyboard-quit)
 672     (org-edit-src-save)
 673     (org-src-do-at-code-block
 674      (call-interactively (lookup-key org-babel-map key)))))
 675
 676
 677 \f
 678 ;;; Public functions
 679
 680 (defun org-src-edit-buffer-p (&optional buffer)
 681   "Non-nil when current buffer is a source editing buffer.
 682 If BUFFER is non-nil, test it instead."
 683   (let ((buffer (org-base-buffer (or buffer (current-buffer)))))
 684     (and (buffer-live-p buffer)
 685          (local-variable-p 'org-src--beg-marker buffer)
 686          (local-variable-p 'org-src--end-marker buffer))))
 687
 688 (defun org-src-switch-to-buffer (buffer context)
 689   (case org-src-window-setup
 690     (current-window (org-pop-to-buffer-same-window buffer))
 691     (other-window
 692      (switch-to-buffer-other-window buffer))
 693     (other-frame
 694      (case context
 695        (exit
 696         (let ((frame (selected-frame)))
 697           (switch-to-buffer-other-frame buffer)
 698           (delete-frame frame)))
 699        (save
 700         (kill-buffer (current-buffer))
 701         (org-pop-to-buffer-same-window buffer))
 702        (t (switch-to-buffer-other-frame buffer))))
 703     (reorganize-frame
 704      (when (eq context 'edit) (delete-other-windows))
 705      (org-switch-to-buffer-other-window buffer)
 706      (when (eq context 'exit) (delete-other-windows)))
 707     (switch-invisibly (set-buffer buffer))
 708     (t
 709      (message "Invalid value %s for `org-src-window-setup'"
 710               org-src-window-setup)
 711      (org-pop-to-buffer-same-window buffer))))
 712
 713 (defun org-edit-footnote-reference ()
 714   "Edit definition of footnote reference at point."
 715   (interactive)
 716   (let* ((context (org-element-context))
 717          (label (org-element-property :label context)))
 718     (unless (and (eq (org-element-type context) 'footnote-reference)
 719                  (org-src--on-datum-p context))
 720       (user-error "Not on a footnote reference"))
 721     (unless label (user-error "Cannot edit remotely anonymous footnotes"))
 722     (let* ((definition (org-with-wide-buffer
 723                         (org-footnote-goto-definition label)
 724                         (org-element-context)))
 725            (inline (eq (org-element-type definition) 'footnote-reference))
 726            (contents
 727             (let ((c (org-with-wide-buffer
 728                       (org-trim (buffer-substring-no-properties
 729                                  (org-element-property :begin definition)
 730                                  (org-element-property :end definition))))))
 731               (add-text-properties
 732                0
 733                (progn (string-match (if inline "\\`\\[fn:.*?:" "\\`.*?\\]") c)
 734                       (match-end 0))
 735                '(read-only "Cannot edit footnote label" front-sticky t
 736                            rear-nonsticky t)
 737                c)
 738               (when inline
 739                 (let ((l (length c)))
 740                   (add-text-properties
 741                    (1- l) l
 742                    '(read-only "Cannot edit past footnote reference"
 743                                front-sticky nil rear-nonsticky nil)
 744                    c)))
 745               c)))
 746       (org-src--edit-element
 747        definition
 748        (format "*Edit footnote [%s]*" label)
 749        #'org-mode
 750        `(lambda ()
 751           (if ,(not inline) (delete-region (point) (search-forward "]"))
 752             (delete-region (point) (search-forward ":" nil t 2))
 753             (delete-region (1- (point-max)) (point-max))
 754             (when (re-search-forward "\n[ \t]*\n" nil t)
 755               (user-error "Inline definitions cannot contain blank lines"))
 756             ;; If footnote reference belongs to a table, make sure to
 757             ;; remove any newline characters in order to preserve
 758             ;; table's structure.
 759             (when ,(org-element-lineage definition '(table-cell))
 760               (while (search-forward "\n" nil t) (delete-char -1)))))
 761        contents
 762        'remote))
 763     ;; Report success.
 764     t))
 765
 766 (defun org-edit-table.el ()
 767   "Edit \"table.el\" table at point.
 768
 769 A new buffer is created and the table is copied into it.  Then
 770 the table is recognized with `table-recognize'.  When done
 771 editing, exit with \\[org-edit-src-exit].  The edited text will
 772 then replace the area in the Org mode buffer.
 773
 774 Throw an error when not at such a table."
 775   (interactive)
 776   (let ((element (org-element-at-point)))
 777     (unless (and (eq (org-element-type element) 'table)
 778                  (eq (org-element-property :type element) 'table.el)
 779                  (org-src--on-datum-p element))
 780       (user-error "Not in a table.el table"))
 781     (org-src--edit-element
 782      element
 783      (org-src--construct-edit-buffer-name (buffer-name) "Table")
 784      #'text-mode t)
 785     (when (org-bound-and-true-p flyspell-mode) (flyspell-mode -1))
 786     (table-recognize)
 787     t))
 788
 789 (defun org-edit-export-block ()
 790   "Edit export block at point.
 791
 792 A new buffer is created and the block is copied into it, and the
 793 buffer is switched into an appropriate major mode.  See also
 794 `org-src-lang-modes'.  When done, exit with
 795 \\[org-edit-src-exit].  The edited text will then replace the
 796 area in the Org mode buffer.
 797
 798 Throw an error when not at an export block."
 799   (interactive)
 800   (let ((element (org-element-at-point)))
 801     (unless (and (eq (org-element-type element) 'export-block)
 802                  (org-src--on-datum-p element))
 803       (user-error "Not in an export block"))
 804     (let* ((type (downcase (org-element-property :type element)))
 805            (mode (org-src--get-lang-mode type)))
 806       (unless (functionp mode) (error "No such language mode: %s" mode))
 807       (org-src--edit-element
 808        element
 809        (org-src--construct-edit-buffer-name (buffer-name) type)
 810        mode
 811        (lambda () (org-escape-code-in-region (point-min) (point-max)))))
 812     t))
 813
 814 (defun org-edit-src-code (&optional code edit-buffer-name)
 815   "Edit the source or example block at point.
 816 \\<org-src-mode-map>
 817 The code is copied to a separate buffer and the appropriate mode
 818 is turned on.  When done, exit with \\[org-edit-src-exit].  This \
 819 will remove the
 820 original code in the Org buffer, and replace it with the edited
 821 version.  See `org-src-window-setup' to configure the display of
 822 windows containing the Org buffer and the code buffer.
 823
 824 When optional argument CODE is a string, edit it in a dedicated
 825 buffer instead.
 826
 827 When optional argument EDIT-BUFFER-NAME is non-nil, use it as the
 828 name of the sub-editing buffer."
 829   (interactive)
 830   (let* ((element (org-element-at-point))
 831          (type (org-element-type element)))
 832     (unless (and (memq type '(example-block src-block))
 833                  (org-src--on-datum-p element))
 834       (user-error "Not in a source or example block"))
 835     (let* ((lang
 836             (if (eq type 'src-block) (org-element-property :language element)
 837               "example"))
 838            (lang-f (and (eq type 'src-block) (org-src--get-lang-mode lang)))
 839            (babel-info (and (eq type 'src-block)
 840                             (org-babel-get-src-block-info 'light)))
 841            deactivate-mark)
 842       (when (and (eq type 'src-block) (not (functionp lang-f)))
 843         (error "No such language mode: %s" lang-f))
 844       (org-src--edit-element
 845        element
 846        (or edit-buffer-name
 847            (org-src--construct-edit-buffer-name (buffer-name) lang))
 848        lang-f
 849        (and (null code)
 850             `(lambda ()
 851                (unless ,(or org-src-preserve-indentation
 852                             (org-element-property :preserve-indent element))
 853                  (untabify (point-min) (point-max))
 854                  (when (> org-edit-src-content-indentation 0)
 855                    (let ((ind (make-string org-edit-src-content-indentation
 856                                            ?\s)))
 857                      (while (not (eobp))
 858                        (unless (looking-at "[ \t]*$") (insert ind))
 859                        (forward-line)))))
 860                (org-escape-code-in-region (point-min) (point-max))))
 861        (and code (org-unescape-code-in-string code)))
 862       ;; Finalize buffer.
 863       (org-set-local 'org-coderef-label-format
 864                      (or (org-element-property :label-fmt element)
 865                          org-coderef-label-format))
 866       (when (eq type 'src-block)
 867         (org-set-local 'org-src--babel-info babel-info)
 868         (let ((edit-prep-func (intern (concat "org-babel-edit-prep:" lang))))
 869           (when (fboundp edit-prep-func)
 870             (funcall edit-prep-func babel-info))))
 871       t)))
 872
 873 (defun org-edit-fixed-width-region ()
 874   "Edit the fixed-width ASCII drawing at point.
 875
 876 This must be a region where each line starts with a colon
 877 followed by a space or a newline character.
 878
 879 A new buffer is created and the fixed-width region is copied into
 880 it, and the buffer is switched into the major mode defined in
 881 `org-edit-fixed-width-region-mode', which see.  When done, exit
 882 with \\[org-edit-src-exit].  The edited text will then replace
 883 the area in the Org mode buffer."
 884   (interactive)
 885   (let ((element (org-element-at-point)))
 886     (unless (and (eq (org-element-type element) 'fixed-width)
 887                  (org-src--on-datum-p element))
 888       (user-error "Not in a fixed-width area"))
 889     (org-src--edit-element
 890      element
 891      (org-src--construct-edit-buffer-name (buffer-name) "Fixed Width")
 892      org-edit-fixed-width-region-mode
 893      (lambda () (while (not (eobp)) (insert ": ") (forward-line))))
 894     ;; Return success.
 895     t))
 896
 897 (defun org-edit-src-abort ()
 898   "Abort editing of the src code and return to the Org buffer."
 899   (interactive)
 900   (let (org-src--allow-write-back) (org-edit-src-exit)))
 901
 902 (defun org-edit-src-continue (e)
 903   "Unconditionally return to buffer editing area under point.
 904 Throw an error if there is no such buffer."
 905   (interactive "e")
 906   (mouse-set-point e)
 907   (let ((buf (get-char-property (point) 'edit-buffer)))
 908     (if buf (org-src-switch-to-buffer buf 'continue)
 909       (user-error "No sub-editing buffer for area at point"))))
 910
 911 (defun org-edit-src-save ()
 912   "Save parent buffer with current state source-code buffer."
 913   (interactive)
 914   (unless (org-src-edit-buffer-p) (user-error "Not in a sub-editing buffer"))
 915   (set-buffer-modified-p nil)
 916   (let ((edited-code (org-src--contents-for-write-back))
 917         (beg org-src--beg-marker)
 918         (end org-src--end-marker)
 919         (overlay org-src--overlay))
 920     (with-current-buffer (org-src--source-buffer)
 921       (undo-boundary)
 922       (goto-char beg)
 923       ;; Temporarily disable read-only features of OVERLAY in order to
 924       ;; insert new contents.
 925       (delete-overlay overlay)
 926       (delete-region beg end)
 927       (let ((expecting-bol (bolp)))
 928         (insert edited-code)
 929         (when (and expecting-bol (not (bolp))) (insert "\n")))
 930       (save-buffer)
 931       (move-overlay overlay beg (point)))))
 932
 933 (defun org-edit-src-exit ()
 934   "Kill current sub-editing buffer and return to source buffer."
 935   (interactive)
 936   (unless (org-src-edit-buffer-p) (error "Not in a sub-editing buffer"))
 937   (let* ((beg org-src--beg-marker)
 938          (end org-src--end-marker)
 939          (write-back org-src--allow-write-back)
 940          (remote org-src--remote)
 941          (coordinates (and (not remote)
 942                            (org-src--coordinates (point) 1 (point-max))))
 943          (code (and write-back (org-src--contents-for-write-back))))
 944     (set-buffer-modified-p nil)
 945     ;; Switch to source buffer.  Kill sub-editing buffer.
 946     (let ((edit-buffer (current-buffer)))
 947       (org-src-switch-to-buffer (marker-buffer beg) 'exit)
 948       (kill-buffer edit-buffer))
 949     ;; Insert modified code.  Ensure it ends with a newline character.
 950     (org-with-wide-buffer
 951      (when (and write-back (not (equal (buffer-substring beg end) code)))
 952        (undo-boundary)
 953        (goto-char beg)
 954        (delete-region beg end)
 955        (let ((expecting-bol (bolp)))
 956          (insert code)
 957          (when (and expecting-bol (not (bolp))) (insert "\n")))))
 958     ;; If we are to return to source buffer, put point at an
 959     ;; appropriate location.  In particular, if block is hidden, move
 960     ;; to the beginning of the block opening line.
 961     (unless remote
 962       (goto-char beg)
 963       (cond
 964        ;; Block is hidden; move at start of block.
 965        ((org-some (lambda (o) (eq (overlay-get o 'invisible) 'org-hide-block))
 966                   (overlays-at (point)))
 967         (beginning-of-line 0))
 968        (write-back (org-src--goto-coordinates coordinates beg end))))
 969     ;; Clean up left-over markers and restore window configuration.
 970     (set-marker beg nil)
 971     (set-marker end nil)
 972     (when org-src--saved-temp-window-config
 973       (set-window-configuration org-src--saved-temp-window-config)
 974       (setq org-src--saved-temp-window-config nil))))
 975
 976
 977 (provide 'org-src)
 978
 979 ;;; org-src.el ends here