tcl/fpga/xilinx-dna.cfg

   1 proc xilinx_dna_addr {chip} {
   2         array set addrs {
   3                 Spartan6 0x30
   4                 Series7 0x17
   5         }
   6         return $addrs($chip)
   7 }
   8
   9 # Get the "Device DNA".
  10 # Most Xilinx FPGA devices contain an embedded, unique device identifier.
  11 # The identifier is nonvolatile, permanently programmed into
  12 # the FPGA, and is unchangeable providing a great serial / tracking number.
  13 # This function returns the DNA as a 64 bit integer with the 7 LSBs zeroed.
  14 # This is compatible with the FUSE DNA which contains all 64 bits.
  15 proc xilinx_get_dna {tap chip} {
  16         set XC7_ISC_ENABLE 0x10
  17         set XC7_ISC_DISABLE 0x16
  18         set XC7_ISC_DNA [xilinx_dna_addr $chip]
  19
  20         irscan $tap $XC7_ISC_ENABLE
  21         runtest 64
  22         irscan $tap $XC7_ISC_DNA
  23         scan [drscan $tap 32 0 32 0] "%08x %08x" hi lo
  24         runtest 64
  25         irscan $tap $XC7_ISC_DISABLE
  26         runtest 64
  27         # openocd interprets DR scans as LSB first, bit-reverse it
  28         return [scan [string reverse [format "%032b%032bb0" $lo $hi]] "%i"]
  29 }
  30
  31 # Print out the "Device DNA" in the same format that impact uses.
  32 proc xilinx_print_dna {dna} {
  33         set dna [expr $dna >> 64 - 57]
  34         echo [format "DNA = %057b (0x%016x)" $dna $dna]
  35 }
  36
  37 proc xc7_get_dna {tap} {
  38         return [xilinx_get_dna $tap Series7]
  39 }
  40
  41 proc xc6s_get_dna {tap} {
  42         return [xilinx_get_dna $tap Spartan6]
  43 }