configure.ac

   1 AC_PREREQ(2.64)
   2 AC_INIT([openocd], [0.10.0+dev],
   3   [OpenOCD Mailing List <openocd-devel@lists.sourceforge.net>])
   4 AC_CONFIG_SRCDIR([src/openocd.c])
   5
   6 m4_include([config_subdir.m4])dnl
   7
   8 # check for makeinfo before calling AM_INIT_AUTOMAKE
   9 AC_CHECK_PROG([MAKEINFO], [makeinfo], [makeinfo])
  10 AS_IF([test "x$MAKEINFO" = "x"], [
  11   MAKEINFO='echo makeinfo missing; true'
  12   AC_MSG_WARN([Info documentation will not be built.])
  13 ])
  14 AC_SUBST([MAKEINFO])
  15
  16 AM_INIT_AUTOMAKE([-Wall -Wno-portability dist-bzip2 dist-zip subdir-objects])
  17
  18 AC_CONFIG_HEADERS([config.h])
  19 AH_BOTTOM([
  20 #include <helper/system.h>
  21 #include <helper/types.h>
  22 #include <helper/replacements.h>
  23 ])
  24
  25 AC_LANG([C])
  26 AC_PROG_CC
  27 AC_PROG_CC_C99
  28 AM_PROG_CC_C_O
  29 AC_PROG_RANLIB
  30 PKG_PROG_PKG_CONFIG([0.23])
  31
  32 dnl disable checks for C++, Fortran and GNU Java Compiler
  33 m4_defun([_LT_AC_LANG_CXX_CONFIG], [:])
  34 m4_defun([_LT_AC_LANG_F77_CONFIG], [:])
  35 m4_defun([_LT_AC_LANG_GCJ_CONFIG], [:])
  36 AC_DISABLE_SHARED
  37 LT_INIT
  38 AC_SUBST([LIBTOOL_DEPS])
  39
  40 dnl configure checks required for Jim files (these are obsolete w/ C99)
  41 AC_C_CONST
  42 AC_TYPE_LONG_LONG_INT
  43
  44 AC_SEARCH_LIBS([ioperm], [ioperm])
  45 AC_SEARCH_LIBS([dlopen], [dl])
  46
  47 AC_CHECK_HEADERS([sys/socket.h])
  48 AC_CHECK_HEADERS([elf.h])
  49 AC_CHECK_HEADERS([dirent.h])
  50 AC_CHECK_HEADERS([fcntl.h])
  51 AC_CHECK_HEADERS([malloc.h])
  52 AC_CHECK_HEADERS([netdb.h])
  53 AC_CHECK_HEADERS([poll.h])
  54 AC_CHECK_HEADERS([pthread.h])
  55 AC_CHECK_HEADERS([strings.h])
  56 AC_CHECK_HEADERS([sys/ioctl.h])
  57 AC_CHECK_HEADERS([sys/param.h])
  58 AC_CHECK_HEADERS([sys/select.h])
  59 AC_CHECK_HEADERS([sys/stat.h])
  60 AC_CHECK_HEADERS([sys/sysctl.h])
  61 AC_CHECK_HEADERS([sys/time.h])
  62 AC_CHECK_HEADERS([sys/types.h])
  63 AC_CHECK_HEADERS([unistd.h])
  64 AC_CHECK_HEADERS([arpa/inet.h ifaddrs.h netinet/in.h netinet/tcp.h net/if.h], [], [], [dnl
  65 #include <stdio.h>
  66 #ifdef STDC_HEADERS
  67 # include <stdlib.h>
  68 # include <stddef.h>
  69 #else
  70 # ifdef HAVE_STDLIB_H
  71 #  include <stdlib.h>
  72 # endif
  73 #endif
  74 #ifdef HAVE_SYS_SOCKET_H
  75 # include <sys/socket.h>
  76 #endif
  77 ])
  78
  79 AC_HEADER_ASSERT
  80 AC_HEADER_STDBOOL
  81 AC_HEADER_TIME
  82
  83 AC_C_BIGENDIAN
  84
  85 AC_CHECK_FUNCS([strndup])
  86 AC_CHECK_FUNCS([strnlen])
  87 AC_CHECK_FUNCS([gettimeofday])
  88 AC_CHECK_FUNCS([usleep])
  89 AC_CHECK_FUNCS([vasprintf])
  90 AC_CHECK_FUNCS([realpath])
  91
  92 # guess-rev.sh only exists in the repository, not in the released archives
  93 AC_MSG_CHECKING([whether to build a release])
  94 AS_IF([test -x "$srcdir/guess-rev.sh"], [
  95   build_release=no
  96 ], [
  97   build_release=yes
  98 ])
  99 AC_MSG_RESULT([$build_release])
 100
 101 # Adapter drivers
 102 # 1st column -- configure option
 103 # 2nd column -- description
 104 # 3rd column -- symbol used for both config.h and automake
 105 m4_define([ADAPTER_ARG], [m4_argn([1], $1)])
 106 m4_define([ADAPTER_DESC], [m4_argn([2], $1)])
 107 m4_define([ADAPTER_SYM], [m4_argn([3], $1)])
 108 m4_define([ADAPTER_VAR], [enable_[]ADAPTER_ARG($1)])
 109 m4_define([ADAPTER_OPT], [m4_translit(ADAPTER_ARG($1), [_], [-])])
 110
 111 m4_define([USB1_ADAPTERS],
 112         [[[ftdi], [MPSSE mode of FTDI based devices], [FTDI]],
 113         [[stlink], [ST-Link Programmer], [HLADAPTER_STLINK]],
 114         [[ti_icdi], [TI ICDI JTAG Programmer], [HLADAPTER_ICDI]],
 115         [[ulink], [Keil ULINK JTAG Programmer], [ULINK]],
 116         [[usb_blaster_2], [Altera USB-Blaster II Compatible], [USB_BLASTER_2]],
 117         [[ft232r], [Bitbang mode of FT232R based devices], [FT232R]],
 118         [[vsllink], [Versaloon-Link JTAG Programmer], [VSLLINK]],
 119         [[xds110], [TI XDS110 Debug Probe], [XDS110]],
 120         [[osbdm], [OSBDM (JTAG only) Programmer], [OSBDM]],
 121         [[opendous], [eStick/opendous JTAG Programmer], [OPENDOUS]],
 122         [[aice], [Andes JTAG Programmer], [AICE]]])
 123
 124 m4_define([USB0_ADAPTERS],
 125         [[[usbprog], [USBProg JTAG Programmer], [USBPROG]],
 126         [[rlink], [Raisonance RLink JTAG Programmer], [RLINK]],
 127         [[armjtagew], [Olimex ARM-JTAG-EW Programmer], [ARMJTAGEW]]])
 128
 129 m4_define([HIDAPI_ADAPTERS],
 130         [[[cmsis_dap], [CMSIS-DAP Compliant Debugger], [CMSIS_DAP]],
 131         [[nulink], [Nu-Link Programmer], [HLADAPTER_NULINK]]])
 132
 133 m4_define([HIDAPI_USB1_ADAPTERS],
 134         [[[kitprog], [Cypress KitProg Programmer], [KITPROG]]])
 135
 136 m4_define([LIBFTDI_ADAPTERS],
 137         [[[usb_blaster], [Altera USB-Blaster Compatible], [USB_BLASTER]],
 138         [[presto], [ASIX Presto Adapter], [PRESTO]],
 139         [[openjtag], [OpenJTAG Adapter], [OPENJTAG]]])
 140
 141 m4_define([LIBGPIOD_ADAPTERS],
 142         [[[linuxgpiod], [Linux GPIO bitbang through libgpiod], [LINUXGPIOD]]])
 143
 144 m4_define([LIBJAYLINK_ADAPTERS],
 145         [[[jlink], [SEGGER J-Link Programmer], [JLINK]]])
 146
 147 m4_define([PCIE_ADAPTERS],
 148         [[[xlnx_pcie_xvc], [Xilinx XVC/PCIe], [XLNX_PCIE_XVC]]])
 149
 150
 151 AC_ARG_ENABLE([doxygen-html],
 152   AS_HELP_STRING([--disable-doxygen-html],
 153     [Disable building Doxygen manual as HTML.]),
 154   [doxygen_as_html=$enableval], [doxygen_as_html=yes])
 155 AC_SUBST([doxygen_as_html])
 156 AC_MSG_CHECKING([whether to build Doxygen as HTML])
 157 AC_MSG_RESULT([$doxygen_as_html])
 158
 159 AC_ARG_ENABLE([doxygen-pdf],
 160   AS_HELP_STRING([--enable-doxygen-pdf],
 161     [Enable building Doxygen manual as PDF.]),
 162   [doxygen_as_pdf=$enableval], [doxygen_as_pdf=no])
 163 AC_SUBST([doxygen_as_pdf])
 164 AC_MSG_CHECKING([whether to build Doxygen as PDF])
 165 AC_MSG_RESULT([$doxygen_as_pdf])
 166
 167 AC_ARG_ENABLE([gccwarnings],
 168   AS_HELP_STRING([--disable-gccwarnings], [Disable compiler warnings]),
 169   [gcc_warnings=$enableval], [gcc_warnings=yes])
 170
 171 AC_ARG_ENABLE([wextra],
 172   AS_HELP_STRING([--disable-wextra], [Disable extra compiler warnings]),
 173   [gcc_wextra=$enableval], [gcc_wextra=$gcc_warnings])
 174
 175 AC_ARG_ENABLE([werror],
 176   AS_HELP_STRING([--disable-werror], [Do not treat warnings as errors]),
 177   [gcc_werror=$enableval], [gcc_werror=$gcc_warnings])
 178
 179 # set default verbose options, overridden by following options
 180 debug_usb_io=no
 181 debug_usb_comms=no
 182
 183 AC_ARG_ENABLE([verbose],
 184   AS_HELP_STRING([--enable-verbose],
 185       [Enable verbose JTAG I/O messages (for debugging).]),
 186   [
 187   debug_usb_io=$enableval
 188   debug_usb_comms=$enableval
 189   ], [])
 190
 191 AC_ARG_ENABLE([verbose_usb_io],
 192   AS_HELP_STRING([--enable-verbose-usb-io],
 193       [Enable verbose USB I/O messages (for debugging)]),
 194   [debug_usb_io=$enableval], [])
 195
 196 AC_ARG_ENABLE([verbose_usb_comms],
 197   AS_HELP_STRING([--enable-verbose-usb-comms],
 198       [Enable verbose USB communication messages (for debugging)]),
 199   [debug_usb_comms=$enableval], [])
 200
 201 AC_MSG_CHECKING([whether to enable verbose USB I/O messages]);
 202 AC_MSG_RESULT([$debug_usb_io])
 203 AS_IF([test "x$debug_usb_io" = "xyes"], [
 204   AC_DEFINE([_DEBUG_USB_IO_],[1], [Print verbose USB I/O messages])
 205 ])
 206
 207 AC_MSG_CHECKING([whether to enable verbose USB communication messages]);
 208 AC_MSG_RESULT([$debug_usb_comms])
 209 AS_IF([test "x$debug_usb_comms" = "xyes"], [
 210   AC_DEFINE([_DEBUG_USB_COMMS_],[1], [Print verbose USB communication messages])
 211 ])
 212
 213 debug_malloc=no
 214 AC_ARG_ENABLE([malloc_logging],
 215   AS_HELP_STRING([--enable-malloc-logging],
 216       [Include free space in logging messages (requires malloc.h).]),
 217   [debug_malloc=$enableval], [])
 218
 219 AC_MSG_CHECKING([whether to enable malloc free space logging]);
 220 AC_MSG_RESULT([$debug_malloc])
 221 AS_IF([test "x$debug_malloc" = "xyes"], [
 222   AC_DEFINE([_DEBUG_FREE_SPACE_],[1], [Include malloc free space in logging])
 223 ])
 224
 225 AC_ARG_ENABLE([dummy],
 226   AS_HELP_STRING([--enable-dummy], [Enable building the dummy port driver]),
 227   [build_dummy=$enableval], [build_dummy=no])
 228
 229 AC_ARG_ENABLE([rshim],
 230   AS_HELP_STRING([--enable-rshim], [Enable building the rshim driver]),
 231   [build_rshim=$enableval], [build_rshim=no])
 232
 233 m4_define([AC_ARG_ADAPTERS], [
 234   m4_foreach([adapter], [$1],
 235         [AC_ARG_ENABLE(ADAPTER_OPT([adapter]),
 236                 AS_HELP_STRING([--enable-ADAPTER_OPT([adapter])],
 237                         [Enable building support for the ]ADAPTER_DESC([adapter])[ (default is $2)]),
 238                 [], [ADAPTER_VAR([adapter])=$2])
 239   ])
 240 ])
 241
 242 AC_ARG_ADAPTERS([
 243   USB1_ADAPTERS,
 244   USB0_ADAPTERS,
 245   HIDAPI_ADAPTERS,
 246   HIDAPI_USB1_ADAPTERS,
 247   LIBFTDI_ADAPTERS,
 248   LIBGPIOD_ADAPTERS,
 249   LIBJAYLINK_ADAPTERS
 250   ],[auto])
 251
 252 AC_ARG_ENABLE([parport],
 253   AS_HELP_STRING([--enable-parport], [Enable building the pc parallel port driver]),
 254   [build_parport=$enableval], [build_parport=no])
 255
 256 AC_ARG_ENABLE([parport_ppdev],
 257   AS_HELP_STRING([--disable-parport-ppdev],
 258       [Disable use of ppdev (/dev/parportN) for parport (for x86 only)]),
 259     [parport_use_ppdev=$enableval], [parport_use_ppdev=yes])
 260
 261 AC_ARG_ENABLE([parport_giveio],
 262     AS_HELP_STRING([--enable-parport-giveio],
 263       [Enable use of giveio for parport (for CygWin only)]),
 264     [parport_use_giveio=$enableval], [parport_use_giveio=])
 265
 266 AC_ARG_ENABLE([jtag_vpi],
 267   AS_HELP_STRING([--enable-jtag_vpi], [Enable building support for JTAG VPI]),
 268   [build_jtag_vpi=$enableval], [build_jtag_vpi=no])
 269
 270 AC_ARG_ENABLE([amtjtagaccel],
 271   AS_HELP_STRING([--enable-amtjtagaccel], [Enable building the Amontec JTAG-Accelerator driver]),
 272   [build_amtjtagaccel=$enableval], [build_amtjtagaccel=no])
 273
 274 AC_ARG_ENABLE([zy1000_master],
 275   AS_HELP_STRING([--enable-zy1000-master], [Use ZY1000 JTAG master registers]),
 276   [build_zy1000_master=$enableval], [build_zy1000_master=no])
 277
 278 AC_ARG_ENABLE([zy1000],
 279   AS_HELP_STRING([--enable-zy1000], [Enable ZY1000 interface]),
 280   [build_zy1000=$enableval], [build_zy1000=no])
 281
 282 AC_ARG_ENABLE([ioutil],
 283   AS_HELP_STRING([--enable-ioutil], [Enable ioutil functions - useful for standalone OpenOCD implementations]),
 284   [build_ioutil=$enableval], [build_ioutil=no])
 285
 286 AS_CASE(["${host_cpu}"],
 287   [arm*|aarch64], [
 288     AC_ARG_ENABLE([bcm2835gpio],
 289       AS_HELP_STRING([--enable-bcm2835gpio], [Enable building support for bitbanging on BCM2835 (as found in Raspberry Pi)]),
 290       [build_bcm2835gpio=$enableval], [build_bcm2835gpio=no])
 291     AC_ARG_ENABLE([imx_gpio],
 292       AS_HELP_STRING([--enable-imx_gpio], [Enable building support for bitbanging on NXP IMX processors]),
 293       [build_imx_gpio=$enableval], [build_imx_gpio=no])
 294   ],
 295   [
 296     build_bcm2835gpio=no
 297     build_imx_gpio=no
 298 ])
 299
 300 AS_CASE(["${host_cpu}"],
 301   [arm*], [
 302     AC_ARG_ENABLE([ep93xx],
 303       AS_HELP_STRING([--enable-ep93xx], [Enable building support for EP93xx based SBCs]),
 304       [build_ep93xx=$enableval], [build_ep93xx=no])
 305
 306     AC_ARG_ENABLE([at91rm9200],
 307       AS_HELP_STRING([--enable-at91rm9200], [Enable building support for AT91RM9200 based SBCs]),
 308       [build_at91rm9200=$enableval], [build_at91rm9200=no])
 309   ],
 310   [
 311     build_ep93xx=no
 312     build_at91rm9200=no
 313 ])
 314
 315 AC_ARG_ENABLE([gw16012],
 316   AS_HELP_STRING([--enable-gw16012], [Enable building support for the Gateworks GW16012 JTAG Programmer]),
 317   [build_gw16012=$enableval], [build_gw16012=no])
 318
 319 AC_ARG_ENABLE([oocd_trace],
 320   AS_HELP_STRING([--enable-oocd_trace],
 321   [Enable building support for some prototype OpenOCD+trace ETM capture hardware]),
 322   [build_oocd_trace=$enableval], [build_oocd_trace=no])
 323
 324 AC_ARG_ENABLE([buspirate],
 325   AS_HELP_STRING([--enable-buspirate], [Enable building support for the Buspirate]),
 326   [build_buspirate=$enableval], [build_buspirate=no])
 327
 328 AC_ARG_ENABLE([sysfsgpio],
 329   AS_HELP_STRING([--enable-sysfsgpio], [Enable building support for programming driven via sysfs gpios.]),
 330   [build_sysfsgpio=$enableval], [build_sysfsgpio=no])
 331
 332 AC_ARG_ENABLE([xlnx_pcie_xvc],
 333   AS_HELP_STRING([--enable-xlnx-pcie-xvc], [Enable building support for Xilinx XVC/PCIe.]),
 334   [build_xlnx_pcie_xvc=$enableval], [build_xlnx_pcie_xvc=no])
 335
 336 AS_CASE([$host_os],
 337   [linux*], [],
 338   [
 339     AS_IF([test "x$build_sysfsgpio" = "xyes"], [
 340       AC_MSG_ERROR([sysfsgpio is only available on linux])
 341     ])
 342
 343     AS_IF([test "x$enable_linuxgpiod" = "xyes"], [
 344       AC_MSG_ERROR([linuxgpiod is only available on linux])
 345     ])
 346
 347     AS_IF([test "x$build_xlnx_pcie_xvc" = "xyes"], [
 348       AC_MSG_ERROR([xlnx_pcie_xvc is only available on linux])
 349     ])
 350
 351     AS_CASE([$host_os], [freebsd*], [],
 352     [
 353       AS_IF([test "x$build_rshim" = "xyes"], [
 354         AC_MSG_ERROR([build_rshim is only available on linux or freebsd])
 355       ])
 356     ])
 357 ])
 358
 359 AC_ARG_ENABLE([minidriver_dummy],
 360   AS_HELP_STRING([--enable-minidriver-dummy], [Enable the dummy minidriver.]),
 361   [build_minidriver_dummy=$enableval], [build_minidriver_dummy=no])
 362
 363 AC_ARG_ENABLE([internal-jimtcl],
 364   AS_HELP_STRING([--disable-internal-jimtcl], [Disable building internal jimtcl]),
 365   [use_internal_jimtcl=$enableval], [use_internal_jimtcl=yes])
 366
 367 AC_ARG_ENABLE([internal-libjaylink],
 368   AS_HELP_STRING([--disable-internal-libjaylink],
 369   [Disable building internal libjaylink]),
 370   [use_internal_libjaylink=$enableval], [use_internal_libjaylink=yes])
 371
 372 build_minidriver=no
 373 AC_MSG_CHECKING([whether to enable ZY1000 minidriver])
 374 AS_IF([test "x$build_zy1000" = "xyes"], [
 375   AS_IF([test "x$build_minidriver" = "xyes"], [
 376     AC_MSG_ERROR([Multiple minidriver options have been enabled.])
 377   ])
 378   AC_DEFINE([HAVE_JTAG_MINIDRIVER_H], [1],
 379       [Define to 1 if you have the <jtag_minidriver.h> header file.])
 380   build_minidriver=yes
 381 ])
 382 AC_MSG_RESULT([$build_zy1000])
 383
 384 AC_ARG_ENABLE([remote-bitbang],
 385   AS_HELP_STRING([--enable-remote-bitbang], [Enable building support for the Remote Bitbang jtag driver]),
 386   [build_remote_bitbang=$enableval], [build_remote_bitbang=no])
 387
 388 AC_MSG_CHECKING([whether to enable dummy minidriver])
 389 AS_IF([test "x$build_minidriver_dummy" = "xyes"], [
 390   AS_IF([test "x$build_minidriver" = "xyes"], [
 391     AC_MSG_ERROR([Multiple minidriver options have been enabled.])
 392   ])
 393   build_minidriver=yes
 394   AC_DEFINE([BUILD_MINIDRIVER_DUMMY], [1], [Use the dummy minidriver.])
 395   AC_DEFINE([HAVE_JTAG_MINIDRIVER_H], [1],
 396       [Define to 1 if you have the <jtag_minidriver.h> header file.])
 397 ])
 398 AC_MSG_RESULT([$build_minidriver_dummy])
 399
 400 AC_MSG_CHECKING([whether standard drivers can be built])
 401 AS_IF([test "x$build_minidriver" = "xyes"], [
 402   AC_MSG_RESULT([no])
 403   AC_MSG_WARN([Using the minidriver disables all other drivers.])
 404   sleep 2
 405 ], [
 406   AC_MSG_RESULT([yes])
 407 ])
 408
 409 AS_CASE(["${host_cpu}"],
 410   [i?86|x86*], [],
 411   [
 412     AS_IF([test "x$parport_use_ppdev" = "xno"], [
 413       AC_MSG_WARN([--disable-parport-ppdev is not supported by the host CPU])
 414     ])
 415     parport_use_ppdev=yes
 416 ])
 417
 418 AS_CASE([$host],
 419   [*-cygwin*], [
 420     is_win32=yes
 421     parport_use_ppdev=no
 422
 423     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[return __MINGW32__;]])],
 424       [is_mingw=yes],[is_mingw=no])
 425     AS_IF([test "x$is_mingw" = "xyes"], [
 426       AS_IF([test "x$parport_use_giveio" = "xno"], [
 427         AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
 428       ])
 429       parport_use_giveio=yes
 430       is_cygwin=no
 431     ], [
 432       is_cygwin=yes
 433       # sys/io.h needed under cygwin for parport access
 434       AS_IF([test "x$build_parport" = "xyes"], [
 435         AC_CHECK_HEADERS([sys/io.h],[],AC_MSG_ERROR([Please install the cygwin ioperm package]))
 436       ])
 437     ])
 438   ],
 439   [*-mingw* | *-msys*], [
 440     is_mingw=yes
 441     is_win32=yes
 442     parport_use_ppdev=no
 443
 444     AS_IF([test "x$parport_use_giveio" = "xno"], [
 445       AC_MSG_WARN([--disable-parport-giveio is not supported by MinGW32 hosts])
 446     ])
 447     parport_use_giveio=yes
 448
 449     AS_IF([test "x$build_buspirate" = "xyes"], [
 450       AC_MSG_ERROR([buspirate currently not supported by MinGW32 hosts])
 451     ])
 452
 453     AC_SUBST([HOST_CPPFLAGS], [-D__USE_MINGW_ANSI_STDIO])
 454   ],
 455   [*darwin*], [
 456     is_darwin=yes
 457
 458     AS_IF([test "x$parport_use_giveio" = "xyes"], [
 459       AC_MSG_WARN([--enable-parport-giveio cannot be used by Darwin hosts])
 460     ])
 461     parport_use_giveio=no
 462   ],
 463   [
 464     AS_IF([test "x$parport_use_giveio" = "xyes"], [
 465       AC_MSG_WARN([--enable-parport-giveio cannot be used by ]$host[ hosts])
 466     ])
 467     parport_use_giveio=no
 468 ])
 469
 470 AS_IF([test "x$is_cygwin" = "xyes"], [
 471     AC_DEFINE([IS_CYGWIN], [1], [1 if building for Cygwin.])
 472 ], [
 473     AC_DEFINE([IS_CYGWIN], [0], [0 if not building for Cygwin.])
 474 ])
 475
 476 AS_IF([test "x$is_mingw" = "xyes"], [
 477     AC_DEFINE([IS_MINGW], [1], [1 if building for Mingw.])
 478 ], [
 479     AC_DEFINE([IS_MINGW], [0], [0 if not building for Mingw.])
 480 ])
 481
 482 AS_IF([test "x$is_win32" = "xyes"], [
 483     AC_DEFINE([IS_WIN32], [1], [1 if building for Win32.])
 484 ], [
 485     AC_DEFINE([IS_WIN32], [0], [0 if not building for Win32.])
 486 ])
 487
 488 AS_IF([test "x$is_darwin" = "xyes"], [
 489     AC_DEFINE([IS_DARWIN], [1], [1 if building for Darwin.])
 490 ], [
 491     AC_DEFINE([IS_DARWIN], [0], [0 if not building for Darwin.])
 492 ])
 493
 494 AS_IF([test "x$build_parport" = "xyes"], [
 495   build_bitbang=yes
 496   AC_DEFINE([BUILD_PARPORT], [1], [1 if you want parport.])
 497 ], [
 498   AC_DEFINE([BUILD_PARPORT], [0], [0 if you don't want parport.])
 499 ])
 500
 501 AS_IF([test "x$build_rshim" = "xyes"], [
 502   AC_DEFINE([BUILD_RSHIM], [1], [1 if you want to debug BlueField SoC via rshim.])
 503 ], [
 504   AC_DEFINE([BUILD_RSHIM], [0], [0 if you don't want to debug BlueField SoC via rshim.])
 505 ])
 506
 507 AS_IF([test "x$build_dummy" = "xyes"], [
 508   build_bitbang=yes
 509   AC_DEFINE([BUILD_DUMMY], [1], [1 if you want dummy driver.])
 510 ], [
 511   AC_DEFINE([BUILD_DUMMY], [0], [0 if you don't want dummy driver.])
 512 ])
 513
 514 AS_IF([test "x$build_ep93xx" = "xyes"], [
 515   build_bitbang=yes
 516   AC_DEFINE([BUILD_EP93XX], [1], [1 if you want ep93xx.])
 517 ], [
 518   AC_DEFINE([BUILD_EP93XX], [0], [0 if you don't want ep93xx.])
 519 ])
 520
 521 AS_IF([test "x$build_zy1000" = "xyes"], [
 522   AC_DEFINE([BUILD_ZY1000], [1], [1 if you want ZY1000.])
 523 ], [
 524   AC_DEFINE([BUILD_ZY1000], [0], [0 if you don't want ZY1000.])
 525 ])
 526
 527 AS_IF([test "x$build_zy1000_master" = "xyes"], [
 528   AC_DEFINE([BUILD_ZY1000_MASTER], [1], [1 if you want ZY1000 JTAG master registers.])
 529 ], [
 530   AC_DEFINE([BUILD_ZY1000_MASTER], [0], [0 if you don't want ZY1000 JTAG master registers.])
 531 ])
 532
 533 AS_IF([test "x$build_at91rm9200" = "xyes"], [
 534   build_bitbang=yes
 535   AC_DEFINE([BUILD_AT91RM9200], [1], [1 if you want at91rm9200.])
 536 ], [
 537   AC_DEFINE([BUILD_AT91RM9200], [0], [0 if you don't want at91rm9200.])
 538 ])
 539
 540 AS_IF([test "x$build_bcm2835gpio" = "xyes"], [
 541   build_bitbang=yes
 542   AC_DEFINE([BUILD_BCM2835GPIO], [1], [1 if you want bcm2835gpio.])
 543 ], [
 544   AC_DEFINE([BUILD_BCM2835GPIO], [0], [0 if you don't want bcm2835gpio.])
 545 ])
 546
 547 AS_IF([test "x$build_imx_gpio" = "xyes"], [
 548   build_bitbang=yes
 549   AC_DEFINE([BUILD_IMX_GPIO], [1], [1 if you want imx_gpio.])
 550 ], [
 551   AC_DEFINE([BUILD_IMX_GPIO], [0], [0 if you don't want imx_gpio.])
 552 ])
 553
 554 AS_IF([test "x$parport_use_ppdev" = "xyes"], [
 555   AC_DEFINE([PARPORT_USE_PPDEV], [1], [1 if you want parport to use ppdev.])
 556 ], [
 557   AC_DEFINE([PARPORT_USE_PPDEV], [0], [0 if you don't want parport to use ppdev.])
 558 ])
 559
 560 AS_IF([test "x$parport_use_giveio" = "xyes"], [
 561   AC_DEFINE([PARPORT_USE_GIVEIO], [1], [1 if you want parport to use giveio.])
 562 ], [
 563   AC_DEFINE([PARPORT_USE_GIVEIO], [0], [0 if you don't want parport to use giveio.])
 564 ])
 565
 566 AS_IF([test "x$build_jtag_vpi" = "xyes"], [
 567   AC_DEFINE([BUILD_JTAG_VPI], [1], [1 if you want JTAG VPI.])
 568 ], [
 569   AC_DEFINE([BUILD_JTAG_VPI], [0], [0 if you don't want JTAG VPI.])
 570 ])
 571
 572 AS_IF([test "x$build_amtjtagaccel" = "xyes"], [
 573   AC_DEFINE([BUILD_AMTJTAGACCEL], [1], [1 if you want the Amontec JTAG-Accelerator driver.])
 574 ], [
 575   AC_DEFINE([BUILD_AMTJTAGACCEL], [0], [0 if you don't want the Amontec JTAG-Accelerator driver.])
 576 ])
 577
 578 AS_IF([test "x$build_gw16012" = "xyes"], [
 579   AC_DEFINE([BUILD_GW16012], [1], [1 if you want the Gateworks GW16012 driver.])
 580 ], [
 581   AC_DEFINE([BUILD_GW16012], [0], [0 if you don't want the Gateworks GW16012 driver.])
 582 ])
 583
 584 AS_IF([test "x$build_oocd_trace" = "xyes"], [
 585   AC_DEFINE([BUILD_OOCD_TRACE], [1], [1 if you want the OpenOCD+trace ETM capture driver.])
 586 ], [
 587   AC_DEFINE([BUILD_OOCD_TRACE], [0], [0 if you don't want the OpenOCD+trace ETM capture driver.])
 588 ])
 589
 590 AS_IF([test "x$build_buspirate" = "xyes"], [
 591   AC_DEFINE([BUILD_BUSPIRATE], [1], [1 if you want the Buspirate JTAG driver.])
 592 ], [
 593   AC_DEFINE([BUILD_BUSPIRATE], [0], [0 if you don't want the Buspirate JTAG driver.])
 594 ])
 595
 596 AS_IF([test "x$use_internal_jimtcl" = "xyes"], [
 597   AS_IF([test -f "$srcdir/jimtcl/configure.ac"], [
 598     AX_CONFIG_SUBDIR_OPTION([jimtcl], [--disable-install-jim])
 599   ], [
 600     AC_MSG_ERROR([jimtcl not found, run git submodule init and git submodule update.])
 601   ])
 602 ])
 603
 604 AS_IF([test "x$build_remote_bitbang" = "xyes"], [
 605   build_bitbang=yes
 606   AC_DEFINE([BUILD_REMOTE_BITBANG], [1], [1 if you want the Remote Bitbang JTAG driver.])
 607 ], [
 608   AC_DEFINE([BUILD_REMOTE_BITBANG], [0], [0 if you don't want the Remote Bitbang JTAG driver.])
 609 ])
 610
 611 AS_IF([test "x$build_sysfsgpio" = "xyes"], [
 612   build_bitbang=yes
 613   AC_DEFINE([BUILD_SYSFSGPIO], [1], [1 if you want the SysfsGPIO driver.])
 614 ], [
 615   AC_DEFINE([BUILD_SYSFSGPIO], [0], [0 if you don't want SysfsGPIO driver.])
 616 ])
 617
 618 AS_IF([test "x$build_xlnx_pcie_xvc" = "xyes"], [
 619   build_xlnx_pcie_xvc=yes
 620   AC_DEFINE([BUILD_XLNX_PCIE_XVC], [1], [1 if you want the Xilinx XVC/PCIe driver.])
 621 ], [
 622   AC_DEFINE([BUILD_XLNX_PCIE_XVC], [0], [0 if you don't want Xilinx XVC/PCIe driver.])
 623 ])
 624
 625 PKG_CHECK_MODULES([LIBUSB1], [libusb-1.0], [
 626         use_libusb1=yes
 627         AC_DEFINE([HAVE_LIBUSB1], [1], [Define if you have libusb-1.x])
 628         PKG_CHECK_EXISTS([libusb-1.0 >= 1.0.9],
 629                 [AC_DEFINE([HAVE_LIBUSB_ERROR_NAME], [1], [Define if your libusb has libusb_error_name()])],
 630                 [AC_MSG_WARN([libusb-1.x older than 1.0.9 detected, consider updating])])
 631         LIBUSB1_CFLAGS=`echo $LIBUSB1_CFLAGS | sed 's/-I/-isystem /'`
 632         AC_MSG_NOTICE([libusb-1.0 header bug workaround: LIBUSB1_CFLAGS changed to "$LIBUSB1_CFLAGS"])
 633         PKG_CHECK_EXISTS([libusb-1.0 >= 1.0.16],
 634                 [AC_DEFINE([HAVE_LIBUSB_GET_PORT_NUMBERS], [1], [Define if your libusb has libusb_get_port_numbers()])])
 635   ], [
 636         use_libusb1=no
 637         AC_MSG_WARN([libusb-1.x not found, trying legacy libusb-0.1 as a fallback; consider installing libusb-1.x instead])
 638 ])
 639
 640 PKG_CHECK_MODULES([LIBUSB0], [libusb], [use_libusb0=yes], [use_libusb0=no])
 641
 642 for hidapi_lib in hidapi hidapi-hidraw hidapi-libusb; do
 643         PKG_CHECK_MODULES([HIDAPI],[$hidapi_lib],[
 644                 use_hidapi=yes
 645                 break
 646         ],[
 647                 use_hidapi=no
 648         ])
 649 done
 650
 651 PKG_CHECK_MODULES([LIBFTDI], [libftdi1], [use_libftdi=yes], [
 652         PKG_CHECK_MODULES([LIBFTDI], [libftdi], [use_libftdi=yes], [use_libftdi=no])
 653 ])
 654
 655 PKG_CHECK_MODULES([LIBGPIOD], [libgpiod], [use_libgpiod=yes], [use_libgpiod=no])
 656
 657 PKG_CHECK_MODULES([LIBJAYLINK], [libjaylink >= 0.2],
 658         [use_libjaylink=yes], [use_libjaylink=no])
 659
 660 m4_define([PROCESS_ADAPTERS], [
 661   m4_foreach([adapter], [$1], [
 662         AS_IF([test "x$build_zy1000" = "xyes"], [
 663                 ADAPTER_VAR([adapter])=no
 664         ])
 665         AS_IF([test $2], [
 666                 AS_IF([test "x$ADAPTER_VAR([adapter])" != "xno"], [
 667                         AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [1], [1 if you want the ]ADAPTER_DESC([adapter]).)
 668                 ], [
 669                         AC_DEFINE([BUILD_]ADAPTER_SYM([adapter]), [0], [0 if you do not want the ]ADAPTER_DESC([adapter]).)
 670                 ])
 671         ], [
 672                 AS_IF([test "x$ADAPTER_VAR([adapter])" = "xyes"], [
 673                         AC_MSG_ERROR([$3 is required for the ADAPTER_DESC([adapter])])
 674                 ])
 675                 ADAPTER_VAR([adapter])=no
 676         ])
 677         AM_CONDITIONAL(ADAPTER_SYM([adapter]), [test "x$ADAPTER_VAR([adapter])" != "xno"])
 678   ])
 679 ])
 680
 681 PROCESS_ADAPTERS([USB1_ADAPTERS], ["x$use_libusb1" = "xyes"], [libusb-1.x])
 682 PROCESS_ADAPTERS([USB0_ADAPTERS], ["x$use_libusb0" = "xyes"], [libusb-0.1])
 683 PROCESS_ADAPTERS([HIDAPI_ADAPTERS], ["x$use_hidapi" = "xyes"], [hidapi])
 684 PROCESS_ADAPTERS([HIDAPI_USB1_ADAPTERS], ["x$use_hidapi" = "xyes" -a "x$use_libusb1" = "xyes"], [hidapi and libusb-1.x])
 685 PROCESS_ADAPTERS([LIBFTDI_ADAPTERS], ["x$use_libftdi" = "xyes"], [libftdi])
 686 PROCESS_ADAPTERS([LIBGPIOD_ADAPTERS], ["x$use_libgpiod" = "xyes"], [libgpiod])
 687 PROCESS_ADAPTERS([LIBJAYLINK_ADAPTERS], ["x$use_internal_libjaylink" = "xyes" -o "x$use_libjaylink" = "xyes"], [libjaylink-0.2])
 688
 689 AS_IF([test "x$build_openjtag" = "xyes"], [
 690   AS_IF([test "x$use_libusb1" != "xyes" -a "x$use_libusb0" != "xyes"], [
 691     AC_MSG_ERROR([libusb-1.x or libusb-0.1 is required for the OpenJTAG Programmer])
 692     build_openjtag=no
 693   ])
 694 ])
 695
 696 AS_IF([test "x$enable_linuxgpiod" != "xno"], [
 697   build_bitbang=yes
 698 ])
 699
 700 AS_IF([test "x$enable_stlink" != "xno" -o "x$enable_ti_icdi" != "xno" -o "x$enable_nulink" != "xno"], [
 701         AC_DEFINE([BUILD_HLADAPTER], [1], [1 if you want the High Level JTAG driver.])
 702         AM_CONDITIONAL([HLADAPTER], [true])
 703 ], [
 704         AC_DEFINE([BUILD_HLADAPTER], [0], [0 if you want the High Level JTAG driver.])
 705         AM_CONDITIONAL([HLADAPTER], [false])
 706 ])
 707 AM_CONDITIONAL([HLADAPTER_STLINK], [test "x$enable_stlink" != "xno"])
 708 AM_CONDITIONAL([HLADAPTER_ICDI], [test "x$enable_ti_icdi" != "xno"])
 709 AM_CONDITIONAL([HLADAPTER_NULINK], [test "x$enable_nulink" != "xno"])
 710
 711 AS_IF([test "x$enable_jlink" != "xno"], [
 712   AS_IF([test "x$use_internal_libjaylink" = "xyes"], [
 713     AS_IF([test -f "$srcdir/src/jtag/drivers/libjaylink/configure.ac"], [
 714       AX_CONFIG_SUBDIR_OPTION([src/jtag/drivers/libjaylink],
 715                 [--enable-subproject-build])
 716     ], [
 717       AC_MSG_ERROR([Internal libjaylink not found, run either 'git submodule init' and 'git submodule update' or disable internal libjaylink with --disable-internal-libjaylink.])
 718     ])
 719   ])
 720 ])
 721
 722 # Presto needs the bitq module
 723 AS_IF([test "x$enable_presto" != "xno"], [
 724   build_bitq=yes
 725 ])
 726
 727 AM_CONDITIONAL([RELEASE], [test "x$build_release" = "xyes"])
 728 AM_CONDITIONAL([PARPORT], [test "x$build_parport" = "xyes"])
 729 AM_CONDITIONAL([DUMMY], [test "x$build_dummy" = "xyes"])
 730 AM_CONDITIONAL([GIVEIO], [test "x$parport_use_giveio" = "xyes"])
 731 AM_CONDITIONAL([EP93XX], [test "x$build_ep93xx" = "xyes"])
 732 AM_CONDITIONAL([ZY1000], [test "x$build_zy1000" = "xyes"])
 733 AM_CONDITIONAL([ZY1000_MASTER], [test "x$build_zy1000_master" = "xyes"])
 734 AM_CONDITIONAL([IOUTIL], [test "x$build_ioutil" = "xyes"])
 735 AM_CONDITIONAL([AT91RM9200], [test "x$build_at91rm9200" = "xyes"])
 736 AM_CONDITIONAL([BCM2835GPIO], [test "x$build_bcm2835gpio" = "xyes"])
 737 AM_CONDITIONAL([IMX_GPIO], [test "x$build_imx_gpio" = "xyes"])
 738 AM_CONDITIONAL([BITBANG], [test "x$build_bitbang" = "xyes"])
 739 AM_CONDITIONAL([JTAG_VPI], [test "x$build_jtag_vpi" = "xyes" -o "x$build_jtag_vpi" = "xyes"])
 740 AM_CONDITIONAL([USB_BLASTER_DRIVER], [test "x$enable_usb_blaster" != "xno" -o "x$enable_usb_blaster_2" != "xno"])
 741 AM_CONDITIONAL([AMTJTAGACCEL], [test "x$build_amtjtagaccel" = "xyes"])
 742 AM_CONDITIONAL([GW16012], [test "x$build_gw16012" = "xyes"])
 743 AM_CONDITIONAL([OOCD_TRACE], [test "x$build_oocd_trace" = "xyes"])
 744 AM_CONDITIONAL([REMOTE_BITBANG], [test "x$build_remote_bitbang" = "xyes"])
 745 AM_CONDITIONAL([BUSPIRATE], [test "x$build_buspirate" = "xyes"])
 746 AM_CONDITIONAL([SYSFSGPIO], [test "x$build_sysfsgpio" = "xyes"])
 747 AM_CONDITIONAL([XLNX_PCIE_XVC], [test "x$build_xlnx_pcie_xvc" = "xyes"])
 748 AM_CONDITIONAL([USE_LIBUSB0], [test "x$use_libusb0" = "xyes"])
 749 AM_CONDITIONAL([USE_LIBUSB1], [test "x$use_libusb1" = "xyes"])
 750 AM_CONDITIONAL([IS_CYGWIN], [test "x$is_cygwin" = "xyes"])
 751 AM_CONDITIONAL([IS_MINGW], [test "x$is_mingw" = "xyes"])
 752 AM_CONDITIONAL([IS_WIN32], [test "x$is_win32" = "xyes"])
 753 AM_CONDITIONAL([IS_DARWIN], [test "x$is_darwin" = "xyes"])
 754 AM_CONDITIONAL([BITQ], [test "x$build_bitq" = "xyes"])
 755 AM_CONDITIONAL([USE_LIBFTDI], [test "x$use_libftdi" = "xyes"])
 756 AM_CONDITIONAL([USE_LIBGPIOD], [test "x$use_libgpiod" = "xyes"])
 757 AM_CONDITIONAL([USE_HIDAPI], [test "x$use_hidapi" = "xyes"])
 758 AM_CONDITIONAL([USE_LIBJAYLINK], [test "x$use_libjaylink" = "xyes"])
 759 AM_CONDITIONAL([RSHIM], [test "x$build_rshim" = "xyes"])
 760
 761 AM_CONDITIONAL([MINIDRIVER], [test "x$build_minidriver" = "xyes"])
 762 AM_CONDITIONAL([MINIDRIVER_DUMMY], [test "x$build_minidriver_dummy" = "xyes"])
 763
 764 AM_CONDITIONAL([INTERNAL_JIMTCL], [test "x$use_internal_jimtcl" = "xyes"])
 765 AM_CONDITIONAL([INTERNAL_LIBJAYLINK], [test "x$use_internal_libjaylink" = "xyes"])
 766
 767 # Look for environ alternatives.  Possibility #1: is environ in unistd.h or stdlib.h?
 768 AC_MSG_CHECKING([for environ in unistd.h and stdlib.h])
 769 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 770 #define _GNU_SOURCE
 771 #include <unistd.h>
 772 #include <stdlib.h>
 773   ]], [[char **ep = environ;]]
 774   )], [
 775     AC_MSG_RESULT([yes])
 776     has_environ=yes
 777   ], [
 778     AC_MSG_RESULT([no])
 779
 780     # Possibility #2: can environ be found in an available library?
 781     AC_MSG_CHECKING([for extern environ])
 782     AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 783     extern char **environ;
 784     ]], [[char **ep = environ;]]
 785       )], [
 786         AC_DEFINE(NEED_ENVIRON_EXTERN, [1], [Must declare 'environ' to use it.])
 787         has_environ=yes
 788       ], [
 789         has_environ=no
 790       ])
 791     AC_MSG_RESULT([${has_environ}])
 792   ])
 793
 794 AS_IF([test "x${has_environ}" != "xyes" ], [
 795   AC_MSG_FAILURE([Could not find 'environ' in unistd.h or available libraries.])
 796 ])
 797
 798 AC_DEFINE([_GNU_SOURCE],[1],[Use GNU C library extensions (e.g. stdndup).])
 799
 800 # set default gcc warnings
 801 GCC_WARNINGS="-Wall -Wstrict-prototypes -Wformat-security -Wshadow"
 802 AS_IF([test "x${gcc_wextra}" = "xyes"], [
 803   GCC_WARNINGS="${GCC_WARNINGS} -Wextra -Wno-unused-parameter"
 804   GCC_WARNINGS="${GCC_WARNINGS} -Wbad-function-cast"
 805   GCC_WARNINGS="${GCC_WARNINGS} -Wcast-align"
 806   GCC_WARNINGS="${GCC_WARNINGS} -Wredundant-decls"
 807 ])
 808 AS_IF([test "x${gcc_werror}" = "xyes"], [
 809   GCC_WARNINGS="${GCC_WARNINGS} -Werror"
 810 ])
 811
 812 # override default gcc cflags
 813 AS_IF([test "x$gcc_warnings" = "xyes"], [
 814   AC_SUBST([GCC_WARNINGS], [$GCC_WARNINGS])
 815 ])
 816
 817 AC_CONFIG_FILES([
 818   Makefile
 819 ])
 820 AC_OUTPUT
 821
 822 echo
 823 echo
 824 echo OpenOCD configuration summary
 825 echo --------------------------------------------------
 826 m4_foreach([adapter], [USB1_ADAPTERS, USB0_ADAPTERS,
 827         HIDAPI_ADAPTERS, HIDAPI_USB1_ADAPTERS, LIBFTDI_ADAPTERS,
 828         LIBGPIOD_ADAPTERS,
 829         LIBJAYLINK_ADAPTERS, PCIE_ADAPTERS],
 830         [s=m4_format(["%-40s"], ADAPTER_DESC([adapter]))
 831         AS_CASE([$ADAPTER_VAR([adapter])],
 832                 [auto], [
 833                         echo "$s"yes '(auto)'
 834                 ],
 835                 [yes], [
 836                         echo "$s"yes
 837                 ],
 838                 [no], [
 839                         echo "$s"no
 840         ])
 841 ])
 842 echo
 843
 844 AS_IF([test "x$build_oocd_trace" = "xyes"], [
 845   echo 'WARNING! Deprecated configure option (--enable-oocd_trace)'
 846   echo 'The oocd_trace driver is deprecated and will be removed in the next release.'
 847   echo 'If you regularly use this driver, please report to the OpenOCD Mailing List.'
 848   echo
 849 ])
 850
 851 AS_IF([test "x$build_zy1000" = "xyes" -o "x$build_zy1000_master" = "xyes"], [
 852   echo 'WARNING! Deprecated configure option (--enable-zy1000, --enable-zy1000-master)'
 853   echo 'Support for the ZY1000 platform is deprecated and will be removed in the next'
 854   echo 'release. If you regularly use this platform, please report to the OpenOCD'
 855   echo 'Mailing List.'
 856   echo
 857 ])
 858
 859 AS_IF([test "x$build_ioutil" = "xyes"], [
 860   echo 'WARNING! Deprecated configure option (--enable-ioutil)'
 861   echo 'Support for the ioutil functions is deprecated and will be removed in the next'
 862   echo 'release. If you regularly depend on this functionality, please report to the'
 863   echo 'OpenOCD Mailing List.'
 864   echo
 865 ])